Finančne funkcije – Prvi del

V teh kategoriji so matematične funkcije za finance, ki jih vsebuje LibreOffice Calc.

ACCRINT

Izračuna nabrane obresti za vrednostni papir v primeru obročnih plačil.

Skladnja

ACCRINT(izdaja; prve_obresti; poravnava; mera; [imenska_vrednost]; frekvenca [; osnova])

Izdaja (obvezno) je datum izdaje vrednostnega papirja.

Prve_obresti (obvezno) je prvi obrestni datum vrednostnega papirja.

Poravnava (obvezno) je datum, ko naj bodo izračunane do takrat nabrane obresti.

Mera (obvezno) je nominalna letna obrestna mera (kuponska obrestna mera)

Imenska_vrednost (neobvezno) je nominalna vrednost vrednostnega papirja. Če je izpuščena, je uporabljena privzeta vrednost 1000.

note

Priporočamo, da vedno navedete vrednost argumenta Par funkcije ACCRINT, namesto da program Calc uporabi naključno privzeto vrednost. S tem bo vaša formula bolj razumljiva in enostavneje jo bo vzdrževati.


Frekvenca (obvezno) je število plačil obresti na leto (1, 2 ali 4).

Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Vrednostni papir je bil izdan 28. 2. 2001. Prve obresti so določene za 31. 8. 2001. Datum poravnave je 1. 5. 2001. Obrestna mera je 0,1 oz. 10 % in imenska vrednost je 1000 denarnih enot. Obresti se izplačujejo na pol leta (frekvenca je 2). Osnova je ameriška metoda (0). Koliko obresti se je nabralo?

=ACCRINT("28.2.2001";"31.8.2001";"1.5.2001";0,1;1000;2;0) vrne 16,94444.

ACCRINTM

Izračuna nabrane obresti vrednostnega papirja v primeru enkratnega izplačila na datum poravnave.

Skladnja

ACCRINTM(izdaja; poravnava; mera [; imenska_vrednost [; osnova]])

Izdaja (obvezno) je datum izdaje vrednostnega papirja.

Poravnava (obvezno) je datum, ko naj bodo izračunane do takrat nabrane obresti.

Mera (obvezno) je nominalna letna obrestna mera (kuponska obrestna mera).

Imenska_vrednost (neobvezno) je nominalna vrednost vrednostnega papirja. Če je izpuščena, je uporabljena privzeta vrednost 1000.

note

Priporočamo, da vedno navedete vrednost argumenta imenska_vrednost funkcije ACCRINTM, namesto da program Calc uporabi naključno privzeto vrednost. S tem bo vaša formula bolj razumljiva in enostavneje jo bo vzdrževati.


Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Vrednostni papir je bil izdan 1. 4. 2001. Datum zapadlosti je 15. 6. 2001. Mera je 0,1 oz. 10 % in imenska vrednost je 1000 denarnih enot. Osnova dnevnega/letnega izračuna je dnevna bilanca (3). Koliko obresti se je nabralo?

=ACCRINTM("1.4.2001";"15.6.2001";0,1;1000;3) vrne 20,54795.

AMORDEGRC

Izračuna višino amortizacije kot degresivno amortizacijo za obračunsko obdobje. V nasprotju s funkcijo AMORLINC je tu uporabljen koeficient amortizacije, ki je neodvisen od amortizacijske dobe.

Skladnja

AMORDEGRC(stroški; datum_nakupa; prvo_obdobje; rešeno; obdobje; mera [; osnova])

Stroški so stroški pridobitve.

Datum_nakupa je datum pridobitve.

Prvo_obdobje je končni datum prvega obračunskega obdobja.

Rešeno je rešena vrednost kapitalskega premoženja na koncu amortizacijske dobe.

Obdobje je obravnavano obračunsko obdobje.

Mera je mera amortizacije.

Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Premoženje je bilo pridobljeno 2020-02-01, stroškom je bil 2000 denarnih enot. Končni datum prvega obračunskega obdobja je bil 2020-12-31. Rešena vrednost premoženja na koncu njegove amortizacijske dobe bo 10 denarnih enot. Mera amortizacije je 0,1 (10 %) in leto se računa po metodi US (osnova 0). Kakšna je vrednost amortizacije v četrtem obdobju amortizacije, če gre za padajočo amortizacijo?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) vrne amortizacijsko vrednost 163 denarnih enot.

