Matematične funkcije

Ta kategorija vsebuje matematične funkcije za Calc. Če želite odpreti Čarovnika za funkcije, izberiteVstavi – Funkcija.

AGGREGATE

Ta funkcija vrne skupni seštevek izračunov v obsegu. Uporabite lahko različne funkcije agregacije, ki so navedene spodaj. Ta funkcija omogoča izpuščanje skritih vrstic, napak ter rezultatov funkcij SUBTOTAL in drugih funkcij AGGREGATE v končnem izračunu.

RAWSUBTRACT

Odšteje množico števil in vrne rezultat brez izključevanja manjših napak zaokrožanja.

COLOR

Vrne numerično vrednosti, izračunano iz kombinacije treh barv (rdeče, zelene in modre) ter kanala alfa, v barvnem sistemu RGBA. Rezultat je odvisen ob barvnega sistema, ki ga uporablja vaš računalnik.

SUMIFS

Vrne vsoto vrednosti celic v obsegu, ki ustreza več pogojem v več obsegih.

SUMIF

Doda celice, ki so določene z danimi pogoji. Ta funkcija se uporablja za pregledovanje obsega, kadar iščete določeno vrednost.

Iskanje podpira regularne izraze. Če so ti omogočeni, lahko vnesete npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi regularen izraz, morate pred vsak znak vnesi znak »\« ali pa besedilo zaobjeti v \Q...\E. Samodejno vrednotenje nadomestnih znakov ali regularnega izraza lahko vklopite in izklopite v – LibreOffice Calc – Izračuni.

warning

Če uporabljate funkcije, v katerih je vsaj eden argument iskalni pogoj, ki predstavlja regularni izraz, se bo niz pogojev najprej poskusil pretvoriti v števila. Primer: ».0« se pretvori v 0.0 itn. Če pretvorba uspe, iskanje ne bo vrnilo regularnega izraza, temveč število. Če preklopite na slovenske krajevne nastavitve, kjer decimalno ločilo ni pika, temveč vejica, pa pretvorba regularnega izraza deluje. Če želite vsiliti iskanje regularnega izraza namesto števila, uporabite izraz, ki ga ni mogoče pretvoriti v numeričnega, npr. ».[0]«, ».\0« ali »(?i).0«.


Skladnja

SUMIF(obseg; pogoji[; obseg_vsote])

Obseg je obseg, v katerem želimo uporabiti pogoje.

Pogoji je celica, v kateri so prikazani iskalni pogoji, ali iskalni pogoji sami. Če so pogoji zapisani v formuli, morajo biti podani v dvojnih narekovajih.

Obseg_vsote je obseg, katerega vrednosti so seštete. Če ta parameter ni naveden, se seštejejo vrednosti v obsegu.

note

SUMIF podpira operatorja konkatenacije sklicev (~) le kot parameter pogoj, pa še to le, če ni podan neobvezni parameter obseg_vsote.


Primer

Če želite sešteti le negativna števila: =SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:B10) – sešteje vrednosti v obsegu B1:B10 pod pogojem, da so ustrezne vrednosti v obsegu A1:A10 večje od 0.

Glejte tudi COUNTIF() za več primerov, ki jih lahko uporabite s funkcijo SUMIF().

SUBTOTAL

Izračuna delne vsote. Če obseg delne vsote že vsebuje, te v nadaljnjih izračunih niso uporabljene. To funkcijo uporabite s samodejnimi filtri, če želite, da se upoštevajo le izbrani podatki.

Skladnja

SUBTOTAL(funkcija; obseg)

Funkcija je število, ki predstavlja eno od naslednjih funkcij:

Indeks funkcije

(vključuje skrite vrednosti)

Indeks funkcije

(prezre skrite vrednosti)

Funkcija

1

101

AVERAGE

2

102

COUNT

3

103

COUNTA

4

104

MAX

5

105

MIN

6

106

PRODUCT

7

107

STDEV

8

108

STDEVP

9

109

SUM

10

110

VAR

11

111

VARP


Uporabite števila 1-11, da vključite ročno skrite vrstice, ali 101-111, da jih izključite; s filtriranjem izločene celice so vedno izključene.

Obseg je obseg celic, ki so vključene vanj.

Primer

Imate tabelo v celičnem obsegu A1:B6, ki vsebujejo seznam pribora za deset učencev. Vrstica 2, ki vsebuje Nalivnik, je ročno skrita. Želite videti vsoto prikazanih številk, ki je le delna vsota izbranih, filtriranih vrstic. V tem primeru je pravilna formula naslednja:

A

B

1

ELEMENT

ŠTEVILO

