資訊函式

此分類包含統計函式。

在函式描述中，有些範例使用了下表中的資料：

	C	D
2	x value	y value
3	-5	-3
4	-2	0
5	-1	1
6	0	3
7	2	4
8	4	6
9	6	8

CELL

傳回儲存格的位置、格式或內容等資訊。

CELL("InfoType" [; Reference])

InfoType 是指規定資訊類型的字元字串。字元字串一律為英文。可選擇使用大寫或小寫。

InfoType	描述
COL	傳回某一個引用欄的數目。 =CELL("COL";D2) 傳回 4。
ROW	傳回某一個引用列的數目。 =CELL("ROW";D2) 傳回 2。
SHEET	傳回某一引用的試算表的號碼。 =CELL("Sheet";Sheet3.D2) 傳回 3。
ADDRESS	傳回某一引用儲存格的絕對地址。 =CELL("ADDRESS";D2) 傳回 $D$2。 =CELL("ADDRESS";Sheet3.D2) 傳回 $Sheet3.$D$2。 =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.$D$2.
FILENAME	傳回某一引用儲存格的試算表名稱及檔案名。 =CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.
COORD	Returns the complete cell address in Lotus™ notation. =CELL("COORD"; D2) 傳回 $A:$D$2。 =CELL("COORD"; Sheet3.D2) 傳回 $C:$D$2。
CONTENTS	傳回一個不帶任何格式的引用儲存個的内容。
TYPE	傳回儲存個内容的類型 b = blank 表示空白的儲存格 l = label 表示文字，也就是公式的結果當作文字顯示出來。 v = value 表示數值，也就是公式的結果當作數值顯示出來。
WIDTH	傳回引用欄的寬度。其單位是儲存個容納零(0)的數目, 字元大小是標準大小。
PREFIX	傳回某一儲存格的文字對齊格式。 ' = 靠左對齊或跨欄置中 " = 靠右對齊 ^ = 置中 \ = 填滿對齊的文字 (目前尚未使用)
PROTECT	傳回某一儲存格被鎖定保護的狀態。 1 = 儲存格已被鎖定保護 0 = 儲存格尚未被鎖定保護
FORMAT	傳回一個說明數字格式的字串。 , = 含有千分符的數字 F = 無千分符的數字 C = 貨幣格式 S = 指數表示方式，如 1.234+E56 P = 百分數 在上述格式中，小數分隔符後的小數位數以數字形式指定。範例：數字格式 #,##0.0 傳回 ,1，而數字格式 00.000% 傳回 P3 D1 = MMM-D-YY, MM-D-YY 及類似的格式。 D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = 所有其它格式 - (負號)在結尾 = 負數字用顏色顯示出來。 () (一對括號)在結尾 = 一個格式碼之中使用的開口式括號
COLOR	傳回 1 ，如果負數字用顏色顯示出來，否則傳回 0 。
PARENTHESES	傳回 1 ，如果在格式碼之中使用了一個開口式括號 ( ，否則傳回 0 。

reference (選擇性)為要檢查的儲存格的位置。reference 為一個範圍、涉及到範圍左上方的儲存格。如果不使用 reference 參數，LibreOffice Calc 就會佔用儲存格公式的所在位置。Microsoft Excel 使用游標所在儲存格的引用。

CURRENT

此函式會傳回所屬公式迄今的計算結果 (亦即到目前為止的計算結果)。其主要用途在於搭配 STYLE() 函式根據儲存格內容，將選定的樣式套用至儲存格。

CURRENT

=1+2+CURRENT()

範例傳回 6。從左至右計算公式：1 + 2 = 3，得出發生 CURRENT() 時的迄今結果；CURRENT() 由此得出 3，加上原始的 3 等於 6。

=A2+B2+STYLE(IF(CURRENT()>10;"Red";"Default"))

範例傳回 A2 + B2 (STYLE 在此傳回 0)。若總和大於 10，會將 Red 樣式套用至儲存格。如需更多說明，請參閱 STYLE 函式。

="choo"&CURRENT()

範例傳回 choochoo。

ORG.OPENOFFICE.CURRENT

FORMULA

將公式儲存格的公式顯示為文字字串。

FORMULA(Reference)

Reference 是包含公式的儲存格參照。

無效的參照或對無公式儲存格的參照，會導致錯誤值 #N/A。

若儲存格 A8 包含公式 =SUM(1;2;3)，則

=FORMULA(A8) 傳回文字 =SUM(1;2;3)。

ISBLANK

如果儲存格的參照是空白的，則傳回 TRUE。此函式用於確定儲存格的內容是否為空。內部具有公式的儲存格，其內容不為空。

ISBLANK(Value)

value 是指要測試的內容。

=ISBLANK(D2) 傳回結果為 FALSE。

ISERR

測試錯誤條件 (#N/A 錯誤值除外)，並傳回 TRUE 或 FALSE。

ISERR(Value)

Value 可以是任何值或表示式，透過測試這個值或表示式可查看是否存在 #N/A 之外的錯誤值。

=ISERR(C8) (其中儲存格 C8 包含 =1/0) 傳回 TRUE，因為 1/0 是錯誤。

=ISERR(C9) (其中儲存格 C9 包含 =NA()) 傳回 FALSE，因為 ISERR() 忽略 #N/A 錯誤。

ISERROR

測試錯誤條件 (包括 #N/A 錯誤值)，並傳回 TRUE 或 FALSE。

ISERROR(Value)

Value 是 (或代表) 要測試的數值。若有錯誤，ISERROR() 傳回 TRUE，沒有錯誤則傳回 FALSE。

=ISERROR(C8) (其中儲存格 C8 包含 =1/0) 傳回 TRUE，因為 1/0 是錯誤。

=ISERROR(C9) (其中儲存格 C9 包含 =NA()) 傳回 TRUE。

ISERROR

Returns the value if the cell does not contain an error value, or the alternative value if it does.

IFERROR(Value; Alternate_value)

Value is the value or expression to be returned if it is not equal or results in an error.

Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an error.

=ISERROR(C8) (其中儲存格 C8 包含 =1/0) 傳回 TRUE，因為 1/0 是錯誤。

=ISERROR(C8) (其中儲存格 C8 包含 =1/0) 傳回 TRUE，因為 1/0 是錯誤。

ISEVEN

如果數值是偶數整數，則傳回 TRUE；如果是奇數，則傳回 FALSE。

ISEVEN(Value)

Value 是要檢查的數值。

若 Value 不是整數，則將忽略小數點後的所有位數。同時也會忽略 Value 的正負號。

=ISEVEN(48) 傳回 TRUE。

=ISEVEN(33) 傳回 FALSE。

=ISEVEN(0) 傳回 TRUE。

=ISEVEN(-2.1) 傳回 TRUE。

=ISEVEN(3.999) 傳回 FALSE。

ISEVEN_ADD

偶數的測試。如果數字除以 2 得出一個整數，則傳回 1。

ISEVEN_ADD(Number)

Number 是測試的數值。

=ISEVEN_ADD(5) 傳回 0。

若儲存格 A1 包含數字 2，則 =ISEVEN_ADD(A1) 傳回 1。

ISFORMULA

如果儲存格是公式儲存格則傳回 TRUE。

ISFORMULA(Reference)

[參照] 指定要在其中進行測試以決定是否包含公式的儲存格參照。

若儲存格 C4 包含數字 5，則 =ISFORMULA(C4) 傳回 FALSE。

ISLOGICAL

測試邏輯值 (TRUE 或 FALSE)。

若發生錯誤，則函式會傳回 FALSE。

ISLOGICAL(Value)

如果 Value 是邏輯值 (TRUE 或 FALSE)，即傳回 TRUE，否則傳回 FALSE。

=ISLOGICAL(99) 傳回 FALSE，因為 99 是數字，不是邏輯值。

不論儲存格 D4 的內容為何，=ISLOGICAL(ISNA(D4)) 一律會傳回 TRUE，因為 ISNA() 傳回邏輯值。

ISNA

如果儲存格包含 #N/A (數值不存在) 的錯誤值則傳回 TRUE。

若發生錯誤，則函式會傳回 FALSE。

ISNA(Value)

value 是要檢查的數值或表示式。

=ISNA(D3) 傳回結果為 FALSE。

ISNA

Returns the value if the cell does not contain the #N/A (value not available) error value, or the alternative value if it does.

IFNA(Value; Alternate_value)

Value is the value or expression to be returned if it is not equal or results in an #N/A error.

Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an #N/A error.

=IFNA(D3;D4) returns the value of D3 if D3 does not result in an #N/A error, or D4 if it does.

ISNONTEXT

測試儲存格內容是否為文字或數字，如果內容是文字，則傳回 FALSE。

若發生錯誤，則函式會傳回 TRUE。

ISNONTEXT(Value)

value 為一個數值或表示式，要利用它檢查是否與文字或數字或布氏值相關。

若儲存格 D2 包含文字 abcdef，則 =ISNONTEXT(D2) 傳回 FALSE。

若儲存格 D9 包含數字 8，則 =ISNONTEXT(D9) 傳回 TRUE。

ISNUMBER

如果值表示數字則傳回 TRUE。

ISNUMBER(Value)

value 是指要被測試以確定其是數字還是文字的任意表達式。

若儲存格 C3 包含數字 4，則 =ISNUMBER(C3) 傳回 TRUE。

若儲存格 C2 包含文字 abcdef，則 =ISNUMBER(C2) 傳回 FALSE。

ISODD

如果數值是奇數，則傳回 TRUE；如果是偶數，則傳回 FALSE。

ISODD(value)

Value 是要檢查的數值。

若 Value 不是整數，則將忽略小數點後的所有位數。同時也會忽略 Value 的正負號。

=ISODD(33) 傳回 TRUE。

=ISODD(48) 傳回 FALSE。

=ISODD(3.999) 傳回 TRUE。

=ISODD(-3.1) 傳回 TRUE。

ISODD_ADD

如果數字不能被 2 整除，則傳回 TRUE (1)。

ISODD_ADD(number)

Number 是測試的數值。

=ISODD_ADD(5) 傳回 1。

ISREF

測試引數是否為參照。若引數為參照，會傳回 TRUE；否則會傳回 FALSE。指定參照時，此函式不會檢查正在參照的值。

ISREF(Value)

value 是指要被測試以確定其是否為參照的值。

=ISREF(C5) 傳回結果為 TRUE，因為 C5 是有效的參照。

=ISREF("abcdef") 一律會傳回 FALSE，因為文字永遠不可能成為參照。

=ISREF(4) 傳回 FALSE。

=ISREF(INDIRECT("A6")) 傳回 TRUE，因為 INDIRECT 是傳回參照的函式。

=ISREF(ADDRESS(1; 1; 2;"Sheet2")) 傳回 FALSE，因為儘管看起來像是參照，ADDRESS 其實是傳回文字的函式。

ISTEXT

如果儲存格內容表示文字則傳回 TRUE。

若發生錯誤，則函式會傳回 FALSE。

ISTEXT(Value)

value 為一個數值、數字、布氏值或錯誤值，要用來檢查是否與文字或數字相關。

若儲存格 D9 包含文字 abcdef，則 =ISTEXT(D9) 傳回 TRUE。

若儲存格 C3 包含數字 3，則 =ISTEXT(C3) 傳回 FALSE。

N

Returns the numeric value of the given parameter. Returns 0 if parameter is text or FALSE.

If an error occurs the function returns the error value.

N(Value)

Value is the parameter to be converted into a number. N() returns the numeric value if it can. It returns the logical values TRUE and FALSE as 1 and 0 respectively. It returns text as 0.

=N(123) 傳回 123

=N(TRUE) 傳回 1

=N(FALSE) 傳回 0

=N("abc") 傳回 0

=N(1/0) 傳回 #DIV/0!

NA

傳回錯誤值 #N/A。

NA()

=NA() 會將儲存格內容轉換成 #N/A。

TYPE

Returns the type of value, where 1 = number, 2 = text, 4 = Boolean value, 8 = formula, 16 = error value, 64 = array.

TYPE(Value)

Value is a specific value for which the data type is determined.

範例 (請參照上方範例表格)

=TYPE(C2) 傳回結果為 2。

=TYPE(D9) 傳回結果為 1。

資訊

傳回目前工作環境的特定資訊。此函式會收到單一文字引數，並視該參數傳回資料。

INFO("Type")

下表列出文字參數 Type 的值，以及 INFO 函式的傳回值。

「Type」的值	傳回值
"osversion"	因相容性原因，一律為 Windows (32-bit) NT 5.01
"system"	The type of the operating system: "ANDROID" for Google mobile operating system "DRAGONFLY" for DragonFly operating system forked from FreeBSD "EMSCRIPTEN" for browser WebAssembly system "FREEBSD", "OPENBSD" or "NETBSD" for operating systems based on the Berkeley Software Distribution (BSD) "HAIKU" for BeOS compatible operating system "iOS" for Apple mobile operating system "LINUX" for GNU/Linux based operating systems "MACOSX" for Apple macOS "SOLARIS" for Oracle Solaris operating system "WNT" for Microsoft Windows
"release"	產品發行版本的識別碼，例如「300m25(Build:9876)」
"numfile"	因相容性原因，一律為 1
"recalc"	目前的公式重新計算模式為「自動」或「手動」(本土化為 LibreOffice 語言)

=INFO("release") 傳回使用中的 LibreOffice 之產品版本編號。

若儲存格 D5 包含文字字串 system，則 =INFO(D5) 會傳回作業系統類型。