Dir Function

Возвращает имя файла, каталога или всех файлов и каталогов на диске или в каталоге, соответствующих указанному пути поиска.

Syntax:


Dir [(Text As String [, Attrib As Integer])]

Возвращаемое значение:

String

Parameters:

Текст. Любое выражение типа String, которое указывает путь поиска, каталог или файл. Данный аргумент может быть указан, только когда функция Dir вызывается в первый раз. При необходимости можно ввести путь в URL-нотации.

Атрибут . Любое целое выражение, указывающее побитовые атрибуты файла. Функция Dir возвращает только файлы или каталоги, которые соответствуют указанным атрибутам. Можно объединять несколько атрибутов, складывая значения атрибутов.

0 . Обычные файлы.

16 . Возвращает только имя каталога.

Используйте этот атрибут, чтобы проверить, существует ли файл или каталог, или чтобы определить все файлы и папки в конкретном каталоге.

Чтобы проверить, существует ли файл, введите полный путь и имя файла. Если имя файла или каталога не существует, функция Dir возвращает строку нулевой длины ("").

To generate a list of all existing files in a specific directory, proceed as follows: The first time you call the Dir function, specify the complete search path for the files, for example, "D:\Files\*.ods". If the path is correct and the search finds at least one file, the Dir function returns the name of the first file that matches the search path. To return additional file names that match the path, call Dir again, but with no arguments.

To return directories only, use the attribute parameter. The same applies if you want to determine the name of a volume (for example, a hard drive partition).

Error codes:

5 Неправильный вызов процедуры

53 Файл не найден

Example:


Sub ExampleDir
' Покажает все файлы и каталоги
Dim sPath As String
Dim sDir As String, sValue As String
    sDir="Каталоги:"
    sPath = CurDir
    sValue = Dir$(sPath + getPathSeparator + "*",16)
    Do
        If sValue <> "." And sValue <> ".." Then
            If (GetAttr( sPath + getPathSeparator + sValue) And 16) >0 Then
                REM получение каталогов
                sDir = sDir & chr(13) & sValue
            End If
        End If
        sValue = Dir$
    Loop Until sValue = ""
    MsgBox sDir,0,sPath
End Sub

Please support us!