Funkcija StrConv

Pretvori niz, kot ga določa vrsta pretvorbe.

To konstanto, funkcijo ali predmet omogočimo z ukazom Option VBASupport 1, ki ga moramo vstaviti pred izvedljivo programsko kodo v modulu.

Skladnja:

StrConv(niz As String, Pretvorba As Integer, [ LCID ])

Vrnjena vrednost:

String

Parametri:

niz: poljuben veljaven izraz vrste String (niz).

Pretvorba: vrsta pretvorbe, ki jo želite izvesti, kot je določeno v spodnji tabeli.

Pretvorba	Vrednost	Opis
vbUpperCase	1	Pretvori znake besedila v velike črke.
vbLowerCase	2	Pretvori znake besedila v male črke.
vbProperCase	3	Pretvori prvo črko vsake besede besedilu v velike črke.
vbWide	4	Pretvori ozke znake (znake polovične širine) v besedilu v široke znake (znake polne širine).
vbNarrow	8	Pretvori široke znake (znake polne širine) v besedilu v ozke znake (znake polovične širine).
vbKatakana	16	Pretvori znake Hiragana v besedilu v znake Katakana.
vbHiragana	32	Pretvori znake Katakana v besedilu v znake Hiragana.
vbUnicode	64	Pretvori znake v besedilu v znake Unicode z uporabo privzete kodne strani sistema.
vbFromUnicode	128	Pretvori znake v besedilu iz Unicode v privzeto kodno stran sistema.

LCID Neobvezno. ID krajevnih nastavitev v desetiški obliki. Če ta parameter izpustite, predvideva ID krajevnih nastavitev sistema. Za možne vrednosti LCID glejte datoteko msi-encodinglist.txt.

Primer:


Option VBASupport 1
Option Explicit
Sub Test_StrConv
    Print StrConv("abc EFG hij", vbUpperCase) '= "ABC EFG HIJ"
    Print StrConv("abc EFG hij", vbLowerCase) ' =  "abc efg hij"
    Print StrConv("abc EFG hij", vbProperCase) ' = "Abc Efg Hij"

    REM Pretvori znake polovične širine (enojni bajt) v nizu v znake polne širine
    Print StrConv("ABCDEVB¥ì¥¹¥¥å©", vbWide) ' = "ＡＢＣＤＥＶＢ￥ì￥¹￥￥å©"

    REM Pretvori znake polne širine (dvojni bajt) v nizu v znake polovične širine
    Print StrConv("ＡＢＣＤ＠＄％２３＇？ＥＧ", vbNarrow) ' = "ABCD@$%23'?EG"

    REM Pretvori znake Hiragana v nizu v znake Katakana
    Print StrConv("かたかな", vbKatakana) ' = "カタカナ"

    REM Pretvori znake Katakana v nizu v znake Hiragana
    Print StrConv("カタカナ", vbHiragana) '= "かたかな"

    REM  Domneva kodiranje v CP-1252, povezano s krajevnimi nastavitvami en-US, uporabljeno v preizkusih enot.
    Dim x() As Byte
    x = StrConv("ÉÏº£ÊÐABC", vbFromUnicode)
    Print UBound(x) ' 8 znakov
    Print x(2) ' = 186
    Print StrConv(x, vbUnicode)' = "ÉÏº£ÊÐABC"
End Sub

Izključne funkcije in ukazi VBA