LibreOffice 24.2 Help
This category contains the Logical functions.
Zero (0) is equivalent to FALSE and all other numbers are equivalent to TRUE.
Empty cells and text in cells are ignored.
A #VALUE error is raised if all arguments are ignored.
A #VALUE error is raised if one argument is direct text (not text in a cell).
Errors as argument lead to an error.
Returns TRUE if all arguments are TRUE. If one of the elements is FALSE, this function returns the FALSE value.
The arguments are either logical expressions themselves (TRUE, 1<5, 2+3=7, B8<10) that return logical values, or arrays (A1:C3) containing logical values.
AND(Logical 1 [; Logical 2 [; … [; Logical 255]]])
The logical values of entries 12<13; 14>12, and 7<6 are to be checked:
=AND(12<13;14>12;7<6) returns FALSE.
=AND(FALSE();TRUE()) returns FALSE.
Returns the logical value FALSE. The FALSE() function does not require any arguments, and always returns the logical value FALSE.
FALSE()
=FALSE() returns FALSE
=NOT(FALSE()) returns TRUE
Specifies a logical test to be performed.
IF(Test [; [ThenValue] [; [OtherwiseValue]]])
Test is any value or expression that can be TRUE or FALSE.
ThenValue (optional) is the value that is returned if the logical test is TRUE.
OtherwiseValue (optional) is the value that is returned if the logical test is FALSE.
In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
=IF(A1>5;100;"too small") If the value in A1 is greater than 5, the value 100 is returned; otherwise, the text too small is returned.
=IF(A1>5;;"too small") If the value in A1 is greater than 5, the value 0 is returned because empty parameters are considered to be 0; otherwise, the text too small is returned.
=IF(A1>5;100;) If the value in A1 is less than 5, the value 0 is returned because the empty OtherwiseValue is interpreted as 0; otherwise 100 is returned.
Complements (inverts) a logical value.
NOT(LogicalValue)
LogicalValue is any value to be complemented.
=NOT(A). If A=TRUE then NOT(A) will evaluate FALSE.
Returns TRUE if at least one argument is TRUE. This function returns the value FALSE, if all the arguments have the logical value FALSE.
The arguments are either logical expressions themselves (TRUE, 1<5, 2+3=7, B8<10) that return logical values, or arrays (A1:C3) containing logical values.
OR(Logical 1 [; Logical 2 [; … [; Logical 255]]])
The logical values of entries 12<11; 13>22, and 45=45 are to be checked.
=OR(12<11;13>22;45=45) returns TRUE.
=OR(FALSE();TRUE()) returns TRUE.
The logical value is set to TRUE. The TRUE() function does not require any arguments, and always returns the logical value TRUE.
TRUE()
If A=TRUE and B=FALSE the following examples appear:
=AND(A;B) returns FALSE
=OR(A;B) returns TRUE
=NOT(AND(A;B)) returns TRUE
Returns true if an odd number of arguments evaluates to TRUE.
The arguments are either logical expressions themselves (TRUE, 1<5, 2+3=7, B8<10) that return logical values, or arrays (A1:C3) containing logical values.
XOR(Logical 1 [; Logical 2 [; … [; Logical 255]]])
=XOR(TRUE();TRUE()) returns FALSE
=XOR(TRUE();TRUE();TRUE()) returns TRUE
=XOR(FALSE();TRUE()) returns TRUE