Finansal İşlevler Kısım Bir

Bu kategori LibreOffice Calc Matematiksel Finans işlevlerini içerir.

AMORDEGRC

Her muhasebeleştirme dönemine ilişkin yıpranmayı verir. İşlev, AMORLINC işlevine benzer, ancak hesaplamada uygulanan yıpranma katsayısı malların ömrüne bağlı değildir.

AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

Tutar kazanç maliyeti anlamına gelir.

Alım tarihimalın satın alındığı tarihtir.

Birinci dönem ilk ödeme döneminin bitiş tarihidir.

Kalan değer malın ömrü tamamlandıktan sonraki değeridir.

Dönembir amortisman dönemidir ve ömürle aynı birimi kullanması gerekir.

Oran yıpranma oranıdır.

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 163 currency units.

AMORLINC

Her muhasebeleştirme dönemine ilişkin yıpranma payını verir. Bir mal muhasebeleştirme döneminin ortasında satın alınırsa, eşit olarak bölünen yıpranma payı hesaba katılır.

AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

Maliyet İktisadi malın satın alma maliyeti.

Alım tarihimalın satın alındığı tarihtir.

Birinci dönem ilk ödeme döneminin bitiş tarihidir.

Kalan değer malın ömrü tamamlandıktan sonraki değeridir.

Dönembir amortisman dönemidir ve ömürle aynı birimi kullanması gerekir.

Oran yıpranma oranıdır.

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming linear depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 200 currency units.

AZALANBAKİYE

Sabit-azalan bakiyeler yöntemini kullanarak, belli bir dönemde bir malın amortisman değerini getirir.

Amortismanın bu formu kullanım ömrünün başında daha fazla değer kaybı elde etmek için kullanılır. (doğrusal amortismana karşı olarak). Değer kaybı her dönemde satın alma fiyatından çıkarılarak hesaplandığı için, her dönem azalır.

DB(Cost; Salvage; Life; Period [; Month])

Maliyet bir varlığın ilk alındığı andaki fiyatıdır.

Kalan değer malın ömrü tamamlandıktan sonraki değeridir.

Ömür malın amorti edildiği dönem sayısıdır (malın yararlı ömrü de denir).

Dönem yıpranmasını hesaplamak istediğiniz dönemdir. Dönem, ömürle aynı birimleri kullanmalıdır.

Ay (İsteğe bağlı) ilk yıldaki ay sayısıdır. Ay geçilirse, 12 olduğu varsayılır.

A computer system with an initial cost of 25,000 currency units is to be depreciated over a three-year period. The salvage value is to be 1,000 currency units. The first period of depreciation comprises 6 months. What is the fixed-declining balance depreciation of the computer system in the second period, which is a full year starting from the end of the first six-month period?

=DB(25000; 1000; 3; 2; 6) returns 11,037.95 currency units.

BUGÜNKÜDEĞER

Bir sabit ödemeli bir yatırımın şu anki değerini getirir.

Bu işlevi gelecekte yapılacak bir dizi sabit faizli ödemenin toplam tutarının bugünkü değerini hesaplamak için kullanın. Örneğin, borç aldığınızda borç tutarı borç veren için bugünkü değerdir. Ödemeler sabit miktardadır dönem boyunca değişemez. Belirlenen dönem sonunda ne kadar para kaldığını da hesaplayabilirsiniz.

Bu değerleri sayılar, tanımlar veya başvurular olarak girin. örneğin faiz yıllık oranı 8% ise fakat siz aylık Oran olarak kullanmak istiyorsanız, 8%/12 girin. LibreOffice Calc otomatik olarak doğru katsayıyı hesaplayacaktır.

PV(Rate; NPer; Pmt [; FV [; Type]])

Oran dönem başına faiz oranıdır.

TAKSİT_SAYISI bir yatırımdaki ödeme dönemleri sayısıdır. Örneğin, dört yıllık bir otomobil kredisi alır ve aylık ödemeler yaparsanız, kredinizin 4*12 (veya 48) dönemi vardır. Formüle TAKSİT_SAYISI olarak 48 girmeniz gerekir.

