財務函式第二部分

返回財務函式第一部份

繼續參閱財務函式第3部分

CUMIPMT

計算累計利息支付，也就是根據恆定利率投資的總利息。

CUMIPMT(Rate; NPer; PV; S; E; Type)

rate 決定週期利率。

NPer 是指總付款期數。NPER 也可以是非整數值。

PV 是指連續支付的目前價值。

S 是指第一期。

E 是指最後一期。

Type 指定支付的到期日是每期的期初或期末。

以年利率 5.5% 計算，2 年中每月支付一次，目前現金值是 5000 貨幣單位，則應支付多少利息？時間範圍從第 4 個週期開始，到第 6 個週期結束。每個週期的開始時支付。

=CUMIPMT(5.5%/12;24;5000;4;6;1) = -57.54 貨幣單位。第 4 期到第 6 期的利息支付為 57.54 貨幣單位。

CUMIPMT_ADD

計算週期的累計利息。

CUMIPMT_ADD(Rate; NPer; PV; StartPeriod; EndPeriod; Type)

Rate 是指每期的利率。

NPer 是指總付款期數。利率與 NPER 必須使用相同的單位，因此兩者皆須每年或每月計算。

PV 是指目前價值。

StartPeriod 是指計算的第一個付款期。

EndPeriod 是指計算的最後一個付款期。

Type 指定支付是在每期期末到期 (Type = 0) 或在每期期初到期 (Type = 1)。

以一棟取得下列地產抵押貸款的房子為例：

利率：每年 9.00% (9% / 12 = 0.0075)，週期期限:30 年 (NPER = 30 * 12 = 360)，Pv：125000 貨幣單位。

在此地產抵押貸款的第二年 (也就是在第 13 期到第 24 期) 支付週期中需付的利息金額為何？

=CUMIPMT_ADD(0.0075;360;125000;13;24;0) 傳回 -11135.23。

第一個月要支付多少利息？

=CUMIPMT_ADD(0.0075;360;125000;1;1;0) 傳回 -937.50。

CUMPRINC

傳回具有恆定利率的投資週期之累計已付利息。

CUMPRINC(Rate; NPer; PV; S; E; Type)

rate 決定週期利率。

NPer 是指總付款期數。NPER 也可以是非整數值。

PV 是指連續支付的目前價值。

S 是指第一期。

E 是指最後一期。

Type 指定支付的到期日是每期的期初或期末。

假定一項貸款的年利率為 5.5% 且必須在 36 個月內完成償付，那麼分期償還額是多少呢？現金值是 15,000 貨幣單位。計算第 10 個至第 18 個週期內應支付的分期償還額。到期日是週期結束時。

=CUMPRINC(5.5%/12;36;15000;10;18;0) = -3669.74 貨幣單位。第 10 期到第 18 期的應付分期償還總額為 3669.74 貨幣單位。

CUMPRINC_ADD

計算一定週期內貸款的類累計贖回。

CUMPRINC_ADD(Rate; NPer; PV; StartPeriod; EndPeriod; Type)

Rate 是指每期的利率。

NPer 是指總付款期數。利率與 NPER 必須使用相同的單位，因此兩者皆須每年或每月計算。

PV 是指目前價值。

StartPeriod 是指計算的第一個付款期。

EndPeriod 是指計算的最後一個付款期。

Type 指定支付是在每期期末到期 (Type = 0) 或在每期期初到期 (Type = 1)。

以一棟取得下列地產抵押貸款的房子為例：

利率：每年 9.00% (9% / 12 = 0.0075)，貸款償還期：30年(支付週期數 = 30 * 12 = 360)，現金值：125000 元。

在此地產抵押貸款的第二年 (也就是在第 13 期到第 24 期) 支付週期中，每一期清償金額多高？

=CUMPRINC_ADD(0.0075;360;125000;13;24;0) 傳回 -934.1071

在第一個月中，您支付的償還金額總和如下：

=CUMPRINC_ADD(0.0075;360;125000;1;1;0) 傳回 -68.27827

DOLLARDE

將以十進制分數格式給出的引用轉換為十進制數字。

DOLLARDE(FractionalDollar; Fraction)

