SOMASES

Retorna a soma dos valores das células de um intervalo que conferem critérios em vários intervalos.

tip

Esta função está disponível desde o LibreOffice 4.0.


Sintaxe

SOMASES(Func_Intervalo; Intervalo1; Criterio[; Intervalo2; Criterio2][; … ; [Intervalo127; Criterio127]])

Intervalo_Func – argumento obrigatório. Um intervalo, um nome de intervalo ou um rótulo de coluna ou linha contendo os valores para calcular a soma.

Intervalo1 – argumento obrigatório. Intervalo de células, o nome de um intervalo nomeado, ou um rótulo de uma coluna ou linha, no qual o critério correspondente deve ser aplicado.

Critério: Um critério é uma referência, número ou texto de uma única célula. É usado em comparações com o conteúdo da célula.

Uma referência a uma célula vazia é interpretada como o valor numérico 0.

Uma expressão correspondente pode ser:

Intervalo2 – Opcional. Intervalo2 e os seguintes tem mesmo significado que Intervalo1

Critério2 – Opcional. Critério2 e todos os seguintes tem mesmo significado que Critério.

A pesquisa suporta caracteres coringa ou expressões regulares. Com as expressões regulares ativadas, você pode inserir "all.*", por exemplo, para encontrar a primeira ocorrência de "all" seguida de qualquer outro caractere. Se deseja pesquisar por um texto que também é uma expressão regular, você deve preceder cada caractere com o caractere "\", ou incluir o texto entre \Q...\E. Você pode ativar a avaliação de caracteres coringa ou expressões regulares em - LibreOffice Calc - Calcular.

warning

Ao usar funções onde um ou mais argumentos são textos de critérios de pesquisa que representam uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Entretanto, ao mudar de região onde o separador decimal não é mais o ponto, a expressão regular passa a valer. Para forçar a avaliação da expressão regular de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número, como por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".


Intervalo_Func e Intervalo1, Intervalo2... devem ter o mesmo tamanho ou a função retorna err:502 - argumento inválido.

note

A relação lógica entre os critérios pode ser definida como E lógico (conjunção). Em outras palavras, se e somente se todos os critérios são verificados, um valor da célula correspondente do intervalo Intervalo_Func é computada.


A função pode ter até 255 argumentos, significando que pode haver 127 intervalos de critérios e critérios correspondentes.

Se uma célula contém VERDADEIRO, é tratada como 1, se tiver FALSO, é tratada como zero.

note

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).


Exemplo

Considere a seguinte tabela

A

B

C

1

Nome do produto

Vendas

Renda

2

canudo

20

65

3

caneta

35

85

4

caderno

20

190

5

mochila

17

180

6

caneta tinteiro

nao

não


warning

Em todos os cálculos abaixo, o intervalo para a soma contém a linha nº 6, que é ignorada por que contém um texto.


Utilização simples

=SOMASES(B2:B6;B2:B6;">=20")

Calcula a soma para os valores do intervalo B2:B6 que são maiores ou igual a 20. Retorna 75 por que a 5ª linha não confere o critério.

=SOMASES(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcula a soma para os valores do intervalo C2:C6 que são maiores que 70 e que correspondem às células de B2:B6 maiores ou igual a 20. Retorna 275 por que a 2ª e a 5ª linha não atendem a pelo menos um dos critérios.

Usar expressões regulares e funções incorporadas

=SOMASES(C2:C6;B2:B6;">"&MíNIMO(B2:B6);B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a soma para os valores do intervalo C2:C6 que correspondem a todos os valores do intervalo B2:B6 exceto seu máximo e seu mínimo. Retorna 255 por que a 3ª e a 5ª linha não atendem a pelo menos um dos critérios.

=SOMASES(C2:C6;A2:A6;"can.*";B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a soma dos valores do intervalo C2:C6 que correspondem a todos os valores do intervalo A2:A6 que começam com as letras «can» e todas as células do intervalo B2:B6 exceto seu máximo. Retorna 65 porque somente a segunda linha atende a todos os critérios.

Critério como referência

Se precisar mudar o critério mais facilmente, você pode especificar uma célula em separado e usar sua referência na condição para a função SOMASES. Por exemplo, a função acima pode ser reescrita como:

=SOMASES(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2="can", a função retorna 65.

Abrir arquivo com exemplo:

♥ Doe para nosso projeto! ♥