note

POZOR: osnova 2 v Microsoft Excel ni podprta. Če uporabljate osnovo 2 in ste izvozili dokument v zapisu XLSX, pri njegovem odpiranju Excel javi napako.


AMORLINC

Izračuna amortizacijo kot linearno amortizacijo za obračunsko obdobje. Če je kapitalsko premoženje pridobljeno med obračunskim obdobjem, je upoštevana sorazmerna višina amortizacije.

Skladnja

AMORLINC(stroški; datum_nakupa; prvo_obdobje; rešeno; obdobje; mera [; osnova])

Stroški so stroški pridobitve.

Datum_nakupa je datum pridobitve.

Prvo_obdobje je končni datum prvega obračunskega obdobja.

Rešeno je rešena vrednost kapitalskega premoženja na koncu amortizacijske dobe.

Obdobje je obravnavano obračunsko obdobje.

Mera je mera amortizacije.

Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Premoženje je bilo pridobljeno 2020-02-01, strošek je bil 2000 denarnih enot. Končni datum prvega obračunskega obdobja je bil 2020-12-31. Rešena vrednost premoženja na koncu njegove amortizacijske dobe bo 10 denarnih enot. Mera amortizacije je 0,1 (10 %) in leto se računa po metodi US (osnova 0). Kakšna je vrednost amortizacije v četrtem obdobju amortizacije, če gre za linearno amortizacijo?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) vrne amortizacijsko vrednost 200 denarnih enot.

note

POZOR: osnova 2 v Microsoft Excel ni podprta. Če uporabljate osnovo 2 in ste izvozili dokument v zapisu XLSX, pri njegovem odpiranju Excel javi napako.


DB

Vrne amortizacijo sredstva za določeno obdobje z uporabo metode fiksno pojemajočega salda.

To obliko amortizacije lahko uporabite, če želite dobiti višjo vrednost na začetku amortizacije (v nasprotju z linearno amortizacijo). Vrednost amortizacije se z vsakim obdobjem zmanjša za višino amortizacije, ki je bila že odšteta od začetnih stroškov.

Skladnja

DB(stroški; rešeno; življenjska_doba; obdobje [; mesec])

Stroški so začetni stroški premoženja.

Rešeno je vrednost sredstva na koncu njegove življenjske dobe.

Življenjska_doba določa obdobje amortizacije.

Obdobje določi dolžino vsakega obdobja. Dolžina mora biti vnesena v isti časovni enoti kot obdobje amortizacije.

Mesec (neobvezno) določi število mesecev za prvo leto amortizacije. Če vnosa ne določite, je uporabljena privzeta vrednost 12.

Primer

Za računalniški sistem z začetno ceno 25.000 denarnih enot računamo amortizacijo v obdobju treh let. Rešena vrednost premoženja naj bo 1.000 denarnih enot. Prvo obdobje amortizacije predstavlja 6 mesecev (pol leta). Kakšna je fiksno nižajoča se amortizacija računalniškega sistema v drugem obdobju, ki je celoletno in se začenja s koncem prvega polletnega obdobja?

=DB(25000; 1000; 3; 2; 6) vrne 11.037,95 denarnih enot.

DDB

Izračuna amortizacijo sredstva za določeno obdobje z uporabo metode aritmetičnega padanja.

To obliko amortizacije lahko uporabite, če potrebujete višjo začetno vrednost namesto linearne amortizacije. Vrednost amortizacije se zmanjša z vsakim obdobjem in se navadno uporablja za sredstva, pri katerih je izguba vrednosti višja takoj po nakupu (npr. vozila, računalniki). Knjižna vrednost pri tej vrsti računanja ne bo nikoli dosegla ničle.

Skladnja

DDB(stroški; rešeno; življenjska_doba; obdobje [; faktor])

Stroški so začetni stroški premoženja.

Rešeno določi vrednost sredstva na koncu njegove življenjske dobe.

Življenjska_doba je število obdobij (npr. let ali mesecev), ki določajo, kako dolgo bo sredstvo v uporabi.

Obdobje je obdobje, za katerega bo izračunana vrednost.

Faktor (neobvezno) je faktor, za katerega se amortizacija zmanjšuje. Če ne vnesete vrednosti, je privzeti faktor 2.