FractionalDollar 是以十進制分數指定的數字。

Fraction 是用為十進位分數分母的整數。

=DOLLARDE(1.02;16) 表示 1 又 2/16。由此得出 1.125。

=DOLLARDE(1.1;8) 表示 1 又 1/8。由此得出 1.125。

DOLLARFR

將指定為十進制數字的引用轉換為混合十進制分數。

DOLLARFR(DecimalDollar; Fraction)

DecimalDollar 是小數。

Fraction 是用為十進位分數分母的整數。

=DOLLARFR(1.125;16) 將小數轉換為十六分之幾。結果是 1.02 (1 又 2/16)。

=DOLLARFR(1.125;8) 將小數轉換為八分之幾。結果是 1.1 (1 又 1/8)。

MDURATION

計算固定利率的債券之 Macauley 修正年限。

MDURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Coupon 是指名義年利率 (殖利率)

Yield 是指有價證券的年收益率。

Frequency 是指年付息次數 (1、2 或 4)。

於 2001 年 1 月 1 日購入一張有價證券；到期日為 2006 年 1 月 1 日。名義利率為 8%，收益率為 9.0%。半年支付利息一次 (頻率為 2)。若使用日結餘利息計算 (底數 3)，則修改的持續期間為多長？

=MDURATION("2001-01-01"; "2006-01-01"; 0.08; 0.09; 2; 3) returns 4.02 years.

MIRR

計算一系列投資的修改內部收益率。

MIRR(Values; Investment; ReinvestRate)

Values 對應至其內容對應支付項目之儲存格的陣列或儲存格參照。

Investment 是指投資的利率 (陣列的負值)

ReinvestRate：轉投資的利率 (陣列的正值)

假設 A1 的儲存格內容 = -5，A2 = 10，A3 = 15，A4 = 8，投資值為 0.5，而轉投資值為 0.1，則結果為 94.16%。

NOMINAL

計算名義年利率、指定的實際利率與每年複合週期的數字。

NOMINAL(EffectiveRate; NPerY)

EffectiveRate 是指實際利率

NPerY 是指年定期付息次數。

有效利率為 13.5%，每年利息支付次數為 12，則年名義利率是多少？

=NOMINAL(13.5%;12) = 12.73%。名義年利率為 12.73%。

NOMINAL_ADD

依據實際利率和年付息次數計算名義年利率。

NOMINAL_ADD(EffectiveRate; NPerY)

EffectiveRate 是指有效的年利率。

NPerY 是指年付息次數。

一個實際年利率為 5.3543% ，按每三個月為支付週期的年名義利率是多少？

=NOMINAL_ADD(5.3543%;4) 傳回 0.0525 或 5.25%。

NPV

Returns the present value of an investment based on a series of periodic cash flows and a discount rate. To get the net present value, subtract the cost of the project (the initial cash flow at time zero) from the returned value.

If the payments take place at irregular intervals, use the XNPV function.

NPV(Rate; Number 1 [; Number 2 [; … [; Number 254]]])

Rate 是指週期的折扣率。

What is the net present value of periodic payments of 10, 20 and 30 currency units with a discount rate of 8.75%. At time zero the costs were paid as -40 currency units.

=NPV(8.75%;10;20;30) = 49.43 貨幣單位。淨現值是報酬值減去初始成本 40 貨幣單位，由此得出 9.43 貨幣單位。

PDURATION

計算為了獲得所需值而需要投資的週期數。

PDURATION(Rate; PV; FV)

Rate 是一個常數。利率會以整個持續時間 (持續期間) 進行計算。每期利率的計算方式是利率除以計算的期間。內部年金率會輸入為 Rate/12。

PV 是指現值 (目前價值)。現金價值是現金存款或抵銷類型的目前現金值。若是存款值，必須輸入正值；存款不得為 0 或 <0。

FV 是指預期值。未來價值會決定存款所需的值 (未來價值)。

利率為 4.75%、現值為 25,000 元以及預期值為 1.000.000 元時，可算出貸款償還期為 79.49 個支付期。把投資未來值除以所需的投資期間，得到每期的支付金額，即是：1,000,000/79.49=12,580.20

PMT

