Função MÉDIASE
Retorna a média aritmética de todas as células no intervalo que satisfaçam uma condição apresentada. A função MÉDIASE soma todos os resultados que conferem a condição e divide pela quantidade dos valores selecionados.
MÉDIASE(Intervalo; Critério [; Intervalo_media ])
Intervalo – argumento obrigatório. Uma matriz, um nome de intervalo ou um rótulo de coluna ou linha contendo os números a calcular ou texto da condição.
A pesquisa suporta caracteres coringa ou expressões regulares. Com as expressões regulares ativadas, você pode inserir "all.*", por exemplo, para encontrar a primeira ocorrência de "all" seguida de qualquer outro caractere. Se deseja pesquisar por um texto que também é uma expressão regular, você deve preceder cada caractere com o caractere "\", ou incluir o texto entre \Q...\E. Você pode ativar a avaliação de caracteres coringa ou expressões regulares em .
Ao usar funções onde um ou mais argumentos são textos de critérios de pesquisa que representam uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Entretanto, ao mudar de região onde o separador decimal não é mais o ponto, a expressão regular passa a valer. Para forçar a avaliação da expressão regular de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número, como por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".
Intervalo_media – opcional. O intervalo de valores para calcular a média.
Se Intervalo_media não for especificado, Intervalo é utilizado para ambos, o cálculo da média e a pesquisa de acordo com a condição. Se Intervalo_media for especificado, o Intervalo é utilizado para a condição de teste, enquanto Intervalo_media é utilizado par o cálculo da média.
Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).
Se uma célula num intervalo de valores for zero ou um texto, a função MÉDIASE ignora esta célula.
Se o intervalo inteiro for vazio, contém só textos ou se nenhum valor verificar a condição (ou qualquer combinação destes), a função retorna o erro #DIV/0!.
Considere a seguinte tabela
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
Nome do produto |
Vendas |
Renda |
|
2 |
canudo |
20 |
65 |
|
3 |
caneta |
35 |
85 |
|
4 |
caderno |
20 |
190 |
|
5 |
mochila |
17 |
180 |
|
6 |
caneta tinteiro |
nao |
não |
Em todos os cálculos abaixo, o intervalo para a soma contém a linha nº 6, que é ignorada por que contém um texto.
Usos simples
=MÉDIASE(B2:B6;"<35")
Calcula a média para os valores do intervalo B2:B6 que são menores de 35. Retorna 19 por que a segunda linha não participa do cálculo.
=MÉDIASE(B2:B6;"<"&MÁXIMO(B2:B6))
Calcula a média para valores do mesmo intervalo que são menores que o máximo valor do intervalo. Retorna 19 por que o maior valor (a segunda linha) não participa no cálculo.
=MÉDIASE(B2:B6;">"&MENOR(B2:B6;1))
Calcula a média para valores do mesmo intervalo que são maiores que o menor valor do intervalo. Retorna 25 por que o menor valor do intervalo (a 4ª linha) não participa do cálculo.
Utilizar o Intervalo_medio
=MÉDIASE(B2:B6;"<35";C2:C6)
A função pesquisa que valores são menores de 35 no intervalo B2:B6, e calcula a média correspondente dos valores do intervalo C2:C6. Retorna 145, por que a segunda linha não participa da conta.
=MÉDIASE(B2:B6;">"&MINIMO(B2:B6);C2:C6)
A função pesquisa que valores no intervalo B2:B6 são maiores que o menor valor no intervalo B2:B6, e calcula a média correspondente no intervalo C2:C6. Retorna 113,3, por que a 4ª linha (onde está o menor valor no intervalo B2:B6) não participa do cálculo.
=MÉDIASE(B2:B6;"<"&MAIOR(B2:B6;2);C2:C6)
A função pesquisa que valores do intervalo B2:B6 são menores que o segundo maior valor no intervalo B2:B6, e calcula a média correspondente no intervalo C2:C6. Retorna 180, por que só a 4ª linha participa da conta.
Usar expressões regulares
=MÉDIASE(A2:A6;"caneta";B2:B6)
A função pesquisa que células no intervalo A2:A6 contém a palavra "caneta", e calcula a média correspondente dos valores do intervalo B2:B6. Retorna 35 por que só a segunda linha participa da conta. A pesquisa é feita no intervalo A2:A3, mas o valor é retornado do intervalo B2:B6
=MÉDIASE(A2:A6;"can.*";B2:B6)
A função pesquisa que células do intervalo A2:A6 começam com "can", e terminam com qualquer número de caracteres para calcular a média dos valores correspondentes no intervalo B2:B6. Retorna 27,5, por que "canudo" também satisfaz a condição e as duas primeiras linhas participam da conta.
=MÉDIASE(A2:A6;".*book.*";B2:B6)
A função pesquisa que células no intervalo A2:A3 contém o texto "book" começando e terminando com outros caracteres e calcula a média correspondente no intervalo B2:B6. Retorna 18,5 por que somente a 3ª e 4ª linhas participam da conta.
Critério como referência
Se desejar mudar o critério mais facilmente, pode especificar uma célula separada e usá-la em referencia como condição para a função MÉDIASE.
=MÉDIASE(A2:A6;".*"&E2&".*";B2:B6)
A função pesquisa que células no intervalo A2:A6 contém uma combinação de caracteres especificada na célula E2 no meio de qualquer outras combinações de caracteres e calcula a média dos valores correspondentes no intervalo B2:B6. Se E2="book" então a função retorna 18,5.
=MÉDIASE(B2:B6;"<"&E2;C2:C6)
A função pesquisa que células do intervalo B2:B6 são menores que o valor especificado em E2 e calcula a média dos valores correspondentes do intervalo C2:C6. Se E2=35, a função retorna 145.