Mga Function ng Spreadsheet

Ang seksyong ito ay naglalaman ng mga paglalarawan ng Spreadsheet function kasama ng isang halimbawa.

ERROR.TYPE

Nagbabalik ng numerong kumakatawan sa isang partikular na uri ng Error, o ang halaga ng error #N/A, kung walang error.

Estilo

Naglalapat ng istilo sa cell na naglalaman ng formula.

ADDRESS

Nagbabalik ng cell address (reference) bilang text, ayon sa tinukoy na mga numero ng row at column. Maaari mong matukoy kung ang address ay binibigyang-kahulugan bilang isang ganap na address (halimbawa, $A$1) o bilang isang kamag-anak na address (bilang A1) o sa isang halo-halong anyo (A$1 o $A1). Maaari mo ring tukuyin ang pangalan ng sheet.

Para sa interoperability, sinusuportahan ng ADDRESS at INDIRECT function ang isang opsyonal na parameter upang tukuyin kung ang R1C1 address notation sa halip na ang karaniwang A1 notation ang dapat gamitin.

Sa ADDRESS, ipinapasok ang parameter bilang pang-apat na parameter, na inililipat ang opsyonal na parameter ng pangalan ng sheet sa ikalimang posisyon.

Sa INDIRECT, ang parameter ay idinagdag bilang pangalawang parameter.

Sa parehong mga pag-andar, kung ang argument ay ipinasok na may halagang 0, kung gayon ang R1C1 notation ang gagamitin. Kung ang argumento ay hindi ibinigay o may halaga maliban sa 0, ang A1 notation ang gagamitin.

Sa kaso ng R1C1 notation, ang ADDRESS ay nagbabalik ng mga address string gamit ang tandang padamdam na '!' bilang separator ng pangalan ng sheet, at inaasahan ng INDIRECT ang tandang padamdam bilang separator ng pangalan ng sheet. Ginagamit pa rin ng parehong function ang tuldok '.' separator ng pangalan ng sheet na may notasyong A1.

Kapag nagbubukas ng mga dokumento mula sa ODF 1.0/1.1 na format, ang mga function ng ADDRESS na nagpapakita ng pangalan ng sheet bilang pang-apat na parameter ay ililipat ang pangalan ng sheet na iyon upang maging ikalimang parameter. Maglalagay ng bagong ikaapat na parameter na may value 1.

Kapag nag-iimbak ng dokumento sa ODF 1.0/1.1 na format, kung ang mga function ng ADDRESS ay may pang-apat na parameter, aalisin ang parameter na iyon.

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

hilera kumakatawan sa row number para sa cell reference

Kolum kumakatawan sa numero ng column para sa cell reference (ang numero, hindi ang titik)

Abs tinutukoy ang uri ng sanggunian:

1: ganap ($A$1)

2: row reference type ay absolute; kamag-anak ang reference ng column (A$1)

3: hilera (kamag-anak); hanay (ganap) ($A1)

4: kamag-anak (A1)

A1 (opsyonal) - kung nakatakda sa 0, ang R1C1 notation ay ginagamit. Kung ang parameter na ito ay wala o nakatakda sa isa pang halaga kaysa sa 0, ang A1 notation ay ginagamit.

Sheet kumakatawan sa pangalan ng sheet. Dapat itong ilagay sa dobleng panipi.

Halimbawa:

=ADDRESS(1;1;2;;"Sheet2") ibinabalik ang sumusunod: Sheet2.A$1

Kung ang formula sa itaas ay nasa cell B2 ng kasalukuyang sheet, at ang cell A1 sa sheet 2 ay naglalaman ng halaga -6 , maaari kang mag-refer nang hindi direkta sa reference na cell gamit ang isang function sa B2 sa pamamagitan ng pagpasok =ABS(INDIRECT(B2)) . Ang resulta ay ang ganap na halaga ng cell reference na tinukoy sa B2, na sa kasong ito ay 6.

COLUMN

Ibinabalik ang column number ng isang cell reference. Kung ang reference ay isang cell ang column number ng cell ay ibinalik; kung ang parameter ay isang cell area, ang mga katumbas na numero ng column ay ibabalik sa isang solong hilera array kung ang formula ay ipinasok bilang isang array formula . Kung ang function na COLUMN na may parameter ng sangguniang lugar ay hindi ginagamit para sa isang array formula, ang numero ng column lamang ng unang cell sa loob ng lugar ang tinutukoy.

COLUMN([Reference])

Sanggunian ay ang reference sa isang cell o cell area na ang unang column number ay makikita.

Kung walang ipinasok na reference, makikita ang column number ng cell kung saan ipinasok ang formula. LibreOffice Awtomatikong itinatakda ng Calc ang reference sa kasalukuyang cell.