2

Nalivnik

10

3

Svinčnik

10

4

Zvezek

10

5

Radirka

10

6

Šilček

10


=SUBTOTAL(9;B2:B6) vrne 50.

=SUBTOTAL(109;B2:B6) vrne 40.

SUMSQ

Izračuna vsoto kvadratov nabora števil.

Skladnja

SUMSQ(število 1 [; število 2 [; ... [; število 255]]])

Število 1, število 2, … , število 255 so numerične vrednosti ali sklici na celice oz. obsege celic s števili.

Primer

Če kot parametre funkcije 1, 2 in 3 vnesete števila 2, 3 in 4, je rezultat 29.

TRUNC

Odreže število tako, da odstrani decimalna mesta.

Skladnja

TRUNC(število; števec)

Vrne število z največ števec decimalnimi mesti. Presežek decimalnih mest je enostavno odstranjen, ne glede na predznak.

TRUNC(število; 0) se vede kot INT(število) za pozitivna števila, negativna števila pa zaokroži proti ničli.

warning

Vidna decimalna mesta rezultata so določena v LibreOffice Calc – Izračuni.


Primer

=TRUNC(1,239;2) vrne 1,23. Pri tem je 9 odrezana.

=TRUNC(-1,234999;3) vrne -1,234. Vse 9-ke so odrezane.

EUROCONVERT

Pretvarja med vrednostmi v starih evropskih nacionalnih valutah in evrih.

Skladnja

EUROCONVERT(vrednost; "iz_valute"; "v_valuto"[; polna_natančnost][; triangularna_natančnost])

Vrednost je količina denarnih enot valute za pretvorbo.

Iz_valute in v_valuto sta denarni enoti za pretvorbo iz prve v drugo. To mora biti besedilo, ki je uradna kratica valute (npr. »EUR« ali »SIT«). Menjalni tečaj (prikazan v evrih) je določila Evropska komisija.

Polna_natančnost je neobvezen parameter. Če je izpuščen ali False, je rezultat zaokrožen glede na decimalke parametra v_valuto. Če je polna_natančnost True, rezultat ni zaokrožen.

Triangularna_natančnost je neobvezen parameter. Če je triangularna_natančnost podana in je >=3, je vmesni rezultat triangularne konverzije (valuta1,EUR,valuta2) zaokrožen na to natančnost. Če je triangularna_natančnost izpuščena, vmesni rezultat ni zaokrožen. Tudi če je v_valuto enako »EUR«, je triangularna_natančnost uporabljena, kot da je triangulacija potrebna in da je bila pretvorba iz EUR v EUR izvršena.

Primeri

=EUROCONVERT(100;"SIT";"EUR") pretvori 100 slovenskih tolarjev v evre.

=EUROCONVERT(100;"EUR";"DEM") pretvori 100 evrov v nemške marke.

CONVERT_OOO

Pretvori vrednost iz enih merskih enot v druge. Faktorji pretvorbe so podani v seznamu nastavitev.

Nekoč je ta seznam faktorjev pretvorbe vključevala nekdanje evropske valute in evro (glejte spodnje primere). Če želite pretvoriti te valute, predlagamo uporabo nove funkcije EUROCONVERT.

Skladnja

CONVERT_OOO(vrednost;"besedilo";"besedilo")

Primer

=CONVERT_OOO(100;"SIT";"EUR") pretvori 100 slovenskih tolarjev v evre.

=CONVERT_OOO(100;"EUR";"DEM") pretvori 100 evrov v nemške marke.

DEGREES

Radiane spremeni v stopinje.

Skladnja

DEGREES(število)

Število je kot v radianih, ki bo pretvorjen v stopinje.

Primer

=DEGREES(PI()) vrne 180 stopinj.

LCM_EXCEL2003

Rezultat je najmanjši skupni večkratnik seznama števil.

note

Funkcije, katerih imena se končajo z _ADD ali _EXCEL2003, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel 2003 brez pripone. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez pripone.


Skladnja

LCM_EXCEL2003(število 1 [; število 2 [; ... [; število 255]]])

Število 1, število 2, … , število 255 so numerične vrednosti ali sklici na celice oz. obsege celic s števili.

Primer

=LCM_EXCEL2003(5;15;25) vrne 75.

GCD_EXCEL2003

Rezultat je največji skupni delitelj seznama števil.

note

Funkcije, katerih imena se končajo z _ADD ali _EXCEL2003, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel 2003 brez pripone. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez pripone.


Skladnja

GCD_EXCEL2003(število 1 [; število 2 [; ... [; število 255]]])