DEVRESEL_ÖDEME her dönemde yapılan düzenli ödemelerdir ve yatırım süresi boyunca değişemez.

GELECEKDEĞER (İsteğe bağlı) gelecekteki değer veya son ödeme yapıldıktan sonra ulaşmak istediğiniz nakit dengesidir. belirtilmezse 0 olduğu varsayılır ve DEVRESEL_ÖDEME bağımsız değişkenini de eklemeniz gerekir. Örneğin, 18 yılda özel bir projeye yatırmak üzere 50.000 TL biriktirmek istiyorsanız, 50.000 TL gelecekteki değerdir. Bu durumda faiz oranına ilişkin bir tahminde bulunarak her ay ne kadar biriktirmeniz gerektiğini belirleyebilirsiniz.

Tür (isteğe bağlı) ödemeler için tarihi işaretler. Tür = 1 ödemelerin dönem başında olacağını gösterir ve Tür = 0 (varsayılan) ödemenin dönem sonunda olacağını gösterir.

LibreOffice Calc fonksiyonlarında, "isteğe bağlı" işaretli parametreler kendisi takip eden bir parametre yoksa boş bırakılabilir. Örneğin, dört parametreli bir işlevde son iki parametre "isteğe bağlı" ise dördüncü parametreyi boş, veya üçüncü ve dördüncü parametreyi boş bırakabilirsiniz, fakat dördüncü parametre dolu ise üçüncü parametreyi boş bırakamazsınız.

Ödeme dönemi 48 ay, dönem sonunda 20.000 para birimi değerinde olacak olan, aylık 500 para birimi ödemeli ve yıllık faiz oranı % 8 olan yatırımın bugünkü değeri nedir?

=BD(8%/12;48;500;20000) = -35,019.37 para birimidir. Bu şartlar altında, 48 ay boyunca ayda 500 para birimi almak ve sonunda 20.000 para birimi kalmasını istiyorsanız, bugün 35.019.37 para birimi yatırmanız gerekir. Çapraz kontrol, 48 x 500 para birimi + 20.000 para birimi = 44.000 para birimi olduğunu göstermektedir. Bu tutar ile yatırılan 35.000 para birimi arasındaki fark ödenen faizi temsil eder.

Eğer formülde bu değerler yerine başvurularını girerseniz, İstediğiniz "eğer-böyle-olsaydı" senaryolarını hesaplayabilirsiniz. Önemli not: Sabitlere başvurular mutlak başvurular olmalıdır. Bu tip yaklaşımlar için örnekler değer kaybı işlevleri altında bulunmaktadır.

DURATION

Sabit faizli kredinin geri ödeme süresini yıl olarak hesaplar.

DURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

Ödeme tahvilin düzenleme tarihidir. Menkul değer düzenleme tarihi, menkul değerin piyasaya çıktığı tarihten sonra alıcıya satıldığı tarihtir.

Vade menkul değerin vade tarihidir. Vade tarihi, menkul değerin bitiş süresidir.

Kupon menkul değerin yıllık kupon oranıdır. (nominal faiz oranı)

Getiri tahvilin yılık getirisidir.

Sıklık bir yıldaki kupon ödemesi sayısıdır. Yıllık ödemelerde sıklık = 1; altı aylık ödemelerde sıklık = 2; üç aylık ödemelerde sıklık = 4 olur.

1/1/2001 tarihinde bir menkul değer satın alındı; vade tarihi 1/1/2006. Nominal faiz oranı %8'dir. Getiri %9.0'dır. Faiz altı ayda bir ödenmektedir (sıklığı 2'dir). Günlük bakiye faizi hesaplaması kullanılarak (temel 3) düzeltilmiş süresi ne kadardır?

=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3) returns 4.2 years.

EDEVRESELDÖNEMSE

Sabit amortisman ödemeli bir mal için faiz seviyesini hesaplar.

EDEVRESELDÖNEMSE(oran; Dönem; toplam_dönem_sayısı; yatırım)

Oran peryodik faiz oranını ayarlar.

Dönembir amortisman dönemidir ve ömürle aynı birimi kullanması gerekir.