Primer

Za računalnik z začetno ceno 75.000 denarnih enot računamo mesečno amortizacijo za 5 let. Vrednost na koncu amortizacijo naj bo 1 denarna enota. Faktor je 2.

=DDB(75000;1;60;12;2) = 1.721,81 denarnih enot. Dvojno padajoča amortizacija v prvem mesecu po nakupu je torej 1.721,81 denarnih enot.

DISC

Izračuna popust (v odstotkih) za vrednostni papir.

Skladnja

DISC(poravnava; zapadlost; cena; odkup [; osnova])

Poravnava je datum nakupa vrednostnega papirja.

Zapadlost je datum, ko vrednostni papir zapade (poteče).

Cena je cena vrednostnega papirja na 100 denarnih enot nominalne vrednosti.

Odkup je odkupna vrednost vrednostnega papirja na 100 denarnih enot nominalne vrednosti.

Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Vrednostni papir kupimo 25.1.2001; datum zapadlosti je 15.11.2001. Cena (kupna cena) je 97, odkupna vrednost pa 100. Kako visoka je poravnava (popust), če računamo z osnovo 3 (dnevna bilanca)?

=DISC("25.1.2001";"15.11.2001";97;100;3) vrne 0,0372 oz. 3,72 odstotkov.

DURATION

Izračuna trajanje v letih določene nespremenljive obrestne mere za vrednostni papir.

Skladnja

DURATION(poravnava; zapadlost; kupon; donos; frekvenca [; osnova])

Poravnava je datum nakupa vrednostnega papirja.

Zapadlost je datum, ko vrednostni papir zapade (poteče).

Kupon je letna kuponska obrestna mera (nominalna obrestna mera).

Donos je letni donos vrednostnega papirja.

Frekvenca je število plačil obresti na leto (1, 2 ali 4).

Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Vrednostni papir kupimo 1. 1. 2001; datum zapadlosti je 1. 1. 2006. Nominalna obrestna mera je 8 %. Donos je 9,0 %. Obresti plačamo dvakrat na leto (frekvenca je 2). Če uporabimo dnevni izravnalni izračun obresti (osnova 3), kako dolgo je prilagojeno trajanje?

=DURATION("01.01.2001";"01.01.2006";0,08;0,09;2;3) vrne 4,2 let.

EFFECT

Izračuna neto letno obrestno mero za nominalno obrestno mero.

Nominalne obresti pomenijo znesek obresti, ki mora biti izplačan na koncu obračunskega obdobja. Efektivne obresti se povečujejo s številom izplačil. Drugače povedano, obresti se pogosto plačuje v obrokih (npr. mesečnih ali četrtletnih) pred koncem obračunskega obdobja.

Skladnja

EFFECT(Nom; P)

Nom so nominalne obresti.

P je število obrestnih plačilnih obdobij na leto.

Primer

Če je letna nominalna obrestna mera 9,75 % in so določena štiri obrestna obračunska obdobja, kolikšna je dejanska obrestna mera (efektivna obrestna mera)?

=EFFECT(9,75%;4) = 10,11 %. Efektivna letna obrestna mera je torej 10,11 %.

EFFECT_ADD

Na podlagi nominalne obrestne mere in števila plačil obresti na leto izračuna efektivno letno obrestno mero.

note

Funkcije, katerih imena se končajo z _ADD ali _EXCEL2003, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel 2003 brez pripone. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez pripone.


Skladnja

EFFECT_ADD(nominalna_stopnja;Nnal)

Nominalna_mera je nominalna letna obrestna mera.

Nnal je število plačil obresti po obdobjih na leto.

Primer

Kolikšna je efektivna letna obrestna mera pri 5,25 % nominalni stopnji in četrtletnih izplačilih?

=EFFECT_ADD(0,0525;4) vrne 0,053543 ali 5,3543 %.

IRR

Izračuna notranje obrestne mere dobička za naložbo. Vrednosti predstavljajo vrednosti dotoka denarja v rednih intervalih, vsaj ena vrednost mora biti negativna (izplačila) in vsaj ena pozitivna (dohodki).

Če plačila niso opravljena ob rednih intervalih, uporabite funkcijo XIRR.

Skladnja

IRR(vrednosti [; ocena])

Vrednosti predstavlja matriko, ki vsebuje vrednosti.

