Математические функции

Эта категория содержит математические функции для Calc. Для вызова мастера функций выберите Вставка – Функция.

АГРЕГАТ

Эта функция возвращает агрегацию вычислений в диапазоне. Можно использовать различные функции агрегации, перечисленные ниже. Функция «Агрегат» при вычислении позволяет пропускать скрытые строки, ошибки, результаты вычисления функции ИТОГ, а также результаты вычисления других функций АГРЕГАТ.

СУММ

Выполняет сложение множества чисел.

СУММЕСЛИМН

Возвращает сумму значений ячеек в диапазоне, который удовлетворяет нескольким условиям в нескольких диапазонах.

ABS

Возвращает абсолютное значение числа.

ABS(Число)

Число: число для расчёта абсолютного значения. Абсолютное значение числа – это его значение без знака +/-.

=ABS(-56) возвращает значение 56.

=ABS(12) возвращает значение 12.

=ABS(0) возвращает значение 0.

ACOS

Вычисляет арккосинус числа.

ACOS(Число)

Эта функция возвращает тригонометрический арккосинус числа, т.е. угол (в радианах), косинус которого равен числу. Возвращается угол от 0 до числа пи.

Для получения значения угла в градусах необходимо использовать функцию ГРАДУСЫ.

=ACOS(-1) возвращает значение 3,14159265358979 (пи радиан).

=ГРАДУСЫ(ACOS(0.5)) возвращает значение 60. Косинус 60 градусов равен 0,5.

ACOSH

Возвращает гиперболический арккосинус числа.

ACOSH(Число)

Эта функция возвращает гиперболический арккосинус числа, т.е. число, гиперболический косинус которого равен числу.

Число должно быть больше или равно 1.

=ACOSH(1) возвращает значение 0.

=ACOSH(COSH(4)) возвращает значение 4.

ACOT

Возвращает арккотангенс данного числа.

ACOT(Число)

Эта функция возвращает тригонометрический арккотангенс числа, т.е. угол (в радианах), котангенс которого равен числу. Возвращается угол от 0 до пи.

Для получения значения угла в градусах необходимо использовать функцию ГРАДУСЫ.

=ACOT(1) возвращает значение 0,785398163397448 (пи/4 радиан).

=ГРАДУСЫ(ACOT(1)) возвращает значение 45. Тангенс 45 градусов равен 1.

ACOTH

Возвращает гиперболический арккотангенс числа.

ACOTH(Число)

Эта функция возвращает гиперболический котангенс числа, т.е. число, гиперболический тангенс которого равен числу.

Если число находится между -1 и 1 включительно, возникает ошибка.

=ACOTH(1.1) возвращает гиперболический арккотангенс 1,1, приблизительно 1,52226.

ASIN

Возвращает арксинус числа.

ASIN(Число)

Эта функция возвращает тригонометрический арксинус числа, т.е. угол (в радианах), синус которого равен числу. Возвращается угол от -пи/2 до +пи/2.

Для получения значения угла в градусах необходимо использовать функцию ГРАДУСЫ.

=ASIN(0) возвращает значение 0.

=ASIN(1) возвращает значение 1,5707963267949 (пи/2 радиан).

=ГРАДУСЫ(ASIN(0.5)) возвращает значение 30. Синус 30 градусов равен 0,5.

ASINH

Возвращает гиперболический арксинус числа.

ASINH(Число)

Эта функция возвращает гиперболический арксинус числа, т.е. число, гиперболический синус которого равен числу.

=ASINH(-90) возвращает значение 5,1929877 (приблизительно).

=ASINH(SINH(4)) возвращает значение 4.

ATAN

Возвращает арктангенс числа.

ATAN(Число)

Эта функция возвращает тригонометрический арктангенс числа, т.е. угол (в радианах), тангенс которого равен числу. Возвращает угол от -пи/2 до пи/2.

Для получения значения угла в градусах необходимо использовать функцию ГРАДУСЫ.

=ATAN(1) возвращает значение 0,785398163397448 (пи/4 радиан).

=ГРАДУСЫ(ATAN(1)) возвращает значение 45. Тангенс 45 градусов равен 1.

ATAN2

Возвращает угол (в радианах) между осью x и линией от начала координат до точки (Число X|Число Y).

ATAN2(Число X; Число Y)

Число X: значение координаты x.

Число Y: значение координаты y.

