WORKDAY.INTL

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

Syntax

WORKDAY.INTL(StartDate; Days [; Weekend [; Holidays]])

StartDate: is the date from when the calculation is carried out.

Days is the number of workdays. Positive value for a result after the start date, negative value for a result before the start date.

Вихідні є необов'язковим параметром - числом або рядком, який використовується для визначення днів тижня, які є вихідними днями, і не вважаються робочими днями. "Вихідні" це число вихідних або рядок, який визначає, коли мають місце вихідні. Числом позначають такі вихідних дні:

Число від 1 до 7 для дводенних вихідних і від 11 до 17 для одного вихідного дня.

Число

Вихідні

1 або опущено

субота й неділя

2

неділя й понеділок

3

понеділок і вівторок

4

вівторок і середа

5

середа й четвер

6

четвер і п'ятниця

7

п'ятниця і субота

11

тільки неділя

12

тільки понеділок

13

тільки вівторок

14

тільки середа

15

тільки четвер

16

тільки п'ятниця

17

тільки субота


Weekend string provides another way to define the weekly non-working days. It must have seven (7) characters – zeros (0) for working day and ones (1) for non-working day. Each character represents a day of the week, starting with Monday. Only 1 and 0 are valid. “1111111” is an invalid string and should not be used. For example, the weekend string “0000011” defines Saturday and Sunday as non-working days.

Holidays is an optional list of dates that must be counted as non-working days. The list can be given in a cell range.

note

При введенні дат як частини формул, косі риси або тире, використовувані в якості роздільників дат, інтерпретуються як арифметичні оператори. Тому дати, введені в цьому форматі не розпізнаються як дати і призводять до помилкових обчислень. Щоб дати не інтерпретувалися як частини формул, використовуйте функцію DATE, наприклад DATE (1954;7;20) або помістіть дату в лапки і використовуйте нотацію ISO 8601, наприклад "1954-07-20". Уникайте використання форматів дати, що залежать від локальних налаштувань, таких як "07/20/54", оскільки розрахунок може призвести до помилок, якщо документ завантажено відповідно до інших локальних налаштувань.


tip

Неоднозначне перетворення можливе для дат і часу ISO 8601 в розширених форматах з роздільниками. Якщо виникає помилка #ЗНАЧЕННЯ!, змініть вибір Генерувати хибу #ЗНАЧЕННЯ! у вікні - LibreOffice Calc - Формула, кнопка Детальніше... у розділі "Детальні налаштування обчислень", у списку Перетворення із тексту у число.


Приклади

What date comes 20 workdays after December 13, 2016? Enter the start date in C3 and the number of workdays in D3.

The weekend parameter (number) may be left blank or defined as 1 for default weekend (non-working days) – Saturday and Sunday.

Cells F3 to J3 contain five (5) holidays for Christmas and New Year in date format: December 24, 2016; December 25, 2016; December 26, 2016; December 31, 2016; and January 1, 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

To define Friday and Saturday as weekend days, use the weekend parameter 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

To define Sunday only the weekend day, use the weekend parameter 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatively, use the weekend string "0000001" for Sunday only weekend.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

The function can be used without the two optional parameters – Weekday and Holidays – by leaving them out:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Technical information

tip

Ця фукція доступна з версії LibreOffice 4.3.


This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.WORKDAY.INTL

Будь ласка, підтримайте нас!