Ocena (neobvezno) je ocena vrednosti. Za izračun notranje obrestne mere dobička je uporabljena ponavljalna (iterativna) metoda. Če imate na voljo le malo vrednosti, morate vnesti začetno oceno, da bo iteracija mogoča.

note

Ta funkcija prezre vse besedilne in prazne celice v obsegu podatkov. Če sumite,da so rezultati funkcije napačni, preverite prisotnost besedila v obsegih podatkov. Uporabite funkcijo poudarjanje vrednosti, s katero poudarite besedilno vsebino v obsegu, ki lahko predstavlja število.


Primer

Če domnevamo, da so vsebine celic A1=-10000, A2=3500, A3=7600 in A4=1000, vrne formula =IRR(A1:A4) rezultat 11,33 %.

warning

Zaradi uporabljene iterativne metode je možno, da IRR ne uspe in vrne napako 523 z opisom »Napaka: izračun ne konvergira« v vrstici stanja. V tem primeru poskusite z drugo vrednostjo za oceno.


ISPMT

Izračuna višino obresti za konstantne (nespremenjene) obroke amortizacije.

Skladnja

ISPMT(mera; obdobje; skupaj_obdobij; invest)

Mera je periodična obrestna mera.

Obdobje je število obrokov za izračun obresti.

Skupaj_obdobij je skupno število obročnih obdobij.

Invest je višina naložbe.

Primer

Za kredit v višini 120.000 denarnih enot s plačilnim rokom dveh let, mesečnimi obroki in 12 % letno obrestno mero nas zanima višina obresti po 1,5 leta.

=ISPMT(1%;18;24;120000) = -300 denarnih enot. Mesečne obresti po 1,5 leta znesejo 300 denarnih enot.

PV

Izračuna sedanjo vrednost naložbe glede na zaporedje rednih plačil.

To funkcijo lahko uporabite, če želite izračunati, koliko denarja potrebujete za naložbo z določeno obrestno mero danes, da boste v določenem obdobju prejeli določeno vsoto (anuiteto). Ugotovite lahko tudi, koliko denarja bo ostalo po poteku obdobja. Določite tudi, če naj bo vsota izplačana na začetku ali koncu vsakega obdobja.

Vrednosti vnesite kot številke, izraze ali sklice. Če so npr. letne obresti znašajo 8 %, za obdobje pa hočete uporabiti mesec, pod Mera vnesite 8%/12 in LibreOffice Calc bo samodejno izračunal pravilni faktor.

Skladnja

PV(mera; NPer; Pmt [; PV [; vrsta]])

Mera določi obrestno mero na obdobje.

NPer je skupno število vseh obdobij (plačilno obdobje).

Pmt je redno plačilo v vsakem obdobju.

FV (neobvezno) določi bodočo preostalo vrednost, ki bo ostala po zadnjem plačilu.

Vrsta (neobvezno) določa roke plačil. Vrsta = 1 pomeni, da je plačilo na začetku obdobja, vrsta = 0 (privzeto) pa pomeni, da je plačilo na koncu obdobja.

V funkcijah LibreOffice Calc lahko parametre, ki niso označeni kot »zahtevani«, izpustite le tedaj, ko ne sledi noben parameter. Če sta npr. za funkcijo s štirimi parametri prva dva označena kot »zahtevano«, lahko izpustite parameter 4 ali parametra 3 in 4, ne smete pa izpustiti zgolj parametra 3.

Primer

Kolikšna je sedanja vrednost naložbe, če je mesečno izplačanih 500 denarnih enot, letna obrestna mera pa je 8 %? Plačilno obdobje je 48 mesecev in na koncu obdobja mora ostati 20.000 denarnih enot.

=PV(8%/12;48;500;20000) = -35.019,37 denarnih enot. Pod naštetimi pogoji morate danes na račun položiti 35.019,37 denarnih enot, če želite 48 mesecev prejemati po 500 denarnih enot na mesec in imeti na koncu še 20.000 denarnih enot. Navzkrižno preverjanje pokaže, da 48 x 500 denarnih enot + 20.000 denarnih enot = 44.000 denarnih enot. Razlika med to vsoto in 35.000 denarnimi enotami na vašem računu predstavlja izplačane obresti.

