Hàm Bảng Tính

Phần này chứa mô tả về các hàm Bảng tính, cùng với mẫu thí dụ.

[text/scalc/01/func_error_type.xhp#error_type_head not found].

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

STYLE

Applies a style to the cell containing the formula.

ADDRESS

Trả về một địa chỉ ô (tham chiếu) dạng văn bản, tùy theo các số thứ tự hàng/cột đã ghi rõ. Bạn cũng có thể quyết định có nên đọc địa chỉ dưới dạng một địa chỉ tuyệt đối (v.d. $A$1), hoặc dưới dạng một địa chỉ tương đối (A1), hoặc dưới dạng hỗn hợp (A$1 hay $A1). Cũng có thể ghi rõ tên của trang tính.

Để hỗ trợ cho việc dùng chung, cả hai hàm ADDRESS và INDIRECT đều hỗ trợ một tham số tùy chọn cho phép xác lập xem địa chỉ sẽ được điền dưới dạng hay R1C1 hay là kiểu A1 thường dùng.

Trong hàm ADDRESS, tham số này được đưa vào tại vị trí thứ tư, chuyển tham số tùy chọn tên của bảng sang vị trí thứ năm.

Trong hàm INDIRECT, tham số trên được thêm vào tại vị trí số hai.

Trong cả hai hàm, nếu như tham số có giá trị 0 thì kiểu kí hiệu địa chỉ R1C1 sẽ được sử dụng, còn nếu như tham số không xuất hiện hay có giá trị khác 0 thì kiểu kí hiệu A1 sẽ được sử dụng.

Trong trường hợp kí hiệu R1C1, hàm ADDRESS trả về chuỗi địa chỉ sử dụng dấu chấm than '!' làm kí hiệu phân cách tên bảng, còn hàm INDIRECT coi dấu chấm than có tác dụng như trên. Cả hai hàm vẫn sử dụng dấu chấm '.' để phân cách tên bảng với kiểu kí hiệu A1.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Khi lưu một tài liệu theo định dạng ODF 1.0/1.1, nếu hàm ADDRESS có tham số thứ 4, tham số đó sẽ bị gỡ bỏ.

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

Hàng đại diện số thứ tự hàng cho tham chiếu ô

Cột đại diện số thứ tự cột cho tham chiếu ô (số, không phải chữ)

Kiểu xác định kiểu tham chiếu :

1: tuyệt đối ($A$1)

2: kiểu tham chiếu hàng là tuyệt đối; tham chiếu cột là tương đối (A$1)

3: hàng (tương đối); cột (tuyệt đối) ($A1)

4: tương đối (A1)

A1 (optional) - nếu có giá trị là 0 thì kiểu kí hiệu R1C1 sẽ được sử dụng, trái lại nếu như tham số này không có mặt hoặc có giá trị khác 0 thì kiểu kí hiệu A1 sẽ được sử dụng.

Trang đại diện tên của trang tính. Nó phải nằm giữa dấu nháy kép.

Thí dụ :

=ADDRESS(1;1;2;"Trang2") trả về « Trang2.A$1 ».

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

AREAS

Trả về số phạm vi riêng thuộc về một phạm vi đa mục. Một phạm vi có thể chứa nhiều ô kề nhau, hay một ô riêng lẻ.

Hàm này nhận một đối số duy nhất. Nếu có nhiều vùng, bạn phải bao chúng trong ngoặc đơn bổ sung. Nhiều vùng có thể được nhập bằng cách sử dụng dấu chấm phẩy (;) để chia tách, nhưng sẽ được chuyển đổi tự động sang toán tử dấu ngã (~). Dấu ngã được sử dụng để nối các vùng.

AREAS(Tham_chiếu)

Tham_chiếu đại diện tham chiếu đến một ô hay phạm vi các ô.

=AREAS((A1:B3;F2;G1)) trả về 3, vì nó là một tham chiếu tới 3 ô hoặc vùng. Sau khi nhập nó được chuyển thành =AREAS((A1:B3~F2~G1)).

=AREAS(All) trả về 1 nếu bạn đã xác định một vùng tên « Tất cả » dưới Dữ liệu > Xác định Phạm vi.

CHOOSE

Sử dụng một chỉ số để trả về một giá trị từ danh sách chứa đến 30 giá trị.

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Chỉ_số là một tham chiếu hay số nằm giữa 1 và 30 mà ngụ ý giá trị nào cần lấy từ danh sách.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

Công thức =CHOOSE(A1;B1;B2;B3;"Hôm nay";"Hôm qua";"Ngày mai"), chẳng hạn, trả về nội dung của ô B2 cho « A1=2 »; cho « A1=4 », hàm trả về chuỗi « Hôm nay ».

COLUMN

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

COLUMN([Reference])

Tham_chiếu là tham chiếu đến một ô hay vùng ô có số thứ tự cột đầu tiên cần tìm.

Không nhập tham chiếu thì tìm số thứ tự cột của ô chứa công thức. LibreOffice Calc tự động đặt tham chiếu thành ô hiện tại.

=COLUMN(A1) bằng với 1. Cột A là cột đầu tiên của bảng.

=COLUMN(C3:E3) bằng với 3. Cột C là cột thứ ba của bảng.

=COLUMN(D3:G10) trả về 4 vì cột D là cột thứ tư của bảng, và hàm COLUMN không được dùng làm công thức mảng. (Trong trường hợp này, giá trị thứ nhất của mảng lúc nào cũng được dùng làm kết quả.)

Hai công thức {=COLUMN(B2:B7)} và =COLUMN(B2:B7) đều trả về 2 vì tham chiếu chỉ chứa cột B làm cột thứ hai của bảng. Vì vùng cột đơn chỉ có một số thứ tự cột, không phân biệt giữa công thức bình thường và công thức dạng công thức mảng.

=COLUMN() trả về 3 nếu công thức được nhập vào cột C.

{=COLUMN(Chó)} trả về mảng hàng đơn (3, 4) nếu con « Chó » là vùng đặt tên (C1:D3).

COLUMNS

Trả về số các cột có trong tham chiếu đã cho.

COLUMNS(Mảng)

Mảng là tham chiếu đến một phạm vi các ô có tổng số cột cần tìm. Đối số cũng có thể là một ô riêng lẻ.

=COLUMNS(B5) trả về 1 vì một ô chỉ chứa một cột.

=COLUMNS(A1:C5) bằng với 3. Tham chiếu chứa ba cột.

=COLUMNS(Chó) trả về 2 nếu con Chó là phạm vi đặt tên (C1:D3).

DDE

Trả về kết quả của một liên kết dựa vào DDE. Nếu nội dung của phạm vi hay phần đã liên kết còn thay đổi, thì giá trị đã trả về sẽ cũng thay đổi. Bạn cần phải nạp lại bảng tính hoặc chọn lệnh trình đơn Sửa - Liên kết để thấy các liên kết đã cập nhật. Không cho phép liên kết đa nền tảng, v.d. liên kết từ một bản cài đặt LibreOffice chạy từ một máy Windows đến một tài liệu được tạo trên một máy Linux.

DDE("Server"; "File"; "Range" [; Mode])

Server is the name of a server application. LibreOffice applications have the server name "soffice".

Tập_tin là tên tập tin hoàn toàn, gồm có đặc tả đường dẫn.

Phạm_vi là vùng chứa dữ liệu cần ước tính.

Chế_độ là một tham số còn tùy chọn mà điều khiển phương pháp theo đó máy chủ DDE chuyển đổi dữ liệu sang số.

Mode	Effect
0 hay thiếu	Định dạng số từ kiểu dáng ô « Mặc định »
1	Dữ liệu lúc nào cũng được đọc theo định dạng tiêu chuẩn cho tiếng Anh Mỹ
2	Dữ liệu được lấy dạng văn bản; không chuyển đổi sang số

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

ERRORTYPE

Trả về số tương ứng với một giá trị lỗi xảy ra trong một ô khác. Với sự giúp của số này, bạn có thể tạo một thông điệp lỗi.

ERRORTYPE(Tham_chiếu)

Tham_chiếu chứa địa chỉ cua ô trong đó lỗi xảy ra.

Nếu ô A1 hiển thị « Err:518 », hàm =ERRORTYPE(A1) trả về số 518.

ORG.OPENOFFICE.ERRORTYPE

GETPIVOTDATA

Hàm GETPIVOTDATA trả về một giá trị kết quả từ một bảng DataPilot. Giá trị có địa chỉ được đặt dùng các tên trường và tên mục, để nó còn lại hợp lệ nếu bố trí của bảng DataPilot cứ thay đổi.

Có thể sử dụng hai lời xác định cú pháp khác nhau :

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

or

GETPIVOTDATA(DataPilot; Ràng_buộc)

Cú pháp thứ hai được giả sử nếu đưa ra chính xác hai tham số, tham số đầu tiên là một ô hay tham chiếu phạm vi các ô. Cú pháp thứ nhất được giả sử trong các trường hợp khác. Trợ lý Hàm hiển thị cú pháp thứ nhất.

First Syntax

Trường_đích là một chuỗi mà chọn một của những trường dữ liệu của bảng DataPilot. Chuỗi này có thể là tên của cột nguồn, hay tên trường dữ liệu như được hiển thị trên bảng (v.d. « Tổng - Buôn bán »).

DataPilot là một tham chiếu đến một ô hay phạm vi các ô mà được định vị bên trong một bảng DataPilot hay chứa một bảng DataPilot. Nếu phạm vi ô chứa vài bảng DataPilot, có dùng bảng được tạo cuối cùng.

Không đưa ra cặp Trường n / Mục n thì trả về tổng số tổng quát. Có thì mỗi cặp thêm một ràng buộc mà kết quả phải thoả. Trường n là tên của một trường từ bảng DataPilot. Mục n là tên của một mục từ trường đó.

Nếu bảng DataPilot chứa chỉ một giá trị kết quả riêng lẻ mà thoả tất cả các ràng buộc, hoặc một tổng phụ mà tóm tắt tất cả các giá trị tương ứng, thì trả về kết quả đó. Không có kết quả tương ứng, hoặc có vài kết quả không có tổng phụ, thì trả về lỗi. Các điều kiện này áp dụng cho những kết quả nằm trong bảng DataPilot.

Nếu dữ liệu nguồn chứa các mục bị ẩn bởi thiết lập của bảng DataPilot, dữ liệu đó bị bỏ qua. Thứ tự của các cặp Trường/Mục không có tác động. Tên của trường hay mục không phân biệt chữ hoa/thường.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Giá trị tổng phụ từ bảng DataPilot chỉ được dùng nếu nó dùng hàm « auto » (tự động), trừ khi được ghi rõ trong ràng buộc, xem Cú pháp thứ hai bên dưới).