ATAN2 возвращает угол (в радианах) между осью x и линией от начала координат до точки (Число X|Число Y)

=ATAN2(-5; 9) возвращает значение 2,07789 радиан.

Для получения значения угла в градусах примените к результату функцию ГРАДУСЫ.

=ГРАДУСЫ(ATAN2(12,3; 12,3)) возвращает значение 45. Тангенс 45 градусов равен 1.

Функция может быть использована для преобразования декартовых координат в полярные координаты.

=ГРАДУСЫ(ATAN2(-8; 5)) возвращает значение φ = 147,9 градусов

ATANH

Возвращает гиперболический арктангенс числа.

ATANH(Число)

Эта функция возвращает гиперболический арктангенс числа, т.е. число, гиперболический тангенс которого равен числу.

Число должно соответствовать правилу -1 < число <1.

=ATANH(0) возвращает значение 0.

CONVERT_OOO

Преобразует в евро значение, выраженное в одной из устаревших валют 19 стран-участниц еврозоны, и обратно. При преобразовании используются фиксированные курсы обмена валют, при которых устаревшие валюты вошли в евро.

CONVERT_OOO(Значение; "Текст1"; "Текст2")

Значение: сумма преобразуемой валюты.

Текст1: строка из трёх символов для указания преобразуемой валюты.

Текст2: строка из трёх символов для указания целевой валюты.

Текст1 и Текст2 должны иметь одно из следующих значений: «ATS», «BEF», «CYP», «DEM», «EEK», «ESP», «EUR», «FIM», «FRF», «GRD», «IEP», «ITL», «LTL», «LUF», «LVL», «MTL», «NLG», «PTE», «SIT» и «SKK».

Один, и только один аргумент Текст1 или Текст2 должен содержать значение «EUR».

=CONVERT_OOO(100;"ATS";"EUR") величину 100 австрийских шиллингов в евро.

=CONVERT_OOO(100;"EUR";"DEM") преобразует 100 евро в немецкие марки.

COS

Возвращает косинус заданного угла (в радианах).

COS(Число)

Возвращает (тригонометрический) косинус числа — угла в радианах.

Для возвращения косинуса угла в градусах следует использовать функцию РАДИАНЫ.

=COS(ПИ()/2) возвращает значение 0, т.е. косинус пи/2 радиан.

=COS(РАДИАНЫ(60)) возвращает значение 0,5, т.е. косинус 60 градусов.

COSH

Возвращает гиперболический косинус числа.

COSH(Число)

Возвращает гиперболический косинус числа.

=COSH(0) возвращает значение 1, т.е. гиперболический косинус 0.

COT

Возвращает котангенс заданного угла (в радианах).

COT(Число)

Возвращает (тригонометрический) котангенс числа — угла в радианах.

Для возврата котангенса угла в степенях используйте функцию РАДИАНЫ.

Котангенс угла эквивалентен 1, разделённой на тангенс этого угла.

Примеры:

=COT(ПИ()/4) возвращает значение 1, т.е. котангенс пи/4 радиан.

=COT(РАДИАНЫ(45)) возвращает значение 1, т.е. котангенс 45 градусов.

COTH

Вычисляет гиперболический котангенс числа (угла).

COTH(Число)

Возвращает гиперболический котангенс числа.

=COTH(1) возвращает гиперболический котангенс 1, приблизительно 1,3130.

CSC

Возвращает косеканс заданного (в радианах) угла. Косеканс угла эквивалентен 1, делённому на синус этого угла.

CSC(Число)

Возвращает (тригонометрический) косеканс числа — угла в радианах.

Для получения косеканса угла, заданного в градусах, следует использовать функцию РАДИАНЫ.

=CSC(ПИ()/4) возвращает приблизительно 1,4142135624, значение, обратное синусу пи/4.

=CSC(РАДИАНЫ(30)) возвращает значение 2, т.е. косеканс 30 градусов.

CSCH

Возвращает гиперболичекский косеканс числа.

CSCH(Число)

Возвращает гиперболический косеканс числа.

=CSCH(1) возвращает приблизительно 0,8509181282, гиперболический косеканс 1.

EXP

Возвращает e возведённое в степень числа. Постоянное e имеет приблизительное значение 2,71828182845904.

EXP(Число)

Число: степень, в которую требуется возвести число «e».

=EXP(1) возвращает 2,71828182845904, математическая константа e с точностью Calc.

LN

