EĞERORTALAMA işlevi
Verilen koşulu sağlayan tüm hücrelerin aritmetik ortalamasını döndürür. EĞERORTALAMA fonksiyonu verilen mantıksal teste uyan tüm değerleri toplar ve değer sayısına böler.
EĞERORTALAMA(Aralık; Kriter [; Ortalama_Aralığı ])
Aralık – gerekli değişken. Bir dizi, isimlendirilmiş bir dizinin adı veya sayılar içeren satır ya da sütun etiketi veya koşul için sayılar veya metin.
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
Ortalama_Aralık – seçimsel. Ortalamanın hesaplanması için bir değer aralığıdır.
If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.
Ortalama hesaplamak için bir değer aralığında bir hücre boşsa veya metin içeriyorsa, EĞERORTALAMA işlevi bu hücreyi yok sayar.
Tüm aralık boşsa, yalnızca metin içeriyorsa veya aralığın tüm değerleri koşulu karşılamıyorsa (veya bunların herhangi bir kombinasyonu), işlev #DIV/0! hatasını döndürür.
Şu tabloyu düşünün
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
Ürün Adı |
Sales |
Revenue |
|
2 |
kurşun kalem |
20 |
65 |
|
3 |
kalem |
35 |
85 |
|
4 |
defter |
20 |
190 |
|
5 |
kitap |
17 |
180 |
|
6 |
pencil-case |
not |
not |
In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.
Basit kullanım
=EĞERORTALAMA(B2:B6;"<35")
B2:B6 aralığının 35'ten küçük değerlerinin ortalamasını hesaplar. İkinci satır hesaplamaya katılmadığından 19'u döndürür.
=EĞERORTALAMA(B2:B6;"<"&MAK(B2:B6))
Aynı aralığın bu aralığın maksimum değerinden küçük değerler için ortalamasını hesaplar. En büyük değer (ikinci satır) hesaplamaya katılmadığı için 19'u döndürür.
=EĞERORTALAMA(B2:B6;">"&KÜÇÜK(B2:B6;1))
Bu aralığın ilk en küçük değerinden daha büyük olan aynı aralıktaki değerlerin ortalamasını hesaplar. İlk küçük değer (dördüncü satır) hesaplamaya katılmadığı için 25 döndürür.
Ortalama_Aralık kullanımı
=EĞERORTALAMA(B2:B6;"<35";C2:C6)
İşlev, B2:B6 aralığında hangi değerlerin 35'in altında olduğunu araştırır ve C2:C6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. İkinci satır hesaplamaya katılmadığı için 145 döndürür.
=EĞERORTALAMA(B2:B6;">"&MİN(B2:B6);C2:C6)
İşlev, B2:B6 aralığındaki hangi değerlerin B2:B6 aralığındaki en düşük değerden büyük olduğunu ve C2:C6 aralığındaki ilgili değerlerin ortalamasını hesaplar. Dördüncü satır (B2:B6 aralığındaki en düşük değer bulunduğu yerde) hesaplamaya katılmadığı için 113.3 döndürür.
=EĞERORTALAMA(B2:B6;"<"&BÜYÜK(B2:B6;2);C2:C6)
İşlev, B2: B6 aralığındaki hangi değerlerin B2:B6 aralığındaki ikinci büyük değerden küçük olduğunu ve C2:C6 aralığındaki ilgili değerlerin ortalamasını hesaplar. Hesaplamaya yalnızca dördüncü satır katıldığından 180 döndürür.
Düzenli ifadeleri kullanmak
=EĞERORTALAMA(A2:A6;"kalem";B2:B6)
İşlev, A2:A6 aralığındaki hücrelerin yalnızca "kalem" kelimesini içeren ve B2:B6 aralığındaki ilgili değerlerin ortalamasını hesaplar. Hesaplamaya yalnızca ikinci satır katıldığı için 35 döndürür. Arama A2:A6 aralığında yapılır, ancak değerler B2:B6 aralığından döndürülür.
=EĞERORTALAMA(A2:A6;"kalem.*";B2:B6)
İşlev, A2:A6 aralığındaki hücrelerin herhangi bir miktarda diğer karakterle biten "kalem" ile başlayan ve B2:B6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. 27,5'i döndürdür, çünkü artık "kalem" de durumu karşılar ve her iki hesapta birinci ve ikinci satırlar katılır.
=EĞERORTALAMA(A1:A6;".*kitap.*";B2:B6)
İşlev A2:A6 aralığındaki hücrelerde "kitap" karakterlerini önünde ve sonunda başka karakterler ile birlikte arar ve onlara karşılık gelen B2:B6 aralığındaki değerlerin ortalamasını hesaplar. Sadece üçüncü ve dördüncü satırlar hesaplamaya dahil edildiğinden 18.5 döndürür.
Bir kriter olarak bir hücreye başvuru
Bir ölçütü kolayca değiştirmek istiyorsanız, onu ayrı bir hücrede belirtmek ve EĞERORTALAMA işlevi koşulunda bu hücreye bir referans kullanmak isteyebilirsiniz.
=EĞERORTALAMA(A2:A6;".*"&E2&".*";B2:B6)
İşlev, A2:A6 aralığındaki hücrelerin, E2'de belirtilen karakterlerin birleşimini içerdiğini ve herhangi bir sayıda karakterle başlayıp bitmesini araştırır ve B2:B6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. E2 = kitap ise, işlev 18.5 döndürür.
=EĞERORTALAMA(B2:B6;"<"&E2;C2:C6)
İşlev, B2:B6 aralığındaki hücrelerin E2'de belirtilen değerden küçük olanları arar ve C2:C6 aralığındaki karşılık gelen değerlerin ortalamasını hesaplar. E2 = 35 ise, işlev 145 döndürür.
Bu fonksiyon Ofis Uygulamaları (OpenDocument) standardının sürüm 1.2 Açık Belge Biçiminin bir parçasıdır. (ISO/IEC 26300:2-2015)