Funkcije za besedilo

To poglavje vsebuje opise funkcij za besedilo.

ARABIC

Pretvori rimsko število v arabsko. Število mora biti med 0 in 3999.

ARABIC("besedilo")

Besedilo je besedilo, ki predstavlja rimsko številko.

=ARABIC("MXIV") vrne 1014

=ARABIC("MMII") vrne 2002

ASC

Funkcija ASC pretvori znake ASCII in katakana polne do polovične širine. Vrne besedilni niz.

Tabelo pretvorb si oglejte na naslovu https://wiki.openoffice.org/wiki/Calc/Funkcionalnosti/Funkcije_JIS_in_ASC.

ASC("besedilo")

Besedilo je besedilo z znaki, ki jih želite pretvoriti.

Glejte tudi funkcijo JIS.

BAHTTEXT

Pretvori številko v besedilo v tajščini, vključno s tajskimi nazivi valute.

BAHTTEXT(število)

Število je poljubno število. »Baht« se doda k celemu delu števila, »Satang« pa k decimalnemu delu števila.

=BAHTTEXT(12,65) vrne niz tajskih znakov s pomenom »Dvanajst Baht in petinšestdeset Satang«.

BASE

Pretvori pozitivno celo število v besedilo številskega sistema na določeni osnovi. Uporabljajo se števila od 0-9 in črke od A-Z.

BASE(število; koren [; najmanjša_dolžina])

Število je pozitivno celo število, ki bo pretvorjeno.

Koren predstavlja osnovo številskega sistema. To je lahko poljubno pozitivno celo število med 2 in 36.

Najmanjša_dolžina (neobvezno) določi najmanjšo dolžino niza znakov, ki je bil ustvarjen. Če je besedilo krajše od določene dolžine, bodo levo od niza dodane ničle.

=BASE(17;10;4) vrne 0017 v desetiškem sistemu.

=BASE(17;2) vrne 10001 v dvojiškem sistemu.

=BASE(255;16;4) vrne 00FF v šestnajstiškem sistemu.

CHAR

Pretvori število v znak po veljavni kodni tabeli. Število je lahko dvomestno ali trimestno celo število.

CHAR(število)

Število je število med 1 in 255 ter predstavlja kodno vrednost znaka.

=CHAR(100) vrne znak d.

="abc" & CHAR(10) & "def" v niz vstavi znak za novo vrstico.

CLEAN

Odstrani vse nenatisljive znake iz niza.

CLEAN("besedilo")

Besedilo je besedilo, iz katerega bodo odstranjeni nenatisljivi znaki.

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) vrne 16, kar kaže, da funkcija CLEAN odstrani nenatisljiva znaka Unicode U+0007 ("BEL") in U+0008 ("BS") na začetku in na koncu podanega znakovnega niza. CLEAN ne odstrani presledkov.

CODE

Vrne številčno kodo prvega znaka v nizu besedila.

CODE("besedilo")

Besedilo je besedilo, za katerega je potrebno poiskati kodo za prvi znak.

=CODE("Hoče") vrne 72, =CODE("hruška") vrne 104.

CONCATENATE

Združi več besedilnih nizov v enega.

CONCATENATE(niz 1 [; niz 2 [; ... [; niz 255]]])

Niz 1[; niz 2][; ... ;[niz 255]] so nizi ali sklici na celice, ki vsebujejo nize.

=CONCATENATE("Dobro ";"jutro ";"gospa ";"Novak") vrne: Dobro jutro gospa Novak.

DECIMAL

Pretvori besedilo z znaki iz izbranega številskega sistema v pozitivno celo število na določeni osnovi. Vrednost korena mora biti med 2 in 36. Presledki in tabulatorji se ne upoštevajo. Besedilno polje ne loči malih in velikih črk.

Če je vrednost korena 16, se vodilni x ali X ali 0x ali 0X in dodan h ali H ne upoštevajo. Če je vrednost korena 2, se dodan b ali B ne upoštevata. Drugi znaki, ki ne sodijo v številski sistem, povzročijo napako.

DECIMAL("besedilo"; koren)

Besedilo je besedilo, ki bo pretvorjeno. Če želite razlikovati med šestnajstiškimi števili, kot je A1, in sklicem na celico A1, morate število zapisati v narekovajih, npr. »A1« ali »DECA«.