傳回具有恆定利率的年金分期支付額。

PMT(Rate; NPer; PV [ ; [ FV ] [ ; Type ] ])

rate 決定週期利率。

NPer 是指支付年金的期數。

PV 是指連續支付的現值 (現金價值)。

FV (選擇性) 是指定期付款結束時達到的所需值 (未來價值)。

Type (選擇性) 指定定期支付的到期日期。Type=1 表示每期期初支付，而 Type=0 表示每期期末支付。

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

如果支付週期為 3 年，現金值為 25,000 貨幣單位，以年利率 1.99% 計算，分期支付額是多少？已知有 36 個月，即支付的週期數是 36，每個支付週期的利率為 1.99%/12。

=PMT(1.99%/12;36;25000) = -715.96 貨幣單位。每月分期付款的結果為 715.96 貨幣單位。

PPMT

在定期等額支付和恒定利率的條件下，計算一項投資在指定週期的支付金額。

PPMT(Rate; Period; NPer; PV [ ; FV [ ; Type ] ])

rate 決定週期利率。

Period 是指償還週期。P = 1 代表第一期，P = NPer 代表最後一期。

NPer 是指支付年金的總期數。

PV 是指連續支付的現值。

FV (選擇性) 是指所需的值 (未來價值)。

Type (選擇性) 定義到期日。F = 1 表示於期初支付，而 F = 0 表示於期末支付。

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

3 年的分期付款，以年利率 8.75% 計算，每月應支付多少？現金值為 5000 貨幣單位，並且一律在每個週期開始時支付。則未來值為 8000 貨幣單位。

=PPMT(8.75%/12;1;36;5000;8000;1) = -350.99 貨幣單位

PRICE

以作為預測收益函式的 100 貨幣單位等值來計算固定利息債券的市值。

