Funções de folha de cálculo

Esta secção contém descrições das funções da folha de cálculo junto com um exemplo.

Função TIPO.ERRO

Devolce o número representativo do tipo de erro ou #N/D se não existir erro.

STYLE

Applies a style to the cell containing the formula.

COL

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

COLUMN([Reference])

referência corresponde à referência a uma célula ou intervalopara a qual se pretende encontrar o número da primeira coluna.

Se não introduzir qualquer referência, é devolvido o número de coluna da célula onde a fórmula foi introduzida. O LibreOffice Calc define automaticamente a referência para a célula atual.

=COL(A1) equivale a 1. A coluna A é a primeira coluna na tabela.

=COL(C3:E3) equivale a 3. A coluna C corresponde à terceira coluna da tabela.

=COL(D3:G10) devolve 4, uma vez que a coluna D corresponde à quarta coluna da tabela e a função COL não é utilizada como uma fórmula de matriz. (Neste caso, o primeiro valor da matriz é sempre utilizado como o resultado.)

{=COL(B2:B7)} e =COL(B2:B7) devolvem ambas 2, uma vez que a referência apenas contém a coluna B como segunda coluna da tabela. Uma vez que as áreas de coluna única apenas têm um número de coluna, é indiferente se a fórmula é utilizada como fórmula de matriz ou não.

=COL() devolve 3 se a fórmula tiver sido introduzida na coluna C.

{=COL(Coelho)} devolve a matriz de linha única (3, 4), se "Coelho" for o nome da área (C1:D3).

COLS

Devolve o número de colunas de uma matriz ou referência.

COLS(matriz)

matriz corresponde à matriz ou referência a um intervalo de células, cujo número total de colunas deve ser determinado. O argumento também pode corresponder a uma única célula.

=COLS(B5) devolve 1, uma vez que uma célula só contém uma coluna.

=COLS(A1:C5) equivale a 3. A referência abrange três colunas.

=COLS(Coelho) devolve 2 se Coelho for o nome do intervalo (C1:D3).

CORRESP

Devolve a posição relativa de um objeto numa matriz e que corresponda ao valor especificado. A função devolve a posição do valor encontrado na matriz_procura na forma numérica.

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

matriz_procura corresponde ao intervalo de células que contém os valores de procura. A matriz de procura pode ser uma linha ou coluna única ou parte de uma linha ou coluna única.

tipo pode receber os valores 1, 0 ou -1. Se = 1 ou omisso, assume-se que a matriz_procura está por ordem ascendente. Se = -1, assume-se que a matriz_procura está por ordem descendente. Se = 0, devolve a posição da primeira ocorrência exata, independentemente da ordenação. Isto corresponde à mesma função no Microsoft Excel.

Se tipo = 0, apenas são encontradas as entradas exatas. Se o critério de pesquisa for encontrado mais do que uma vez, a função devolve o índice da primeira entrada encontrada. Apenas se tipo = 0, é que consegue pesquisar por expressões regulares ou caracteres universais (se ativas nas opções de cálculo).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

=CORRESP(200;D1:D100) procura o valor 200 na área D1:D100, ordenada pela coluna D. Logo que este valor for encontrado, a função devolve o número da linha onde este se encontra. Se for encontrado um valor maior durante a procura na coluna, é devolvido o número da linha anterior.

DDE