Število 1, število 2, … , število 255 so numerične vrednosti ali sklici na celice oz. obsege celic s števili.

Primer

=GCD_EXCEL2003(5;15;25) vrne 5.

SUM

Sešteje nabor števil.

Skladnja

SUM(število 1 [; število 2 [; ... [; število 255]]])

Število 1, število 2, … , število 255 so numerične vrednosti ali sklici na celice oz. obsege celic s števili.

tip

SUM prezre vse besedilne in prazne celice v obsegu ali matriki. Če sumite,da so rezultati funkcije SUM napačni, preverite prisotnost besedila v obsegih podatkov. Uporabite funkcijo poudarjanje vrednosti, s katero poudarite besedilno vsebino v obsegu, ki lahko predstavlja število.


Primer

Če v besedilne okvire 1; 2 in 3 vnesete števila 2; 3 in 4, je rezultat 9.

=SUM(A1;A3;B5) izračuna vsoto treh celic. =SUM (A1:E10) izračuna vsoto vseh celic v obsegu celic od A1 do E10.

Pogoji, med seboj povezani z AND, se lahko uporabijo s funkcijo SUM() na naslednji način:

Primer predpostavke: V tabelo ste vnesli račune. Stolpec A vsebuje datum računa, stolpec B pa zneske. Želite formulo, s katero bi lahko izračunali skupni znesek za le določen mesec, npr. le za obdobje >=2008-01-01 do <2008-02-01. Datumi obsegajo vrednosti A1:A40, zneski pa B1:B40. C1 vsebuje začetni datum (2008-01-01) računov, ki smo jih upoštevali, C2, ki vsebuje datum 2008-02-01, pa ni več vključen.

Vnesite naslednjo formulo kot matrično formulo:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Če želite to formulo vnesti kot matrično, pritisnite tipke dvigalka+vnašalka, namesto da bi pritisnili le vnašalko, s čimer bi zaprli formulo. Formula se bo v oklepajih prikazala v vrstici Formula.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Formula temelji na dejstvu, da je rezultat primerjave 1, če je pogoj dosežen, in 0, če ni dosežen. Posamezen rezultat primerjave bo obravnavan kot polje in bo uporabljen v množenju matrike, na koncu bodo posamezne vrednosti seštete in podale rezultat – matriko.

SERIESSUM

Sešteje prve člene potenčnega zaporedja.

SERIESSUM(x;n;m;c) = c1xn + c2xn+m + c3xn+2m + ... + cixn + (i-1)m.

Skladnja

SERIESSUM(X; N; M; koeficienti)

X je vhodna vrednost potenčnega zaporedja.

N je začetna stopnja potence.

M je prirastek za povečanje N-ja.

Koeficienti je niz koeficientov. Za vsak koeficient je niz vsote povečan za en razdelek.

RADIANS

Stopinje pretvori v radiane.

Skladnja

RADIANS(število)

Število je kot v stopinjah, ki bo pretvorjen v radiane.

Primer

=RADIANS(90) vrne 1,5707963267949, kar je PI/2 z natančnostjo modula Calc.

PI

Vrne 3,14159265358979, vrednost matematične konstante PI, na 14 decimalnih mest natančno.

Skladnja

PI()

Primer

=PI() vrne 3,14159265358979.

ABS

Vrne absolutno vrednost števila.

Skladnja

ABS(število)

Število je število, katerega absolutno vrednost želimo izračunati. Absolutna vrednost števila je njegova vrednost brez predznaka +/-.

Primer

=ABS(-56) vrne 56.

=ABS(12) vrne 12.

=ABS(0) vrne 0.

QUOTIENT

Vrne celoštevilčni del operacije deljenja.

Skladnja

QUOTIENT(deljenec;delitelj)

Vrne celoštevilčni del imenovalca, deljenega s števcem.

QUOTIENT je enak INT(števec/imenovalec) za števec in imenovalec z enakim predznakom, le da lahko vrne napake z drugačnimi kodami napake. Splošneje: enak je INT(števec/imenovalec/SIGN(števec/imenovalec))*SIGN(števec/imenovalec).

Primer

=QUOTIENT(11;3) vrne 3. Ostanek 2 je izgubljen.

EXP

Vrne e, stopnjevan na potenco števila. Vrednost konstante e je približno 2,71828182845904.

Skladnja

EXP(število)

Število je potenca, na katero želimo eksponirati konstanto e.

Primer

=EXP(1) vrne 2,71828182845904, matematično konstanto e s Calcovo natančnostjo.

FACT

Vrne fakulteto števila.

Skladnja

FACT(število)