PRICE(Settlement; Maturity; Rate; Yield; Redemption; Frequency [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Rate 是指名義年利率 (票面利率)

Yield 是指有價證券的年收益率。

Redemption 是指票面價值 100 貨幣單位的贖回價值。

Frequency 是指年付息次數 (1、2 或 4)。

於 1999 年 2 月 15 日購入一張有價證券；到期日為 2007 年 11 月 15 日。名義利率為 5.75%，收益率為 6.5%。贖回價值為 100 貨幣單位。利息每半年支付一次 (頻率為 2)。以 0 為底數計算價格如下：

=PRICE("1999-02-15"; "2007-11-15"; 0.0575; 0.065; 100; 2; 0) returns 95.04287.

PRICEDISC

計算不附息債券同等值票面價值 100 貨幣單位的價格。

PRICEDISC(Settlement; Maturity; Discount; Redemption [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Discount 是指有價證券的折扣率 (以百分比為單位)。

Redemption 是指票面價值 100 貨幣單位的贖回價值。

於 1999 年 2 月 15 日購入一張有價證券；到期日為 1999 年 3 月 1 日。折扣百分比為 5.25%，贖回價值為 100。根據底數 2 進行計算，價格折扣如下：

=PRICEDISC("1999-02-15"; "1999-03-01"; 0.0525; 100; 2) returns 99.79583.

PRICEMAT

計算在到期日期支付利息的債券等值票面價值為 100 貨幣單位的價格。

PRICEMAT(Settlement; Maturity; Issue; Rate; Yield [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Issue 是指有價證券的發行日期。

Rate 是指有價證券在發行日期時的利率。

Yield 是指有價證券的年收益率。

購入日：1999 年 2 月 15 日，到期日：1999 年 4 月 13 日，發行日期：1998 年 11 月 11 日，利率：6.1%，年收益率：6.1%，基準：30/360 = 0。

實際價格計算方式如下：

=PRICEMAT("1999-02-15";"1999-04-13";"1998-11-11"; 0.061; 0.061;0) returns 99.98449888.

SLN

傳回一個週期中資產的直線折舊。在折舊期間內折舊的金額固定。

SLN(Cost; Salvage; Life)

Cost 是指資產的最初成本。

Salvage 是指資產在折舊結束後的價值。

Life 是指決定資產折舊期數的折舊期。

購買價值為 50,000 元的辦公設備超過 7 年後開始每年折舊。剩餘價值為 3,500 元。

=SLN(50000;3,500;84) = 553.57 貨幣單位。辦公室設備每月分期折舊金額為 553.57 貨幣單位。

TBILLEQ

Calculates the annual return on a treasury bill. A treasury bill is purchased on the settlement date and sold at the full par value on the maturity date, that must fall within the same year. A discount is deducted from the purchase price.

TBILLEQ(Settlement; Maturity; Discount)

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Discount 是指購買有價證券的折扣百分比。

購入日：1999 年 3 月 31日，到期日：1999 年 6 月 1 日，貼現率：9.14%。

比照有價證券的國庫券利息計算方式如下：

=TBILLEQ("1999-03-31";"1999-06-01"; 0.0914) returns 0.094151 or 9.4151 per cent.

TBILLPRICE

計算每 100 貨幣單位的國庫券價格。

TBILLPRICE(Settlement; Maturity; Discount)

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Discount 是指購買有價證券的折扣百分比。

購入日：1999 年三月 31日，到期日：1999 年六月 1 日，貼現率：9%。

國庫券實際價格的計算方式如下：

=TBILLPRICE("1999-03-31";"1999-06-01"; 0.09) returns 98.45.

TBILLYIELD

計算國庫券的收益。

TBILLYIELD(Settlement; Maturity; Price)

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Price 是指票面價值 100 貨幣單位的國庫券價格 (購買價格)。

購入日：1999 年 3 月 31 日，到期日：1999 年 6 月 1 日，實際價格：98.45 貨幣單位。

國庫券年收益率的計算方式如下：

=TBILLYIELD("1999-03-31";"1999-06-01"; 98.45) returns 0.091417 or 9.1417 per cent.

YIELD

計算債券的收益。

YIELD(Settlement; Maturity; Rate; Price; Redemption; Frequency [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Rate 是指年利率。

Price 是指票面價值 100 貨幣單位的有價證券價格 (購買價格)。

Redemption 是指票面價值 100 貨幣單位的贖回價值。

Frequency 是指年付息次數 (1、2 或 4)。

於 1999 年 2 月 15 日購入一張有價證券。2007 年 11 月 15 日到期。利率為 5.75%。每 100 貨幣單位的票面價值為 95.04287，贖回價值為 100 單位。半年付息一次(即頻率為 2)，且底數為 0。則收益率多高？

=YIELD("1999-02-15"; "2007-11-15"; 0.0575 ;95.04287; 100; 2; 0) returns 0.065 or 6.50 per cent.

YIELDDISC

計算不附息債券的年收益。

YIELDDISC(Settlement; Maturity; Price; Redemption [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Price 是指票面價值 100 貨幣單位的有價證券價格 (購買價格)。

Redemption 是指票面價值 100 貨幣單位的贖回價值。

於 1999 年 2 月 15 日購入一張無息有價證券。到期日為 1999 年 3 月 1 日。每票面價值 100 單位為 99.795 貨幣單位，贖回價值為 100 單位。底數為 2。則收益率多高？

=YIELDDISC("1999-02-15"; "1999-03-01"; 99.795; 100; 2) returns 0.052823 or 5.2823 per cent.

YIELDMAT

計算債券的年收益，而債券的利息在到期日支付。

YIELDMAT(Settlement; Maturity; Issue; Rate; Price [; Basis])

Settlement 是指有價證券的購買日期。

Maturity 是指有價證券的到期 (過期) 日期。

Issue 是指有價證券的發行日期。

Rate 是指有價證券在發行日期時的利率。

Price 是指票面價值 100 貨幣單位的有價證券價格 (購買價格)。

於 1999 年 3 月 15 日購入一張有價證券，到期日為 1999 年 11 月 3 日。發行日期為 1998 年 11 月 8 日。利率以 6.25% 計算，實際價格則以 100.0123 單位計算。底數為 0。則收益率多高？

=YIELDMAT("1999-03-15"; "1999-11-03"; "1998-11-08"; 0.0625; 100.0123; 0) returns 0.060954 or 6.0954 per cent.

返回財務函式第一部份

繼續參閱財務函式第3部分