Возвращает натуральный логарифм числа (по основанию e). Основание е - это константа с приблизительным значением 2,71828182845904.

LN(Число)

Число: число для расчёта натурального логарифма.

=LN(3) возвращает натуральный логарифм 3 (приблизительно 1,0986).

=LN(EXP(321)) возвращает значение 321.

LOG

Возвращает логарифм числа по указанному основанию.

LOG(Число [; Основание])

Число: число для расчёта логарифма.

Основание (необязательный параметр): основание для расчёта логарифма. Если этот параметр опущен, то используется основание 10.

=LOG(10; 3) возвращает логарифм 10 по основанию 3 (приблизительно 2,0959).

=LOG(7^4; 7) возвращает значение 4.

LOG10

Возвращает десятичный логарифм числа.

LOG10(Число)

Возвращает десятичный логарифм числа.

=LOG10(5) возвращает десятичный логарифм 5 (приблизительно 0,69897).

SEC

Возвращает секанс заданного (в радианах) угла. Секанс угла эквивалентен делению 1 на косинус этого угла.

SEC(Число)

Возвращает (тригонометрический) секанс Числа — угла в радианах.

Чтобы получить секанс угла, заданного в градусах, используйте функцию РАДИАНЫ.

=SEC(ПИ()/4) возвращает приблизительно 1,4142135624, величину, обратную косинусу пи/4.

=SEC(РАДИАНЫ(60)) возвращает 2, секанс 60 градусов.

SECH

Возвращает гиперболический секанс числа.

SECH(Число)

Возвращает гиперболический секанс Числа.

=SECH(0) возвращает 1, гиперболический секанс 0.

SIN

Возвращает синус заданного угла (в радианах).

SIN(Число)

Возвращает (тригонометрический) синус числа (угол в радианах).

Для получения синуса угла в градусах следует использовать функцию РАДИАНЫ.

=SIN(ПИ()/2) возвращает значение 1, т.е. синус пи/2 радиан.

=SIN(РАДИАНЫ(30)) возвращает значение 0,5, т.е. синус 30 градусов.

SINH

Вычисляет гиперболический синус числа.

SINH(Число)

Возвращает гиперболический синусЧисла.

=SINH(0) возвращает значение 0, т.е. гиперболический синус 0.

TAN

Возвращает тангенс заданного угла (в радианах).

TAN(Число)

Возвращает (тригонометрический) тангенс числа — угла в радианах.

Для возвращения тангенса угла в градусах следует использовать функцию РАДИАНЫ.

= TAN(ПИ()/4) возвращает значение 1, т.е. тангенс пи/4 радиан.

=TAN(РАДИАНЫ(45)) возвращает значение 1, т.е. тангенс 45 градусов.

TANH

Возвращает гиперболический тангенс числа.

TANH(Число)

Возвращает гиперболический тангенс Числа.

=TANH(0) возвращает значение 0, т.е. гиперболический тангенс 0.

ГРАДУСЫ

Служит для преобразования радианов в градусы.

ГРАДУСЫ(число)

Число: угол в градусах для преобразования в радианы.

=ГРАДУСЫ(ПИ()) возвращает 180 градусов.

ЗНАК

Возвращает знак числа. Возвращает 1, если число положительно, -1, если отрицательно и 0, если равно нулю.

ЗНАК(Число)

Число: число, знак которого необходимо определить.

=ЗНАК(3,4) возвращает значение 1.

=ЗНАК(-4,5) возвращает значение -1.

ИТОГ

Служит для расчёта промежуточных итогов. Если диапазон уже содержит промежуточные итоги, они не используются в дальнейших расчётах. Использование этой функции совместно с автофильтрами позволяет учитывать только фильтрованные записи.

ИТОГ(Функция; Диапазон)

Функция: число, обозначающее одну из следующих функций:

Индекс функции (включает скрытые значения)	Индекс функции (игнорирует скрытые значения)	Функция
1	101	СРЗНАЧ
2	102	СЧЁТ
3	103	СЧЁТА
4	104	МАКС
5	105	МИН
6	106	ПРОИЗВ
7	107	СТОТКЛ
8	108	СТОТКЛГ
9	109	СУММ
10	110	ДИСП
11	111	ДИСПГ

Указывайте числа 1-11 для включения вручную скрытых строк или 101-111 для их исключения; исключённые фильтром ячейки всегда исключаются.