Vrne število!, fakulteto števila, ki se izračuna kot 1*2*3*4* ... * število.

=FACT(0) po definiciji vrne 1.

Fakulteta negativnega števila vrne napako »neveljaven argument«.

Primer

=FACT(3) vrne 6.

=FACT(0) vrne 1.

CSCH

Vrne hiperbolični kosekans števila.

tip

Ta funkcija je na voljo od LibreOffice 3.5.


Skladnja

CSCH(število)

Vrne hiperbolični kosekans števila.

Primer

=CSCH(1) vrne približno 0,8509181282, kar je hiperbolični kosekans 1.

Odprite datoteko s primerom:

COSH

Vrne hiperbolični kosinus števila.

Skladnja

COSH(število)

Vrne hiperbolični kosinus števila.

Primer

=COSH(0) vrne 1, kar je hiperbolični kosinus 0.

Odprite datoteko s primerom:

COTH

Vrne hiperbolični kotangens danega števila (kota).

Skladnja

COTH(število)

Vrne hiperbolični kotangens števila.

Primer

=COTH(1) vrne hiperbolični kotangens 1, približno 1,3130.

Odprite datoteko s primerom:

SECH

Vrne hiperbolični sekans števila.

tip

Ta funkcija je na voljo od LibreOffice 3.5.


Skladnja

SECH(število)

Vrne hiperbolični sekans števila.

Primer

=SECH(0) vrne 1, kar je hiperbolični sekans 0.

Odprite datoteko s primerom:

SINH

Vrne hiperbolični sinus števila.

Skladnja

SINH(število)

Vrne hiperbolični sinus števila.

Primer

=SINH(0) vrne 0, kar je hiperbolični sinus 0.

Odprite datoteko s primerom:

TANH

Vrne hiperbolični tangens števila.

Skladnja

TANH(število)

Vrne hiperbolični tangens števila.

Primer

=TANH(0) vrne 0, hiperbolični tangens 0.

Odprite datoteko s primerom:

ACOT

Vrne inverzni kotangens (arkus tangens) danega števila.

Skladnja

ACOT(število)

Ta funkcija vrne inverzni trigonometrični kotangens števila, kar je kot (v radianih), katerega kotangens je število. Vrnjeni kot ima vrednost med 0 in PI.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ACOT(1) vrne 0,785398163397448 (PI/4 radianov).

=DEGREES(ACOT(1)) vrne 45. Tangens 45 stopinj je 1.

Odprite datoteko s primerom:

CSC

Vrne kosekans danega kota (v radianih). Kosekans kota je enak 1, deljeni z sinusom tega kota.

tip

Ta funkcija je na voljo od LibreOffice 3.5.


Skladnja

CSC(število)

Vrne (trigonometrični) kosekans števila, kot v radianih.

Če želite kosekans kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=CSC(PI()/4) vrne približno 1,4142135624, to je obratna vrednost sinusa PI/4 radianov.

=CSC(RADIANS(30)) vrne 2, kosekans 30 stopinj.

Odprite datoteko s primerom:

COS

Vrne kosinus podanega kota (v radianih).

Skladnja

COS(število)

Vrne (trigonometrični) kosinus števila, kot v radianih.

Če želite kosinus kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=COS(PI()/2) vrne 1, to je kosinus PI/2 radianov.

=COS(RADIANS(60)) vrne 0,5, kosinus 60 stopinj.

Odprite datoteko s primerom:

ATAN2

Vrne kot (v radianih) med osjo X in črto od izhodišča do točke (ŠteviloX|ŠteviloY).

Ikona opombe

Ta funkcija je del standarda Open Document Format for Office Applications (OpenDocument) različice 1.2 (ISO/IEC 26300:2-2015).


Skladnja

ATAN2(številoX; številoY)

ŠteviloX je vrednost koordinate X.

ŠteviloY je vrednost koordinate Y.

tip

Programski jeziki imajo običajno obratno zaporedje argumentov pri svojih funkcijah atan2().


ATAN2 vrne kot (v radianih) med osjo X in črto od izhodišča do točke (ŠteviloX, ŠteviloY).

Primer

=ATANH(-5;9) vrne 2,07789 radianov.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

=DEGREES(ATAN2(12,3;12,3)) vrne 45. Tangens 45 stopinj je 1.

note

LibreOffice vrne 0 za ATAN2(0;0).


Funkcijo lahko uporabite za pretvorbo kartezijskih koordinat v polarne.

=DEGREES(ATAN2(-8;5)) vrne φ = 147,9 stopinj

Primer kartezijskih koordinat v polarnih koordinatah

Odprite datoteko s primerom:

COT