Second Syntax

DataPilot có cùng một nghĩa trong cú pháp thứ nhất.

Ràng buộc là một danh sách định giới bằng dấu cách. Cũng có thể đặt mục giữa dấu nháy đơn. Toàn bộ chuỗi phải nằm giữa dấu nháy kép, nếu bạn không tham chiếu đến chuỗi đó từ một ô khác.

Một của những mục có thể là tên trường dữ liệu. Tên trường dữ liệu có thể bị bõ sót nếu bảng DataPilot chỉ chứa một trường dữ liệu, không thì phải có nó.

Mỗi mục khác ghi rõ một ràng buộc có dạng Trường[Mục] (gồm có cặp ngoặc vuông), hoặc chỉ có Mục nếu tên mục duy nhất trong mọi trường được dùng trong bảng DataPilot.

Một tên hàm có thể được thêm dưới dạng Trường[Mục;Hàm], mà sẽ gây ra ràng buộc chỉ tương ứng với giá trị tổng phụ mà dùng hàm đó. Những tên hàm có thể là Sum (Tổng), Count (Đếm), Average (Trung bình), Max (Đại), Min (Tiểu), Product (Tích), Count (Đếm: chỉ các số), StDev (Độ lệch chuẩn: mẫu), StDevP (Độ lệch chuẩn: dân số), Var (Phương sai: mẫu), and VarP (Phương sai: dân số), không phân biệt chữ hoa/thường.