Koren predstavlja osnovo številskega sistema. To je lahko poljubno pozitivno celo število med 2 in 36.

=DECIMAL("17";10) vrne 17.

=DECIMAL("FACE";16) vrne 64206.

=DECIMAL("0101";2) vrne 5.

DOLLAR

Pretvori število v količino v zapisu valute, zaokroženem na navedeno število decimalnih mest. V polje Vrednost vpišite število, ki ga hočete pretvoriti v valuto. Če želite, lahko v polje Decimalke vnesete število decimalnih mest. Če ne boste določili količine decimalnih mest, bodo vsa števila v obliki valute prikazana z dvema decimalnima mestoma.

Obliko valute si lahko nastavite v sistemskih nastavitvah.

DOLLAR(vrednost [; decimalke])

Vrednost je število, sklic na celico, ki vsebuje število, ali formula, ki vrne število.

Decimalke je neobvezen parameter števila decimalnih mest.

=DOLLAR(255) vrne $255.00 pri angleških (ZDA) krajevnih nastavitvah in valuti USD (dolar), ￥255.00 pri japonskih krajevnih nastavitvah in valuti JPY (jen) oz. 255,00 € pri slovenskih krajevnih nastavitvah in valuti EUR (evro).

=DOLLAR(367.456;2) vrne $367,46. Uporabite decimalno ločilo, ki ustreza veljavnim področnim nastavitvam.

EXACT

Primerja dva niza besedil in vrne TRUE, če sta enaka. Ta funkcija loči med malimi in velikimi črkami.

EXACT("besedilo1"; "besedilo2")

Besedilo1 je prvo besedilo za primerjavo.

Besedilo2 je drugo besedilo za primerjavo.

=EXACT("Društvo Lugos";"Društvo LUGOS") vrne FALSE.

FIND

Poišče položaj niza besedila v drugem nizu. Lahko tudi definirate, kje naj se iskanje začne. Iskani niz je lahko število ali kakršen koli niz znakov. Funkcija iskanja loči med malimi in velikimi črkami.

SEARCH("najdi_besedilo"; "besedilo" [; položaj])

Najdi_besedilo se nanaša na besedilo, ki ga želite najti.

Besedilo je besedilo, v katerem poteka iskanje.

Položaj (neobvezno) je položaj v besedilu, od katerega naprej poteka iskanje.

=FIND(76;998877665544) vrne 6.

FIXED

Vrne število kot besedilo z navedenim številom decimalnih mest in opcijsko z ločilom tisočic.

FIXED(število; [decimalke = 2 [; brez_ločila_tisočic = FALSE]])

Število se zaokroži na decimalke decimalnih mest (za decimalnim ločilom) in rezultat je oblikovan kot besedilo, skladno z ustreznimi področnimi nastavitvami.

Decimalke (neobvezno) določa število prikazanih decimalnih mest. Če je parameter decimalke negativen, bo število zaokroženo na ABS(decimake) mest desno od decimalne vejice. Če je decimalke ulomek, bo preprosto okrajšan in ne upošteva najbližjega celega števila.

Brez_ločila_tisočic (neobvezno) določa, ali bo uporabljeno ločilo tisočic. Če je parameter TRUE ali število, ki ni enako nič, ločilo tisočic v izdelanem nizu ne bo uporabljeno. Če je parameter enak 0 ali pa ga sploh ni, bodo prikazana ločila tisočic, kot to določajo vaše veljavne področne nastavitve.

=FIXED(1234567,89;3) vrne 1.234.567,890 kot besedilni niz.

=FIXED(123456,789;;TRUE) vrne 123456,79 kot besedilni niz.

=FIXED(12345,6789;-2) vrne 12.300 kot besedilni niz.

=FIXED(12134567,89;-3;1) vrne 12135000 kot besedilni niz.

=FIXED(12345,789;3/4) vrne 12.346 kot besedilni niz.

=FIXED(12345,789;8/5) vrne 12.345,8 kot besedilni niz.

JIS

Funkcija JIS pretvarja znake ASCII in katakana polne do polovične širine. Vrne niz besedila.

