İŞGÜNÜ.ULUSL

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

tip

This function is available since LibreOffice 4.3.


Syntax

WORKDAY.INTL(StartDate; Days [; Weekend [; Holidays]])

StartDate: is the date from when the calculation is carried out.

Günler İşgünü sayısı. Başlangıç tarihinden sonraki bir sonuç için artı değeri, başlangıç tarihinden önceki bir sonuç için eksi değeri.

Haftasonu isteğe bağlıdır – hangi günlerin haftasonu olduğunu ve çalışma günü olarak sayılmaması gerektiğini gösteren bir sayı veya karakter dizisidir. Haftasonu sayısı aşağıdaki gibi belirlenir:

1 ile 7 arasındaki sayılar iki günlük haftasonlarını, 11 ile 17 arasındaki sayılar ise tek günlük haftasonlarını gösterir.

Sayı

Hafta Sonu

1 veya atlanmış

Cumartesi ve Pazar

2

Pazar ve Pazartesi

3

Pazartesi ve Salı

4

Salı ve Çarşamba

5

Çarşamba ve Perşembe

6

Perşembe ve Cuma

7

Cuma ve Cumartesi

11

Sadece Pazar

12

Sadece Pazartesi

13

Sadece Salı

14

Sadece Çarşamba

15

Sadece Perşembe

16

Sadece Cuma

17

Sadece Cumartesi


Haftasonu karakter dizisi çalışılmayan günleri göstermenin bir başka yolunu sunar. Yedi (7) karakter içermelidir – sıfırlar (0) çalışma gününü, birler (1) çalışılmayan günleri gösterir. Her karakter haftanın bir gününü gösterir, Pazartesi ile başlar. Sadece 1 ve 0'a izin verilir. “1111111” geçersiz bir dizidir ve kullanılmamalıdır. Örneğin “0000011” Cumartesi ve Pazar günlerinin tatil olduğunu gösterir.

Tatiller çalışma gününden sayılmaması gereken tarihlerin isteğe bağlı bir listesidir. Liste bir hücre aralığında verilebilir.

note

Tarihleri formüllerin bir parçası olarak girerken kullanılan eksi ve bölü işaretleri aritmetik işlemler için ayrılmıştır. Bu nedenle bu biçimde girilen tarihler tarih olarak algılanmaz ve hatalı işlemler yapılmasına neden olur. Tarihleri formüllerde kullanabilmek için TARİH fonksiyonunu kullanın, örneğin TARİH(1954;7;20) veya ISO 8601 yazımını kullanarak "1954-07-20" gibi çift tırnak arasında yazın. Yerelinize bağlı "07/20/54" gibi tarih gösterimlerinden kaçının, dosyanız başka bir yerelde açıldığında hatalar oluşabilir.


tip

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in - LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.


Example

13 Aralık 2016'dan sonra 20 iş günü ne zamana karşılık gelir? Başlangıç tarihini C3'e ve D3'te iş günlerinin sayısını girin.

Haftasonu parametresi (sayı) boş bırakılabilir veya varsayılan hafta sonu (çalışmayan günler) için 1 olarak tanımlanabilir - Cumartesi ve Pazar.

F3 hücresinden J3 hücresine kadar beş (5) Noel ve Yılbaşı tatili bulunmaktadır: 24 Aralık 2016; 25 Aralık 2016; 26 Aralık 2016; 31 Aralık 2016; 1 Ocak 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

Haftasonu olarak Cuma ve Cumartesi'yi belirlemek için haftasonu parametresi olarak 7 kullanın.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

Haftasonu olarak sadece Pazar'ı tanımlamak için haftasonu parametresi olarak 11 kullanın.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatif olarak, sadece Pazar'ın haftasonu olması için "0000001" dizesini kullanın.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

İşlev, iki isteğe bağlı parametre olan – Hafta içi ve Tatil günleri – olmadan kullanılabilir:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Please support us!