Vrne kotangens danega kota (v radianih).

Skladnja

COT(število)

Vrne (trigonometrični) kotangens števila, kot v radianih.

Če želite vrnjeno vrednost kotangensa kota v stopinjah, uporabite funkcijo RADIANS.

Kotangens kota je enak 1, deljeno s tangensom tega kota.

Primeri:

=COT(PI()/4) vrne 1, kotangens PI/4 radianov.

=COT(RADIANS(45)) vrne 1, kotangens 45 stopinj.

Odprite datoteko s primerom:

SQRTPI

Vrne kvadratni koren izraza (PI krat število).

Skladnja

SQRTPI(število)

Vrne pozitivno vrednost kvadratnega korena od (PI pomnoženo s številom).

To je enako SQRT(PI()*število).

Primer

=SQRTPI(2) vrne kvadratni koren števila (2PI), približno 2,506628.

LOG

Vrne logaritem števila na določeno osnovo.

Skladnja

LOG(število[; osnova])

Število je vrednost, katere logaritem želimo izračunati.

Osnova (neobvezno) je osnova za izračun logaritma. Če je izpuščena, je privzeta osnova 10.

Primer

=LOG(10;3) vrne logaritem števila 10 z osnovo 3 (približno 2,0959).

=LOG(7^4;7) vrne 4.

LOG10

Vrne logaritem števila z osnovo 10.

Skladnja

LOG10(število)

Vrne logaritem z osnovo 10 števila.

Primer

=LOG10(5) vrne logaritem števila 5 z osnovo 10 (približno 0,69897).

LCM

Vrne najmanjši skupni večkratnik enega ali več celih števil.

Skladnja

LCM(celo število 1 [; celo število 2 [; ... [; celo število 255]]])

Celo število 1, celo število 2, … , celo število 255 so cela števila ali sklici na celice oz. obsege celic, ki vsebujejo cela števila.

Primer

Če kot parametre funkcije 1, 2 in 3 vnesete števila 512, 1024 in 2000, bo rezultat število 128000.

GCD

Vrne največji skupni delitelj dveh ali več celih števil.

Največji skupni delitelj je največje pozitivno celo število, ki brez ostanka deli vsa podana cela števila.

Skladnja

GCD(celo število 1 [; celo število 2 [; ... [; celo število 255]]])

Celo število 1, celo število 2, … , celo število 255 so cela števila ali sklici na celice oz. obsege celic, ki vsebujejo cela števila.

Primer

=GCD(16;32;24) vrne rezultat 8, ker je 8 največje število, ki deli 16, 24 in 32 brez ostanka.

=GCD(B1:B3), kjer celice B1, B2, B3 vsebujejo vrednosti 9, 12, 9, vrne 3.

RANDBETWEEN

Vrne naključno celo število iz navedenega obsega.

Skladnja

RANDBETWEEN(Dno; Vrh)

Vrne naključno celo število med Dnomin Vrhom (vključno z obema).

Ta funkcija izdela novo naključno število vsakokrat, ko Calc opravi preračun. Če želite izvesti ponovni izračun ročno, pritisnite tipko F9.

Če želite generirati naključna števila, ki se nikoli ponovno ne izračunajo, kopirajte celice, ki vsebujejo to funkcijo, in uporabite Uredi – Posebno lepljenje (tako da Prilepi vse in Formule nista označena in da je označeno polje Števila).

Primer

=RANDBETWEEN(20;30) vrne celo število med 20 in 30.

RANDBETWEEN.NV

Vrne obstojno naključno celo število iz navedenega obsega.

tip

Ta funkcija je na voljo od LibreOffice 7.0.


Skladnja

RANDBETWEEN.NV(Dno; Vrh)

Vrne obstojno naključno celo število med celima številoma dno in vrh (vključno z obema). Obstojna funkcija se ne izračuna ponovno ob novih dogodkih vnosa ali pritiskanja tipka F9. Se pa funkcija ponovno izračuna, če pritisnete tipko F9 s kazalko v celici, ki vsebuje funkcijo, pri odpiranju datoteke ali ko sta ponovno izračunana dno oz. vrh.

Primer

=RANDBETWEEN.NV(20;30) vrne obstojno celo število med 20 in 30.

=RANDBETWEEN.NV(A1;30) vrne obstojno celo število med vrednostjo celice A1 in številom 30. Funkcija se ponovno izračuna, ko se vsebina celice A1 spremeni.

RAND

Vrne naključno število med 0 in 1.

Skladnja

RAND()

Ta funkcija izdela novo naključno število vsakokrat, ko Calc opravi preračun. Če želite izvesti ponovni izračun ročno, pritisnite tipko F9.

