Função MÉDIA.SE.S

Devolve a média aritmética de um intervalo de células que cumprem um determinado conjunto de condições ou critérios. A função MÉDIA.SE.S soma todos os valores que cumpram o teste e divide essa soma pelo número de valores selecionados.

Esta função está disponível desde o LibreOffice 4.0.

Sintaxe

MÉDIA.SE.S(Func_Range; Range1; Criterion[; Range2; Criterion2][; … ; [Range127; Criterion127]])

intervalo_média - argumento obrigatório. É o intervalo de células, um nome de intervalo ou a etiqueta de uma coluna ou linha que contém os valores para calcular a média.

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

Nas pesquisas pode utilizar caracteres universais e expressões regulares. Com as expressões regulares ativadas, pode inserir "all.*", por exemplo, para encontrar a primeira ocorrência de "all" seguida de qualquer outro carácter. Se quiser pesquisar por um texto que também é uma expressão regular, deve preceder cada carácter com "\"ou incluir o texto entre \Q...\E. Pode ativar a avaliação de caracteres universais ou expressões regulares em - LibreOffice Calc - Calcular.

Ao usar funções onde um ou mais argumentos são textos que representem uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Contudo, se mudar de configuração regional e o separador decimal não for o ponto, a expressão regular será utilizada. Para forçar a avaliação da expressão regular em vez de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número como, por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".

Func_Range and Range1, Range2... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

A função pode ter até 255 argumentos, significando que pode haver 127 intervalos de critérios e critérios correspondentes.

Se a célula contiver VERDADEIRO, será tratada como 1 e se contiver FALSO, será tratada como 0 (zero).

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).

Exemplo

Considere a seguinte tabela

	A	B	C
1	Nome do produto	Vendas	Rendimento
2	pencil	20	65
3	pen	35	85
4	caderno	20	190
5	book	17	180
6	pencil-case	não	não

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

Utilização

=MÉDIA.SE.S(B2:B6;B2:B6;">=20")

Calcula a média para os valores do intervalo B2:B6 que são maiores ou iguais a 20. Devolve 25, uma vez que a quinta linha não cumpre o critério.

=MÉDIA.SE.S(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcula a média para os valores do intervalo C2:C6 que são maiores que 70 e que correspondem às células de B2:B6 com valores maiores ou iguais a 20. Devolve 137,50 uma vez que a segunda e a quinta linha não cumprem pelo menos um dos critérios.

Utilizar expressões regulares e funções incorporadas

=MÉDIA.SE.S(C2:C6;B2:B6;">"&MÍNIMO(B2:B6);B2:B6;"<"&MÁXIMOB2:B6))

Calcula a média dos valores no intervalo C2:C6 que coincidam com todos os valores no intervalo B2:B6, exceto os valores máximo e mínimo. Devolve 127,5 uma vez que a terceira e a quinta linha não cumprem, pelo menos, um dos critérios.

=MÉDIA.SE.S(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a média dos valores do intervalo C2:C6 que correspondem a todos os valores do intervalo A2:A6 que começam com as letras "pen" e todas as células do intervalo B2:B6, exceto seu máximo. Devolve 65 porque apenas a segunda linha cumpre todos os critérios.

Referência a uma célula como critério

Se quiser alterar o critério facilmente, pode especificar o critério numa célula distinta e utilizar uma referência a esta célula como condição da função MÉDIA.SE.S. Por exemplo, a função acima pode ser escrita da seguinte forma:

=MÉDIA.SE.S(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2 = pen, a função devolve 65, uma vez que a ligação à célula é substituída pelo seu conteúdo.

Abrir ficheiro com exemplo:

MÉDIA, MÉDIAA, DESV.MÉDIO, MÉDIA.SE

COUNTIFS, MINIFS, função MÁXIMO.SE.S, MÉDIA.SE.S, SUMIFS

Lista de expressões regulares