Довідка LibreOffice 24.8

Rounds a number to the nearest multiple of a significance value.

For a positive number and a positive significance value, the function rounds down (towards zero). For a negative number and a negative significance value, the direction of rounding is determined by the value of a mode parameter. The function returns an error if the number and significance values have opposite signs.

If the spreadsheet is exported to Microsoft Excel, the FLOOR function is exported as the equivalent FLOOR.MATH function that has existed since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either FLOOR.PRECISE that has existed since Excel 2010, or FLOOR.XCL that is exported as the FLOOR function compatible with all Excel versions.

FLOOR(Number[; Significance[; Mode]])

Number is the number that is to be rounded, or a reference to a cell containing the number.

Significance (optional) is the value, or a reference to a cell containing the value, to whose multiple Number is to be rounded. It defaults to +1 or -1 depending on the sign of Number.

Mode (optional) is a number, or a reference to a cell containing a number. The function only uses Mode if both Number and Significance are negative. Then if Mode is given and not equal to zero, numbers are rounded up (towards zero); if Mode is equal to zero or not given, negative numbers are rounded down (away from zero).

=FLOOR(3.45) returns 3.

=FLOOR(3.45, 3) returns 3.

=FLOOR(-1.234) returns -2.

=FLOOR(-45.67, -2, 0) returns -46.

=FLOOR(-45.67, -2, 1) returns -44.

Rounds a number to the nearest multiple of a significance value.

For a positive number the function rounds down (towards zero). For a negative number, the direction of rounding is determined by the value of a mode parameter. The sign of the significance value is ignored.

This function exists for interoperability with Microsoft Excel 2013 or newer.

FLOOR.MATH(Number[; Significance[; Mode]])

Significance (optional) is the value, or a reference to a cell containing the value, to whose multiple Number is to be rounded. It defaults to 1.

Mode (optional) is a number, or a reference to a cell containing a number. If Mode is given and not equal to zero, a negative Number is rounded up (towards zero). If Mode is equal to zero or is not given, a negative Number is rounded down (away from zero).

=FLOOR.MATH(3.45) returns 3.

=FLOOR.MATH(3.45,-3) returns 3.

=FLOOR.MATH(-1.234) returns -2.

=FLOOR.MATH(-45.67,-2, 0) returns -46.

=FLOOR.MATH(-45.67,+2, 1) returns -44.

COM.MICROSOFT.FLOOR.MATH

Rounds a number down to the nearest multiple of a significance value.

For a positive number the function rounds down (towards zero). For a negative number, the function rounds down (away form zero). The sign of the significance value is ignored.

FLOOR.PRECISE(Number[; Significance])

Significance (optional) is the value, or a reference to a cell containing the value, to whose multiple Number is to be rounded. It defaults to 1.

=FLOOR.PRECISE(3.45) returns 3.

=FLOOR.PRECISE(-45.67,2) returns -46.

COM.MICROSOFT.FLOOR.PRECISE

Rounds a number to the nearest multiple of a significance value.

For a positive number and a positive significance value, the function rounds down (towards zero). For a negative number and a positive significance value, the function rounds down (away from zero). For a negative number and a negative significance value, the function rounds up (towards zero). The function returns an error if the number is positive and the significance value is negative.

This function exists for interoperability with Microsoft Excel 2007 or older. If a Calc spreadsheet is exported to Microsoft Excel, references to Calc’s FLOOR.XCL function are exported as references to Excel’s FLOOR function, which is compatible with all Excel versions. If a Microsoft Excel spreadsheet is imported into Calc, references to Excel’s FLOOR function are imported as references to Calc’s FLOOR.XCL function.

FLOOR.XCL(Number; Significance)

Significance is the value, or a reference to a cell containing the value, to whose multiple Number is to be rounded.

=FLOOR.XCL(3.45,2) returns 2.

=FLOOR.XCL(-45.67,2) returns -46.

=FLOOR.XCL(-45.67,-2) returns -44.

COM.MICROSOFT.FLOOR