Определение операционной системы

Определение операционной системы может выполняться в языке Python или Basic.

С помощью класса Python:


        """ the_module """
        import os, platform
        class Platform():
            @property
            def ComputerName(self): return platform.node()
            @property
            def DirSeparator(self): return os.sep
            @property
            def isLinux(self): return (self.OSName=='Linux')
            @property
            def isMacOSX(self): return (self.OSName=='Darwin')
            @property
            def isWindows(self): return (self.OSName=='Windows')
            @property
            def OSName(self): return platform.system()
            @property
            def PathDelimiter(self): return os.pathsep

С помощью classmodule в Basic:

В LibreOffice Basic отсутствует встроенная возможность определения MacOS X. Идентифицировать платформу можно с помощью LibreOffice API.


        ''' Имя модуля: Platform '''
        Option Compatible
        Option ClassModule
        Option Explicit
        
        Public Property Get ComputerName As String
            If isWindows Then ComputerName = Environ("ComputerName")
        End Property ' Platform.ComputerName
        
        Public Property Get DirSeparator As String
            DirSeparator = GetPathSeparator()
        End Property ' Platform.DirSeparator
        
        Public Property Get IsLinux As Boolean
            isLinux = ( GetGUIType()=4 ) ' Applies to macOS as well 
        End Property ' Platform.isLinux
        
        Public Property Get IsMacOSX As Boolean
            isMacOSX = ( OSName="MAC" )
        End Property ' Platform.isMacOSX
        
        Public Property Get IsWindows As Boolean
            isWindows = ( GetGUIType()=1 )
        End Property ' Platform.isWindows
        
        Public Property Get OSName As String
            ' Возвращает имя платформы в виде "MAC", "UNIX", "WIN"
            ' Заимствовано из функции «Tools.UCB.ShowHelperDialog»
            With GlobalScope.Basiclibraries
                If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
            End With
            Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess
            keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Help")
            OSName = keyNode.GetByName("System")
        End Property ' Platform.OSName
        
        Public Property Get PathDelimiter As String
            Select Case OSName
                Case "MAC", "UNIX" : PathDelimiter = ":"
                Case "WIN" : PathDelimiter = ";"
             End Select
        End Property ' Platform.PathDelimiter

Переменная среды ComputerName доступна только на Windows. Вызовы макросов Python из Basic помогают преодолеть ограничения LibreOffice Basic.

Примеры:

С помощью Python

>>> from < the_module > import Platform

>>> print(Platform().isMacOSX) # свойство объекта

True

>>> input(Platform().OSName) # свойство объекта

Darwin

Из меню Сервис – Макросы - Выполнить макрос….


        from < the_module > import Platform
        import screen_io as ui
        p = Platform()
        ui.MsgBox(''.join(['isMacOS: ',str(p.isMacOSX)]),0,p.OSName)

С помощью LibreOffice Basic


        Sub Platform_example()
            Dim p As New Platform ' экземпляр класса Platform
            MsgBox p.isLinux ' свойство объекта
            Print p.isWindows, p.OSName ' свойства объекта
        End Sub ' Platform_example

• ScriptForge.Platform service provides a collection of properties about the current execution environment and context, that include platform detection.

• Extensive operating system name identification is available from INFO("system") Calc formula.

Ввод/Вывод на экран

GetPathSeparator Function

Вызов сценариев Python из Basic

Примеры кода на Python

Справка по макросам на Python в LibreOffice