Če v formulo namesto teh vrednosti vnesete sklice, lahko izračunate poljubno število scenarijev »če-potem«. Upoštevajte: sklici na konstante morajo biti definirani kot absolutni sklici. Primere za programe te vrste najdete pod funkcijami amortizacije.

RECEIVED

Izračuna prejeto vsoto, ki je izplačana za obveznico z določeno obrestno mero na določen datum.

Skladnja

RECEIVED(poravnava; zapadlost; naložba; popust [; osnova])

Poravnava je datum nakupa vrednostnega papirja.

Zapadlost je datum, ko vrednostni papir zapade (poteče).

Naložba je nakupna cena.

Popust je odstotek popusta pri nakupu vrednostnega papirja.

Osnova (neobvezno): izbere se s seznama možnosti in prikazuje, kako bo izračunano leto.

Osnova

Izračun

0 ali izpuščen

Metoda US (NASD), 12 mesecev po 30 dni vsak

1

Točno število dni v mesecih, točno število dni v letu

2

Točno število dni v mesecu, leto ima 360 dni

3

Točno število dni v mesecu, leto ima 365 dni

4

Evropska metoda, 12 mesecev po 30 dni vsak


Primer

Datum poravnave: 15. februar 1999, datum zapadlosti: 15. maj 1999, višina investicije: 1000 denarnih enot, popust: 5,75 odstotkov, osnova: Dnevna bilanca/360 = 2.

Vsota, ki jo boste prejeli na datum zapadlosti, se izračuna tako:

=RECEIVED("15.2.1999";"15.5.1999";1000;0,0575;2) vrne 1014,420266.

SYD

Izračuna aritmetično padajočo mero amortizacije.

To funkcijo lahko uporabite, če želite izračunati amortizacijo za določeno obdobje celotne amortizacijske dobe predmeta. Aritmetično padajoča amortizacija od obdobja do obdobja za stalno vsoto zmanjšuje višino amortizacije.

Skladnja

SYD(stroški; rešeno; življenjska_doba; obdobje)

Stroški so začetni stroški premoženja.

Rešeno je vrednost premoženja po amortizaciji.

Življenjska_doba je obdobje, ki določi časovni razpon, v katerem premoženje izgublja vrednost.

Obdobje določi obdobje, za katerega računamo amortizacijo.

Primer

Domači kino, ki je stal 50.000 denarnih enot, letno izgublja vrednost naslednjih 5 let. Vrednost reševanja naj bo 10.000 denarnih enot. Izračunati hočete amortizacijo za prvo leto.

=SYD(50000;10000;5;1)=13,333.33 denarnih enot. Višina amortizacije za prvo leto je 13.333,33 denarnih enot.

Če želite imeti pregled višine amortizacije v različnih obdobjih, je najbolje, če določite depreciacijsko tabelo. Če eno zraven druge vnašate različne formule za amortizacijo, ki so na voljo v programu LibreOffice Calc, boste videli, katera je najprimernejša. Tabelo izpolnite tako:

A

B

C

D

E

1

Začetni stroški

Rešena vrednost

Življenjska doba

Časovno obdobje

Amort. SYD

2

50.000 denarnih enot

10.000 denarnih enot

5

1

13.333,33 denarnih enot

3

2

10.666,67 denarnih enot

4

3

8.000,00 denarnih enot

5

4

5.333,33 denarnih enot

6

5

2.666,67 denarnih enot

7

6

0,00 denarnih enot

8

7

9

8

10

9

11

10

12

13

>0

Skupaj

40.000,00 denarnih enot


Formula v celici E2 je taka:

=SYD($A$2;$B$2;$C$2;D2)

Ta formula se v stolpcu E ponavlja vse do E11 (izberite E2, potem pa spodnji desni rob celice z miško potegnite navzdol).

V celici E13 je formula za preverjanje skupnega zneska amortizacije. Ker negativne vrednosti v E8:E11 ne smejo biti upoštevane, uporablja funkcijo SUMIF. Pogoj >0 je v celici A13. Formula v E13 je taka:

=SUMIF(E2:E11;A13)

Sedaj lahko pogledate amortizacijo za obdobje 10 let, za vrednost reševanja v višini 1 denarne enote, vnesete drugačne začetne stroške itd.

Finančne funkcije – Drugi del

Finančne funkcije – Tretji del

Seznam funkcij po kategorijah

Podprite nas!