財務函式第一部分
此分類包含 LibreOffice Calc 的數學財務函式。
ACCRINT
計算債券分期支付時的應計利息。
ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])
Issue 是指有價證券的發行日期。
FirstInterest 是指有價證券的第一個計息日。
Settlement 是利息的應計日期。
Rate 是指名義年利率 (票面利率)
Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.
We recommend that you always specify the value that you require for ACCRINT’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.
Frequency 是指年付息次數 (1、2 或 4)。
於 2001 年 2 月 28 日公開發行一張有價證券。第一次配息設在 2001 年 8 月 31 日，交割日期為 2001 年 5 月 1 日。利率為 0.1 或 10%，票面價值為 1000 貨幣單位。半年付息一次 (頻率為 2)。基數為美式 (0)，應計利息為多少？
=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) 傳回 16.94444。
ACCRINTM
計算在結算日期一次性支付的債券之應計利息。
ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])
Issue 是指有價證券的發行日期。
Settlement 是利息的應計日期。
Rate 是指名義年利率 (票面利率)。
Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.
We recommend that you always specify the value that you require for ACCRINTM’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.
於 2001 年 4 月 1 日公開發行一張有價證券。到期日定於 2001 年 6 月 15 日。年利率為 0.1 或 10%，票面價值為 1000 貨幣單位。計算利息的年/天數基數為實際天數 (3)。應計利息為多少？
=ACCRINTM("2001-04-01";"2001-06-15";0.1;1000;3) 傳回 20.54795。
AMORDEGRC
計算一個結算週期內遞減分攤的折舊金額。與 AMORLINC 不同的是，此處使用了與折舊年限無關的折舊係數。
AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])
Cost 是指購買成本。
DatePurchased 是指購買日期。
FirstPeriod 是指第一期結算的結束日期。
Salvage 是指資本資產在折舊年限結束時的剩餘價值。
Period 是指考量的結算期間。
Rate 是指折舊率。
An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?
=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 163 currency units.
Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.
AMORLINC
計算一個結算週期內線性分攤的折舊金額。如果在結算週期內購入了資本資產，則會考量一定比例的折舊金額。
AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])
Cost 是指購買成本。
DatePurchased 是指購買日期。
FirstPeriod 是指第一期結算的結束日期。
Salvage 是指資本資產在折舊年限結束時的剩餘價值。
Period 是指考量的結算期間。
Rate 是指折舊率。
An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming linear depreciation, what is the amount of depreciation in the fourth depreciation period?
=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 200 currency units.
Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.
DB
使用算術遞減法，傳回指定期限內資產的折舊金額。
如果您 (和線形折舊相反) 想要取得在折舊開始時較高的折舊值，則請使用此折舊格式。折舊值在每一折舊時間範圍都會根據已從資產值減去的折舊減少。
DB(Cost; Salvage; Life; Period [; Month])
Cost 是指資產的最初成本。
Salvage 是指資產在折舊結束後的價值。
Life 定義資產的使用期間，一旦超過使用期間資產便會開始折舊。
Period 為每個週期的長度。長度必須以和折舊期間相同的日期單位輸入。
Month (可選擇) 為折舊第一年中的月數。若未定義此項目，會採用預設值 12。
A computer system with an initial cost of 25,000 currency units is to be depreciated over a three-year period. The salvage value is to be 1,000 currency units. The first period of depreciation comprises 6 months. What is the fixed-declining balance depreciation of the computer system in the second period, which is a full year starting from the end of the first six-month period?
=DB(25000; 1000; 3; 2; 6) returns 11,037.95 currency units.
DDB
使用算術遞減法，傳回指定期限內資產的折舊金額。
如果您希望得到比線性折舊法更高的初始折舊值，請使用這種折舊方式。其折舊值在每個週期內逐次遞減，這種方式通常用於購買後在短期內價值損失非常大的資產 (例如汽車、電腦)。請註意，採用這種方式計算的帳面價值永不可能為零。
DDB(Cost; Salvage; Life; Period [; Factor])
Cost 固定為資產的期初成本。
Salvage 固定為資產於週期結束後的剩餘價值。
Life 為定義資產要使用的期數 (例如，年或月)。
Period 說明數值的計算期間。
Factor (可選擇) 為折舊減少的係數。若未輸入數值，則為係數預設值 2。
一筆成本為 75.000 元的電腦設備應於超過 5 年後按月折舊。剩餘價值為 1 元。係數為 2。
=DDB(75000;1;60;12;2) = 1,721.81 貨幣單位。因此，購買後第十二個月的雙倍遞減折舊金額為 1,721.81 貨幣單位。
DISC
計算債券的折扣 (貼現) 百分比。
DISC(Settlement; Maturity; Price; Redemption [; Basis])
Settlement 是指有價證券的購買日期。
Maturity 是指有價證券的到期 (過期) 日期。
Price 是指票面價值每 100 貨幣單位的有價證券價格。
Redemption 是指票面價值 100 貨幣單位的有價證券之贖回價值。
於 2001 年 1 月 25 日購入一張有價證券；到期日為 2001 年 11 月 15 日。實際價格 (購入價) 為 97，贖回價格為 100。若以實際天數計算 (基數 3)，則償付率 (貼現率) 多高？
=DISC("2001-01-25";"2001-11-15";97;100;3) 傳回約 0.0372 或 3.72%。
DURATION
計算固定利率的債券之年限。
DURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])
Settlement 是指有價證券的購買日期。
Maturity 是指有價證券的到期 (過期) 日期。
Coupon 是指年票面利率 (利息的名義利率)
Yield 是指有價證券的年收益率。
Frequency 是指年付息次數 (1、2 或 4)。
於 2001 年 1 月 1 日購入一張有價證券；到期日為 2006 年 1 月 1 日。票面利率為 8%，收益率為 9.0%。半年支付利息一次 (頻率為 2)。若使用日結餘利息計算 (基數 3)，則持續期間為多長？
=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3) returns 4.2 years.
EFFECT
傳回名義利率的淨年利率。
因為名義利率和計算時間範圍結束的利息到期日期相關，利息通常會每月按照比例在計算時間範圍結束前的一季或一其他時間範圍到期，也就是實際上預先支付，因此實際利息會隨利息貼現款項提昇。
EFFECT(Nom; P)
Nom 是指名義利息。
P 是指年付息週期數。
如果年名義利率為 9.75%，且設定四個利息計算時間範圍，則實際上利率 (實際利息) 為多高？
=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.
EFFECT_ADD
依據名義利率和年付息次數計算實際年利率。
The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.
EFFECT_ADD(NominalRate; NPerY)
NominalRate 為名義年利率。
NPerY 是指每年付息的次數。
5.25% 年利率與按季支付時，實際利息為何？
=EFFECT_ADD(0.0525;4) 傳回 0.053543 或 5.3543%。
IRR
計算一項投資的內部收益率。這些值表示常規時間間隔內的現金流值，其中至少要有一個值為負值 (支出)，且至少要有一個值為正值 (收入)。
If the payments take place at irregular intervals, use the XIRR function.
IRR(Values [; Guess])
Values 代表包含數值的陣列。
Guess (可選擇) 為估計值。是一種用於計算內部收益率的反覆運算方法。若您僅可以提供幾個數值，則應提供一個初始估值，以啟用反覆運算。
This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.
在假設儲存格內容為 A1=-10000、A2=3500、A3=7600 且 A4=1000 的情況下，公式 =IRR(A1:A4) 會得出結果為 11.33%。
Because of the iterative method used, it is possible for IRR to fail and return Error 523, with "Error: Calculation does not converge" in the status bar. In that case, try another value for Guess.
ISPMT
計算分期償還額恆定時的利率。
ISPMT(Rate; Period; TotalPeriods; Invest)
Rate 用以設定定期的利率。
Period 是指計算利息的分期付款期數。
TotalPeriods 是指分期付款的總期數。
Invest 為某項投資的金額。
一筆兩年期按月還款的貸款，總額為 120,000 貨幣單位，要求計算年利率為 12% 時，在 1.5 年後的利息額。
=ISPMT(1%;18;24;120000) = -300 貨幣單位。每月利息金額在 1 年半後為 300 貨幣單位。
PV
傳回一系列定期支付所得的投資現值。
若要在特定週期數後取得特定金額 (年金)，您可以利用此函式計算今天的固定支出為多少。因此您可以選擇性地指定，在最後一期剩下多少錢。也可詳細說明，要在每次週期開始或結束時支付金額。
您可以將數值以數字、表示式或是參照的形式輸入。例如，年利率 8%，您想輸入月作為週期，則請在「利息」欄位中輸入 8%/12。LibreOffice Calc 會自動計算正確的係數。
PV(Rate; NPer; Pmt [; FV [; Type]])
Rate 定義每期的利率。
NPer 是指總期數 (付款期)。
Pmt 是指每期進行的固定付款。
FV (可選擇) 定義在完成最後分期付款金額後，所應剩下的未來殘值。
Type (可選擇) 代表付款的到期日。Type = 1 表示到期日期是期初，Type = 0 (預設) 表示到期日期是期末。
In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
如果每月可獲利 500 元，年利率 8%，則投資的現金值為多高？付款時間為 48 個月，且最終數值應為 20.000 元。
=PV(8%/12;48;500;20000) = -35,019.37 貨幣單位。在指定情況下，若要連續 48 個月每個月收到 500 貨幣單位，並在結束時剩下 20,000 貨幣單位，則須在今日存入 35,019.37 貨幣單位。交叉檢查顯示 48 x 500 貨幣單位 + 20,000 貨幣單位 = 44,000 貨幣單位。此金額與存入的 35,000 貨幣單位之間的差異值，代表支付的利息。
請您不要直接輸入數值，而是將參照輸入公式中，如此一來，您便可以詳細計算任意的「如果代入...則得出...」分析藍本。請您考慮將常數參照設定為絕對參照。您可以在折舊函式中找到這類應用程式的範例。
RECEIVED
計算固定利率的債券在指定時間點時付息的應收金額。
RECEIVED(Settlement; Maturity; Investment; Discount [; Basis])
Settlement 是指有價證券的購買日期。
Maturity 是指有價證券的到期 (過期) 日期。
Investment 是指購買總價。
Discount 是指購買有價證券的折扣百分比。
購入日：1999 年二月 15 日，到期日：1999 年五月 15 日，購入金額：1000 貨幣單位，貼現率：5.75%，基準：實際天數/360 = 2。
至到期日的支付金額計算方式如下：
=RECEIVED("1999-02-15";"1999-05-15";1000;0.0575;2) 傳回 1014.420266。
SYD
傳回算術遞減折舊率。
您可以使用此函式在物件的整個折舊期間，針對週期計算折舊金額。數字折舊會以一個常數金額逐期減少折舊總計。
SYD(Cost; Salvage; Life; Period)
Cost 是指資產的最初成本。
Salvage 是指折舊後資產的剩餘價值。
Life 是指固定資產折舊期間的週期。
Period 定義計算折舊的週期。
一間成本為 50.000 元的錄影帶店應於超過 5 年後每年折舊。剩餘價值為 10.000 元。要計算其第一年的折舊。
=SYD(50000;10000;5;1)=13,333.33 貨幣單位。第一年的折舊率金額為 13,333.33 貨幣單位。
您最好設定折舊表，以便隨時獲知每一時間範圍的折舊率。如果將 LibreOffice Calc 的不同折舊公式並排輸入，您也能看見針對此情況，哪一種折舊格式最有用的。請您依據下述方法輸入表格：
|
A |
B |
C |
D |
E |
|
|---|---|---|---|---|---|
|
1 |
期初成本 |
剩餘價值 |
使用週期 |
時間期 |
折舊 SYD |
|
2 |
50,000 貨幣單位 |
10,000 貨幣單位 |
5 |
1 |
13,333.33 貨幣單位 |
|
3 |
2 |
10,666.67 貨幣單位 |
|||
|
4 |
3 |
8,000.00 貨幣單位 |
|||
|
5 |
4 |
5,333.33 貨幣單位 |
|||
|
6 |
5 |
2,666.67 貨幣單位 |
|||
|
7 |
6 |
0.00 貨幣單位 |
|||
|
8 |
7 |
||||
|
9 |
8 |
||||
|
10 |
9 |
||||
|
11 |
10 |
||||
|
12 |
|||||
|
13 |
>0 |
總計 |
40,000.00 貨幣單位 |
E2 中的公式如下：
=SYD($A$2;$B$2;$C$2;D2)
這個公式會在欄 E 到 E11 中複製 (選擇 E2，然後透過滑鼠將右下角向下拖曳)。
在儲存格 E13 中則為控制加總所有折舊金額的公式。您可利用 SUMIF 函式，在 E8:E11 中不會參考負值。條件 >0 位於儲存格 A13 中。E13 中的公式如下：
=SUMIF(E2:E11;A13)
您現在可以檢視 10 年為週期的折舊，或是剩餘價值為 1 元時，或輸入其他成本...等。