Če želite izdelati naključna števila, ki se nikoli ponovno ne izračunajo, storite nekaj od naslednjega:

Primer

=RAND() vrne naključno število med 0 in 1.

RAND.NV

Vrne obstojno naključno število med 0 in 1.

tip

Ta funkcija je na voljo od LibreOffice 7.0.


Skladnja

RAND.NV()

Ta funkcija vrne obstojno naključno število ob vnosu. Obstoja funkcija se ne izračuna ponovno ob novih dogodkih vnosa. Funkcija se ne izračuna ponovno, če pritisnete tipko F9, razen če je kazalka v celici, ki vsebuje funkcijo. Funkcija se ponovno izračuna le ob odpiranju datoteke.

Primer

=RAND.NV() vrne obstojno naključno število med 0 in 1.

LN

Vrne naravni logaritem, katerega osnova je konstanta e. Vrednost konstante e je približno 2,71828182845904.

Skladnja

LN(število)

Število je vrednost, katere naravni logaritem želimo izračunati.

Primer

=LN(3) vrne naravni logaritem števila 3 (približno 1,0986).

=LN(EXP(321)) vrne 321.

ACOS

Vrne obraten trigonometrični kosinus števila.

Skladnja

ACOS(število)

Ta funkcija vrne inverzni arkus kosinus števila, kar je kot (v radianih), katerega kosinus je število. Vrnjeni kot ima vrednost med 0 in PI.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ACOS(-1) vrne 3,14159265358979 (PI radianov)

=DEGREES(ACOS(0,5)) vrne 60. Kosinus 60 stopinj je 0,5.

Odprite datoteko s primerom:

ACOSH

Vrne obratni hiperbolični kosinus števila.

Skladnja

ACOSH(število)

Ta funkcija vrne inverzni hiperbolični kosinus Števila, kar je število, katerega hiperbolični kosinus je Število.

Število mora biti večje ali enako 1.

Primer

=ACOSH(1) vrne 0.

=ACOSH(COSH(4)) vrne 4.

Odprite datoteko s primerom:

ACOTH

Vrne obratni hiperbolični kotangens danega števila.

Skladnja

ACOTH(število)

Ta funkcija vrne inverzni hiperbolični kotangens števila, kar je število, katerega hiperbolični kotangens je število.

Napaka se pojavi, če ima število vrednost med vključno -1 in 1.

Primer

=ACOTH(1,1) vrne inverzni hiperbolični kotangens 1,1, kar je približno 1,52226.

Odprite datoteko s primerom:

ASINH

Vrne obratni hiperbolični sinus števila.

Skladnja

ASINH(število)

Ta funkcija vrne inverzni hiperbolični sinus števila, ki je število, katerega hiperbolični sinus je število.

Primer

=ASINH(-90) vrne približno -5,1929877.

=ASINH(SINH(4)) vrne 4.

Odprite datoteko s primerom:

ATANH

Vrne obratni hiperbolični tangens števila.

Skladnja

ATANH(število)

Ta funkcija vrne inverzni hiperbolični tangens števila, kar je število, katerega hiperbolični tangens je število.

Število mora ustrezati pogoju: -1 < število < 1.

Primer

=ATANH(0) vrne 0.

Odprite datoteko s primerom:

ASIN

Vrne obratni trigonometrični sinus števila.

Skladnja

ASIN(število)

Ta funkcija vrne inverzni trigonometrični sinus števila, kar je kot (v radianih), katerega sinus je število. Vrnjeni kot ima vrednost med -PI/2 in +PI/2.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ASIN(0) vrne 0.

=ASIN(1) vrne 1.5707963267949 (PI/2 radianov).

=DEGREES(ASIN(0,5)) vrne 30. Sinus 30 stopinj je 0,5.

Odprite datoteko s primerom:

ATAN

Vrne obratni trigonometrični tangens števila.

Skladnja

ATAN(število)

Ta funkcija vrne inverzni trigonometrični tangens števila, kar je kot (v radianih), katerega tangens je število. Vrnjeni kot ima vrednost med -PI/2 in PI/2.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ATAN(1) vrne 0,785398163397448 (PI/4 radianov).

=DEGREES(ATAN(1)) vrne 45. Tangens 45 stopinj je 1.

Odprite datoteko s primerom:

MOD

Vrne ostanek pri deljenju prvega celega števila z drugim.

Skladnja

MOD(deljenec; delitelj)

Za celoštevilčne argumente ta funkcija vrne deljenca po modulu delitelja, to je ostanek pri deljenju deljenca z deliteljem.

