COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

This function is available since LibreOffice 4.0.

Syntax

COUNTIFS(Range; Criterion[; Range2; Criterion2][; ... ; [Range127; Criterion127]])

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

Sökningen stöder jokertecken eller reguljära uttryck. Med reguljära uttryck aktiverat, kan du skriva "all.*", för att hitta första platsen för "all" följt av vilka bokstäver som helst (eller inga). Om du vill söka efter en text som också är ett reguljärt uttryck, anger du "\"-tecknet (bakstreck), eller omger texten med \Q...\E. Du kan stänga av eller aktivera automatisk evaluering av jokertecken och reguljära uttryck i inställningarna under - LibreOffice Calc - Beräkna.

Att använda funktioner där ett eller flera argument är sök-kritierier som representerar reguljära uttryck, ger ett första försök att konvertera söksträngen till ett tal. Till exempel, ".0" konverteras till 0.0 och så vidare. Om det lyckas så gör ett försök att matcha numeriskt istället för strängbaserat. Men om en locale används där decimalskiljetecknet inte är punkt kommer det att evalueras som reguljärt uttryck. För att tvinga en matchning som strängbaserat reguljärt uttryck istället för numeriskt som ett tal kan du använda något som inte kan tolkas som ett tal, till exmpel ".[0]", ".\0" eller "(?i).0".

Range, Range2, ... and Criterion, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

This function is part of the Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

Example

Consider the following table

	A	B	C
1	Product Name	Sales	Revenue
2	pencil	20	65
3	pen	35	85
4	notebook	20	190
5	book	17	180
6	pencil-case	not	not

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

Simple usage

=ANTAL.OMF(B2:B6;">=20")

Counts the amount of rows of the range B2:B6 with values greater than or equal to 20. Returns 3, because the fifth and the sixth rows do not meet the criterion.

=ANTAL.OMF(B2:B6;">=20";C2:C6;">70")

Counts the amount of rows that contain simultaneously values greater than 70 in the C2:C6 range and values greater than or equal to 20 in the B2:B6 range. Returns 2, because the second, the fifth and the sixth rows do not meet at least one criterion.

Using regular expressions and nested functions

For these examples to work as described, make sure that Enable regular expressions in formulas is selected in - LibreOffice Calc - Calculate.

=ANTAL.OMF(B2:B6;"[:alpha:]*")

Counts the amount of rows of the B2:B6 range that contain only alphabet symbols. Returns 1, because only sixth row meets the criterion.

=ANTAL.OMF(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Counts the amount of rows of the B2:B6 range excluding rows with minimum and maximum values of this range. Returns 2, because the third, the fifth and the sixth rows do not meet at least one criterion.

=ANTAL.OMF(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Counts the amount of rows that correspond to all cells of the A2:A6 range starting with "pen" and to all cells of the B2:B6 range with exception of its maximum. Returns 1, because only second row meets all criteria.

Reference to a cell as a criterion

Om du vill göra det enklare att ändra ett kriterium, så kan du ange det i en separat cell och sedan referera till den cellen ifrån funktionen ANTAL.OMF. Exempelvis kan ovanstående funktion skrivas så här:

=ANTAL.OMF(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

If E2 = pen, the function returns 1, because the link to the cell is substituted with its content and it works as a function above.

Open file with example:

COUNTIFS wiki page.

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, [text/scalc/01/func_averageifs.xhp#averageifs_head not found]., SUMIFS

Lista med reguljära uttryck