=COLUMN(A1) katumbas ng 1. Ang Hanay A ay ang unang hanay sa talahanayan.

=COLUMN(C3:E3) katumbas ng 3. Ang Hanay C ay ang ikatlong hanay sa talahanayan.

=COLUMN(D3:G10) nagbabalik ng 4 dahil ang column D ay ang ikaapat na column sa talahanayan at ang COLUMN function ay hindi ginagamit bilang array formula. (Sa kasong ito, ang unang halaga ng array ay palaging ginagamit bilang resulta.)

{=COLUMN(B2:B7)} at =COLUMN(B2:B7) parehong nagbabalik ng 2 dahil naglalaman lamang ang reference ng column B bilang pangalawang column sa table. Dahil isang column number lang ang mga lugar ng single-column, wala itong pinagkaiba kung gagamitin o hindi ang formula bilang array formula.

=COLUMN() nagbabalik ng 3 kung ang formula ay ipinasok sa column C.

{=COLUMN(Rabbit)} ibinabalik ang single-row array (3, 4) kung "Rabbit" ang pinangalanang lugar (C1:D3).

DDE

Ibinabalik ang resulta ng isang DDE-based na link. Kung magbabago ang mga nilalaman ng naka-link na hanay o seksyon, magbabago rin ang ibinalik na halaga. Dapat mong i-reload ang spreadsheet o pumili I-edit - Mga link para makita ang mga na-update na link. Mga cross-platform na link, halimbawa mula sa a LibreOffice Ang pag-install na tumatakbo sa isang Windows machine sa isang dokumento na ginawa sa isang Linux machine, ay hindi pinapayagan.

DDE("Server"; "File"; "Range" [; Mode])

server ay ang pangalan ng isang server application. LibreOffice ang mga application ay may pangalan ng server na "opisina".

file ay ang kumpletong pangalan ng file, kasama ang pagtutukoy ng path.

Saklaw ay ang lugar na naglalaman ng data na susuriin.

Mode ay isang opsyonal na parameter na kumokontrol sa paraan kung saan ang DDE server ay nagko-convert ng data nito sa mga numero.

Mode	Epekto
0 o nawawala	Format ng numero mula sa "Default" na istilo ng cell
1	Ang data ay palaging binibigyang kahulugan sa karaniwang format para sa US English
2	Kinukuha ang data bilang text; walang conversion sa mga numero

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") binabasa ang mga nilalaman ng cell A1 sa sheet1 ng LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Motto ngayong araw") nagbabalik ng motto sa cell na naglalaman ng formula na ito. Una, dapat kang maglagay ng linya sa motto.odt na dokumento na naglalaman ng motto text at tukuyin ito bilang unang linya ng isang seksyon na pinangalanan Motto ngayon (sa LibreOffice Manunulat sa ilalim Ipasok - Seksyon ). Kung ang motto ay binago (at nai-save) sa LibreOffice Dokumento ng manunulat, ang motto ay na-update sa lahat LibreOffice Calc cell kung saan tinukoy ang DDE link na ito.

DIREKTO

Ibinabalik ang sanggunian tinukoy ng isang text string. Ang function na ito ay maaari ding gamitin upang ibalik ang lugar ng isang kaukulang string.

INDIRECT(Ref [; A1])

Ref kumakatawan sa isang sanggunian sa isang cell o isang lugar (sa anyong teksto) kung saan ibabalik ang mga nilalaman.

A1 (opsyonal) - kung nakatakda sa 0, ang R1C1 notation ay ginagamit. Kung ang parameter na ito ay wala o nakatakda sa isa pang halaga kaysa sa 0, ang A1 notation ay ginagamit.

=INDIRECT(A1) katumbas ng 100 kung ang A1 ay naglalaman ng C108 bilang isang sanggunian at ang cell C108 ay naglalaman ng isang halaga ng 100 .

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) ang kabuuan ng mga cell sa lugar ng A1 hanggang sa cell na may address na tinukoy ng row 1 at column 3. Nangangahulugan ito na ang area A1:C1 ay may kabuuan.

ERRORTYPE

Ibinabalik ang numerong katumbas ng isang halaga ng error nangyayari sa ibang cell. Sa tulong ng numerong ito, makakabuo ka ng text ng mensahe ng error.

ERRORTYPE(Reference)

Sanggunian naglalaman ng address ng cell kung saan nangyayari ang error.

Kung ipinapakita ng cell A1 ang Err:518, ang function =ERRORTYPE(A1) ibinabalik ang numerong 518.

ORG.OPENOFFICE.ERRORTYPE

GETPIVOTDATA

Ang GETPIVOTDATA function ay nagbabalik ng value ng resulta mula sa isang pivot table. Tinutugunan ang halaga gamit ang mga pangalan ng field at item, kaya nananatili itong wasto kung magbabago ang layout ng pivot table.