toplam_dönem sayısı yatırım için ödeme dönemlerinin toplam sayısıdır (taksit sayısı).

Yatırım yatırımın bugünkü değeridir. Kredi için, yatırım kredi miktarıdır.

120.000 para birimi değerinde, iki yıl süreli aylık ödemeli bir kredinin, yıllık faiz oranı %12 iken 1,5 yıl sonraki faizin seviyesidir.

=EDEVRESEL DÖNEMSE(1%;18;24;120000) = -300 para birimidir. alınan kredinin 1,5 (18 Ay) yılında aylık ödemenin 300 para birimi kredi faizine ödenir.

EFFECT

Verilen Nominal faiz oranı için, yıllık net faiz oranını getirir.

Nominal faiz hesaplama dönemi sonundaki faiz miktarı anlamına gelir. Efektif faiz yapılan ödemelerin artmasıyla artar. Bir başka deyişle hesaplama dönemi öncesinde, dönemsel ödenir (örneğin aylık, üç aylık).

EFFECT(Nom; P)

NOM nominal faizdir.

Dönem Yıl başına faiz ödeme dönemlerinin sayısıdır.

Eğer yıllık nominal faiz oranı % 9,75 ve dört faiz ödeme dönemi belirlenmişse, gerçek faiz oranı nedir (efektif oran)?

=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.

ETKİN_ADD

Nominal faiz bazında yıllık devresel ödemeleri olan bir yatırımın, gerçek yıllık faiz oranını hesaplar.

ETKİN_ADD(Nominal Oran; Ndönem)

Nominal Oran Nominal faizin yıllık oranıdır.

NPerY yıl başına bileşik faiz ödemeleri sayısıdır.

5,25% nominal faizli üç aylık dönem faiz ödemeli bir kağıdın ya da yatırımın efektif faiz oranı nedir?

=ETKİN_ADD(0,0525;4) 0,053543 veya 5,3534% olarak döner.

GERÇEKFAİZ

Dönemsel faiz ödemesi yapan kağıdın tahakkuk etmiş faizini getirir.

ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])

Düzenleme menkul değer düzenleme tarihidir. ihraç tarihi olarak da bilinir.

İlk faiz menkul değerin (tahvilin) ilk faiz tarihidir.

Ödeme Birikmiş faizin hesaplandığı tarihtir (kağıdın satın alındığı tarih).

Oran tahvilin yıllık nominal faiz oranı (kupon faiz oranı)

Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.

Sıklık bir yıldaki kupon ödemesi sayısıdır. Yıllık ödemelerde sıklık = 1; altı aylık ödemelerde sıklık = 2; üç aylık ödemelerde sıklık = 4 olur.

Bir tahvil 28.2.2001 tarihinde düzenlenmiştir (ihraç tarihi). İlk faiz ödeme tarihi 31.8.2001 olarak verilmiştir. Ödeme tarihi (hesaplama günü) 1.5.2001.Faiz oranı 0,1 veya 10%, Kupon oranı = 0 ve Denklik (değeri) 1000 para birimidir. Faiz ödemesi yılda iki kez yapılmakta Sıklık = 2 (frekansı 2 dir). Kural US metodu (0) uygulanmışsa, Bu tahvilin ne kadar faizi birikmiştir?

=GERÇEKFAİZ("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) 16.94444 sonucunu verir.

GERÇEKFAİZV

Vadesinde faiz ödeyen hisse senedine ilişkin tahakkuk eden faizi verir.

ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])

Düzenleme menkul değer düzenleme tarihidir. ihraç tarihi olarak da bilinir.

Ödeme Birikmiş faizin hesaplandığı tarihtir (kağıdın satın alındığı tarih).

Oran Yıllık nominal faiz oranıdır (tahvilin yıllık kupon oranıdır).

Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.

Bir tahvil 15.4.2001 tarihinde çıkarılmıştır. Vade tarihi 15.10.2001 olarak düzenlenmiştir. Faiz oranı 0,1 veya 10% nominal değeri (oran) 1000 para birimidir. Günlük/yıllık hesap temeli (3) dür. Ne kadar faiz tahakkuk eder?

