MkDir Statement

Skapar en ny katalog i ett datamedium.

Syntax:


MkDir Text As String

Parametrar:

Text: Ett stränguttryck som anger namn och sökväg för den katalog som ska skapas. Du kan även använda URL-notation.

Om sökvägen inte är bestämd så skapas katalogen i den aktuella katalogen.

Felkoder:

5 Felaktigt proceduranrop

76 Det går inte att hitta sökvägen

Exempel:


Sub ExampleFileIO
' Exempel för funktioner i filorganisationen
Const sFile1 As String = "file://c|/autoexec.bat"
Const sDir1 As String = "file://c|/Temp"
Const sSubDir1 as String ="Test"
Const sFile2 as String = "Kopierad.tmp"
Const sFile3 as String = "Byttnamn.tmp"
Dim sFile As String
    sFile = sDir1 + "/" + sSubDir1
    ChDir( sDir1 )
    If Dir(sSubDir1,16)="" Then ' Existerar katalogen?
        MkDir sSubDir1
        MsgBox sFile,0,"Skapa katalog"
    End If
    sFile = sFile + "/" + sFile2
    FileCopy sFile1 , sFile
    MsgBox fSysURL(CurDir()),0,"Aktuell katalog"
    MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Skapat den"
    MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Fillängd"
    MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Filattribut"
    Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
    ' Byt namn i samma katalog
    sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
    SetAttr( sFile, 0 ) 'Radera alla attribut
    MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Nya filattribut"
    Kill sFile
    RmDir sDir1 + "/" + sSubDir1
End Sub
 
' Konverterar en systemsökväg till en URL
Function fSysURL( fSysFp As String ) As String
Dim iPos As String
    iPos = 1
    iPos = Instr(iPos,fSysFp, getPathSeparator())
    Do While iPos > 0
        Mid( fSysFp, iPos , 1,"/")
        iPos = Instr(iPos+1,fSysFp, getPathSeparator())
    Loop
    ' Kolon i DOS
    iPos = Instr(1,fSysFp,":")
    If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
    fSysURL = "file://" & fSysFp
End Function

Please support us!