Dalawang magkaibang kahulugan ng syntax ang maaaring gamitin:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

o

GETPIVOTDATA(pivot table; Constraints)

Ang pangalawang syntax ay ipinapalagay kung eksaktong dalawang parameter ang ibinigay, kung saan ang unang parameter ay isang cell o cell range reference. Ang unang syntax ay ipinapalagay sa lahat ng iba pang mga kaso. Ipinapakita ng Function Wizard ang unang syntax.

Unang Syntax

TargetField ay isang string na pumipili ng isa sa mga field ng data ng pivot table. Ang string ay maaaring ang pangalan ng source column, o ang data field name gaya ng ipinapakita sa table (tulad ng "Sum - Sales").

pivot table ay isang reference sa isang cell o hanay ng cell na nakaposisyon sa loob ng pivot table o naglalaman ng pivot table. Kung naglalaman ang hanay ng cell ng ilang pivot table, gagamitin ang talahanayang huling ginawa.

Kung hindi Patlang n / Item n binigay ang mga pares, ibinabalik ang grand total. Kung hindi, ang bawat pares ay nagdaragdag ng isang hadlang na dapat matugunan ng resulta. Patlang n ay ang pangalan ng isang field mula sa pivot table. aytem n ay ang pangalan ng isang item mula sa field na iyon.

Kung ang talahanayan ng pivot ay naglalaman lamang ng isang value ng resulta na tumutupad sa lahat ng mga hadlang, o isang subtotal na resulta na nagbubuod sa lahat ng tumutugmang halaga, ibabalik ang resultang iyon. Kung walang tumutugmang resulta, o maraming resulta na walang subtotal para sa kanila, may ibabalik na error. Nalalapat ang mga kundisyong ito sa mga resultang kasama sa pivot table.

Kung ang source data ay naglalaman ng mga entry na itinago ng mga setting ng pivot table, ang mga ito ay hindi papansinin. Ang pagkakasunud-sunod ng mga pares ng Field/Item ay hindi makabuluhan. Ang mga pangalan ng field at item ay hindi case-sensitive.

Kung walang ibibigay na hadlang para sa isang filter, ang napiling value ng field ay tahasang ginagamit. Kung may ibinigay na hadlang para sa isang filter, dapat itong tumugma sa napiling halaga ng field, o may ibabalik na error. Ang mga filter ay ang mga field sa kaliwang tuktok ng isang pivot table, na na-populate gamit ang "Mga Filter" na bahagi ng dialog ng layout ng pivot table. Mula sa bawat filter, maaaring pumili ng isang item (value), na nangangahulugang iyon lang ang item na kasama sa pagkalkula.

Ang mga subtotal na halaga mula sa pivot table ay ginagamit lamang kung ginagamit nila ang function na "auto" (maliban kapag tinukoy sa pagpilit, tingnan ang Pangalawang Syntax sa ibaba).

Pangalawang Syntax

pivot table ay may parehong kahulugan tulad ng sa unang syntax.

Mga hadlang ay isang listahang pinaghihiwalay ng espasyo. Maaaring ma-quote ang mga entry (single quotes). Ang buong string ay dapat na nakapaloob sa mga quote (double quotes), maliban kung ire-reference mo ang string mula sa isa pang cell.

Ang isa sa mga entry ay maaaring ang pangalan ng field ng data. Maaaring iwanan ang pangalan ng field ng data kung ang talahanayan ng pivot ay naglalaman lamang ng isang field ng data, kung hindi, dapat itong naroroon.

Ang bawat isa sa iba pang mga entry ay tumutukoy ng isang hadlang sa form Field[Item] (na may literal na mga character [ at ]), o lamang item kung ang pangalan ng item ay natatangi sa lahat ng field na ginagamit sa pivot table.

Maaaring magdagdag ng pangalan ng function sa form Field[Item;Function] , na magiging sanhi ng pagpilit na tumugma lamang sa mga subtotal na halaga na gumagamit ng function na iyon. Ang mga posibleng pangalan ng function ay Sum, Count, Average, Max, Min, Product, Count (Numbers only), StDev (Sample), StDevP (Population), Var (Sample), at VarP (Population), case-insensitive.

HANAY

Ibinabalik ang row number ng isang cell reference. Kung ang reference ay isang cell, ibinabalik nito ang row number ng cell. Kung ang reference ay isang hanay ng cell, ibinabalik nito ang mga katumbas na numero ng row sa isang hanay Array kung ang formula ay ipinasok bilang isang array formula . Kung hindi ginagamit ang function na ROW na may reference ng range sa isang array formula, ang row number lang ng unang range na cell ang ibabalik.

ROW([Reference])

Sanggunian ay isang cell, isang lugar, o ang pangalan ng isang lugar.