HLOOKUP

Tìm một giá trị và tham chiếu đến những ô bên dưới vùng đã chọn. Hàm này thẩm tra hàng đầu của một mảng chứa một giá trị nào đó không. Hàm thì trả về giá trị trong một hàng của mảng, đặt tên trong Chỉ_số cùng cột.

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomic Number	1	2	3	...	118
4	Relative Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

HYPERLINK

Khi bạn nhấn vào một ô mà chứa hàm HYPERLINK, siêu liên kết sẽ mở.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

Số 0 được trả về cho các ô và phần tử ma trận trống.

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

INDEX

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=INDEX(Prices;4;1) trả về giá trị từ hàng 4, cột 1 của phạm vi cơ sở dữ liệu được xác định dưới Dữ liệu > Xác định như là Giá (Prices).

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=INDEX(A1:B6;1;1) ngụ ý giá trị ở góc trên, bên trái của phạm vi A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.

INDIRECT

Trả về tham chiếu được một chuỗi văn bản ghi rõ. Hàm này cũng có thể được dùng để trả về vùng của một chuỗi tương ứng.

INDIRECT(Ref [; A1])

Tham_chiếu đại diện một tham chiếu đến một ô hay vùng (theo dạng văn bản) cho đó cần trả về nội dung.

A1 (optional) - nếu có giá trị là 0 thì kiểu kí hiệu R1C1 sẽ được sử dụng, trái lại nếu như tham số này không có mặt hoặc có giá trị khác 0 thì kiểu kí hiệu A1 sẽ được sử dụng.

