Informacijske funkcije

V tej kategoriji so funkcije informacij.

Za dostop do tega ukaza ...

Vstavi – Funkcija – Kategorija Informacije


Podatki v tej tabeli so podlaga za nekatere od primerov v opisih funkcij:

C

D

2

vrednost x

vrednost y

3

-5

-3

4

-2

0

5

-1

1

6

0

3

7

2

4

8

4

6

9

6

8


CELL

Poišče informacije o naslovu, oblikovanju ali vsebini celice.

Skladnja

CELL("vrsta_info" [; sklic])

Vrsta_info je niz znakov, ki določa vrsto informacij. Niz znakov je vedno v angleščini. Vseeno je, ali uporabljate velike ali male črke.

Vrsta_info

Pomen

COL

Najde številko stolpca s sklicem.

=CELL("COL";D2) vrne 4.

ROW

Najde številko vrstice s sklicem.

=CELL("ROW";D2) vrne 2.

SHEET

Najde številko delovnega lista s sklicem.

=CELL("Sheet";Sheet3.D2) vrne 3.

ADDRESS

Najde absolutni naslov celice s sklicem.

=CELL("ADDRESS";D2) vrne $D$2.

=CELL("ADDRESS";Sheet3.D2) vrne $Sheet3.$D$2.

=CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) vrne 'file:///X:/dr/test.ods'#$Sheet1.$D$2.

FILENAME

Vrne ime datoteke in številko delovnega lista celice s sklicem.

=CELL("FILENAME";D2) vrne 'file:///X:/dr/own.ods'#$Sheet1, če je formula v trenutnem dokumentu X:\dr\own.ods na delovnem listu Sheet1.

=CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) vrne 'file:///X:/dr/test.ods'#$Sheet1.

COORD

Vrne celotni naslov celice v zapisu Lotus™.

=CELL("COORD"; D2) vrne $A:$D$2.

=CELL("COORD"; Sheet3.D2) vrne $C:$D$2.

CONTENTS

Brez oblikovanja vrne vsebino celice s sklicem.

TYPE

Vrne vrsto vsebine celice.

b = prazna celica (angl. blank)

l = besedilo, rezultat formule v obliki besedila (angl. label)

v = vrednost, rezultat formule v obliki števila (angl. value)

WIDTH

Vrne širino stolpca s sklicem. Enota je število ničel (0) v privzeti pisavi in velikosti, ki jih je mogoče spraviti v stolpec.

PREFIX

Vrne poravnavo celice s sklicem.

' = poravnaj levo

" = poravnaj desno

^ = na sredini

\ = ponavljanje (trenutno nedejavno)

PROTECT

Vrne stanje zaščite celice za celico.

1 = celica je zaščitena

0 = celica ni zaščitena

FORMAT

Vrne niz znakov, ki nakaže obliko števil.

. = število z ločevanjem tisočic

F = število brez ločevanja tisočic

C = valutna oblika

S = eksponentna predstavitev, npr. 1,234+E56

P = odstotki

Pri zgornjih oblikah je število decimalnih mest za decimalno vejico navedeno s številko. Primer: oblika #,##0,0 vrne ,1 in oblika 00,000% vrne P3

D1 = MMM-D-LL, MM-D-LL in podobne oblike

D2 = DD-MM

D3 = MM-LL

D4 = DD-MM-LLLL UU:MM:SS

D5 = MM-DD

D6 = UU:MM:SS AM/PM

D7 = UU:MM AM/PM

D8 = UU:MM:SS

D9 = UU:MM

G = Vse druge oblike

- (minus) na koncu = negativna števila so označena z barvo

() (oklepaji) na koncu = v oblikovni kodi je odprt oklepaj

COLOR

Vrne 1, če so bile negativne vrednosti oblikovane z barvo, sicer pa vrne 0.

PARENTHESES