Kung hindi ka nagsasaad ng reference, makikita ang row number ng cell kung saan ipinasok ang formula. LibreOffice Awtomatikong itinatakda ng Calc ang reference sa kasalukuyang cell.

=ROW(B3) nagbabalik ng 3 dahil ang sanggunian ay tumutukoy sa ikatlong hilera sa talahanayan.

{=ROW(D5:D8)} ibinabalik ang single-column array (5, 6, 7, 8) dahil ang tinukoy na reference ay naglalaman ng mga row 5 hanggang 8.

=ROW(D5:D8) nagbabalik ng 5 dahil ang ROW function ay hindi ginagamit bilang array formula at tanging ang numero ng unang hilera ng reference ang ibinalik.

{=ROW(A1:E1)} at =ROW(A1:E1) parehong nagbabalik ng 1 dahil naglalaman lamang ang reference ng row 1 bilang unang row sa table. (Dahil ang mga single-row na lugar ay mayroon lamang isang row number, hindi ito magkakaroon ng anumang pagkakaiba kung ang formula ay ginagamit bilang isang array formula.)

=ROW() nagbabalik ng 3 kung ang formula ay ipinasok sa row 3.

{=ROW(Rabbit)} ibinabalik ang single-column array (1, 2, 3) kung "Rabbit" ang pinangalanang lugar (C1:D3).

HLOOKUP

Naghahanap ng value at reference sa mga cell sa ibaba ng napiling lugar. Bine-verify ng function na ito kung ang unang hilera ng isang array ay naglalaman ng isang tiyak na halaga. Ibinabalik ng function ang halaga sa isang hilera ng array, na pinangalanan sa Index , sa parehong column.

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Para sa paliwanag sa mga parameter, tingnan ang: VLOOKUP (nagpapalitan ng mga column at row)

Ipagpalagay na nakagawa kami ng isang maliit na talahanayan ng database na sumasakop sa hanay ng cell A1:DO4 at naglalaman ng pangunahing impormasyon tungkol sa 118 elemento ng kemikal. Ang unang column ay naglalaman ng mga row heading na "Element", "Symbol", "Atomic Number", at "Relative Atomic Mass". Ang mga kasunod na column ay naglalaman ng may-katuturang impormasyon para sa bawat isa sa mga elemento, na inayos mula kaliwa pakanan ng atomic number. Halimbawa, ang mga cell B1:B4 ay naglalaman ng "Hydrogen", "H", "1" at "1.008", habang ang mga cell DO1:DO4 ay naglalaman ng "Oganesson", "Og", "118", at "294".

	A	B	C	D	...	DO
1	Elemento	Hydrogen	Helium	Lithium	...	Oganesson
2	Simbolo	H	He	Li	...	Og
3	Numero ng Atomic	1	2	3	...	118
4	Relatibong Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) nagbabalik ng "Pb", ang simbolo para sa lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) nagbabalik ng 79, ang atomic number para sa ginto.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) nagbabalik ng 12.011, ang relatibong atomic mass ng carbon.

HYPERLINK

Kapag nag-click ka sa isang cell na naglalaman ng HYPERLINK function, magbubukas ang hyperlink.

Kung gagamitin mo ang opsyonal CellValue parameter, hinahanap ng formula ang URL, at pagkatapos ay ipinapakita ang teksto o numero.

HYPERLINK("URL" [; CellValue])

URL tumutukoy sa target ng link. Ang opsyonal CellValue Ang parameter ay ang teksto o isang numero na ipinapakita sa cell at ibabalik bilang resulta. Kung ang CellValue parameter ay hindi tinukoy, ang URL ay ipinapakita sa cell text at ibabalik bilang resulta.

Ang numero 0 ay ibinalik para sa mga walang laman na cell at mga elemento ng matrix.

=HYPERLINK("http://www.example.org") ipinapakita ang text na "http://www.example.org" sa cell at ipapatupad ang hyperlink http://www.example.org kapag na-click.

=HYPERLINK("http://www.example.org";"Mag-click dito") ipinapakita ang tekstong "Mag-click dito" sa cell at ipapatupad ang hyperlink http://www.example.org kapag na-click.

=HYPERLINK("http://www.example.org";12345) ipinapakita ang numerong 12345 at ipapatupad ang hyperlink na http://www.example.org kapag na-click.

=HYPERLINK($B4) kung saan naglalaman ang cell B4 http://www.example.org . Ang function ay nagdaragdag ng http://www.example.org sa URL ng hyperlink cell at ibinabalik ang parehong teksto na ginamit bilang resulta ng formula.

=HYPERLINK("http://www.";"I-click ") at "example.org" ipinapakita ang text na Click example.org sa cell at ipapatupad ang hyperlink http://www.example.org kapag na-click.