=INDIRECT(A1) bằng với 100 nếu ô A1 chứa C108 làm tham chiếu và C108 chứa giá trị 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) cộng lại tất cả các ô trong vùng từ A1 đến ô có địa chỉ được xác định bởi hàng 1, cột 3. Vì thế cộng lại vùng A1:C3.

LOOKUP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

Véc-tơ_tìm là vùng hàng đơn hay cột đơn trong đó cần tìm kiếm.

Véc-tơ_kết_quả là một phạm vi hàng đơn hay cột đơn khác từ đó lấy kết quả của hàm. Kết quả là ô của véc-tơ kết quả có cùng một chỉ số với mục tương ứng được tìm bởi véc-tơ tìm.

=LOOKUP(A1;D1:D100;F1:F100) tìm kiếm trong ô tương ứng trong phạm vi D1:D100 tìm số bạn đã nhập vào ô A1. Đối với mục tương ứng đã tìm, chỉ số được quyết định, v.d. ô thứ 12 trong phạm vi này. Sau đó thì nội dung của ô thứ 12 được trả về làm giá trị của hàm (trong véc-tơ kết quả).

MATCH

Trả về vị trí tương đối của một mục trong một mảng tương ứng với một giá trị đã ghi rõ. Hàm này trả về vị trí của biến được tìm trong lookup_array (mảng tra cứu) dạng số.

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

Mảng_tra_cứu là tham chiếu trong đó cần tìm kiếm. Một mảng tra cứu có thể là một hàng/cột đơn, hay phần của một hàng/cột đơn.

Kiểu có thể đại diện một của những giá trị (1, 0, -1). Nếu kiểu là 1 hay không đưa ra tham số tùy chọn này, giả sử rằng cột đầu của mảng tìm được sắp xếp theo thứ tự tăng dần. Nếu kiểu là -1, giả sử rằng cột được sắp xếp theo thứ tự giảm dần. Đây tương ứng với cùng một hàm trong MS Excel.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

=MATCH(200;D1:D100) tìm kiếm qua vùng D1:D100, mà được sắp xếp theo cột D, so với giá trị 200. Một khi tới giá trị này, trả về số thứ tự cua hàng chứa nó. Nếu tìm một giá trị lớn hơn trong khi tìm kiếm, thì trả về số thứ tự của hàng trước đó.

OFFSET

Trả về giá trị của một ô bị bù lại theo một số hàng/cột nào đó từ một điểm tham chiếu đã cho.

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Tham_chiếu là tham chiếu từ đó hàm tìm tham chiếu mới.

Hàng là số hàng theo đó tham chiếu bị sửa chữa lên (giá trị âm) hay xuống.

Hàng là số hàng theo đó tham chiếu bị sửa chữa lên (giá trị âm) hay xuống.

Cao (tùy chọn) là bề cao theo chiều dọc của một vùng bắt đầu ở vị trí tham chiếu mới.

Rộng (optional) là bề rộng theo chiều ngang của một vùng bắt đầu ở vị trí tham chiếu mới.

Không cho phép đối số Hàng hay Cột đưa tới số không hay hàng/cột đầu âm.

Không cho phép đối số Cao hay Rộng đưa tới số không hay số đếm hàng/cột âm.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