=GERÇEKFAİZV("2001-04-01";"2001-06-15";0.1;1000;3) 20.54795 sonucunu verir.

GETİRİ

Tamamı yatırılmış bir tahvil için vadesinde alınan tutarı verir.

RECEIVED(Settlement; Maturity; Investment; Discount [; Basis])

Ödeme tahvilin düzenleme tarihidir. Menkul değer düzenleme tarihi, menkul değerin piyasaya çıktığı tarihten sonra alıcıya satıldığı tarihtir.

Vade menkul değerin vade tarihidir. Vade tarihi, menkul değerin bitiş süresidir.

Yatırım menkul değere yatırılan tutar, satın alma toplamı.

İndirim tahvilin alınması sırasında indirim yüzdesidir.

Satın Alma tarihi (ödeme): Şubat 15 1999, Vade tarihi : Mayıs 15 1999, yatırım toplamı: 1000 para birimi, indirim: yüzde 5,75, Temel: Günlük Balans/360 = 2.

Vade tarihindeki getiri miktarı şöyle hesaplanır.

=GETİRİ("1999-02-15";"1999-05-15";1000;0.0575;2) 1014.420266 sonucunu verir.

YAT

Aritmetik-azalan amortisman değerini hesaplar.

Bir nesnenin toplam değer kaybının bir dönem için olan kısmını bulmak için bu işlevi kullanın. Dönemler boyunca aritmetik azalan sabit toplamlı değer kaybı uygulanır.

YAT(Maliyet; Kalan değer; Ömür; Dönem)

Maliyet bir varlığın ilk alındığı andaki fiyatıdır.

Kalan değer değer kaybı sonrasında varlığın fiyatıdır.

Ömürmalın amorti edildiği dönem sayısıdır (malın yararlı ömrü de denir).

Dönem Değer kaybının hesaplandığı dönemi belirler.

Alış fiyatı 50.000 para birimi olan bir video sistemine gelecek 5 yıl için yıllık olarak amortisman işletilecektir. Hurda fiyatı 10.000 para birimi değerindedir. İlk yıl için değer kaybını hesaplamak istiyorsunuz.

=YAT(50000;10000;5;1)=13.333,33 para birimi. Birinci yıl için için değer kaybı miktarı 13.333,33 para birimidir.

Her dönemdeki değer kayıp hızlarını anlamak için, bir değer kaybı tablosu oluşturmak en iyisidir, LibreOffice Calc farklı değer kaybı formüllerinin peşi sıra girilmesiyle en elverişli olan amortisman formunu görebilirsiniz. Tabloyu aşağıdaki gibi girin:

	A	B	C	D	E
1	Başlangıç Fiyatı	Hurda Değeri	Kullanım Ömrü	Zaman Periyotu	Deprec. SYD
2	50,000 para birimi	10,000 para birimi	5	1	13,333.33 para birimi
3				2	10,666.67 para birimi
4				3	8,000.00 para birimi
5				4	5,333.33 para birimi
6				5	2,666.67 para birimi
7				6	0.00 para birimi
8				7
9				8
10				9
11				10
12
13	>0			Toplam	40,000.00 para birimi

E2'deki formül şöyle devam eder:

=YAT($A$2;$B$2;$C$2;D2)