=HYPERLINK("#Sheet1.A1";"Pumunta sa itaas") ipinapakita ang teksto Pumunta sa itaas at tumalon sa cell Sheet1.A1 sa dokumentong ito.

=HYPERLINK("file:///C:/writer.odt#Specification";"Pumunta sa Bookmark ng Writer") ipinapakita ang tekstong "Pumunta sa Bookmark ng Manunulat", nilo-load ang tinukoy na dokumento ng teksto at tumalon sa bookmark na "Specification".

=HYPERLINK("file:///C:/Documents/";"Buksan ang folder ng Documents") ipinapakita ang tekstong "Open Documents folder" at ipinapakita ang mga nilalaman ng folder gamit ang karaniwang file manager sa iyong operating system.

INDEX

Ang INDEX ay nagbabalik ng reference, isang value o isang array ng mga value mula sa isang reference range, na tinukoy ng row at column index number o array ng row at array ng mga column index number, at isang opsyonal na range index.

Ang INDEX() ay nagbabalik ng reference kung ang argument ay isa o higit pang reference. Kapag ginamit sa isang cell sa form na =INDEX(), naresolba ang reference at ipinapakita ang mga value. Kapag ginamit ang INDEX() sa mga argumento ng iba pang function, =FUNCTION(INDEX()...), nakukuha ng function ang reference na ipinasa na ibinalik ng INDEX(). Ang pagbabalik ng isang sanggunian ay iba sa pagbabalik ng isang hanay ng mga halaga para sa mga function na humahawak sa mga ito nang iba.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Sanggunian ay isang sanggunian, na ipinasok nang direkta o sa pamamagitan ng pagtukoy ng pangalan ng hanay. Kung ang sanggunian ay binubuo ng maraming hanay, dapat mong ilakip ang listahan ng mga sanggunian o mga pangalan ng hanay sa mga panaklong, o gamitin ang tilde (~) operator ng pagsasama-sama ng saklaw o tumukoy ng pinangalanang hanay na may maraming lugar.

hilera (opsyonal) ay kumakatawan sa row o ang array ng mga row index ng reference range, kung saan magbabalik ng value. Sa kaso ng zero o tinanggal (walang partikular na row) ang lahat ng mga reference na row ay ibinalik.

Kolum (opsyonal) ay kumakatawan sa column o array ng mga column index ng reference range, kung saan magbabalik ng value. Sa kaso ng zero o tinanggal (walang partikular na column) ibinabalik ang lahat ng na-refer na column.

Saklaw (opsyonal) ay kumakatawan sa index ng subrange kung tumutukoy sa isang maramihang hanay, ang default ay 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} magbalik ng 2 row array na naglalaman ng 7 at 1. Ang row index {2;1} pick row 2 then row 1. Ang column index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} magbalik ng 4 na hanay ng 2 hanay na hanay. Pinipili ng row index array na {1;2;3;4} ang mga row 3 hanggang 6 at pinipili ng {3;1} ang pangatlo (F) at unang column (D). Ang mga column 1 at 3 ng source reference ay pinapalitan sa resultang array.

=INDEX(Mga Presyo;4;1) ibinabalik ang halaga mula sa row 4 at column 1 ng database range na tinukoy sa Data - Tukuyin bilang Mga presyo .

=INDEX(SumX;4;1) ibinabalik ang halaga mula sa hanay SumX sa row 4 at column 1 gaya ng tinukoy sa Sheet - Pinangalanang Mga Saklaw at Expression - Tukuyin .

{=INDEX(A1:B6;1)} ibinabalik ang mga halaga ng unang hilera ng A1:B6. Ilagay ang formula bilang isang array formula .

{=INDEX(A1:B6;0;1)} ibinabalik ang mga halaga ng unang column ng A1:B6. Ilagay ang formula bilang isang array formula .

=INDEX(A1:B6;1;1) ay nagpapahiwatig ng halaga sa kaliwang itaas ng hanay ng A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} ibinabalik ang mga halaga ng pangalawang hanay na C1:D6 ng maramihang hanay. Ilagay ang formula bilang isang array formula .

MATCH

Ibinabalik ang kaugnay na posisyon ng isang item sa isang array na tumutugma sa isang tinukoy na halaga. Ibinabalik ng function ang posisyon ng value na makikita sa lookup_array bilang isang numero.

MATCH(Search; LookupArray [; Type])

Maghanap ay ang halaga na hahanapin sa single-row o single-column array.

LookupArray ay ang sanggunian na hinanap. Ang lookup array ay maaaring isang row o column, o bahagi ng isang row o column.

Uri maaaring kunin ang mga halagang 1, 0, o -1. Kung Uri = 1 o kung nawawala ang opsyonal na parameter na ito, ipinapalagay na ang unang column ng hanay ng paghahanap ay pinagsunod-sunod sa pataas na pagkakasunud-sunod. Kung Uri = -1 ito ay ipinapalagay na ang hanay sa pinagsunod-sunod sa pababang pagkakasunod-sunod. Ito ay tumutugma sa parehong function sa Microsoft Excel.

