NUMBERVALUE

Converts the string representation of a number into a locale-independent numeric value.

tip

This function is available since LibreOffice 4.1.


The input text may be in a locale-dependent or other bespoke format.

The output number is formatted as a valid floating point value and shown using the current cell's number format.

tip

Refer to the Numbers / Format help page to learn how to change the format of numbers in a cell.


语法

NUMBERVALUE(Text[; Decimal Separator[; Group Separator]])

Text is a string that contains the number to be converted.

Decimal Separator is a single character that specifies the decimal separator in Text. It can be omitted if Text does not include any decimal or group separators.

Group Separator is a string that specifies the character(s) used as the group separator in Text. It can be omitted if Text does not include any group separators. The Decimal Separator character should not be used in Group Separator.

示例

=NUMBERVALUE("1.234.567,89"; ","; ".") returns 1234567.89 (considering en-US locale). The function removes the two group separators and changes the decimal separator from a comma to a full stop.

=NUMBERVALUE("123·4"; "·") returns 123.4 (considering en-US locale). The function changes the decimal separator from a "·" to a full stop. No group separator is used in the supplied number and so the Group Separator argument is omitted.

=NUMBERVALUE("123e12") returns 1.23E+14 (considering en-US locale). No decimal or group separators are used in the supplied number and so the Decimal Separator and Group Separator arguments are omitted.

=NUMBERVALUE("1#!234#!567"; "."; "#!") returns 1234567 (considering en-US locale). Note that in this case the group separator is specified as a two-character string.

请支持我们!