Vrne 1, če oblikovna koda vsebuje odprt oklepaj (, sicer pa vrne 0.


Sklic (seznam možnosti) je preverjani položaj celice. Če je sklic obseg, se celica premakne zgoraj levo od obsega. Če sklica ni, uporabi LibreOffice Calc položaj tiste celice, v kateri je formula. Microsoft Excel uporabi sklic celice, v kateri je kazalka.

CURRENT

Ta funkcija vrne dosedanji rezultat ocene formule, katere del je (z drugimi besedami: rezultat, do kakršnega je pripeljalo dosedanje ocenjevanje). Njena glavna uporaba je skupaj s funkcijo STYLE() pri uporabi izbranih slogov na celicah glede na njihovo vsebino.

Skladnja

CURRENT()

Primer

=1+2+CURRENT()

Ta primer vrne 6. Formula je izračunana z leve na desno na naslednji način: 1 + 2 je enako 3, kar preda rezultat datumu, ko naleti na CURRENT(); CURRENT() tako vrne 3, kar se prišteje izvirni 3, da dobimo 6.

=A2+B2+STYLE(IF(CURRENT()>10;"Rdeče”;”Privzeto”))

Primer vrne A2 + B2 (STYLE vrne v tem primeru 0). Če je vsota večja od 10, je slog Rdeče dodeljen celici. Oglejte si funkcijo STYLE za podrobnejšo razlago.

="ču"&CURRENT()

Ta primer vrne čuču.

Tehnični podatki

Ta funkcija ni del standarda Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Imenski prostor je

ORG.OPENOFFICE.CURRENT

FORMULA

Prikaže formulo celice s formulo kot besedilo.

Ta funkcija se vedno znova izračuna, ko se izvede ponovno izračunavanje.

Skladnja

FORMULA(sklic)

sklic je sklic na celico, ki vsebuje formulo.

Neveljaven sklic ali sklic na celico, ki ne vsebuje formule, vrne napako #N/A (ni na voljo).

Primer

Če celica A8 vsebuje formulo =SUM(1;2;3), potem

=FORMULA(A8) vrne besedilo =SUM(1;2;3).

IFERROR

Vrne vrednost, če celica ne vsebuje vrednosti napake, ali nadomestno vrednost, če jo.

tip

Ta funkcija je na voljo od LibreOffice 4.0.


Skladnja

IFERROR(vrednost; nadomestna_vrednost)

Vrednost je vrednost ali izraz, ki bo vrnjen, če ni enak napaki ali če je ne povzroči.

Nadomestna_vrednost je vrednost ali izraz, ki bo vrnjen, če izraz ali vrednost Vrednost ni enaka napaki ali je ne povzroči.

Primer

=IFERROR(C8;C9), kjer celica C8 vsebuje =1/0, vrne vrednost celice C9, ker je 1/0 neveljaven izraz.

=IFERROR(C8;C9), kjer celica C8 vsebuje =1/0, vrne 13, vrednost celice C8, ki ni neveljaven izraz.

IFNA

Vrne vrednost, če celica ne vsebuje napake #N/A (vrednost ni na voljo), ali nadomestno vrednost, če jo.

tip

Ta funkcija je na voljo od LibreOffice 4.0.


Skladnja

IFNA(vrednost; nadomestna_vrednost)

Vrednost je vrednost ali izraz, ki bo vrnjen, če ni enak napaki #N/A ali je ne povzroči.

Nadomestna_vrednost je vrednost ali izraz, ki bo vrnjen, če izraz ali vrednost Vrednost ni enaka napaki #N/A ali je ne povzroči.

Primer

=IFNA(D3;D4) vrne vrednost D3, če D3 ne da rezultata #N/A, oz. D4, če ga povzroči.

INFO

Vrne specifične informacije o trenutnem delovnem okolju. Funkcija sprejme en besedilni argument in vrne podatke v odvisnosti od tega parametra.

Ta funkcija se vedno znova izračuna, ko se izvede ponovno izračunavanje.

Skladnja

INFO("vrsta")

V naslednji tabeli je seznam vrednosti besedilnega parametra vrsta in vrnjenih vrednosti funkcije INFO.

Vrednost za »vrsto«

Vrnjena vrednost

"osversion"

Vedno »Windows (32-bit) NT 5.01«, zaradi združljivosti

"system"

Vrsta operacijskega sistema:
»ANDROID« za operacijski sistem za mobilne naprave podjetja Google;
»DRAGONFLY« za operacijski sistem DragonFly, razvit iz FreeBSD;
»EMSCRIPTEN« za brskalniški sistem WebAssembly;
»FREEBSD«, »OPENBSD« ali »NETBSD« za operacijske sisteme na osnovi BSD (Berkeley Software Distribution);
»HAIKU« za operacijski sistem, združljiv z BeOS;
»iOS« za operacijski sistem za mobilne naprave podjetja Apple;
»LINUX« za operacijske sisteme na osnovi GNU/Linux;
»MACOSX« za macOS podjetja Apple;
»SOLARIS« za operacijski sistem Solaris podjetja Oracle;
»WNT« za Microsoft Windows.

"release"

Identifikator izdaje izdelka; primer: »300m25(Build:9876)«

"numfile"

Zaradi združljivosti vedno 1

"recalc"

Trenutni način preračunavanja formul, lahko »Samodejno« ali »Ročno« (lokalizirano v jezik LibreOffice)


note

Drugi programi za delo s preglednicami morda sprejmejo lokalizirane vrednosti parametra vrsta, LibreOffice Calc pa sprejme samo angleške vrednosti.


Primer

=INFO("release") vrne številko različice LibreOffice, ki jo uporabljate.

=INFO(D5), pri čemer vsebina celice D5 vsebuje niz system, ki vrne vrsto operacijskega sistema.

ISBLANK

Vrne TRUE, če je sklic na celico prazen. Ta funkcija se uporablja za preverjanje, ali je vsebina celice prazna. Celica s formulo ni prazna.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

ISBLANK(vrednost)

Vrednost je vsebina, ki jo preverjamo.

Primer

=ISBLANK(D2) kot rezultat vrne FALSE.

ISERR

Preveri za napačne pogoje, razen #N/A (ni na voljo) in vrne TRUE ali FALSE.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

ISERR(vrednost)

Vrednost je poljubna vrednost ali izraz, za katerega bo preverjeno, če je prisotna vrednost napake, različna od #N/A (ni na voljo).

Primer

=ISERR(C8), kjer celica C8 vsebuje =1/0, vrne TRUE, ker je 1/0 napaka.

=ISERR(C9), kjer celica C9 vsebuje =NA(), ker ISERR() ne upošteva napake #N/A (ni na voljo).

ISERROR

Preveri veljavnost pogojev, vključno z vrednostjo napake #N/A (ni na voljo), in vrne TRUE ali FALSE.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

ISERROR(vrednost)

Vrednost je ali se sklicuje na vrednost za preverjanje. ISERROR() vrne TRUE, če je napaka, in FALSE, če napake ni.

Primer

=ISERROR(C8), kjer celica C8 vsebuje =1/0, vrne TRUE, ker je 1/0 neveljaven izraz.

=ISERROR(C9), kjer celica C9 vsebuje =NA(), vrne TRUE.

ISEVEN

Vrne TRUE, če je vrednost sodo celo število ali FALSE, če je vrednost liha.

Skladnja

ISEVEN(vrednost)

Vrednost je vrednost, ki jo želimo preveriti.

Če Vrednost ni celo število, so vse decimalke prezrte. Prezrt je tudi predznak Vrednosti.

Primer

=ISEVEN(48) vrne TRUE

=ISEVEN(33) vrne FALSE.

=ISEVEN(0) vrne TRUE

=ISEVEN(-2,1) vrne TRUE

=ISEVEN(3,999) vrne FALSE

ISEVEN_ADD

Preveri sodost števila. Vrne 1, če je rezultat deljenja števila z 2 celo število.

note

Funkcije, katerih imena se končajo z _ADD ali _EXCEL2003, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel 2003 brez pripone. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez pripone.


Skladnja

ISEVEN_ADD(število)

Število je vrednost, ki bo preizkušena.

Primer

=ISEVEN_ADD(5) vrne 0.

=ISEVEN_ADD(A1) vrne 1, če celica A1 vsebuje število 2.

ISFORMULA

Vrne TRUE, če celica vsebuje formulo.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

ISFORMULA(sklic)

Sklic pomeni sklic na celico, za katero želimo preveriti, če vsebuje formulo.

Primer

=ISFORMULA(C4) vrne FALSE, če celica C4 vsebuje število 5.

ISLOGICAL

Preveri logično vrednost (TRUE ali FALSE).

Če pride do napake, funkcija vrne FALSE.

Skladnja

ISLOGICAL(vrednost)

Vrne TRUE, če je Vrednost logična vrednost (TRUE ali FALSE), v nasprotnem primeru vrne FALSE.

Primer

=ISLOGICAL(99) vrne FALSE, ker je 99 število in ne logična vrednost.

=ISLOGICAL(ISNA(D4)) vrne TRUE, ne glede na to, kaj vsebuje celica D4, ker ISNA() vrne logično vrednost.

ISNA

Vrne TRUE, če celica vsebuje napačno vrednost #N/A (vrednost ni na voljo).

Če pride do napake, funkcija vrne FALSE.

Skladnja

ISNA(vrednost)

Vrednost je vrednost ali izraz, ki ga preverjamo.

Primer

=ISNA(D3) kot rezultat vrne FALSE.

ISNONTEXT

Preveri, ali celica vsebuje besedilo ali številke, in vrne FALSE, če je vsebina besedilo.

Če pride do napake, funkcija vrne TRUE.

Skladnja

ISNONTEXT(vrednost)

Vrednost je poljubna vrednost ali poljubni izraz, ki ga preverjamo, bodisi da je besedilo, številke ali Boolova vrednost.

Primer

=ISNONTEXT(D2) vrne FALSE, če celica D2 vsebuje besedilo abcdef.

=ISNONTEXT(D9) vrne TRUE, če celica D9 vsebuje število 8.

ISNUMBER

Vrne TRUE, če se vrednost sklicuje na število.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

ISNUMBER(vrednost)

Vrednost je kateri koli izraz, ki ga preverjamo, ali je število ali besedilo.

Primer

=ISNUMBER(C3) vrne TRUE, če celica C3 vsebuje število 4.

=ISNUMBER(C2) vrne FALSE, če celica C2 vsebuje besedilo abcdef.

ISODD

Vrne TRUE, če je vrednost liha, ali FALSE, če je število sodo.

Skladnja

ISODD(vrednost)

Vrednost je vrednost, ki jo želimo preveriti.

Če Vrednost ni celo število, so vse decimalke prezrte. Prezrt je tudi predznak Vrednosti.

Primer

=ISODD(33) vrne TRUE

=ISODD(48) vrne FALSE.

=ISODD(3,999) vrne TRUE

=ISODD(-3,1) vrne TRUE

ISODD_ADD

Vrne TRUE (1), če rezultat pri deljenju z 2 ni celo število.

note

Funkcije, katerih imena se končajo z _ADD ali _EXCEL2003, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel 2003 brez pripone. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez pripone.


Skladnja

ISODD_ADD(število)

Število je vrednost, ki bo preizkušena.

Primer

=ISODD_ADD(5) vrne 1.

ISREF

Preveri, če je argument sklic. Vrne TRUE, če je argument sklic, sicer vrne FALSE. Če je podan sklic, funkcija ne preuči sklicane vrednosti.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

ISREF(vrednost)

Vrednost je vrednost, za katero želite preveriti, ali je sklic.

Primer

=ISREF(C5) vrne rezultat TRUE, ker je C5 veljaven sklic.

=ISREF("abcdef") vedno vrne FALSE, saj navadno besedilo nikoli ne more biti sklic.

=ISREF(4) vrne FALSE.

=ISREF(INDIRECT("A6")) vrne TRUE, saj je INDIRECT funkcija, ki vrne sklic.

=ISREF(ADDRESS(1; 1; 2;"DelovniList2")) vrne FALSE, ker je ADDRESS funkcija, ki vrne besedilo, čeprav je videti kot sklic.

ISTEXT

Vrne TRUE, če je vsebina celice sklic na besedilo.

Če pride do napake, funkcija vrne FALSE.

Skladnja

ISTEXT(vrednost)

Vrednost je vrednost, število, Boolova vrednost ali napačna vrednost, ki jo preverjamo.

Primer

=ISTEXT(D9) vrne TRUE, če celica D9 vsebuje besedilo abcdef.

=ISTEXT(C3) vrne FALSE, če celica C3 vsebuje število 3.

N

Vrne številsko vrednost danega parametra. Vrne 0, če je parameter besedilo ali FALSE.

Če pride do napake, funkcija vrne vrednost napake.

Skladnja

N(vrednost)

Vrednost je parameter za pretvorbo v številko. N() vrne številsko vrednost, če je to mogoče. Logični vrednosti TRUE in FALSE vrne kot 1 in 0. Besedilo vrne kot 0.

Primer

=N(123) vrne 123

=N(TRUE()) vrne 1

=N(FALSE()) vrne 0

=N("abc") vrne 0

=N(1/0) vrne #DIV/0!

NA

Vrne napačno vrednost #N/A.

Skladnja

NA()

Primer

=NA() pretvori vsebino celice v #N/A.

TYPE

Vrne vrsto vrednosti, kjer je 1 = število, 2 = besedilo, 4 = logična vrednost, 8 = formula, 16 = vrednost napake, 64 = matrika.

Če se pojavi napaka, funkcija vrne logično ali številsko vrednost.

Skladnja

TYPE(vrednost)

Vrednost je dana vrednost, za katero je potrebno ugotoviti vrsto podatka.

Primer (glejte tabelo s primeri zgoraj)

=TYPE(C2) vrne kot rezultat 2.

=TYPE(D9) vrne kot rezultat 1.

Podprite nas!