=OFFSET(A1;2;2) trả về giá trị trong ô C3 (A1 được dời xuống theo hai hàng và hai cột). Nếu ô C3 chứa giá trị 100, hàm này trả về giá trị 100.

=OFFSET(B2:C3;1;1) trả về một tham chiếu đến B2:C3 được dời xuống theo một hàng và sang phải theo một cột (C3:D4).

=OFFSET(B2:C3;-1;-1) trả về một tham chiếu đến B2:C3 được dời lên theo một hàng và sang trái theo một cột (A1:B2).

=OFFSET(B2:C3;0;0;3;4) trả về một tham chiếu đến B2:C3 có kích cỡ được thay đổi thành 3 hàng và 4 cột (B2:E4).

=OFFSET(B2:C3;1;0;3;4) trả về một tham chiếu đến B2:C3 được dời xuống theo một hàng, có kích cỡ được thay đổi thành 3 hàng và 4 cột (B2:E4).

=SUM(OFFSET(A1;2;2;5;6)) quyết định tổng số diện tích bắt đầu từ ô C3 và có chiều cao 5 hàng và chiều rộng 6 cột (diện tích = C3:H7).

ROW

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

ROW([Reference])

Tham_chiếu là một ô, vùng hay tên của vùng.

Nếu bạn không chỉ ra một tham chiếu, hàm sẽ tìm số thứ tự hàng của ô chứa công thức. LibreOffice Calc tự động đặt tham chiếu thành ô hiện tại.

Công thức =ROW(B3) trả về 3 vì tham chiếu chỉ tới hàng thứ ba trên bảng.

Công thức {=ROW(D5:D8)} trả về mảng cột đơn (5, 6, 7, 8) vì tham chiếu đã ghi rõ chứa các hàng 5 đến 8.

Công thức =ROW(D5:D8) trả về 5 vì hàm ROW không được dùng làm công thức mảng, và chỉ trả về hàng đầu của tham chiếu.

Hai công thức {=ROW(A1:E1)} và =ROW(A1:E1) đều trả về 1 vì tham chiếu chỉ chứa hàng 1 làm cột đầu của bảng. (Vì vùng hàng đơn chỉ có một số thứ tự hàng, không khác gì trường hợp công thức được dùng làm công thức mảng.)

Công thức =ROW() trả về 3 nếu công thức được nhập vào hàng 3.

Công thức {=ROW(Chó)} trả về mảng cột đơn (1, 2, 3) nếu con « Chó » là vùng đặt tên (C1:D3).

ROWS

Trả về số hàng trong một tham chiếu hay mảng.

ROWS(Mảng)

Mảng là tham chiếu hay vùng đặt tên cho đó cần tính tổng số hàng.

Công thức =Rows(B5) trả về 1 vì một ô chỉ chứa một hàng.

=ROWS(A10:B12) trả về 3.

Công thức =ROWS(Chó) trả về 3 nếu con « Chó » là vùng đặt tên (C1:D3).

SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

SHEET([Reference])

Tham_chiếu còn tùy chọn: nó là tham chiếu đến một ô, vùng hay chuỗi tên trang tính.

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

SHEETS

Xác định số trang tính trong một tham chiếu. Nếu bạn không nhập vào tham số thì nó trả về số trang tính trong tài liệu hiện tại.

SHEETS([Reference])

Tham_chiếu là tham chiếu đến một trang tính hay vùng. Tham số này còn tùy chọn.

=SHEETS(Trang1.A1:Trang3.G12) trả về 3 nếu Trang tính số 1-3 nằm theo thứ tự được ngụ ý.

VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Chỉ_số là số thứ tự của cột trong mảng mà chứa giá trị cần trả về. Cột đầu có số thứ tự 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Hãy nhập vào ô B1 công thức này:

=VLOOKUP(A1;D1:E100;2)

Một khi bạn nhập một số vào ô A1, ô B1 sẽ hiển thị chuỗi văn bản tương ứng được chứa trong cột thứ hai của tham chiếu D1:E100. Nhập một số không tồn tại thì hiển thị chuỗi văn bản có số kế tiếp, về hướng xuống. Để ngăn cản trường hợp này, nhập FALSE (Sai) làm tham số cuối cùng trong công thức, để tạo một thông điệp lỗi khi một số không tồn tại được nhập vào.