Диапазон: диапазон, ячейки которого включаются в расчёт.

Имеется таблица, расположенная в диапазоне A1:B6, содержащая ведомость материалов для 10 студентов.

	A	B
1	ЭЛЕМЕНТ	КОЛИЧЕСТВО
2	Ручка	10
3	Карандаш	10
4	Тетрадь	10
5	Резинка	10
6	Точилка	10

Давайте условимся, что одна из строк скрыта вручную, в таком случае первая формула покажет сумму 5 отфильтрованных чисел; тогда как вторая формула покажет сумму только 4 отображаемых.

=ИТОГ(9; B2:B6) возвращает значение 50.

=ИТОГ(109; B2:B6) возвращает значение 40.

КОРЕНЬ

Возвращает положительный квадратный корень числа.

КОРЕНЬ(Число)

Возвращает положительный квадратный корень Числа.

Число должно быть положительным.

=КОРЕНЬ(16) возвращает значение 4.

=КОРЕНЬ(-16) возвращает ошибку недопустимый аргумент.

КОРЕНЬПИ

Возвращает квадратный корень от (пи, умноженного на число).

КОРЕНЬПИ(Число)

Возвращает положительный квадратный корень от (пи, умноженного на Число).

Это действие эквивалентно КОРЕНЬ(ПИ()*Число).

=КОРЕНЬПИ(2) возвращает квадратный корень из (2пи), приблизительно 2,506628.

МУЛЬТИНОМ

Возвращает факториал суммы аргументов, делённый на произведение факториалов аргументов.

МУЛЬТИНОМ(Число 1 [; Число 2 [; … [; Число 255]]])

=МУЛЬТИНОМ(F11:H11): если ячейки диапазона F11:H11 содержат значения 2, 3 и 4 возвращает значение 1260. Это соответствует формуле = (2+3+4)! / (2!*3!*4!)

НЕЧЁТ

Возвращает число, округлённое до ближайшего нечётного целого.

НЕЧЁТ(Число)

Возвращает результат округления Числа в большую сторону до следующего нечётного числа.

=НЕЧЁТ(1,2) возвращает значение 3.

=НЕЧЁТ(1) возвращает значение 1.

=НЕЧЁТ(0) возвращает значение 1.

=НЕЧЁТ(-3,1) возвращает значение -5.

НОД

Возвращает наибольший общий делитель для двух или более целых чисел.

Самый большой общий делитель — наибольшее положительное целое число, на которое каждое из данных целых чисел делится без остатка.

НОД(Целое число 1 [; Целое число 2 [; … [; Целое число 255]]])

=НОД(16; 32; 24) выдаёт результат 8, поскольку 8 является наибольшим числом, на которое числа 16, 24 и 32 делятся без остатка.

=НОД(B1:B3), если ячейки B1, B2, B3 содержат 9, 12, 9, возвращает 3.

НОД_EXCEL2003

В результате возвращает наибольший общий делитель списка чисел.

НОД_EXCEL2003(Число 1 [; Число 2 [; … [; Число 255]]])

=НОД_EXCEL2003(5; 15; 25) возвращает значение 5.

НОК

Возвращает наименьшее общее кратное для одного или нескольких целых чисел.

НОК(Целое число 1 [; Целое число 2 [; … [; Целое число 255]]])

Если в качестве Целого числа 1;2 и 3 ввести числа 512; 1024 и 2000, то результат составит 128000.

НОК_EXCEL2003

В результате возвращается наименьшее общее кратное списка чисел.

НОК_EXCEL2003(Число 1 [; Число 2 [; … [; Число 255]]])

=НОК_EXCEL2003(5; 15; 25) возвращает значение 75.

ОКРУГЛ

Округление числа до указанного количества знаков после запятой.

ОКРУГЛ(Число [; Количество])

Возвращает Число с округлением до Количества знаков после запятой. Если количество опущено или равно нулю, то округление выполняется до ближайшего целого числа. При отрицательном количестве округление выполняется до ближайшего десятка, сотни, тысячи и т.д.

Эта функция округляет число до ближайшего числа. См. варианты ОКРУГЛВНИЗ и ОКРУГЛВВЕРХ.

=ОКРУГЛ(2,348; 2) возвращает значение 2,35.

=ОКРУГЛ(-32,4834; 3) возвращает значение -32,483. Измените формат ячейки таким образом, чтобы отображались все десятичные разряды.