Ta funkcija je implemenirana kot deljenec - delitelj * INT(deljenec/delitelj). Ta formula vrne rezultat, če argumenti niso cela števila.

Primer

=MOD(22;3) vrne 1, ostanek pri deljenju 22 s 3.

=MOD(11,25;2,5) vrne 1,25.

SQRT

Vrne pozitivno vrednost korena števila.

Skladnja

SQRT(število)

Vrne pozitivni koren števila.

Število mora biti pozitivno.

Primer

=SQRT(16) vrne 4.

=SQRT(-16) vrne napako neveljaven argument.

SIGN

Vrne predznak števila. Vrne 1, če je število pozitivno, -1, če je število negativno, in 0, če je število nič.

Skladnja

SIGN(število)

Število je število, katerega predznak želimo ugotoviti.

Primer

=SIGN(3,4) vrne 1.

=SIGN(-4,5) vrne -1.

SEC

Vrne sekans danega kota (v radianih). Sekans kota je enak 1, deljeno s kosinusom tega kota.

tip

Ta funkcija je na voljo od LibreOffice 3.5.


Skladnja

SEC(število)

Vrne (trigonometrični) sekans števila, kot v radianih.

Če želite vrnjeno vrednost sekansa kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=SEC(PI()/4) vrne približno 1,4142135624, to je obratna vrednost kosinusa PI/4 radianov.

=SEC(RADIANS(60)) vrne 2, sekans 60 stopinj.

Odprite datoteko s primerom:

SIN

Vrne sinus podanega kota (v radianih).

Skladnja

SIN(število)

Vrne (trigonometrični) sinus števila, to je kot v radianih.

Če želite vrnjeno vrednost sinusa kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=SIN(PI()/2) vrne 1, kar je sinus PI/2 radianov.

=SIN(RADIANS(30)) vrne 0,5, sinus 30 stopinj.

Odprite datoteko s primerom:

TAN

Vrne tangens danega kota (v radianih).

Skladnja

TAN(število)

Vrne (trigonometrični) tangens števila, kot v radianih.

Če želite vrnjeno vrednost tangensa kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=TAN(PI()/4) vrne 1, kar je tangens PI/4 radianov.

=TAN(RADIANS(45)) vrne 1, tangens 45 stopinj.

Odprite datoteko s primerom:

MULTINOMIAL

Vrne zmnožek vrste faktorjev vsote argumentov deljenih z produktom zmnožka vrste faktorjev in argumentov.

Skladnja

MULTINOMIAL(število 1 [; število 2 [; ... [; število 255]]])

Število 1, število 2, … , število 255 so numerične vrednosti ali sklici na celice oz. obsege celic s števili.

Primer

=MULTINOMIAL(F11:H11) vrne 1260, če celice od F11 do H11 vsebujejo vrednosti 2, 3 in 4. To ustreza formuli =(2+3+4)! / (2!*3!*4!)

COMBIN

Vrne število kombinacij podmnožic elementov brez ponovitev.

Skladnja

COMBIN(števec1; števec2)

Števec1 je število elementov v množici.

Števec2 je število elementov v množici, med katerimi je mogoče izbirati.

COMBIN vrne število načinov izbora teh elementov. Primer: če imamo v množici tri elemente A, B in C, lahko 2 elementa izberemo na 3 različne načine: AB, AC in BC.

COMBIN izračuna izraz: števec1!/(števec2!*(števec1-števec2)!)

Primer

=COMBIN(3;2) vrne 3.

COMBINA

Vrne število kombinacij podmnožic elementov, vključno s ponovitvami.

Skladnja

COMBINA(števec1; števec2)

Števec1 je število elementov v množici.

Števec2 je število elementov v množici, med katerimi je mogoče izbirati.

COMBINA vrne število različnih načinov izbora teh elementov, pri čemer vrstni red izbiranja ni pomemben, dovoljeno je tudi ponavljanje elementov. Primer: če imamo v množici tri elemente, A, B in C, lahko 2 elementa izberemo na 6 različnih načinov: AA, AB, AC, BB, BC in CC.

COMBINA izračuna izraz: (števec1+števec2-1)! / (števec2!(števec1-1)!)

Primer

=COMBINA(3;2) vrne 6.

POWER

Vrne število na potenco drugega števila.

Skladnja

POWER(osnova; stopnja_potence)

Vrne osnovo na stopnjo potence stopnja_potence.

Enak rezultat lahko dosežemo z uporabo operatorja ^:

osnova^stopnja_potence

Primer

=POWER(4;3) vrne 64, kar je 4 na 3. potenco.

