Funkcija CreateUnoServiceWithArguments

Tvori instanco storitve UNO z upraviteljem procesnih storitev ProcessServiceManager, vključno z dopolnilnimi neobveznimi argumenti.

Skladnja:


     CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object
tip

Storitve UNO, ki jih je mogoče uporabiti s funkcijo CreateUnoServiceWithArguments, je mogoče identificirati z imeni metod, ki sledijo vzorcu createInstanceWith.. ali createWith...


Parametri:

ServiceName: ime storitve UNO, ki naj bo ustvarjena.

Arguments: eden ali več argumentov, ki določajo instanco storitve. Arguments je shranjen kot enodimenzionalno polje, skladno s položaji elementov v definiciji metode konstruktorja.

Vrnjena vrednost:

Instanca danega imena storitve UNO, sicer vrednost Null.

note

Seznam storitev, ki so na razpolago, najdete na strani com::sun::star Module (v angl. jeziku).


Primer:

Spodnji primer com.sun.star.ui.dialogs.FilePicker prikaže pogovorno okno Shrani kot z dvema dodatnima kontrolnikoma: s seznamskim in potrditvenim poljem.


    Sub FileSaveAsDialog()
       td = com.sun.star.ui.dialogs.TemplateDescription
       options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
       dlg = CreateUnoServiceWithArguments( _
          "com.sun.star.ui.dialogs.FilePicker", _
          Array(options))
    End Sub ' FileSaveAsDialog
tip

Storitve UNO imajo obsežno spletno dokumentacijo na spletišču api.libreoffice.org. Obiščite stran o storitvi FilePicker (v angl.), da izveste več o metodah, ki jih nudi storitev, uporabljena v zgornjem primeru.


Primer:

Naslednja koda uporablja storitev com.sun.star.security.DocumentDigitalSignatures za podpisovanje trenutnega dokumenta:


Sub  SignCurrentDocDialog
   Dim pv(0) as new com.sun.star.beans.PropertyValue
   pv(0).Name  = "StorageFormat"
   pv(0).Value = "ZipFormat"
   mode = com.sun.star.embed.ElementModes
   sf = CreateUnoService("com.sun.star.embed.StorageFactory")
   storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
   dds = CreateUnoServiceWithArguments( _
      "com.sun.star.security.DocumentDigitalSignatures", _
      Array("1.2", True)) 
   dds.signDocumentContent(storage, Null)
End Sub ' SignCurrentDocDialog

Metodi konstruktorja CreateWithVersion in createWithVersionAndValidSignature constructor methods v storitvi UNO com.sun.star.security.DocumentDigitalSignatures nakazujeta dva različna načina tvorjenja instance te storitve s funkcijo CreateUnoServiceWithArguments.

Podobne teme

Funkcija CreateUnoService

Predmeti, funkcije in storitve UNO Basic

Raba funkcij programa Calc v makrih

Podprite nas!