=ОКРУГЛ(2,348; 0) возвращает значение 2.

=ОКРУГЛ(2,5) возвращает значение 3.

=ОКРУГЛ(987,65; -2) возвращает значение 1000.

ОКРУГЛВВЕРХ

Служит для округления числа в большую сторону (от нуля) до определённой точности.

ОКРУГЛВВЕРХ(Число [; Количество])

Возвращает Число, округлённое (от нуля) до Количества знаков после запятой. Если количество не указано или равняется нулю, округление проводится до целого числа. Если количество отрицательно, округление выполняется до ближайшего десятка (сотни, тысячи и т.д.).

Эта функция округляет число в направлении от нуля. См. варианты ОКРУГЛВНИЗ и ОКРУГЛ.

=ОКРУГЛВВЕРХ(1,1111; 2) возвращает значение 1,12.

=ОКРУГЛВВЕРХ(1,2345; 1) возвращает значение 1,3.

=ОКРУГЛВВЕРХ(45,67; 0) возвращает значение 46.

=ОКРУГЛВВЕРХ(-45,67) возвращает значение -46.

=ОКРУГЛВВЕРХ(987,65; -2) возвращает значение 1000.

ОКРУГЛВНИЗ

ОКРУГЛТ

Округление числа до ближайшего кратного значения другого числа.

ОКРУГЛТ(Число; Множитель)

Округление Числа до ближайшего Множителя.

Также можно использовать Множитель * ROUND(Число/Множитель).

=ОКРУГЛТ(15,5; 3) возвращает значение 15, поскольку 15,5 ближе к 15 (= 3*5), чем к 18 (= 3*6).

=ОКРУГЛТ(1,4; 0,5) возвращает значение 1,5 (= 0,5*3).

ОСТАТ

Возвращает остаток от деления одного числа на другое.

ОСТАТ(Делимое; Делитель)

Для целочисленных аргументов эта функция возвращает остаток от деления делимого на делитель, т.е. остаток от деления значения Делимое на значение Делитель.

Эта функция реализована как Делимое - Делитель * ЦЕЛОЕ(Делимое/Делитель), и эта формула возвращает результат, если аргументы - не целые числа.

=MOD(22; 3) возвращает значение 1, т.е. остаток от деления 22 на 3.

=ОСТАТ(11,25; 2,5) возвращает значение 1,25.

ОТБР

ПЕРЕСЧЕТЕВРО

Выполняет преобразование старой национальной валюты в евро и обратно.

ПЕРЕСЧЕТЕВРО(Значение; "Из валюты"; "В валюту" [; Полная разрядность [; Точность триангуляции]])

Значение: сумма в валюте для пересчёта.

Параметры Из валюты и В валюту являются соответственно исходными и целевыми единицами валюты для пересчёта. Значения этих параметров должны быть представлены в текстовом формате и соответствовать официальному сокращению валюты (например, «EUR»). Курсы (приведены по отношению к евро) установлены Европейской Комиссией.

Параметр Полная разрядность является необязательным. Если параметр опущен или имеет значение ЛОЖЬ, то результат округляется в соответствии с количеством десятичных знаков после запятой в значении целевой валюты. Если параметр «Полная разрядность» имеет значение ИСТИНА, то результат не округляется.

Параметр Точность триангуляции является необязательным. Если значение параметра «Точность триангуляции» указано и >=3, промежуточный результат триангуляционного преобразования (валюта1,EUR,валюта2) округляется с этой точностью. Если параметр «Точность триангуляции» опущен, то промежуточный результат не округляется. Кроме того, если целевой валютой является «EUR», то параметр «Точность триангуляции» используется исходя из необходимости триангуляции с применением пересчёта из евро в евро.

Примеры

=ПЕРЕСЧЕТЕВРО(100; "ATS"; "EUR") выполняет пересчёт 100 австрийских шиллингов в евро.

=ПЕРЕСЧЕТЕВРО(100; "EUR"; "DEM") выполняет пересчёт 100 евро в немецкие марки.

ПИ

Возвращает 3,14159265358979 — значение математической константы «пи» до 14 знаков после запятой.

ПИ()

=ПИ() возвращает значение 3,14159265358979.

ПРОИЗВ

Служит для умножения всех аргументов и получения произведения.

ПРОИЗВ(Число 1 [; Число 2 [; … [; Число 255]]])

=ПРОИЗВ(2; 3; 4) возвращает значение 24.