Tabelo pretvorb si oglejte na naslovu https://wiki.openoffice.org/wiki/Calc/Funkcionalnosti/Funkcije_JIS_in_ASC.

JIS("besedilo")

Besedilo je besedilo z znaki, ki jih želite pretvoriti.

Glejte tudi funkcijo ASC.

LEFT

Vrne prvi znak ali znake besedila.

LEFT("besedilo" [; število])

Besedilo je besedilo, v katerem želite določiti začetne dele besed.

Število (neobvezno) določi število znakov za začetno besedilo. Če tega parametra ne določite, je vrnjen en znak.

=LEFT("sladoled";3) vrne »sla«.

LEFTB

Vrne prvi znak ali znake besedila DBCS.

LEFT("besedilo" [; število_bajtov])

Besedilo je besedilo, v katerem želite določiti začetne dele besed.

Število_bajtov (neobvezno) določi število znakov, ki jih želite izluščiti z začetka s funkcijo LEFTB, glede na bajte. Če tega parametra ne določite, vrne en znak.

LEFTB("中国";1) vrne » « (1 bajt je le pol znaka DBCS, zato funkcija vrne znak za presledek).

LEFTB("中国";2) vrne »中« (2 bajta tvorita celovit znak DBCS).

LEFTB("中国";3) vrne »中 « (3 bajti tvorijo en znak DBCS in pol, zato je zadnji vrnjeni znak presledek).

LEFTB("中国";4) vrne »中国« (4 bajti tvorijo dva celovita znaka DBCS).

LEFTB("pisarna";3) vrne »pis« (3 znaki, ki niso znaki DBCS, vsak dolžine 1 bajt).

LEN

Izračuna dolžino niza skupaj s presledki.

LEN("besedilo")

Besedilo je besedilo, katerega dolžino želite določiti.

=LEN("Dober večer") vrne 11.

=LEN(12345,67) vrne 8.

LENB

Za jezike z naborom dvobajtnih znakov (DBCS) vrne število bajtov za predstavljanje znakov v nizu besedila.

LENB("besedilo")

Besedilo je besedilo, katerega dolžino želite določiti.

LENB("中") vrne 2 (1 znak DBCS, ki ga tvorita 2 bajta).

LENB("中国") vrne 4 (2 znaka DBCS, vsakega tvorita 2 bajta).

LENB("pisarna") vrne 7 (7 znakov, ki niso znaki DBCS, vsakega tvori 1 bajt).

=LENB("Dober večer") vrne 11.

=LENB(12345,67) vrne 8.

LOWER

Vse velike črke v besedilnem nizu pretvori v male.

LOWER("besedilo")

Besedilo se nanaša na besedilo, ki bo pretvorjeno.

=LOWER("Lugos") vrne lugos.

MID

Vrne niz besedila. Parametra določata začetni položaj in število znakov.

MID("besedilo"; začetek; število)

Besedilo je besedilo, iz katerega se bodo izločali posamezni deli.

Začetek je položaj znaka, od katerega naprej se bodo izločali deli besedila.

Število določa število znakov v delu besedila.

=MID("LUGOS";3;2) vrne GO.

MIDB

Vrne niz besedila v naboru dvobajtnih znakov (DBCS). Parametra določata začetni položaj in število znakov.

MIDB("besedilo"; začetek; število_bajtov)

Besedilo je besedilo, iz katerega se bodo izločali posamezni deli.

Začetek je položaj znaka, od katerega naprej se bodo izločali deli besedila.

Število_bajtov določa vrnjeno število znakov iz besedila dvobajtnih znakov (DBCS), v bajtih.

MIDB("中国";1;0) vrne »« (0 bajtov je vedno prazen niz).

MIDB("中国";1;1) vrne » « (1 bajt predstavlja le polovico znaka DBCS, zato je rezultat znak za presledek).

MIDB("中国";1;2) vrne »中« (2 bajta tvorita en celovit znak DBCS).

MIDB("中国";1;3) vrne »中 « (3 bajti tvorijo en znak DBCS in pol, zato zadnji bajt vrne presledek).

MIDB("中国";1;4) vrne »中国« (4 bajti tvorijo dva celovita znaka DBCS).

