Bagay sa Koleksyon

Maaaring gamitin ang mga koleksyon upang mag-imbak ng mga item ng iba't ibang uri. Maaaring ma-access ang bawat item sa pamamagitan ng index nito o sa pamamagitan ng opsyonal na key na nauugnay dito.

A Koleksyon object ay may mga sumusunod na pamamaraan:

• Idagdag: naglalagay ng bagong item sa koleksyon. Opsyonal, maaaring tukuyin ang isang string value bilang susi sa item.

• Bilang: ibinabalik ang bilang ng mga item sa koleksyon.

• item: ibinabalik ang item sa koleksyon sa pamamagitan ng pagpasa sa index o key nito.

• Alisin: inaalis ang tinukoy na item mula sa koleksyon sa pamamagitan ng index o key nito.

Maaaring ma-access ang mga item sa isang Koleksyon alinman sa pamamagitan ng kanilang mga indeks (tulad ng sa isang 1-based na single-dimensional Array) o sa pamamagitan ng kanilang mga nauugnay na key.

Ang Diksyunaryo ng ScriptForge pinalawak ng serbisyo ang Koleksyon object sa pamamagitan ng pagbibigay ng mga karagdagang feature bilang key retrieval at replacement, pati na rin ang pag-import/export sa Array objects at JSON strings.

Paglikha ng Koleksyon

Upang lumikha ng a Koleksyon gamitin ang Bago keyword. Ang sumusunod na halimbawa ay lumilikha ng a Koleksyon object at populate ito ng tatlong item:

    Dim myCollection as New Collection
    myCollection.Add("Some text")
    myCollection.Add(100)
    myCollection.Add(Array(1, 2, 3, 4))
    MsgBox myCollection.Count ' 3
  

Pagdaragdag ng mga Item

Ang Idagdag paraan ay maaaring gamitin upang magdagdag ng mga bagong item sa Koleksyon bagay.

oCollection.Add(item, [key], [before|after])

item: ang item na idaragdag sa Koleksyon . Maaaring kahit anong uri.

susi: string value na ginamit bilang natatanging key na ginamit para matukoy ang value na ito.

bago, pagkatapos: opsyonal na argumento ng keyword na nagsasaad kung saan ilalagay ang bagong item sa Koleksyon . Isa lamang sa mga argumento dati o pagkatapos maaaring tukuyin upang matukoy ang index o key bago kung saan (o pagkatapos nito) ang bagong item ay ilalagay.

Ang halimbawa sa ibaba ay nagdaragdag ng dalawang elemento sa a Koleksyon . Ang una ay may susi na nauugnay dito, samantalang ang pangalawa ay wala.

    Dim myCollection as New Collection
    myCollection.Add(100, "first")
    myCollection.Add(101)
  

Ang Idagdag Sinusuportahan din ng pamamaraan ang mga argumento ng keyword:

    myCollection.Add(item := 100, key := "first")
  

Ang mga susi ay dapat na natatangi sa a Koleksyon bagay. Ang paghahambing sa pagitan ng mga susi ay case-insensitive . Ang pagdaragdag ng mga duplicate na key ay magreresulta sa isang runtime error.

Ang halimbawa sa ibaba ay naglalarawan kung paano gamitin ang dati at Pagkatapos mga argumento ng keyword upang matukoy ang posisyon ng item na idinaragdag.

    Dim myCollection as Variant
    myCollection = New Collection
    myCollection.Add(item := 101, key := "first")
    myCollection.Add(item := 103, key := "third")
    myCollection.Add(item := 105, key := "fifth")
    MsgBox myCollection.Item(2) ' 103
    myCollection.Add(item := 102, key := "second", before := "third")
    MsgBox myCollection.Item(2) ' 102
    myCollection.Add(item := 104, key := "fourth", after := 3)
    MsgBox myCollection.Item(4) ' 104
  

Mga bagay sa a Koleksyon object ay itinalaga ng isang integer index value na nagsisimula sa 1 at tumutugma sa pagkakasunud-sunod kung saan sila idinagdag.

Pag-access sa Mga Item

Gamitin ang item paraan upang ma-access ang isang naibigay na item sa pamamagitan ng index o key nito.

oCollection.Item(index)

oCollection.Item(key)

index: isang integer value na tumutukoy sa index ng item na ibabalik.

susi: isang string value na tumutukoy sa susi ng item na ibabalik.

    Dim myCollection as New Collection
    myCollection.Add(item := 101, key := "A")
    myCollection.Add(item := 102, key := "B")
    myCollection.Add(item := 103, key := "C")
    MsgBox myCollection.Item("A") ' 101
    MsgBox myCollection.Item(3)   ' 103
  

Pag-alis ng mga Item

Gamitin ang Alisin paraan para tanggalin ang mga bagay mula sa a Koleksyon bagay.

Maaaring alisin ang mga item sa pamamagitan ng kanilang mga indeks o mga pangunahing halaga.

oCollection.Remove(index)

oCollection.Remove(key)

index: isang integer value na tumutukoy sa index ng item na aalisin.

susi: isang string value na tumutukoy sa key ng item na aalisin.

    Dim myCollection as New Collection
    myCollection.Add(item := 101, key := "first")
    myCollection.Add(item := 102, key := "second")
    myCollection.Add(item := 103, key := "third")
    MsgBox myCollection.Count ' 3
    ' Removes the  first value
    myCollection.Remove(1)
    ' Removes the value whose key is "third"
    myCollection.Remove("third")
    MsgBox myCollection.Count ' 1
  

Pag-ulit sa lahat ng Item

Posibleng gumamit ng a Para sa Bawat ... Susunod pahayag na umulit sa lahat ng aytem sa a Koleksyon .

    Dim myCollection as New Collection
    myCollection.Add(item := 101, key := "A")
    myCollection.Add(item := 102, key := "B")
    myCollection.Add(item := 103, key := "C")
    For Each value In myCollection
        MsgBox value
    Next value
  

Pag-clear ng Koleksyon

Upang alisin ang lahat ng mga item mula sa a Koleksyon bagay na tawag sa Alisin pamamaraan para sa bawat item, tulad ng inilalarawan sa halimbawa sa ibaba:

    ' Lumikha ng sample na Koleksyon na may dalawang entry
    Dim myCollection as New Collection
    myCollection.Add(item := 10, key := "A")
    myCollection.Add(item := 11, key := "B")
    MsgBox myCollection.Count ' 2
    ' Tinatanggal ang lahat ng item sa koleksyon
    For i = myCollection.Count To 1 Step -1
    	myCollection.Remove(i)
    Next i
    MsgBox myCollection.Count ' 0