РАДИАНЫ

Преобразует градусы в радианы.

РАДИАНЫ(Число)

Число: угол в градусах для преобразования в радианы.

=РАДИАНЫ(90) возвращает значение 1,5707963267949, т.е. пи/2 до степени точности Calc.

РЯД.СУММ

Суммирование первых членов степенного ряда.

РЯД.СУММ(x;n;m;c) = c₁xⁿ + c₂x^n+m + c₃x^n+2m + ... + c_ix^{n + (i-1)m}.

РЯД.СУММ(X; N; M; Коэффициенты)

X: вводимое значение для степенного ряда.

N: начальная степень

M: приращение, на которое требуется увеличить N.

Коэффициенты: ряд коэффициентов. Для каждого коэффициента сумма ряда увеличивается на один раздел.

=РЯД.СУММ(A1; 0; 1; {1; 2; 3}) вычисляет значение 1+2x+3x², где x — значение ячейки A1. Если A1 содержит 1, формула возвращает 6; если A1 содержит 2, формула возвращает 17; если A1 содержит 3, формула возвращает 34; и так далее.

СЛУЧМЕЖДУ

Возвращает случайное целое число из указанного диапазона.

СЛУЧМЕЖДУ(Нижняя граница; Верхняя граница)

Возвращает случайное целое число между целыми значениями Нижней и Верхней границы (оба числа включаются в расчёт).

Эта функция генерирует новое случайное число при каждом пересчёте Calc. Принудительно пересчитать таблицу в Calc можно при нажатии F9.

Для генерации случайных неповторимых чисел следует скопировать ячейки, содержащие эту функцию, и выбрать Правка - Вставить как (без выбора Вставить все и Формулы и с выбором Числа).

=СЛУЧМЕЖДУ(20; 30) возвращает произвольное целое число от 20 до 30.

СЛУЧМЕЖДУ.ДВ

Возвращает неизменяемое целое случайное число в заданном диапазоне.

СЛУЧМЕЖДУ.ДВ(Низ; Верх)

Возвращает неизменяемое целое случайное число в диапазоне между числами Низ и Верх (оба включительно). Неизменяемая функция не выполняет пересчёт при вводе новых чисел или при нажатии F9. Однако выполняет пересчёт при нажатии F9, когда курсор находится на ячейке, содержащей функцию, а также при открытии файла, при использовании команды Пересчитать безусловно (Shift++F9) и при пересчёте чисел Верх или Низ.

=СЛУЧМЕЖДУ.ДВ(20;30) возвращает неизменяемое целое число в диапазоне между 20 и 30.

=СЛУЧМЕЖДУ.ДВ(A1;30) возвращает неизменяемое целое число в диапазоне между значениями ячеек A1 и 30. Функция пересчитывается при изменении содержимого ячейки A1.

ORG.LIBREOFFICE.RANDBETWEEN.NV

СЛЧИС

Возвращает случайное число от 0 до 1.

СЛЧИС()

Эта функция генерирует новое случайное число при каждом пересчёте Calc. Принудительный пересчёт вручную в Calc можно выполнить при нажатии F9.

Для генерации случайных чисел, которые никогда не пересчитываются, необходимо либо:

• Копировать ячейки, каждая из которых содержит =СЛЧИС(), и использовать Правка - Вставить как (без выбора Вставить все, Формулы и с выбором Числа).

• Используйте команду «Заполнить случайными числами» (Лист - Заполнить - Заполнить случайными числами).

• Используйте функцию СЛЧИС.ДВ() для неизменяемых случайных чисел.

=СЛЧИС() возвращает случайное число от 0 до 1.

СЛЧИС.ДВ

Возвращает неизменяемое целое число между 0 и 1.

СЛЧИС.ДВ()

Функция генерирует неизменяемое целое случайное число при вводе. Неизменяемая функция не выполняет пересчёт при вводе новых чисел. При нажатии F9 функция не выполняет пересчёт, за исключением случая, когда курсор размещён на ячейке, содержащей функцию, а также при использовании команды Пересчитать безусловно (Shift++F9). Функция пересчитывается при открытии файла.

=СЛЧИС.ДВ() возвращает неизменяемое случайное число между 0 и 1.

ORG.LIBREOFFICE.RAND.NV

СТЕПЕНЬ

Возвращает результат возведения числа в степень.

СТЕПЕНЬ(Основание; Степень)