Kung Uri = 0, mga eksaktong tugma lang ang makikita. Kung ang criterion sa paghahanap ay natagpuan nang higit sa isang beses, ibabalik ng function ang index ng unang katumbas na halaga. Kung Type = 0 lang makakahanap ka ng mga regular na expression (kung naka-enable sa mga opsyon sa pagkalkula) o mga wildcard (kung naka-enable sa mga opsyon sa pagkalkula).

Kung ang Uri = 1 o ang ikatlong parameter ay nawawala, ang index ng huling halaga na mas maliit o katumbas ng pamantayan sa paghahanap ay ibabalik. Para sa Uri = -1, ibinabalik ang index ng huling halaga na mas malaki o katumbas.

=MATCH(200;D1:D100) hinahanap ang lugar D1:D100, na pinagsunod-sunod ayon sa column D, para sa halagang 200. Sa sandaling maabot ang halagang ito, ibabalik ang bilang ng row kung saan ito natagpuan. Kung may nakitang mas mataas na halaga sa panahon ng paghahanap sa column, ibabalik ang numero ng nakaraang row.

MGA HANAY

Ibinabalik ang bilang ng mga column sa ibinigay na reference.

COLUMNS(Array)

Array ay ang reference sa isang hanay ng cell na ang kabuuang bilang ng mga column ay makikita. Ang argument ay maaari ding maging isang cell.

=COLUMNS(B5) nagbabalik ng 1 dahil ang isang cell ay naglalaman lamang ng isang column.

=COLUMNS(A1:C5) katumbas ng 3. Ang sanggunian ay binubuo ng tatlong hanay.

=COLUMNS(Kuneho) nagbabalik ng 2 kung Kuneho ay ang pinangalanang hanay (C1:D3).

MGA HANAY

Ibinabalik ang bilang ng mga row sa isang reference o array.

ROWS(Array)

Array ay ang sanggunian o pinangalanang lugar na ang kabuuang bilang ng mga hilera ay tutukuyin.

=Rows(B5) nagbabalik ng 1 dahil ang isang cell ay naglalaman lamang ng isang row.

=ROWS(A10:B12) nagbabalik 3.

=ROWS(Kuneho) nagbabalik ng 3 kung "Kuneho" ang pinangalanang lugar (C1:D3).

MGA LUGAR

Ibinabalik ang bilang ng mga indibidwal na hanay na kabilang sa maraming hanay. Ang isang hanay ay maaaring binubuo ng magkadikit na mga cell o isang solong cell.

Inaasahan ng function ang isang solong argumento. Kung nagsasaad ka ng maraming hanay, dapat mong ilakip ang mga ito sa mga karagdagang panaklong. Maaaring maglagay ng maraming hanay gamit ang semicolon (;) bilang divider, ngunit ito ay awtomatikong mako-convert sa tilde (~) operator. Ang tilde ay ginagamit upang sumali sa mga hanay.

MGA LUGAR(Sanggunian)

Kinakatawan ng reference ang reference sa isang cell o hanay ng cell.

=AREAS((A1:B3;F2;G1)) nagbabalik ng 3, dahil ito ay isang sanggunian sa tatlong mga cell at/o mga lugar. Pagkatapos ng entry ito ay mako-convert sa =AREAS((A1:B3~F2~G1)).

=AREAS(Lahat) nagbabalik ng 1 kung tinukoy mo ang isang lugar na pinangalanang Lahat sa ilalim Data - Tukuyin ang Saklaw .

MGA SHEET

Tinutukoy ang bilang ng mga sheet sa isang reference. Kung hindi ka magpasok ng anumang mga parameter, ibabalik nito ang bilang ng mga sheet sa kasalukuyang dokumento.

MGA SHEET([Sanggunian])

Sanggunian ay ang reference sa isang sheet o isang lugar. Opsyonal ang parameter na ito.

=SHEETS(Sheet1.A1:Sheet3.G12) nagbabalik ng 3 kung ang Sheet1, Sheet2, at Sheet3 ay umiiral sa pagkakasunod-sunod na ipinahiwatig.

OFFSET

Ibinabalik ang halaga ng isang cell na na-offset ng isang tiyak na bilang ng mga row at column mula sa isang ibinigay na reference point.

OFFSET(Sanggunian; Mga Hanay; Mga Haligi [; Taas [; Lapad]])

Sanggunian ay ang sanggunian kung saan hinahanap ng function ang bagong sanggunian.

Mga hilera ay ang bilang ng mga row kung saan naitama ang reference pataas (negatibong halaga) o pababa. Gamitin ang 0 upang manatili sa parehong row.