=4^3 vrne tudi 4 na potenco 3.

MROUND

Vrne število, zaokroženo na najbližji večkratnik drugega števila.

Skladnja

MROUND(Število; Večkratnik)

Vrne število, zaokroženo na najbližji večkratnik Večkratnika.

Drugače bi to lahko zapisali kot Večkratnik * ROUND(Število/Večkratnik).

Primer

=MROUND(15,5;3) vrne 15, saj je 15,5 bližje 15 (= 3*5) kot 18 (= 3*6).

=MROUND(1,4;0,5) vrne 1,5 (= 0,5*3).

EVEN

Zaokroži pozitivno število na naslednje sodo celo število in negativno število navzdol na naslednje sodo celo število.

Skladnja

EVEN(število)

Vrne število zaokroženo navzgor na naslednje sodo celo število, stran od nič.

Primer

=EVEN(2,3) vrne 4.

=EVEN(2) vrne 2.

=EVEN(0) vrne 0.

=EVEN(-0,5) vrne -2.

ODD

Zaokroži pozitivno število navzgor na najbližje liho celo število in negativno število navzdol na najbližje liho celo število.

Skladnja

ODD(število)

Vrne število, zaokroženo na naslednje višje liho celo število, stran od nič.

Primer

=ODD(1,2) vrne 3.

=ODD(1) vrne 1.

=ODD(0) vrne 1.

=ODD(-3,1) vrne -5.

ROUNDUP

Zaokroži številko navzgor, stran od nič, na določeno natančnost.

Skladnja

ROUNDUP(število[; števec])

Vrne število, zaokroženo navzgor (stran od nič) na števec decimalnih mest. Če števec izpustite ali ima vrednost nič, funkcija zaokroži na celoštevilčno vrednost. Če je števec negativno število, funkcija zaokroži navzdol na naslednje 10, 100, 1000 itn.

Ta funkcija zaokroži stran od nič. Poglejte si tudi ROUNDDOWN in ROUND.

Primer

=ROUNDUP(1,1111;2) vrne 1,12.

=ROUNDUP(1,2345;1) vrne 1,3.

=ROUNDUP(45,67;0) vrne 46.

=ROUNDUP(-45,67) vrne -46.

=ROUNDUP(987,65;-2) vrne 1000.

ROUND

Zaokroži število na določeno število decimalnih mest.

Skladnja

ROUND(število[; števec])

Vrne število, zaokroženo na števec decimalnih mest. Če števec izpustite ali ima vrednost nič, funkcija zaokroži na najbližje celo število. Če je števec negativen, funkcija zaokroži na najbližjih 10, 100, 1000 itn.

Ta funkcija zaokroži na najbližje število. Poglejte si tudi ROUNDDOWN in ROUNDUP.

Primer

=ROUND(2,348;2) vrne 2,35

=ROUND(-32,4834;3) vrne -32,483. Če želite videti izpisana vsa decimalna mesta, spremenite oblikovanje celice.

=ROUND(2,348;0) vrne 2.

=ROUND(2,5) vrne 3.

=ROUND(987,65;-2) vrne 1000.

ROUNDDOWN

Zaokroži število navzdol, proti nič, z določeno natančnostjo.

Skladnja

ROUNDDOWN(število[; števec])

Vrne število, zaokroženo navzdol (proti nič) na števec decimalnih mest. Če števec izpustite ali ima vrednost nič, funkcija zaokroži na celoštevilčno vrednost. Če je števec negativno število, funkcija zaokroži navzdol na naslednjih 10, 100, 1000 itn.

Ta funkcija zaokroži proti nič. Poglejte si tudi ROUNDUP in ROUND.

Primer

=ROUNDDOWN(1,234;2) vrne 1,23.

=ROUNDDOWN(45,67;0) vrne 45.

=ROUNDDOWN(-45,67) vrne -45.

=ROUNDDOWN(987,65;-2) vrne 900.

PRODUCT

Zmnoži vsa dana števila, ki so podana kot argumenti, in kot rezultat vrne produkt.

Skladnja

PRODUCT(število 1 [; število 2 [; ... [; število 255]]])

Število 1, število 2, … , število 255 so numerične vrednosti ali sklici na celice oz. obsege celic s števili.

Primer

=PRODUCT(2;3;4) vrne 24.

INT

Število zaokroži navzdol na najbližje celo število.

Skladnja

INT(število)

Vrne število, zaokroženo navzdol na najbližje celo število.

Negativna števila se zaokrožijo navzdol na spodnje celo število.

Primer

=INT(5,7) vrne 5.

=INT(-1,3) vrne -2.

Podprite nas!