Devolve os dados de uma ligação DDE. Se o conteúdo do intervalo ou secção for alterado, o valor devolvido também será alterado. Deve recarregar a folha de cálculo ou escolher Editar - Ligações para ver as ligações atualizadas. Não são permitidas ligações entre plataformas diferentes (por exemplo, entre um documento do LibreOffice instalado numa máquina Windows e um documento criado numa máquina Linux.

DDE("Server"; "File"; "Range" [; Mode])

servidor é o nome da aplicação que serve de servidor. As aplicações do LibreOffice têm "soffice" como nome de servidor.

ficheiro é o nome de ficheiro completo, incluindo a especificação do caminho.

intervalo é a área que contém os dados que pretende avaliar.

modo é um parâmetro opcional que controla o método através do qual o servidor DDE converte os respetivos dados em números.

Mode	Effect
0 ou em falta	Formato numérico do estilo de célula "Padrão"
1	Os dados são sempre interpretados segundo o formato padrão para inglês americano
2	Os dados são obtidos em forma de texto; não são convertidos em números

=DDE("soffice";"c:\office\documento\dados1.ods";"folha1.A1") lê o conteúdo da célula A1 na folha1 da folha de cálculo dados1.ods do LibreOffice Calc.

=DDE("soffice";"c:\office\documento\dica.odt";"Dica do dia") devolve a dica do dia que exista na célula que contém esta fórmula. Primeiro tem que introduzir uma linha no documento dica.odt que contém o texto e definir esta como a primeira linha de uma secção com o nome Dica do dia (no LibreOffice Writer em Inserir - Secção). Se a dica for modificada (e guardada) no documento do LibreOffice Writer, a dica é atualizada em todas as células do LibreOffice Calc para as quais esta ligação DDE estiver definida.

DESLOCAMENTO

Devolve o valor de uma célula deslocada num determinado número de linhas e colunas de um determinado ponto de referência.

OFFSET(Reference; Rows; Columns [; Height [; Width]])

referência é a referência a partir da qual a função procura a nova referência.

linhas é o número de linhas com base no qual a referência foi corrigida para cima (valor negativo) ou para baixo. Utilize 0 para ficar na mesma linha.

colunas (opcional) é o número de colunas com base no qual a referência foi corrigida para a esquerda (valor negativo) ou para a direita. Utilize 0 para ficar na mesma coluna.

altura (opcional) é a altura vertical de uma área que começa na posição da nova referência.

largura (opcional) é a largura horizontal de uma área que começa na posição da nova referência.

Os argumentos linhas e colunas não devem indicar uma linha ou coluna inicial nula ou negativa.

Os argumentos altura e largura não podem indicar uma contagem de linhas ou colunas negativa ou igual a zero.

Nas funções do LibreOffice Calc, pode excluir parâmetros marcados como "opcionais" apenas quando não são seguidos por mais parâmetros. Por exemplo, numa função com 4 parâmetros, em que os dois últimos parâmetros são marcados como "opcionais", pode excluir o parâmetro 4 ou os parâmetros 3 e 4, mas não apenas o parâmetro 3.

=DESLOCAMENTO(A1;2;2) devolve o valor na célula C3 (A1 deslocada duas linhas e duas colunas para baixo). Se C3 incluir o valor 100, esta função devolve o valor 100.

=DESLOCAMENTO(B2:C3;1;1) devolve uma referência a B2:C3 movido 1 linha para baixo e uma coluna para a direita (C3:D4).

=DESLOCAMENTO(B2:C3;-1;-1) devolve uma referência a B2:C3 movida 1 linha para cima e uma coluna para a esquerda (A1:B2).

=DESLOCAMENTO(B2:C3;0;0;3;4) devolve uma referência a B2:C3 redimensionada a 3 linhas e 4 colunas (B2:E4).

=DESLOCAMENTO(B2:C3;1;0;3;4) devolve uma referência a B2:C3, movida uma linha para baixo e redimensionada a 3 linhas e 4 colunas (B3:E5).

=SOMA(DESLOCAMENTO(A1;2;2;5;6)) determina o total da área que começa na célula C3 e tem uma altura de 5 linhas e uma largura de 6 colunas (área=C3:H7).

ENDEREÇO

Devolve o endereço (referência) de uma célula na forma de texto, de acordo com os números de linha e coluna especificados. É possível determinar se o endereço deve ser interpretado como um endereço absoluto (por exemplo, $A$1), como um endereço relativo (por exemplo, A1) ou um endereço de forma mista (A$1 ou $A1). Também é possível especificar o nome da folha.

Para interoperabilidade, as funções ENDEREÇO e INDIRETO permitem um parâmetro opcional para especificar se deve ser utilizada a notação de endereço L1C1 em vez da notação A1.

Na função ENDEREÇO, o parâmetro é inserido como o quarto parâmetro, movendo o parâmetro de nome da folha opcional para a quinta posição.

Na função INDIRETO, o parâmetro é acrescentado como o segundo parâmetro.

Em ambas as funções, se o argumento for inserido com o valor 0, é utilizada a notação L1C1. Se o argumento não for fornecido ou tiver um valor diferente de 0, é utilizada a notação A1.

No caso da notação L1C1, a função ENDEREÇO devolve cadeias de endereço utilizando o ponto de exclamação '!' como o separador do nome da folha e a função INDIRETO espera o ponto de exclamação como separador do nome da folha. Ambas as funções ainda utilizam o ponto '.' como o separador do nome da folha na notação A1.

Ao abrir documentos no formato ODF 1.0/1.1, as funções ENDEREÇO que tenham um nome de folha como quarto parâmetro, irão mover o nome de folha para o quinto parâmetro. Será introduzido um novo quarto parâmetro com o valor 1.

Ao guardar um documento no formato ODF 1.0/1.1, se as funções ENDEREÇO tiverem um quarto parâmetro, esse parâmetro será removido.

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

linha representa o número de linha a utilizar na referência

coluna representa o número da coluna a utilizar na referência (o número, não a letra)

abs determina o tipo de referência:

1: absoluta ($A$1)

2: o tipo de referência da linha é absoluta; a referência da coluna é relativa (A$1)

3: linha (relativa); coluna (absoluta) ($A1)

4: relativa (A1)

A1 (opcional) - se definido como 0 ou Falso, é utilizada a notação L1C1. Se este parâmetro for omisso ou estiver definido um valor diferente de 0, é utilizada a notação A1.

folha representa o nome da folha. Tem de ser colocado entre aspas.

Exemplo:

=ENDEREÇO(1;1;2;folha) devolve o seguinte: Folha2.A$1

Se a fórmula acima estiver na célula B2 da folha atual e a célula A1 da folha 2 incluir o valor -6, pode fazer uma referência indireta à célula referenciada utilizando uma função em B2, introduzindo =ABS(INDIRETO(B2)). O resultado é o valor absoluto da referência de célula especificada em B2 que, neste caso, corresponde a 6.

FOLHA

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

SHEET([Reference])

referência é opcional e corresponde a uma referência a uma célula, intervalo ou cadeia de texto com um nome de folha.

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

FOLS

Devolve o número de folhas da referência especificada. Se não introduzir quaisquer parâmetros, devolve o número de folhas do documento ativo.

SHEETS([Reference])

referência corresponde à referência a uma célula ou intervalo de dados. Este parâmetro é opcional.

=FOLS(Folha1.A1:Folha3.G12) devolve 3 se Folha1, Folha2 e Folha3 existirem na sequência indicada.

HIPERLIGAÇÃO

Ao clicar numa célula que contenha a função HIPERLIGAÇÃO, abre-se a hiperligação.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

O número 0 é devolvido para células vazias e elementos de matriz.

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

INDIRETO

Devolve a referência especificada por um valor de texto. Esta função também pode ser utilizada para devolver a área da cadeia correspondente.

INDIRECT(Ref [; A1])

ref_texto representa uma referência a uma célula ou área (na forma de texto) para a qual devolver o conteúdo.

A1 (opcional) - se definido como 0 ou Falso, é utilizada a notação L1C1. Se este parâmetro for omisso ou estiver definido um valor diferente de 0, é utilizada a notação A1.

=INDIRETO(A1) equivale a 100 se A1 incluir C108 como uma referência e a célula C108 incluir um valor de 100.

=SOMA(INDIRETO("a1:" & ENDEREÇO(1;3))) soma as células na área de A1 até à célula com o endereço definido pela linha 1 e coluna 3. Ou seja, soma a área A1:C1.

LIN

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

ROW([Reference])

referência é uma célula, uma área ou o nome de uma área.

Se não indicar uma referência, é devolvido o número de linha da célula onde a fórmula é introduzida. O LibreOffice Calc define automaticamente a referência para a célula atual.

=LIN(B3) devolve 3, uma vez que a referência corresponde à terceira linha da tabela.

{=LIN(D5:D8)} devolve a matriz de coluna única (5, 6, 7, 8), uma vez que a referência especificada contém as linhas 5 a 8.

=LIN(D5:D8) devolve 5, uma vez que a função LIN não é utilizada como fórmula de matriz, devolvendo apenas o número da primeira linha da referência.

{=LIN(A1:E1)} e =LIN(A1:E1) devolvem ambos 1, uma vez que a referência apenas contém a linha 1 como a primeira linha da tabela. (Visto as áreas de linha única terem apenas um número de linha, é indiferente se a fórmula é utilizada como fórmula de matriz ou não.)

=LIN() devolve 3 se a fórmula tiver sido introduzida na linha 3.

{=LIN(Coelho)} devolve a matriz de coluna única (1, 2, 3) se "Coelho" for o nome da área (C1:D3).

LINS

Devolve o número de linhas de uma referência ou matriz.

LINS(matriz)

matriz é a referência ou área com nome definido cujo número total de linhas deve ser determinado.

=LINS(B5) devolve 1, uma vez que uma célula contém apenas uma linha.

=LINS(A10:B12) devolve 3.

=LINS(Coelho) devolve 3 se "Coelho" for o nome da área (C1:D3).

OBTERDADOSDIN

A função OBTERDADOSDIN devolve um resultado da tabela dinâmica. O valor é referenciado atrás dos nomes de item e campo, permanecendo válido se o esquema da tabela dinâmica mudar.

Pode utilizar duas definições de sintaxe diferentes:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

or

OBTERDADOSDIN(tabela_dinâmica; restrições)

A segunda sintaxe é assumida se forem fornecidos exatamente dois parâmetros, dos quais o primeiro parâmetro é uma referência a uma célula ou a um intervalo de células. A primeira sintaxe é assumida em todos os outros casos. O Assistente de funções mostra a primeira sintaxe.

First Syntax

campo_dados é o nome do campo a partir do qual os valores serão extraídos. Pode ser o nome da coluna de origem ou o nome do campo de dados tal como está na tabela (como "Soma - Vendas").

tabela_dinâmica é a referência a uma célula ou intervalo de células que está posicionada numa tabela dinâmica, ou inclui uma tabela dinâmica. Se o intervalo de células inclui várias tabelas dinâmicas, é utilizada a tabela que foi criada em último lugar.

Se não forem indicados pares campo/item, é devolvida a soma total. Caso contrário, cada par adiciona uma restrição que o resultado terá de satisfazer. Campo é o nome de um campo da tabela dinâmica. Item é o nome de um item desse campo.

Se a tabela dinâmica só incluir um valor de resultado que satisfaça todas as restrições ou um valor de subtotal que resuma todos os valores correspondentes, esse resultado é devolvido. Se não existir qualquer resultado correspondente ou existirem vários sem um subtotal para os mesmos, é devolvido um erro. Estas condições aplicam-se ao resultados incluídos na tabela dinâmica.

Se a origem dos dados incluir entradas que estejam ocultas por definições da tabela dinâmica, estão são ignoradas. A ordem dos pares campo/item não é significativa. Os nomes de campo e item não diferenciam maiúsculas e minúsculas.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Os valores de subtotal da tabela dinâmica apenas serão utilizados se utilizarem a função "auto" (exceto quando especificado na restrição, consultar Segunda sintaxe).

Second Syntax

tabela_dinâmica tem o mesmo significado da primeira sintaxe.

restrições é uma lista separada por espaços. As entradas podem ser introduzidas entre plicas. A cadeia completa tem de ser colocada entre aspas, a não ser que referencie uma cadeia de outra célula.

Uma das entradas pode ser o nome do campo de dados. O nome do campo de dados pode não ser preenchido se a tabela dinâmica incluir apenas um campo de dados. Caso contrário, terá de ser preenchido.

Cada uma das outras entradas especifica uma restrição no formulário campo[item] (com caracteres literais [ e ]) ou apenas item se o nome do item for único dentro de todos os campos utilizados na tabela dinâmica.

Pode adicionar um nome de função segundo a forma Campo[Item;Função], o que fará com que a restrição corresponda apenas a valores de subtotal que utilizem essa função. Os nomes de função possíveis são Soma, Contar, Média, Máximo, Mínimo, Produto, Contar (só números), DesvPad (amostra), DesvPadN (população), Variância (amostra) e Variâncias (população), não sensíveis a maiúsculas/minúsculas.

PROC

Devolve o conteúdo de uma célula de um intervalo de coluna ou linha única. Opcionalmente, o valor atribuído (do mesmo índice) é devolvido numa coluna ou linha diferente. Em contraste com as funções PROCV e PROCH, os vetores de procura e de resultados podem estar em posições diferentes. Não é necessário que sejam adjacentes. Adicionalmente, o vetor de procura da função PROC tem de estar ordenado de forma ascendente. Caso contrário, a procura não devolverá qualquer valor útil.

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

vetor_procura é a área de uma coluna ou uma linha onde a procura deve ser realizada.

vetor_resultado é o outro intervalo de uma linha ou uma coluna a partir do qual é obtido o resultado da função. O resultado é a célula do vetor de resultados com o mesmo índice da ocorrência encontrada no vetor de procura.

=PROC(A1;D1:D100;F1:F100) procura a célula correspondente no intervalo D1:D100 do número introduzido em A1. É determinado o índice da ocorrência encontrada, por exemplo, a 12.ª célula deste intervalo. Assim, o conteúdo da 12.ª célula é devolvido como valor da função (no vetor de resultados).

PROCH

Procura um valor e referência às células situadas por baixo da área selecionada. Esta função verifica se a primeira linha de uma matriz contém um determinado valor. A função devolve o valor numa linha da matriz, indicada no Índice, na mesma coluna.

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Para ver a explicação dos parâmetros consulte: PROCV (onde se lê linhas, deve ler colunas)

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomic Number	1	2	3	...	118
4	Relative Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

PROCV

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

A matriz é a referência, que contém pelo menos tantas colunas quantas forem passadas no número do argumento do índice.

índice corresponde ao número da coluna na matriz de onde o valor deve ser retirado. A primeira coluna tem o número 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

O utilizador pretende que, ao introduzir o número de um prato do menu na célula A1, o nome do prato seja mostrado imediatamente como texto na célula (B1). A atribuição de números aos nomes está contida na matriz D1:E100. D1 contém 100, E1 contém o nome Sopa de vegetais e assim sucessivamente para os 100 pratos. Os números na coluna D são ordenados de forma ascendente. Assim, o parâmetro opcional ordenação não é necessário.

Introduza a seguinte fórmula em B1:

=PROCV(A1;D1:E100;2)

Assim que introduz um número em A1, a célula B1 irá mostrar o texto existente na segunda coluna da referência D1:E100. Se introduzir um número não existente, a célula mostra o texto correspondente ao número imediatamente a seguir. Para evitar que tal aconteça, introduza FALSO como último parâmetro da fórmula; dessa forma, a célula mostra uma mensagem de erro quando se introduz um número não existente.

SELECIONAR

Utiliza um índice para devolver um valor de uma lista constituída por 30 valores ou menos.

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

núm_índice corresponde à referência ou número entre 1 e 30 que indica qual é o valor a ser obtido da lista.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

=SELECIONAR(A1;B1;B2;B3;"Hoje";"Ontem";"Amanhã"), por exemplo, devolve o conteúdo da célula B2 para A1 = 2; para A1 = 4, a função devolve o texto "Hoje".

TIPOERRO

Devolve o número correspondente ao valor de erro. Com a ajuda deste número, pode criar um texto de mensagem de erro.

TIPOERRO(valor_erro)

valor_erro contém o endereço da célula na qual ocorre o erro.

Se a célula A1 mostrar Err:518, a função =TIPOERRO(A1) devolve o número 518.

ORG.OPENOFFICE.ERRORTYPE

ÁREAS

Devolve o número de áreas numa referência. Uma área é um intervalo de células contíguas ou uma única célula.

A função espera um único argumento. Se especificar vários intervalos, terá de colocá-los entre parênteses adicionais. Pode introduzir vários intervalos utilizando um ponto e vírgula (;) como separador, embora este seja automaticamente convertido para o operador til (~). O til é utilizado para unir intervalos.

ÁREAS(referência)

A referência representa a referência a uma célula ou intervalo de dados.

=ÁREAS((A1:B3;F2;G1)) devolve 3, uma vez que se trata de uma referência a três células e/ou áreas. Após a entrada, é convertido para =ÁREAS((A1:B3~F2~G1)).

=ÁREAS(Tudo) devolve 1 se tiver definido uma área com o nome "Tudo" em Dados - Definir intervalo.

ÍNDICE

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=ÍNDICE(preços;4;1) devolve o valor da linha 4 e coluna 1 do intervalo de base de dados definido em Dados - Definir como preços.

=ÍNDICE(soma_x;4;1) devolve o valor do intervalo soma_x na linha 4 e coluna 1, como definido em Folha - Intervalo ou expressão nomeada - Definir.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=ÍNDICE(A1:B6;1;1) indica o valor no canto superior esquerdo do intervalo A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.