Sütun E'deki Bu formül aşağıya E11'e doğru doldurularak çoğaltılmıştır (E2'yi seçin, ve fare ile hücrenin sağ altına tıklayıp doldurma tutamağını aşağıya doğru sürükleyin).

E13 hücresi amortisman oranlarının toplamını alan formül içermektedir. E8:E11 hücre aralığında eksi değerleri dikkate almayan ETOPLA işlevi kullanmaktadır. >0 ölçütü A13 hücresinde bulunmaktadır. E13 hücresindeki formül şöyledir:

=ETOPLA(E2:E11;A13)

Şimdi 10 yıllık dönemde değer kaybını görebilir, veya 1 para birimi hurda değeri, veya farklı bir satın alma fiyatı gibi değerleri girip sonuçları görebilirsiniz.

ÇİFTAZALANBAKİYE

Aritmetik-azama metodunu kullanarak, belli bir dönemde bir malın amortisman değerini getirir.

Çift azalan bakiye yöntemi, yıpranmayı hızlandırılmış oranda hesaplar. Bu işlevi ilk yıllarda hızlı değer kaybı gerekliyse kullanın. Yıpranma ilk dönemde en yüksek değerindedir ve bunu izleyen dönemlerde azalır. İlk döneminde satın alınan bir malın değer kaybı çok hızlı oluyorsa ( örneğin teçhizat, bilgisayar) bu işlevi seçebilirsiniz. Şunu da not edelim bu hesaplama türünde malın defter değeri asla 0 değerine inmez.

DDB(Cost; Salvage; Life; Period [; Factor])

Maliyet bir malın ilk alındığı andaki sabit fiyatıdır.

Kalan değer malın ömrü tamamlandıktan sonraki değeridir.

Ömür eşyanı ne kadar süre kullanılacağını belirten dönem (örnek, yıl veya ay) rakamıdır.

Dönem Değer kaybının hesaplandığı dönemi belirler.

Faktör (İsteğe bağlı) bakiyenin azalma oranıdır. Faktör girilmezse, 2 olarak varsayılır (çift azalan bakiye yöntemi).

75.000 para birimine satın alınan bilgisayar sistemi 5 yıllık dönemde aylık olarak değer kaybına uğramıştır. Dönem sonundaki fiyatı 1 para birimi ve faktör 2 dir.

=ÇİFTAZALANBAKİYE(75000;1;60;12;2) = 1.721,81 para birimi. Bu nedenle, satın alındıktan sonraki on iki aylık dönemde çift azalan amortisman 1.721.81 para birimidir.

İNDİRİM

Bir hisse senedine ilişkin indirim oranını yüzde olarak verir.

DISC(Settlement; Maturity; Price; Redemption [; Basis])

Ödeme tahvilin düzenleme tarihidir. Menkul değer düzenleme tarihi, menkul değerin piyasaya çıktığı tarihten sonra alıcıya satıldığı tarihtir.

Vade menkul değerin vade tarihidir. Vade tarihi, menkul değerin bitiş süresidir.

Fiyat menkul değerin (tahvilin) 100 para birimlik nominal değeri için fiyatıdır.

Paraya Dönüştürme menkul değerin 100 para birimlik yeniden satın alma değerinin fiyatıdır.

25.1.2001 Tarihinde alınan Bir tahvil; vade tarihi 15.11.2001. Fiyatı (Satın alma fiyatı) 97, paraya dönüştürme değeri 100. günlük dengeleme hesabıyla (temel 3) indirim miktarı ne kadar olur?

=İNDİRİM("2001-01-25";"2001-11-15";97;100;3) yaklaşık yüzde 0.0372 veya 3.72 sonucunu verir.

İÇ_VERİM_ORANI

Bir yatırımın masraf ve kar hariç, iç geri ödeme oranını hesaplar. Değerler düzenli aralıklarla nakit akışını gösterir. En azından bir değer negatif olmalı (ödemeler), en azından bir değer pozitif olmalıdır. (gelirler)

Eğer ödemeler düzenli aralıklarla yapılıyorsa AİÇVERİMORANI fonksiyonunu kullanın.

IRR(Values [; Guess])

Değerler sayıları içeren dizi ya da hücre başvurusu.

Tahmin (İsteğe bağlı) İÇ_VERİM_ORANI'na yakın olduğunu tahmin ettiğiniz bir sayıdır. İç verim oranını hesaplamak için bir yineleme tekniği kullanılır. Şayet az sayıda değeriniz mevcutsa, yinelemenin yapılabilmesi için bir ilk tahmin değeri verilmelidir.

Varsayıma göre hücre içerikleri A1=-10000, A2=3500, A3=7600 ve A4=1000, formül =İÇ_VERİM_ORANI(A1:A4) 80,24% sonucunu verir.

Finansal İşlevler Kısım İki

Finansal İşlevler Kısım Üç