Функции электронных таблиц
Этот раздел содержит описание функций электронных таблиц, а также примеры.
ТИП.ОШИБКИ
Returns a number representing a specific Error type, or the error value #N/A, if there is no error.
DDE
Возвращает результат для ссылки DDE. Если содержимое диапазона или раздела изменилось, возвращаемое значение также меняется. Чтобы просмотреть обновлённые ссылки, следует перезагрузить электронную таблицу или выбрать команду Правка - Ссылки. Межплатформенные ссылки, например, ссылки в установке LibreOffice, запущенной в ОС Windows на документ, созданный в ОС Linux, запрещены.
DDE("Server"; "File"; "Range" [; Mode])
Server is the name of a server application. LibreOffice applications have the server name "soffice".
Файл: полное имя файла, включая путь.
Диапазон: область, содержащая данные для оценки.
Режим: необязательный параметр для управления методами преобразования данных в числа на сервере DDE.
|
Режим |
Результат |
|
0 или отсутствует |
Формат числа из стиля ячейки "По умолчанию" |
|
1 |
Данные всегда преобразуются в стандартный формат для английского языка (США) |
|
2 |
Данные извлекаются в виде текста; преобразование в числа не выполняется |
=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.
=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.
АДРЕС
Возвращает адрес (ссылку) ячейки в виде текста в соответствии с указанными номерами строки и столбца. Можно выбрать отображение адреса как абсолютного (например, $A$1), относительного (A1) или смешанного типа (A$1 или $A1). Можно также указать имя листа.
Для функциональной совместимости функции АДРЕС и ДВССЫЛ поддерживают необязательный параметр, который позволяет указать, использовать ли вместо нотации адреса A1 нотацию R1C1.
В функции АДРЕС этот параметр вставляется в качестве четвёртого параметра, смещая при этом необязательный параметр имени листа на пятое место.
В функции ДВССЫЛ этот параметр добавляется в качестве второго параметра.
В обеих функциях, если аргумент вставлен со значением 0, используется нотация R1C1. Если аргумент не используется или его значение не равно нулю, используется нотация A1.
Если используется нотация R1C1, функция АДРЕС возвращает строки адреса, используя в качестве разделителя имён листов восклицательный знак '!', а функция ДВССЫЛ ожидает, что в качестве разделителя имён листов используется восклицательный знак. В нотации А1 обе функции по-прежнему используют в качестве разделителя имён листов точку '.'.
When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.
Если при сохранении документа в формате ODF 1.0/1.1 в функциях АДРЕС имеется четвёртый параметр, этот параметр будет удалён.
Не сохраняйте электронную таблицу в старом формате ODF 1.0/1.1, если четвёртый параметр функции АДРЕС использовался со значением 0.
Функция ДВССЫЛ сохраняется без преобразования в формат ODF 1.0/1.1. Если имеется второй параметр, более старая версия Calc возвратит для этой функции ошибку.
ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])
Строка: номер строки для ссылки на ячейку.
Столбец: номер столбца для ссылки на ячейку (число, а не буква).
Абс определяет тип ссылки:
1: абсолютная ($A$1)
2: абсолютная ссылка на строку, относительная ссылка на столбец (A$1)
3: строка (относительная), столбец (абсолютная) ($A1)
4: относительная (A1)
A1 (необязательный параметр): если для этого параметра установлено значение 0, то используется нотация R1C1. Если этот параметр отсутствует или имеет значение, отличное от 0, то используется нотация A1.
Лист: имя листа. Имя столбца заключается в двойные кавычки.
Пример:
=АДРЕС(1; 1; 2; ;"Лист2") возвращает следующий результат: Лист2.A$1
If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.
ВПР
Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])
Lookup is the value of any type looked for in the first column of the array.
Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.
Индекс: количество столбцов в массиве, который содержит возвращаемое значение. Первому столбцу соответствует номер 1.
SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.
You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.
Введите следующую формулу в ячейку B1:
=ВПР(A1; D1:E100; 2)
При вводе номера в ячейку A1 в ячейке B1 будет отображен соответствующий текст, который содержится во втором столбце массива D1:E100. При вводе несуществующего номера в ячейке отображается текст для следующего номера. Для исключения этого задайте последнему параметру формулы значение ЛОЖЬ, чтобы при вводе несуществующего номера отображалось сообщение об ошибке.
ВЫБОР
Эта функция использует индекс для возврата значения из списка, содержащего до 30 значений.
CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])
Индекс: ссылка или число в диапазоне от 1 до 30, указывающее на значение, которое требуется извлечь из списка.
Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.
=CHOOSE(A1; B1; B2; B3; "Сегодня"; "Вчера"; "Завтра"), например, возвращает содержимое ячейки B2 для A1 = 2; для A1 = 4 функция возвращает текст "Сегодня".
ГИПЕРССЫЛКА
При щелчке ячейки с функцией ГИПЕРССЫЛКА открывается соответствующая гиперссылка.
If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.
Чтобы открыть ячейку с гиперссылкой с помощью клавиатуры, выделите ячейку, нажмите клавишу F2, чтобы включить режим редактирования, поместите курсор в начало гиперссылки, нажмите сочетание клавиш SHIFT+F10, а затем выберите команду Открыть гиперссылку.
HYPERLINK("URL" [; CellValue])
URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.
Для пустых ячеек и элементов матрицы возвращается 0.
=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.
=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.
=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.
=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.
=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.
=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.
=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".
=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.
ГПР
Служит для поиска значения и ссылки на ячейки в выделенной области. Эта функция проверяет первую строку массива на наличие определённого значения. Функция возвращает значение в тот же столбец в строку массива в соответствии с её номером в индексе.
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])
For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)
Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.
|
A |
B |
C |
D |
... |
DO |
|
|---|---|---|---|---|---|---|
|
1 |
Element |
Hydrogen |
Helium |
Lithium |
... |
Oganesson |
|
2 |
Symbol |
H |
He |
Li |
... |
Og |
|
3 |
Atomic Number |
1 |
2 |
3 |
... |
118 |
|
4 |
Relative Atomic Mass |
1.008 |
4.0026 |
6.94 |
... |
294 |
=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.
=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.
=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.
ДВССЫЛ
Возвращает ссылку в виде текстовой строки. Эту функцию можно также использовать для получения области соответствующей строки.
Для функциональной совместимости функции АДРЕС и ДВССЫЛ поддерживают необязательный параметр, который позволяет указать, использовать ли вместо нотации адреса A1 нотацию R1C1.
В функции АДРЕС этот параметр вставляется в качестве четвёртого параметра, смещая при этом необязательный параметр имени листа на пятое место.
В функции ДВССЫЛ этот параметр добавляется в качестве второго параметра.
В обеих функциях, если аргумент вставлен со значением 0, используется нотация R1C1. Если аргумент не используется или его значение не равно нулю, используется нотация A1.
Если используется нотация R1C1, функция АДРЕС возвращает строки адреса, используя в качестве разделителя имён листов восклицательный знак '!', а функция ДВССЫЛ ожидает, что в качестве разделителя имён листов используется восклицательный знак. В нотации А1 обе функции по-прежнему используют в качестве разделителя имён листов точку '.'.
When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.
Если при сохранении документа в формате ODF 1.0/1.1 в функциях АДРЕС имеется четвёртый параметр, этот параметр будет удалён.
Не сохраняйте электронную таблицу в старом формате ODF 1.0/1.1, если четвёртый параметр функции АДРЕС использовался со значением 0.
Функция ДВССЫЛ сохраняется без преобразования в формат ODF 1.0/1.1. Если имеется второй параметр, более старая версия Calc возвратит для этой функции ошибку.
INDIRECT(Ref [; A1])
Ссылка: ссылка на ячейку или область (в текстовой форме), содержимое которой подлежит возврату.
A1 (необязательный параметр): если для этого параметра установлено значение 0, то используется нотация R1C1. Если этот параметр отсутствует или имеет значение, отличное от 0, то используется нотация A1.
If you open an Excel spreadsheet that uses indirect addresses calculated from string functions, the sheet addresses will not be translated automatically. For example, the Excel address in INDIRECT("[filename]sheetname!"&B1) is not converted into the Calc address in INDIRECT("filename#sheetname."&B1).
=ДВССЫЛ(A1) возвращает значение 100, если ячейка A1 содержит ссылку на ячейку C108, а ячейка C108 содержит значение 100.
=СУММ(ДВССЫЛ("a1:" & АДРЕС(1; 3))) суммирует содержимое ячеек в области от A1 до ячейки, адрес которой определён в строке 1 и столбце 3. Таким образом, вычисляется сумма диапазона A1:C1.
ДСВТ
Функция ДСВТ возвращает значение результата из сводной таблицы. Значение адресуется с помощью имён поля и элемента, поэтому оно остаётся действительным даже при изменении структуры сводной таблицы.
Можно использовать два разных синтаксиса:
GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])
или
ДСВТ(сводная таблица; ограничения)
Второй синтаксис используется при наличии двух параметров, первый из которых является ячейкой или ссылкой на диапазон ячеек. Во всех других случаях применяется первый синтаксис. В мастере функций отображается первый синтаксис.
First Syntax
Целевое_поле: строка для выбора одного из полей данных сводной таблицы. Эта строка может содержать имя исходного столбца или имя поля данных, отображаемое в таблице (например, "Сумма – Сбыт").
Сводная_таблица является ссылкой на ячейку или диапазон ячеек, расположенный в сводной таблице или содержащий сводную таблицу. Если диапазон ячеек содержит несколько сводных таблиц, то используется таблица, созданная последней.
При отсутствии пар поле n/элемент n возвращается общий итог. В противном случае каждая пара добавляет ограничение, которому должен удовлетворять результат. Поле n является именем поля из сводной таблицы. Элемент n является именем элемента из этого поля.
Если сводная таблица содержит только одно значение результата, которое удовлетворяет всем ограничениям, или результат промежуточного итога, который является суммой всех сопоставимых значений, то возвращается этот результат. При отсутствии результата сопоставления или при нескольких результатах без промежуточного итога возвращается ошибка. Эти условия относятся к результатам, включённым в сводную таблицу.
Исходные данные, которые содержат записи, скрытые настройками сводной таблицы, игнорируются. Порядок пар "поле/элемент" не имеет значения. Регистр имён полей и элементов не учитывается.
If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.
Значения промежуточных итогов из сводной таблицы используются только для функции "Авто" (кроме значений, включённых в ограничения, см. ниже Второй синтаксис).
Second Syntax
Сводная_таблица: аналогично первому варианту синтаксиса.
Ограничения: список значений, разделённых пробелами. Элементы списка могут заключаться в кавычки (одиночные). Вся строка заключается в двойные кавычки (за исключением случая ссылки на строку из другой ячейки).
Одна из записей может быть именем поля данных. Если сводная таблица содержит только одно поле данных, имя поля данных можно не указывать; в противном случае его необходимо определить.
Все остальные записи указывают ограничение в форме Поле[Элемент] (с символами "[" и "]"), либо только Элемент, если имя элемента уникально среди всех полей, используемых в сводной таблице.
Имя функции можно добавить в форме Поле[Элемент;Функция], в результате чего сопоставление ограничится только значениями промежуточных итогов, для которых эта функция используется. Допустимые имена функций - Sum, Count, Average, Max, Min, Product, Count (только числа), StDev (выборка), StDevP (заполнение), Var (выборка) и VarP (заполнение) без учёта регистра.
ИНДЕКС
Функция INDEX возвращает поддиапазон, для которого указаны номер строки и столбца или имя диапазона. В зависимости от контекста, функция INDEX возвращает ссылку или значение.
INDEX(Reference [; Row [; Column [; Range]]])
Ссылка: ссылка, введённая вручную или определённая посредством указания имени диапазона. Если ссылка содержит несколько диапазонов, то эту ссылку или имя диапазона следует заключить в скобки.
Строка (необязательный параметр): индекс строки в диапазоне, для которого возвращается значение. В случае нуля (строка не указана) возвращаются все вызванные строки.
Столбец (необязательный параметр): индекс столбца в диапазоне, для которого возвращается значение. В случае нуля (столбец не указан) возвращаются все столбцы в ссылке.
Диапазон (необязательный параметр): индекс поддиапазона в случае ссылки на составной диапазон.
=INDEX(Цены; 4; 1) возвращает значение для строки 4 и столбца 1 из диапазона в базе данных, определённого по пути Данные – Определить как Цены.
=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.
=INDEX(A1:B6; 1) возвращает ссылку на первую сроку диапазона A1:B6.
=INDEX(A1:B6; 0; 1) возвращает ссылку на первый столбец диапазона A1:B6.
=INDEX((multi);4;1) indicates the value contained in row 4 and column 1 of the (multiple) range, which you named under Sheet - Named Ranges and Expressions - Define as multi. The multiple range may consist of several rectangular ranges, each with a row 4 and column 1. If you now want to call the second block of this multiple range enter the number 2 as the range parameter.
=INDEX(A1:B6; 1; 1) возвращает значение левой верхней ячейки диапазона A1:B6.
=INDEX((составной); 0; 0; 2) возвращает ссылку на второй диапазон составного диапазона.
ЛИСТ
Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.
ЛИСТ([Ссылка])
Ссылка (необязательный параметр): ссылка на ячейку или область, либо строка с именем листа.
=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.
=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.
ЛИСТЫ
Служит для определения количества листов для ссылки. Если параметры не заданы, возвращается количество листов в текущем документе.
ЛИСТЫ([Ссылка])
Ссылка: ссылка на лист или область. Этот параметр является необязательным.
=SHEETS(Sheet1.A1:Sheet3.G12) возвращает значение 3, если листы лист1, листt2 и лист3 стоят в указанной последовательности.
ОБЛАСТИ
Возвращает количество отдельных диапазонов, входящих в составной диапазон. Диапазон может состоять из смежных ячеек или одной ячейки.
В функцию передаётся только один аргумент. При определении составных диапазонов их необходимо заключать в дополнительные скобки. Составные диапазоны указываются через точку с запятой (;), но этот знак автоматически преобразуется в оператор "тильда" (~). Тильда используется для объединения диапазонов.
ОБЛАСТИ(Ссылка)
Ссылка. Ссылка на ячейку или диапазон ячеек.
=ОБЛАСТИ((A1:B3; F2; G1)) возвращает значение 3, поскольку это ссылка на три ячейки или области. После ввода выполняется преобразование в =ОБЛАСТИ((A1:B3~F2~G1)).
=ОБЛАСТИ(Все) возвращает значение 1, если в окне Данные – определить диапазон была определена область с именем «Все».
ПОИСКПОЗ
Возвращает относительную позицию в массиве элемента, который совпадает с заданным значением. Функция возвращает позицию значения, найденного в массиве, в виде числа.
MATCH(Search; LookupArray [; Type])
Search is the value which is to be searched for in the single-row or single-column array.
Массив: ссылка для поиска. Это может быть одна строка или столбец, либо часть одной строки или столбца.
Тип: параметр, который может принимать значения 1, 0 или -1. Если этот параметр имеет значение 1, либо значение не указано, предполагается, что значения в первом столбце массива отсортированы по возрастанию. Если этому параметру присвоено значение -1, это означает, что значения столбца отсортированы по убыванию. Эта функция соответствует аналогичной функции в Microsoft Excel.
If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).
If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
=MATCH(200; D1:D100) выполняет поиск значения 200 в области D1:D100, отсортированной по столбцу D. По достижении этого значения возвращается номер соответствующей строки. Если найденное значение больше искомого, возвращается номер предыдущей строки.
ПРОСМОТР
Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.
Если с помощью функции LOOKUP не удаётся установить критерий поиска, то он соответствует самому большому значению в векторе просмотра, который меньше, чем критерий поиска, или равен ему.
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
LOOKUP(Lookup; SearchVector [; ResultVector])
Lookup is the value of any type to be looked for; entered either directly or as a reference.
Вектор_поиска: область для выполнения поиска, состоящая из отдельной строки или столбца.
Вектор_результата: другой диапазон из одной строки или одного столбца, из которого извлекается результат функции. Функция возвращает ячейку для вектора результата с тем же индексом, что и экземпляр, найденный в векторе просмотра.
=LOOKUP(A1; D1:D100; F1:F100) позволяет выполнить поиск соответствующей ячейки в диапазоне D1:D100 для числа, указанного в ячейке A1. Для найденного экземпляра определяется индекс, например, 12-я ячейка в этом диапазоне. Затем содержимое 12-й ячейки возвращается в виде значения функции (в векторе результата).
СМЕЩ
Возвращает значение смещения ячейки от заданной точки на определённое число строк и столбцов.
OFFSET(Reference; Rows; Columns [; Height [; Width]])
Ссылка: ссылка, начиная с которой функция выполняет поиск новой ссылки.
Строки: количество строк, на которое ссылка была смещена вверх (отрицательное значение) или вниз.
Строки: количество строк, на которое ссылка была смещена вверх (отрицательное значение) или вниз.
Высота (необязательный параметр) высота области, которая начинается с новой позиции ссылки.
Ширина (необязательный параметр): ширина области, которая начинается с новой позиции ссылки.
Аргументы Строки и Столбцы не должны привести к нулю или отрицательной строке или столбцу начала.
Аргументы Высота и Ширина не должны привести к нулю или отрицательному количеству строк или столбцов.
В функциях LibreOffice Calc параметры, отмеченные, как "необязательные" могут быть пропущены, только если нет параметров, идущих после. Например, в функции с четырьмя параметрами, в которой последние два параметра "необязательные", вы можете пропустить 4-й параметр или 3-й и 4-й, но нельзя пропустить только 3-й параметр.
=СМЕЩ(A1; 2; 2) возвращает значение ячейки C3 (ячейка A1 смещается вниз на две строки и два столбца). Если ячейка C3 содержит значение 100, то эта функция возвращает значение 100.
=СМЕЩ(B2:C3; 1; 1) возвращает ссылку на диапазон B2:C3, перемещённый на 1 строку вниз и на один столбец вправо (C3:D4).
=СМЕЩ(B2:C3; -1; -1) возвращает ссылку на диапазон B2:C3, поднятый на 1 строку и сдвинутый влево на 1 столбец (A1:B2).
=СМЕЩ(B2:C3; 0; 0; 3; 4) возвращает ссылку на диапазон B2:C3, размер которого изменён на 3 строки и 4 столбца (B2:E4).
=СМЕЩ(B2:C3; 1; 0; 3; 4) возвращает ссылку на диапазон B2:C3, смещённый вниз на одну строку и изменивший размер на 3 строки и 4 столбца (B2:E4).
=СУММ(СМЕЩ(A1; 2; 2; 5; 6)) позволяет определить общую площадь области, которая начинается с ячейки C3 и имеет в своём составе 5 строк в высоту и 6 столбцов в ширину (область=C3:H7).
If Width or Height are given, the OFFSET function returns a cell range reference. If Reference is a single cell reference and both Width and Height are omitted, a single cell reference is returned.
СТИЛЬ
Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats, "red" and "green" have to be defined beforehand.
The STYLE function should not be used without compelling reason, its purpose is the use with asynchronous Add-In functions to visually notify about the availability of a result. In almost all other cases using conditional formatting instead is a better choice.
STYLE("Style" [; Time [; "Style2"]])
Стиль: имя стиля, назначенного ячейке. Имена стилей заключаются в кавычки.
Время (необязательный параметр): промежуток времени в секундах. Если этот параметр не задан, то по истечении определённого промежутка времени стиль остаётся без изменений.
Стиль2 (необязательный параметр): имя стиля, применяемого к ячейке по истечении определённого промежутка времени. Если этот параметр не определён, то используется стиль «По умолчанию».
В функциях LibreOffice Calc параметры, отмеченные, как "необязательные" могут быть пропущены, только если нет параметров, идущих после. Например, в функции с четырьмя параметрами, в которой последние два параметра "необязательные", вы можете пропустить 4-й параметр или 3-й и 4-й, но нельзя пропустить только 3-й параметр.
=STYLE("невидимый"; 60; "по умолчанию") применяет к ячейке прозрачный формат на 60 секунд после повторного расчёта или загрузки документа, после чего применяет формат "По умолчанию". Для обеих ячеек необходимо предварительно определить формат.
Since STYLE() has a numeric return value of zero, this return value gets appended to a string. This can be avoided using T() as in the following example:
="Текст"&T(STYLE("myStyle"))
Другой пример см. в описании ТЕКУЩ().
ORG.OPENOFFICE.STYLE
СТОЛБЕЦ
Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.
СТОЛБЕЦ([Ссылка])
Ссылка: ссылка на ячейку или область ячеек, для которой требуется определить номер первого столбца.
Если ссылка не указана, возвращается номер столбца для ячейки с формулой. LibreOffice Calc автоматически создаёт ссылку на текущую ячейку.
=COLUMN(A1) возвращает значение 1. Столбец A является первым столбцом в таблице.
=COLUMN(C3:E3) возвращает значение 3. Столбец C является третьим столбцом в таблице.
=COLUMN(D3:G10) возвращает значение 4, поскольку столбец D является четвёртым в таблице, а функция COLUMN не используется в качестве формулы массива. (В этом случае результатом всегда является первое значение массива.)
{=COLUMN(B2:B7)} и =COLUMN(B2:B7) возвращают значение 2, поскольку ссылка указывает только на столбец B, являющийся вторым столбцом в таблице. Поскольку для области, состоящей из одного столбца, можно извлечь только один номер столбца, формулу массива использовать необязательно.
=COLUMN() возвращает значение 3, если формула была введена в столбце C.
{=COLUMN(Rabbit)} возвращает массив с одной строкой (3, 4), если " Rabbit" – указанный диапазон (C1:D3).
СТРОКА
Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.
СТРОКА([Ссылка])
Ссылка: ячейка, область или имя области.
Если ссылка не указана, возвращается номер строки для ячейки, которая содержит формулу. LibreOffice Calc автоматически создаёт ссылку на текущую ячейку.
=ROW(B3) возвращает значение 3, поскольку ссылка указывает на третью строку таблицы.
{=ROW(D5:D8)} возвращает массив, состоящий из одного столбца (5, 6, 7, 8), поскольку ссылка указывает на строки с 5 по 8.
=ROW(D5:D8) возвращает значение 5, поскольку функция ROW не используется как формула массива, таким образом, возвращается только номер первой строки ссылки.
{=ROW(A1:E1)} и =ROW(A1:E1) возвращают значение 1, поскольку ссылка указывает только на строку 1 как на первую строку в таблице. (Поскольку для области, состоящей из одной строки, можно извлечь только один номер строки, формулу массива использовать необязательно.)
=ROW() возвращает значение 3, если формула была введена в строку 3.
{=ROW(Rabbit)} возвращает массив с одним столбцом (1, 2, 3), если "Rabbit" – указанный диапазон (C1:D3).
ТИПОШИБКИ
Возвращает номер типа ошибки в другой ячейке. С помощью этого номера можно воспроизвести текст сообщения об ошибке.
В строке состояния при щелчке ячейки с ошибкой отображается стандартный код ошибки LibreOffice.
ТИПОШИБКИ(Ссылка)
Ссылка: адрес ячейки с ошибкой.
Если в ячейке A1 отображается Ошибка:518, функция =ТИПОШИБКИ(A1) возвращает номер 518.
ORG.OPENOFFICE.ERRORTYPE
ЧСТОЛБ
Возвращает количество столбцов для заданной ссылки.
ЧСТОЛБ(Массив)
Массив: ссылка на диапазон ячеек, для которого требуется подсчитать общее количество столбцов. Аргументом также может являться отдельная ячейка.
=COLUMNS(B5) возвращает значение 1, поскольку ячейка содержит только один столбец.
=COLUMNS(A1:C5) возвращает значение 3. Диапазон содержит три столбца.
=COLUMNS(Rabbit) возвращает значение 2, если Rabbit – указанный диапазон (C1:D3).
ЧСТРОК
Возвращает количество строк в массиве или ссылке.
ЧСТРОК(Массив)
Массив: ссылка или имя области, для которой требуется определить общее количество строк.
=ROWS(B5) возвращает значение 1, поскольку ячейка включает только одну строку.
=ROWS(A10:B12) возвращает значение 3.
=ROWS(Rabbit) возвращает значение 3, если " Rabbit" – указанный диапазон (C1:D3).