MIDB("中国";2;1) vrne » « (bajt na položaju 2 ni na začetku znaka v nizu DBCS; vrnjen je 1 znak za presledek).

MIDB("中国";2;2) vrne » « (bajt na položaju 2 kaže na drugo polovico prvega znaka v nizu DBCS; iskana 2 bajta zato tvorita drugo polovico prvega znaka in prvo polovico drugega znaka v nizu; zato funkcija vrne 2 znaka za presledek).

MIDB("中国";2;3) vrne » 国« (bajt na položaju 2 ni na začetku znaka v nizu DBCS; za bajt na položaju 2 vrne znak za presledek).

MIDB("中国";3;1) vrne » « (bajt na položaju 3 je na začetku znaka v nizu DBCS, toda 1 bajt dolžine je le pol znaka DBCS, zato vrne znak za presledek).

MIDB("中国";3;2) vrne »国« (bajt na položaju 3 je na začetku znaka v nizu DBCS; 2 bajta tvorita en znak DBCS).

MIDB("pisarna";2;3) vrne »isa« (bajt na položaju 2 je na začetku znaka v nizu, ki ni niz DBCS, tako 3 bajti takšnega niza tvorijo 3 znake).

PROPER

Vse besede v nizu besedila napiše z veliko začetnico.

PROPER("besedilo")

Besedilo se nanaša na besedilo, ki bo pretvorjeno.

=PROPER("društvo lugos") vrne Društvo Lugos.

REPLACE

Zamenja znake v nizu besedila z drugim nizom besedila. To funkcijo se lahko uporabi tako za zamenjavo črk kot tudi števil (ki se avtomatsko pretvorijo v besedilo). Rezultat te funkcije je vedno prikazan kot besedilo. Če hočete s številom, ki ga je že nadomestilo besedilo, delati nadaljnje izračune, ga morate spremeniti nazaj v število s funkcijoVALUE.

Če nočete, da program število prepozna kot število in ga avtomatično pretvori v besedilo, ga dajte v narekovaje.

REPLACE("besedilo"; položaj; dolžina; "novo_besedilo")

Besedilo se nanaša na besedilo, v katerem bo zamenjan določen del.

Položaj je položaj znaka, kjer se bo začela zamenjava besedila.

Dolžina je število znakov v besedilu, ki bodo zamenjani.

Novo_besedilo je besedilo, ki bo nadomestilo Besedilo.

=REPLACE("1234567";1;1;"444") vrne »444234567«. En znak na položaju 1 je v celoti zamenjalo novo_besedilo.

REPT

Niz znakov ponovi v želenem številu kopij.

REPT("besedilo"; število)

Besedilo je besedilo, ki bo ponovljeno.

Število je število ponovitev.

Rezultat lahko obsega največ 255 znakov.

=REPT("Dobro jutro";2) vrne Dobro jutroDobro jutro.

RIGHT

Vrne zadnji znak ali znake besedila.

RIGHT("besedilo" [; število])

Besedilo je besedilo, v katerem bo določen končni del.

Število (neobvezno) je število znakov z desnega konca besedila.

=RIGHT("LUGOS";3) vrne GOS.

RIGHTB

Vrne zadnji znak ali znake besedila v naboru dvobajtnih znakov (DBCS).

RIGHTB("besedilo" [; število_bajtov])

Besedilo je besedilo, v katerem bo določen končni del.

Število_bajtov (neobvezno) je število vrnjenih znakov z desnega konca besedila, glede na bajte.

RIGHTB("中国";1) vrne » « (1 bajt je le pol znaka DBCS. zato vrne znak za presledek).

RIGHTB("中国";2) vrne »国« (2 bajta tvorita en celovit znak DBCS).

RIGHTB("中国";3) vrne » 国« (3 bajti tvorijo pol znaka DBCS in en celovit znak DBCS, zato za prvo polovico znaka vrne presledek).

RIGHTB("中国";4) vrne »中国« (4 bajti tvorijo dva celovita znaka DBCS).

RIGHTB("pisarna";3) vrne »rna« (3 znaki, ki niso znaki DBCS, vsakega tvori 1 bajt).

ROMAN

Arabska števila spremeni v rimska. Vrednost števila mora biti med 0 in 3999, pri načinu pa lahko uporabite cela števila med 0 in 4.

