РАБДЕНЬ.МЕЖД

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

Синтаксис

WORKDAY.INTL(StartDate; Days [; Weekend [; Holidays]])

StartDate: is the date from when the calculation is carried out.

Days is the number of workdays. Positive value for a result after the start date, negative value for a result before the start date.

Weekend is an optional parameter – a number or a string used to specify the days of the week that are weekend days and are not considered working days. Weekend is a weekend number or string that specifies when weekends occur. Weekend number values indicate the following weekend days:

Number 1 to 7 for two-day weekends and 11 to 17 for one-day weekends.

Number	Выходные
1 or omitted	Суббота и воскресенье
2	Воскресенье и понедельник
3	Понедельник и вторник
4	Вторник и среда
5	Среда и четверг
6	Четверг и пятница
7	Пятница и суббота
11	Только воскресенье
12	Только понедельник
13	Только вторник
14	Только среда
15	Только четверг
16	Только пятница
17	Только суббота

Weekend string provides another way to define the weekly non-working days. It must have seven (7) characters – zeros (0) for working day and ones (1) for non-working day. Each character represents a day of the week, starting with Monday. Only 1 and 0 are valid. “1111111” is an invalid string and should not be used. For example, the weekend string “0000011” defines Saturday and Sunday as non-working days.

Holidays is an optional list of dates that must be counted as non-working days. The list can be given in a cell range.

При вводе дат как части формул, косые черты или тире, используемые в качестве разделителей дат, интерпретируются как арифметические операторы. Поэтому даты, введённые в этом формате, не распознаются как даты и приводят к ошибочным вычислениям. Чтобы даты не интерпретировались как части формул, используйте функцию DATE, например DATE (1954;7;20) или поместите дату в кавычки и используйте нотацию ISO 8601, например «1954-07-20». Избегайте использования форматов даты, зависящих от локальных настроек, таких как «07/20/54», расчёт может привести к ошибкам, если документ загружен в соответствии с иными локальными настройками.

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in - LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.

Примеры

What date comes 20 workdays after December 13, 2016? Enter the start date in C3 and the number of workdays in D3.

The weekend parameter (number) may be left blank or defined as 1 for default weekend (non-working days) – Saturday and Sunday.

Cells F3 to J3 contain five (5) holidays for Christmas and New Year in date format: December 24, 2016; December 25, 2016; December 26, 2016; December 31, 2016; and January 1, 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

To define Friday and Saturday as weekend days, use the weekend parameter 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

To define Sunday only the weekend day, use the weekend parameter 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatively, use the weekend string "0000001" for Sunday only weekend.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

The function can be used without the two optional parameters – Weekday and Holidays – by leaving them out:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Техническая информация

Эта функция доступна начиная с LibreOffice 4.3.

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.WORKDAY.INTL

WORKDAY.INTL wiki page.

Функции Дата и Время

[text/scalc/01/func_isoweeknum.xhp#isoweeknum not found].

[text/scalc/01/func_weeknum_ooo.xhp#weeknum_ooo not found].