Возвращает Основание, возведённое в Степень.

Тот же результат можно получить путём использования оператора возведения в степень ^: Основание^Степень

=СТЕПЕНЬ(4;3) возвращает 64, что составляет 4 в степени 3.

=4^3 также возвращает 4 в степени 3.

=СТЕПЕНЬ(2;-3) возвращает 0,125.

=СТЕПЕНЬ(-2;1/3) возвращает -1,25992104989487.

=СТЕПЕНЬ(-2;2/3) возвращает ошибку #ЧИСЛО!

СУММКВ

Вычисляет суму квадратов множества чисел.

СУММКВ(Число 1 [; Число 2 [; … [; Число 255]]])

Если ввести числа 2; 3 и 4 в качестве аргументов 1; 2 и 3, то в результате возвращается число 29.

ФАКТР

Возвращает факториал неотрицательного целого числа.

ФАКТР(Целое число)

Возвращает целое_число!, то есть факториал Целого числа, производит вычисление в виде 1*2*3*4* ... * целое_число.

Возвращает ошибку «недопустимый аргумент», если аргумент является отрицательным целым числом.

Возвращает ошибку #ЗНАЧ!, если аргумент больше 170, по причине слишком большой величины целого числа (примерно 7E+306.

=ФАКТР(0) возвращает 1 по определению.

Если аргумент не является целым числом, то округляется в меньшую сторону.

=ФАКТР(3) возвращает значение 6.

=ФАКТР(3.8) возвращает значение 6.

=ФАКТР(0) возвращает значение 1.

ЦЕЛОЕ

Округляет число до ближайшего меньшего целого.

ЦЕЛОЕ(Число)

Возвращает результат округления числа до ближайшего меньшего целого.

Отрицательные числа округляются до меньшего целого.

=ЦЕЛОЕ(5.7) возвращает значение 5.

=ЦЕЛОЕ(-1.3) возвращает значение -2.

ЧЁТН

Округление положительного числа в большую сторону до следующего чётного числа, а отрицательного целого числа в меньшую сторону до следующего чётного числа.

ЧЁТН(Число)

Возвращает результат округления числа в большую сторону до следующего чётного целого числа.

=ЧЁТН(2,3) возвращает значение 4.

=ЧЁТН(2) возвращает значение 2.

=ЧЁТН(0) возвращает значение 0.

=ЧЁТН(-0,5) возвращает значение -2.

ЧАСТНОЕ

Возвращает целочисленную часть результата операции деления.

ЧАСТНОЕ(Числитель; Знаменатель)

Возвращает целую часть Числителя, разделённого на Знаменатель.

ЧАСТНОЕ эквивалентно ЦЕЛОЕ(числитель/знаменатель) для числителей и знаменателей с одинаковым знаком, кроме случаев возникновения ошибок с различными кодами. В более общем виде, это эквивалентно ЦЕЛОЕ(числитель/знаменатель/ЗНАК(числитель/знаменатель))*ЗНАК(числитель/знаменатель).

=ЧАСТНОЕ(11; 3) возвращает число 3. Остаток 2 отбрасывается.

ЧКОМБ

Возвращает число комбинаций элементов без повторений.

ЧКОМБ(Число1; Число2)

Количество1: количество элементов в множестве.

Количество2: количество элементов для выбора из множества.

ЧКОМБ возвращает число упорядоченных способов выбора этих элементов. Например, если имеются 3 элемента A, B и C, два элемента можно выбрать тремя различными способами, а именно, AB, AC и BC.

ЧКОМБ реализует формулу: Количество1!/(Количество2!*(Количество1-Количество2)!)

=ЧКОМБ(3; 2) возвращает значение 3.

ЧКОМБА

Возвращает количество комбинаций подмножества элементов с учётом повторений.

ЧКОМБА(Число1; Число2)

Количество1: количество элементов в множестве.

Количество2: количество элементов для выбора из множества.

Функция ЧКОМБА возвращает число уникальных способов выбора этих элементов, где порядок выбора не имеет значения и разрешается несколько экземпляров одного элемента. Например, если имеются 3 элемента A, B и C, то два элемента можно выбрать шестью различными способами, т.е. AA, AB, AC, BB, BC и CC.

ЧКОМБА использует следующую формулу: (Количество1+Количество2-1)! / (Количество2!(Количество1-1)!)

=ЧКОМБА(3; 2) возвращает значение 6.