ROMAN(število [; način])

Število je število, ki bo spremenjeno v rimsko število.

Način (neobvezno) določi stopnjo poenostavitve. Višja kot je vrednost, bolj je rimsko število poenostavljeno.

=ROMAN(999) vrne CMXCIX

=ROMAN(999;0) vrne CMXCIX

=ROMAN (999;1) vrne LMVLIV

=ROMAN(999;2) vrne XMIX

=ROMAN(999;3) vrne VMIV

=ROMAN(999;4) vrne IM

SEARCH

Izračuna položaj dela besedila v nizu znakov. Lahko si nastavite točko v besedilu, pri kateri naj se iskanje začne. Besedilo, po katerem boste iskali, je lahko število ali kakršen koli niz znakov. Funkcija iskanja ne loči med malimi in velikimi črkami. Če besedila ne najde, vrne napako 519 (#VALUE).

SEARCH("najdi_besedilo"; "besedilo" [; položaj])

Najdi_besedilo je besedilo, ki ga želite poiskati.

Besedilo je besedilo, v katerem bo potekalo iskanje.

položaj (neobvezno) je položaj v besedilu, od katerega naprej naj poteka iskanje.

=SEARCH(54;998877665544) vrne 10.

SUBSTITUTE

V nizu nadomesti del starega besedila z novim.

SUBSTITUTE("besedilo"; "najdi_besedilo"; "novo_besedilo" [; pojavitev])

Besedilo je besedilo, v katerem bodo zamenjani določeni deli.

Najdi_besedilo je del besedila, ki bo (nekajkrat) zamenjan.

Novo_besedilo je besedilo, ki bo nadomestilo del starega.

Pojavitev (neobvezno) nakazuje, katera pojavitev iskanega besedila naj se zamenja. Če ta parameter ni podan, se iskano besedilo zamenja povsod.

=SUBSTITUTE("123123123";"3";"abc") vrne 12abc12abc12abc.

=SUBSTITUTE("123123123";"3";"abc";2) vrne 12312abc123.

T

Ta funkcija vrne ciljno besedilo ali prazen niz, če cilj ni besedilo.

T(vrednost)

Če je vrednost niz ali se sklicuje na niz, T vrne ta niz besedila, sicer vrne prazen niz.

=T(12345) vrne prazen niz.

=T("12345") vrne niz 12345.

TEXT

Vrednost spremeni v besedilo glede na dano obliko.

TEXT(vrednost; oblika)

Vrednost je (numerična ali besedilna) vrednost, ki bo pretvorjena.

Oblika je besedilo, ki določa obliko. Uporabljajte takšna ločila za desetice in tisočice, kot veljajo za jezik, ki je nastavljen pri obliki celic.

=TEXT(12,34567;"###,##") vrne besedilo 12,35

=TEXT(12,34567;"000,00") vrne besedilo 012,35

=TEXT("xyz";"=== @ ===") vrne besedilo === xyz ===

TRIM

Odstrani presledke iz niza, tako da pusti le en presledek med posameznimi besedami.

TRIM("besedilo")

Besedilo se nanaša na besedilo, v katerem želite odstraniti presledke.

=TRIM(" pozdravljen, svet ") vrne pozdravljen, svet brez začetnih in končnih presledkov in z enojnim presledkom med besedami.

UNICHAR

Pretvori številčno kodo v znak ali črko Unicode.

UNICHAR(število)

=UNICHAR(169) vrne znak zaščitenih avtorskih pravic ©.

UNICODE

Vrne številčno kodo prvega znaka Unicode v nizu besedila.

UNICODE("besedilo")

=UNICODE("©") številko znaka Unicode 169 za znak zaščitenih avtorskih pravic.

UPPER

Izbran niz črk v besedilnem polju spremeni v velike črke.

UPPER("besedilo")

Besedilo se nanaša na male črke, ki jih želite spremeniti v velike.

=UPPER("Dober večer") vrne DOBER VEČER.

VALUE

Besedilni niz spremeni v število.

VALUE("besedilo")

Besedilo je besedilo, ki bo pretvorjeno v število.

=VALUE("4321") vrne 4321.