Mga hanay ay ang bilang ng mga column kung saan naitama ang reference sa kaliwa (negatibong halaga) o sa kanan. Gamitin ang 0 upang manatili sa parehong column

taas (opsyonal) ay ang patayong taas para sa isang lugar na nagsisimula sa bagong posisyon ng sanggunian.

Lapad (opsyonal) ay ang pahalang na lapad para sa isang lugar na nagsisimula sa bagong posisyon ng sanggunian.

Mga argumento Mga hilera at Mga hanay hindi dapat humantong sa zero o negatibong panimulang row o column.

Mga argumento taas at Lapad hindi dapat humantong sa zero o negatibong bilang ng mga row o column.

Sa mga function ng LibreOffice Calc, ang mga parameter na minarkahan bilang "opsyonal" ay maiiwan lamang kapag walang sumusunod na parameter. Halimbawa, sa isang function na may apat na parameter, kung saan ang huling dalawang parameter ay minarkahan bilang "opsyonal", maaari mong iwanan ang parameter 4 o mga parameter 3 at 4, ngunit hindi mo maaaring iwanang mag-isa ang parameter 3.

=OFFSET(A1;2;2) ibinabalik ang halaga sa cell C3 (Ang A1 ay inilipat ng dalawang row at dalawang column pababa). Kung ang C3 ay naglalaman ng halaga 100 ibinabalik ng function na ito ang halaga na 100.

=OFFSET(B2:C3;1;1) nagbabalik ng reference sa B2:C3 na inilipat pababa ng 1 row at isang column sa kanan (C3:D4).

=OFFSET(B2:C3;-1;-1) nagbabalik ng reference sa B2:C3 na inilipat pataas ng 1 row at isang column sa kaliwa (A1:B2).

=OFFSET(B2:C3;0;0;3;4) nagbabalik ng reference sa B2:C3 na binago ang laki sa 3 row at 4 na column (B2:E4).

=OFFSET(B2:C3;1;0;3;4) nagbabalik ng reference sa B2:C3 na inilipat pababa ng isang row na binago sa 3 row at 4 na column (B3:E5).

=SUM(OFFSET(A1;2;2;5;6)) tinutukoy ang kabuuan ng lugar na nagsisimula sa cell C3 at may taas na 5 row at lapad na 6 na column (lugar=C3:H7).

PUMILI

Gumagamit ng index para magbalik ng value mula sa isang listahan ng hanggang 30 value.

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Index ay isang reference o numero sa pagitan ng 1 at 30 na nagsasaad kung aling value ang kukunin sa listahan.

Halaga 1, Halaga 2, ..., Halaga 30 ay ang listahan ng mga value na ipinasok bilang reference sa isang cell o bilang mga indibidwal na value.

=CHOOSE(A1;B1;B2;B3;"Ngayon";"Kahapon";"Bukas") , halimbawa, ibinabalik ang mga nilalaman ng cell B2 para sa A1 = 2; para sa A1 = 4, ibinabalik ng function ang tekstong "Ngayon".

SHEET

Ibinabalik ang numero ng sheet ng alinman sa isang reference o isang string na kumakatawan sa isang pangalan ng sheet. Kung hindi ka maglalagay ng anumang mga parameter, ang resulta ay ang numero ng sheet ng spreadsheet na naglalaman ng formula.

SHEET([Reference])

Sanggunian ay opsyonal at ang reference sa isang cell, isang lugar, o isang string ng pangalan ng sheet.

=SHEET(Sheet2.A1) nagbabalik ng 2 kung ang Sheet2 ay ang pangalawang sheet sa dokumento ng spreadsheet.

=SHEET("Sheet3") nagbabalik ng 3 kung ang Sheet3 ay ang ikatlong sheet sa dokumento ng spreadsheet.

TINGNAN

Ibinabalik ang mga nilalaman ng isang cell mula sa isang hanay ng isang hilera o isang hanay. Opsyonal, ang nakatalagang halaga (ng parehong index) ay ibinabalik sa ibang column at row. Bilang laban sa VLOOKUP at HLOOKUP , ang vector ng paghahanap at resulta ay maaaring nasa magkaibang posisyon; hindi nila kailangang magkatabi. Bilang karagdagan, ang vector ng paghahanap para sa LOOKUP ay dapat na pinagsunod-sunod pataas, kung hindi, ang paghahanap ay hindi magbabalik ng anumang magagamit na mga resulta.

LOOKUP(Lookup; SearchVector [; ResultVector])

Paghahanap ay ang halaga ng anumang uri na hahanapin; direktang ipinasok o bilang sanggunian.

SearchVector ay ang isang hanay o isang hanay na lugar na hahanapin.

ResultaVector ay isa pang single-row o single-column range kung saan kinukuha ang resulta ng function. Ang resulta ay ang cell ng vector ng resulta na may kaparehong index gaya ng halimbawang matatagpuan sa vector ng paghahanap.

=LOOKUP(A1;D1:D100;F1:F100) hinahanap ang katumbas na cell sa hanay na D1:D100 para sa numerong inilagay mo sa A1. Para sa halimbawang natagpuan, ang index ay tinutukoy, halimbawa, ang ika-12 na cell sa hanay na ito. Pagkatapos, ang mga nilalaman ng ika-12 na cell ay ibinalik bilang ang halaga ng function (sa vector ng resulta).

VLOOKUP

Vertical na paghahanap na may reference sa mga katabing cell sa kanan. Sinusuri ng function na ito kung ang isang partikular na halaga ay nasa unang column ng isang array. Ibinabalik ng function ang value sa parehong row ng column na pinangalanan ni Index . Kung ang Inayos ang parameter ay tinanggal o itinakda sa TRUE o isa, ipinapalagay na ang data ay pinagsunod-sunod sa pataas na pagkakasunud-sunod. Sa kasong ito, kung ang eksaktong Paghahanap ay hindi nahanap, ang huling halaga na mas maliit kaysa sa pamantayan ay ibabalik. Kung Inayos ay nakatakda sa FALSE o zero, isang eksaktong tugma ang dapat mahanap, kung hindi, ang error Error: Hindi Available ang Value ang magiging resulta. Kaya na may halagang zero ang data ay hindi kailangang ayusin sa pataas na pagkakasunud-sunod.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Paghahanap ay ang halaga ng anumang uri na hinahanap sa unang hanay ng array.

Array ay ang reference, na binubuo ng hindi bababa sa kasing dami ng mga column gaya ng numerong ipinasa sa Index argument.

Index ay ang bilang ng column sa array na naglalaman ng value na ibabalik. Ang unang column ay may numero 1.

SortedRangeLookup ay isang opsyonal na parameter na nagsasaad kung ang unang column sa array ay naglalaman ng mga hangganan ng hanay sa halip na mga simpleng halaga. Sa mode na ito, ibinabalik ng lookup ang value sa row na may unang column na may value na katumbas ng o mas mababa sa Paghahanap . Hal, maaari itong maglaman ng mga petsa kung kailan binago ang ilang halaga ng buwis, kaya ang mga halaga ay kumakatawan sa mga petsa ng pagsisimula ng isang panahon kung kailan naging epektibo ang isang partikular na halaga ng buwis. Kaya, ang paghahanap para sa isang petsa na wala sa unang hanay ng hanay, ngunit nasa pagitan ng ilang umiiral na mga petsa ng hangganan, ay magbibigay ng mas mababa sa mga ito, na magbibigay-daan upang malaman na ang data ay epektibo sa hinanap na petsa. Ilagay ang Boolean value na FALSE o zero kung ang unang column ay hindi isang listahan ng hangganan ng hanay. Kapag TRUE o hindi ibinigay ang parameter na ito, ang unang column sa array dapat ayusin sa pataas na pagkakasunud-sunod . Ang mga pinagsunod-sunod na column ay maaaring maghanap nang mas mabilis at ang function ay palaging nagbabalik ng isang halaga, kahit na ang halaga ng paghahanap ay hindi eksaktong tumugma, kung ito ay mas malaki kaysa sa pinakamababang halaga ng pinagsunod-sunod na listahan. Sa mga hindi naayos na listahan, dapat na eksaktong tumugma ang halaga ng paghahanap. Kung hindi, ang function ay magbabalik ng #N/A na may mensahe: Error: Hindi Available ang Value .

Gusto mong ipasok ang numero ng isang ulam sa menu sa cell A1, at ang pangalan ng ulam ay lilitaw kaagad bilang teksto sa kalapit na cell (B1). Ang pagtatalaga ng Number to Name ay nakapaloob sa D1:E100 array. Naglalaman ang D1 100 , E1 ay naglalaman ng pangalan Sabaw ng Gulay , at iba pa, para sa 100 item sa menu. Ang mga numero sa hanay D ay pinagsunod-sunod sa pataas na pagkakasunud-sunod; kaya, ang opsyonal Inayos hindi kinakailangan ang parameter.

Ipasok ang sumusunod na formula sa B1:

=VLOOKUP(A1;D1:E100;2)

Sa sandaling magpasok ka ng isang numero sa A1 B1 ay magpapakita ng kaukulang teksto na nilalaman sa ikalawang hanay ng sanggunian D1:E100. Ang pagpasok ng isang hindi umiiral na numero ay nagpapakita ng teksto na ang susunod na numero ay pababa. Upang maiwasan ito, ilagay ang FALSE bilang huling parameter sa formula upang magkaroon ng mensahe ng error kapag may inilagay na hindi umiiral na numero.