Funções de planilha

Esta seção contém descrições das funções de Planilha junto com um exemplo.

Função TIPO.ERRO

Retorna um número representando um tipo específico de erro, ou o erro #N/DISP, se não houver erro.

ESTILO

Aplica um estilo à célula que contém a fórmula.

ÁREAS

Retorna o número de intervalos individuais que pertencem a um intervalo múltiplo. Um intervalo pode ser composto de diversas células ou de uma única célula.

A função espera um argumento singular. Se estabelecer vários intervalos, você deve envolvê-los com parênteses adicionais. Múltiplos intervalos podem ser inseridos com um ponto e vírgula (;) como separador, porém serão convertidos automaticamente para o operador til (~). O til é utilizado para unir intervalos.

ÁREAS(Referência)

Referência representa a referência a uma célula ou a um intervalo de células.

=ÁREAS((A1:B3;F2;G1)) retornará 3, pois é uma referência a três células e/ou áreas. Após a entrada isto se converte em =ÁREAS((A1:B3~F2~G1)).

=ÁREAS(Todas) retorna 1 se você definiu uma área de nome Todas em Dados - Definir intervalo.

COLUNA

Retorna o número da coluna de uma referência de célula. Se a referência for uma célula, o número da coluna da célula será retornado; se o parâmetro for uma área de célula, os números de coluna correspondentes serão retornados em uma matriz de linha única se a fórmula for inserida como uma fórmula de matriz. Se a função COLUNA tiver um parâmetro de referência de área e não for usada para uma fórmula de matriz, apenas o número da coluna da primeira célula da área será determinado.

COLUNA([Referência])

Referência é a referência a uma célula ou área de célula cujo primeiro número de coluna deve ser localizado.

Se nenhuma referência for inserida, será localizado o número da coluna da célula na qual a fórmula foi inserida. O LibreOffice Calc define automaticamente a referência como a célula atual.

=COLUNA(A1) é igual a 1. A coluna A é a primeira coluna da tabela.

=COLUNA(C3:E3) é igual a 3. A coluna C é a terceira coluna na tabela.

=COLUNA(D3:G10) retorna 4 por que a coluna D é a quarta coluna na tabela e a função COLUNA não é usada numa fórmula de matriz. (Neste caso, o primeiro valor da matriz é sempre usado como resultado.)

{=COLUNA(B2:B7)} e =COLUNA(B2:B7) ambas retornam 2 por que a referência só contém B como segunda coluna na tabela. Já que áreas de uma coluna só tem um número de coluna, não faz diferença se a fórmula for de matriz ou não.

=COLUNA() retorna 3 se a fórmula foi inserida na coluna C.

{=COLUNA(Coelho)} retorna a matriz de uma linha (3, 4) caso "Coelho" seja o nome da área (C1:D3).

COLUNAS

Retorna o número de colunas da referência especificada.

COLUNAS(Matriz)

Matriz é a referência a um intervalo de células cujo número total de colunas deve ser encontrado. O argumento pode também ser uma célula única.

=COLUNAS(B5) retorna 1 por que uma célula só contém uma coluna.

=COLUNAS(A1:C5) igual a 3. A referência compreende três colunas.

=COLUNAS(Coelho) retorna 2 se Coelho for o intervalo nomeado (C1:D3).

CORRESP

Retorna a posição relativa de um item de matriz que corresponde a um valor especificado. A função retorna a posição do valor encontrado na matriz_de_consulta como um número.

CORRESP(Pesquisa; MatrizDePesquisa [; Tipo])

Pesquisa é o valor a ser pesquisado na matriz de linha única ou de coluna única.

MatrizDePesquisa é a referência pesquisada. Uma matriz de pesquisa pode ser uma linha ou coluna única, ou parte de uma linha ou coluna.

Tipo pode receber os valores 1, 0 ou -1. Se Tipo = 1 ou se este parâmetro opcional for omitido, assume-se que a primeira coluna da matriz de pesquisa está em ordem crescente. Se Tipo = -1, assume-se que a coluna está em ordem decrescente. Essa função corresponde à mesma função do Microsoft Excel.

Se Tipo = 0, somente valores exatos existentes serão encontrados. Se o critério de pesquisa for encontrado mais de uma vez, a função retorna o índice do primeiro valor encontrado. Somente quando Tipo = 0 é que se pode procurar por expressões regulares ou caracteres curinga (se ativados nas opções de cálculo).

Se Tipo = 1 ou o terceiro parâmetro for omitido, retorna o índice do último valor que for menor ou igual ao critério de pesquisa. Para Tipo = -1, retorna o índice do último valor maior ou igual.

=CORRESP(200;D1:D100) pesquisa a área D1:D100, que está ordenada pela coluna D, pelo valor de 200. Assim que o valor for encontrado, o número da linha onde o valor foi encontrado será retornado. Se um valor maior for encontrado durante a pesquisa na coluna, o número da linha anterior será retornado.

DDE

Retorna o resultado de um vínculo tipo DDE. Se o conteúdo do intervalo ou da seção vinculada for alterado, o valor retornado também será alterado. Você deve recarregar a planilha ou escolher Editar - Vínculos para ver os vínculos atualizados. Não é permitido cruzar vínculos entre plataformas diferentes, por exemplo, de uma instalação do LibreOffice executada em um computador com Windows para um documento criado em um computador com Linux.

DDE("Servidor"; "Arquivo"; "Intervalo" [; Modo])

Servidor é o nome da aplicação servidora. As aplicações do LibreOffice têm nome de servidor "soffice".

Arquivo é o nome completo do arquivo, incluindo a especificação do caminho.

Intervalo é a área que contém os dados que serão avaliados.

Modo é um parâmetro opcional que controla o método através do qual o servidor DDE converte seus dados em números.

Modo	Efeito
0 ou ausente	Formato de número do estilo de célula "Padrão"
1	Os dados são sempre interpretados no formato padrão para o inglês americano
2	Os dados são recuperados como texto; não ocorre a conversão em números

=DDE("soffice";"c:\office\document\dados1.ods";"Planilha1.A1") lê o conteúdo da célula A1 da Planilha1 do arquivo dados1.ods do LibreOffice Calc.

=DDE("soffice";"c:\office\document\frases.odt";"Frase do dia") retorna uma frase numa célula contendo esta fórmula. Primeiro, você deve inserir uma linha no documento frase.odt contendo o texto da frase e definir como primeira linha de uma seção de nome Frase do dia (em LibreOffice Writer sob Inserir - Seção). Se a frase for modificada (e salva) no documento do LibreOffice Writer, a frase será atualizada em todas as células do LibreOffice Calc nas quais esse vínculo DDE foi definido.

DESLOC

Retorna o valor de uma célula deslocada por um determinado número de linhas e colunas a partir de um determinado ponto de referência.

DESLOC(Referência; Linhas; Colunas [; Altura [; Largura]])

Referência é a referência da qual a função pesquisa pela nova referência.

Linhas é o número de linhas pela qual a referência foi corrigida para cima (valor negativo) ou para baixo. Use 0 para ficar na mesma linha.

Colunas é o número de colunas pela qual a referência foi corrigida para a esquerda (valor negativo) ou para a direita. Use 0 para ficar na mesma coluna.

Altura (opcional) é a altura de uma área que começa na nova posição de referência.

Largura (opcional) é a largura horizontal de uma área que começa na nova posição de referência.

Os argumentos Linhas e Colunas não devem indicar uma linha ou coluna inicial nula ou negativa.

Os argumentos Altura e Largura não podem resultar numa contagem nula ou negativa de colunas ou linhas.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

=DESLOC(A1;2;2) retorna o valor na célula C3 (A1 movida de duas linhas e duas colunas para baixo). Se C3 contém o valor 100 essa função retorna o valor 100.

=DESLOC(B2:C3;1;1) retorna uma referência a B2:C3 movida 1 linha para baixo e uma coluna para a direita (C3:D4).

=DESLOC(B2:C3;-1;-1) retorna uma referência a B2:C3 movida uma linha para cima e uma coluna para a esquerda (A1:B2).

=DESLOC(B2:C3;0;0;3;4) retorna uma referência a B2:C3 redimensionada para 3 linhas e 4 colunas (B2:E4).

=DESLOC(B2:C3;1;0;3;4) retorna uma referência a B2:C3 movida uma linha para baixo e redimensionada a 3 linhas e 4 colunas (B3:E5).

=SOMA(DESLOC(A1;2;2;5;6)) determina o total da área que começa na célula C3 e tem uma altura de 5 linhas e largura de 6 colunas (área=C3:H7).

ENDEREÇO

Retorna o endereço (referência) de uma célula na forma de texto, de acordo com os números de linha e coluna especificados. Você pode determinar se o endereço deve ser interpretado como absoluto (por exemplo, $A$1), relativo (como A1) ou em uma forma mista (A$1 ou $A1). Você também pode especificar o nome da planilha.

Para interoperabilidade, as funções ENDEREÇO e INDIRETO suportam um parâmetro opcional para especificar se a notação R1C1 será utilizada no lugar da tradicional notação A1.

Na função ENDEREÇO, o parâmetro é inserido na quarta posição, deslocando o nome opcional da planilha para a quinta posição.

Na função INDIRETO, o parâmetro é anexado como segundo parâmetro.

Em ambas as funções, se o argumento for inserido com valor 0, então a notação R1C1 será utilizada. Se o argumento for omitido ou tiver valor diferente de 0, então a notação A1 será utilizada.

No caso da notação R1C1, a função ENDEREÇO retorna cadeias de caracteres de endereço utilizando o ponto de exclamação '!' como separador do nome da planilha, e a função INDIRETO requer o ponto de exclamação como separador do nome de planilha. Ambas as funções continuam utilizando o ponto '.' como separador do nome da planilha com a notação A1.

Ao abrir documentos com formato ODF 1.0/1.1, as funções ENDEREÇO que mostrarem um nome de planilha como quarto parâmetro deslocarão este nome de planilha para que se torne o quinto parâmetro. Um novo quarto parâmetro com valor 1 será inserido.

Ao gravar um documento no formato ODF 1.0/1.1, se as funções ENDEREÇO tiverem um quarto parâmetro, ele será removido.

ENDEREÇO(Linha; Coluna [; Abs [; A1 [;"Planilha"]]])

Linha representa o número da linha para a referência da célula

Coluna representa o número da coluna para a referência da célula (o número, não a letra)

Abs determina o tipo de referência:

1: absoluto ($A$1)

2: o tipo de referência de linha é absoluto; a referência de coluna é relativa (A$1)

3: linha (relativa); coluna (absoluta) ($A1)

4: relativa (A1)

A1 (opcional) - Se definido como 0, a notação R1C1 será utilizada. Se este parâmetro estiver ausente ou definido com outro valor que 0, a notação A1 será utilizada.

Planilha representa o nome da planilha. Deve estar entre aspas duplas.

Exemplo:

=ENDEREÇO(1;1;2;"Planilha2") retorna o seguinte: Planilha2.A$1

Se a fórmula acima está na célula B2 na planilha atual, e a célula A1 na planilha 2 contém o valor -6, você pode referenciar indiretamente para a célula referenciada usando uma função em B2 inserindo =ABS(INDIRETO(B2)). O resultado é o valor absoluto da referência da célula especificada em B2, que neste caso é 6.

ESCOLHER

Utiliza um índice para retornar um valor de uma lista de até 30 valores.

ESCOLHER(Índice; Valor1 [; Valor2 [; ... [; Valor30]]])

Índice é uma referência ou um número entre 1 e 30 que indica o valor a tomar da lista.

Valor1; Valor2; ... ; Valor30 é a lista de valores inseridos como referência para uma célula ou como valores individuais.

=ESCOLHER(A1;B1;B2;B3;"Hoje";"Ontem";"Amanhã"), por exemplo, retorna o conteúdo da célula B2 para A1 = 2; para A1 = 4, a função retorna o texto "Hoje".

HIPERLINK

Ao clicar numa célula que contém a função HIPERLINK, o hiperlink é aberto.

Se utilizar o parâmetro opcional ValorCélula, a fórmula localizará o URL e exibirá o texto ou número.

HIPERLINK("URL" [; "ValorCélula"])

URL especifica o vínculo ao destino. O parâmetro opcional ValorCélula é o texto ou número que será exibido na célula e será o resultado da função. Se o parâmetro ValorCélula não for especificado, a URL será exibida na célula de texto e será o resultado da função.

O número 0 será retornado para células vazias e elementos de matriz.

=HIPERLINK("http://www.exemplo.org") exibe o texto "http://www.exemplo.org" na célula e executa o hiperlink http://www.example.org ao clicar na mesma.

=HIPERLINK("http://www.exemplo.org";"Clique aqui") exibe o texto "Clique aqui" na célula e executa o hiperlink http://www.exemplo.org quando clicado.

=HIPERLINK("http://www.exemplo.org";12345) exibe o número 12345 e executa o hiperlink http://www.example.org quando clicado.

=HIPERLINK($B4) onde a célula B4 contém http://www.exemplo.org. A função adiciona http://www.exemplo.org no URL da célula do hiperlink e retorna o mesmo texto que é usado como resultado da fórmula.

=HIPERLINK("http://www.";"Clique ") & "exemplo.org" exibe o texto Clique exemplo.org na célula e executa o hiperlink http://www.exemplo.org quando clicado.

=HIPERLINK("#Planilha1.A1";"Vá para o início") exibe o texto Vá para o início e vai para a célula Planilha1.A1 neste documento.

=HIPERLINK("file:///C:/writer.odt#Especificacao";"Ir para marca-página do Writer") exibe o texto "Ir para marca-página do Writer", carrega o documento de texto especificado e salta até o marca-página "Especificacao".

=HIPERLINK("file:///C:/Documentos/";"Abrir pasta de documentos") exibe o texto "Abrir pasta de documentos" e mostra o conteúdo da pasta com o geraciador de arquivos padrão de seu sistema operacional.

ÍNDICE

ÍNDICE retorna uma referência, um valor ou uma matriz de valores de um intervalo de referência, especificado por número de índice de linha e coluna ou matriz de índices de linha e matriz de índices de colunas, e um índice de intervalo opcional.

ÍNDICE() retorna uma referência se o argumento for uma ou mais referências. Quando usado em uma célula no formato =ÍNDICE(), a referência é resolvida e os valores exibidos. Quando ÍNDICE() é usado em argumentos de outras funções, =FUNÇÃO(ÍNDICE()...), a função obtém a referência passada que foi retornada por ÍNDICE(). Retornar uma referência é diferente de retornar uma matriz de valores para funções que os manipulam de maneira diferente.

ÍNDICE(Referência [; [Linha] [; [Coluna] [; Intervalo]]])

Referência é uma referência, inserida seja diretamente ou ao especificar um nome de intervalo. Se a referência consistir de múltiplos intervalos, você deve colocar a referência ou nome de intervalo entre parênteses, ou utilizar o operador til (~) para concatenar intervalos ou definir um intervalo nomeado com várias áreas.

Linha (opcional) representa o índice ou matriz de índices de linhas do intervalo de referência, para a qual deve-se retornar um valor. Se zero ou omitido (nenhuma linha especificada), retorna todas as linhas referenciadas.

Coluna (opcional) representa o índice ou matriz de índices de colunas do intervalo de referência, para a qual deve-se retornar um valor. Se zero ou omitido (nenhuma coluna especificada), retorna todas as colunas referenciadas.

Intervalo (opcional) representa o índice do sub intervalo se este se referir a um intervalo múltiplo, o padrão é 1.

{=ÍNDICE({1,3,5;7,9,10},{2;1},1)} retorna uma matriz de 2 linhas contendo 7 e 1. Os índices de linha {2;1} seleciona a linha 2 e em seguida 1. O índice de coluna 1 seleciona a primeira coluna.

{=ÍNDICE(D3:G12,{1;2;3;4},{3,1})} retorna uma matriz de 4 linhas e 2 colunas. A matriz de índices {1;2;3;4} seleciona as linhas 3 até 6 e {3;1} seleciona a terceira (F) e primeira coluna (D). As colunas 1 e 3 do intervalo de origem são invertidas na matriz resultante.

=ÍNDICE(Preços;4;1) retorna o valor desde a linha 4 e coluna 1 do intervalo de banco de dados definido em Dados - Definir como Preços.

=ÍNDICE(SomaX;4;1) retorna o valor a partir do intervalo SomaX na linha 4 e coluna 1 como definido em Planilha - Intervalos nomeados e expressões - Definir.

{=ÍNDICE(A1:B6;1)} retorna os valores da primeira linha de A1:B6. Insira a fórmula como uma fórmula de matriz.

{=ÍNDICE(A1:B6;0;1)} retorna os valores da primeira coluna de A1:B6. Insira a fórmula como uma fórmula de matriz.

=ÍNDICE(A1:B6;1;1) indica o valor no canto superior esquerdo do intervalo A1:B6.

{=ÍNDICE((A1:B6;C1:D6);0;0;2)} retorna os valores do segundo intervalo C1:D6 do intervalo múltiplo. Digite a fórmula como uma fórmula de matriz.

INDIRETO

Retorna a referência especificada por uma cadeia de caracteres de texto. Esta função também pode ser usada para retornar a área de uma cadeia de caracteres correspondente.

INDIRETO(Ref [; A1])

Ref representa a referência a uma célula ou uma área (na forma textual) para a qual deve-se retornar o conteúdo.

A1 (opcional) - Se definido como 0, a notação R1C1 será utilizada. Se este parâmetro estiver ausente ou definido com outro valor que 0, a notação A1 será utilizada.

=INDIRETO(A1) é igual a 100 caso A1 contenha C108 como referência e a célula C108 contém o valor de 100.

=SOMA(INDIRETO("a1:" & ENDEREÇO(1;3))) totaliza as células na área A1 até a célula com o endereço definido pela linha 1 e a coluna 3. Significa que a área A1:C1 é totalizada.

INFODADOSTABELADINÂMICA

A função INFODADOSTABELADINÂMICA retorna um valor da tabela dinâmica. O valor é endereçado utilizando campo e nomes do item, de forma que permanece válido caso o leiaute da tabela dinâmica seja alterado.

Duas definições de sintaxe podem ser usadas:

INFODADOSTABELADINÂMICA(CampoAlvo; TabelaDinâmica; [; Campo 1; Item 1][; ... [Campo 126; Item 126]])

ou

INFODADOSTABELADINÂMICA(tabela dinâmica; Restrições)

Assume-se a segunda sintaxe se forem dados dois parâmetros, dos quais o primeiro é uma célula ou referência a um intervalo de células. Assume-se a primeira sintaxe em todos os outros casos. O Assistente de funções mostra a primeira sintaxe.

Primeira sintaxe

CampoAlvo é uma cadeia de caracteres que seleciona um dos campos de dados da tabela dinâmica. A cadeia pode ser o nome da coluna de origem, ou o nome do campo de dados como mostrado na tabela (assim como "Soma - Vendas").

Tabela dinâmica é uma referência a uma célula ou intervalo de células posicionado dentro da tabela dinâmica ou que contém uma tabela dinâmica. Se o intervalo de células contém várias tabelas dinâmicas, a última tabela criada será utilizada.

Se nenhum par Campo n / Item n for dado, o total geral será calculado. Senão, cada par adiciona uma restrição que o resultado deve satisfazer. Campo n é o nome de um campo da tabela dinâmica. Item n é o nome de um item deste campo.

Se a tabela dinâmica contém somente um único valor resultante que atende a todas as restrições, ou um resultado de subtotal que resume todos os valores que combinam, este resultado será retornado. Se não houver um resultado que combine, ou vários deles sem um subtotal para eles, ocorrerá um erro. Essas condições se aplicam a resultados incluídos na tabela dinâmica.

Se a fonte de dados contém entradas ocultas pelas configurações da tabela dinâmica, elas serão ignoradas. A ordem dos pares Campo/Item não é significativa. Nomes de campos e de itens não são sensíveis à caixa.

Se não for dada uma restrição para um filtro, o valor do campo selecionado será utilizado implicitamente. Se for dada uma restrição para um filtro, ela deve combinar com o valor do campo selecionado, ou então ocorrerá um erro. Filtros são campos na parte superior esquerda da tabela dinâmica, preenchida utilizando a área "Filtros" da caixa de diálogo de leiaute da tabela dinâmica. De cada filtro, um item (valor) pode ser selecionado, o que significa que este item será incluído no cálculo.

Valores de subtotal da tabela dinâmica somente são utilizados se eles usarem a função "auto" (exceto quando especificado na restrição, veja a Segunda sintaxe abaixo).

Segunda sintaxe

tabela dinâmica tem o mesmo significado como na primeira sintaxe.

Restrições é uma lista separada por espaços. As entradas podem estar entre aspas (aspas simples). O texto inteiro deve estar entre aspas (aspas duplas), a não ser que o texto seja referenciado de uma outra célula.

Uma das entradas pode ser o nome do campo de dados. O nome do campo de dados pode ser deixado de lado se a tabela contém somente um campo de dados, senão ele deve estar presente.

Cada uma das outras entradas especificam uma restrição na forma de Campo[Item] (com caracteres literais [ e ]), ou somente Item se o nome do item for único entre todos os campos utilizados na tabela dinâmica.

Um nome de função pode ser adicionado na forma Campo[Item;Função], que causará a restrição a corresponder somente valores de sub total que usam esta função. Os nomes de função são Soma, Contagem, Média, Máx, Mín, Produto, Contagem(Somente números), DesvPad(Amostra), DesvPadP(População), Var(Amostra), e VarP(População), independente da caixa.

LINHA

Retorna o número da linha de uma referência de célula. Se a referência for uma célula, esta função retornará o número da linha dessa célula. Se a referência for um intervalo de células, a função retornará os números das linhas correspondentes em uma matriz de uma coluna caso a fórmula tenha sido inserida como uma fórmula de matriz. Se a função LINHA, referente a um intervalo, não for utilizada em uma fórmula de matriz, somente o número da linha da primeira célula do intervalo será retornada.

LINHA([Referência])

Referência é uma célula, uma área ou o nome de uma área.

Se você não indicar uma referência, será localizado o número da linha da célula na qual a fórmula foi inserida. O LibreOffice Calc define automaticamente a referência como a célula atual.

=LINHA(B3) retorna 3 por que a referência é a terceira linha da tabela.

{=LINHA(D5:D8)} retorna a matriz de uma coluna (5, 6, 7, 8) por que a referência especificada contém as linhas 5 a 8.

=LINHA(D5:D8) retorna 5 por que a função LINHA não é usada como fórmula de matriz e somente o número da primeira linha da referência será retornado.

{=LINHA(A1:E1)} e =LINHA(A1:E1) ambas retornam 1 por que a referência só contém a linha 1 como primeira coluna na tabela. (Porque áreas de uma única linha só tem um número de linha, não faz diferença se a fórmula é de matriz ou não.)

=LINHA() retorna 3 se a fórmula foi inserida na linha 3.

{=LINHA(Coelho)} retorna a matriz de uma coluna (1, 2, 3) se "Coelho" for o nome da área (C1:D3).

LINHAS

Retorna o número de linhas em uma referência ou em uma matriz.

LINHAS(Matriz)

Matriz é a referência ou área nomeada cujo número total de linhas será retornado.

=LINHAS(B5) retorna 1 por que uma célula só contém uma linha.

=LINHAS(A10:B12) retorna 3.

=LINHAS(Coelho) retorna 3 se "Coelho" for o intervalo nomeado (C1:D3).

PLANILHA

Retorna o número de planilha de uma referência ou um texto que representa um nome de planilha. Se não inserir nenhum parâmetro, o resultado será o número da planilha que contém a fórmula.

PLANILHA([Referência])

Referência é opcional e é uma referência a uma célula, uma área ou um nome de planilha.

=PLANILHA(Planilha2.A1) retorna 2 se Planilha2 é a segunda planilha no documento.

=PLANILHA("Planilha3") retorna 3 se Planilha3 é a terceira planilha no documento.

PLANILHAS

Determina o número de planilhas em uma referência. Se você não inserir nenhum parâmetro, essa função retornará o número de planilhas do documento atual.

PLANILHAS([Referência])

Referência é a referência a uma planilha ou área. Esse parâmetro é opcional.

=PLANILHAS(Planilha1.A1:Planilha3.G12) retorna 3 se Planilha1, Planilha2, e Planilha3 existirem na sequência indicada.

PROC

Retorna o conteúdo de uma célula de um intervalo de uma linha ou uma coluna. Opcionalmente, o valor atribuído (do mesmo índice) é retornado numa coluna e linha diferente. Ao contrário de PROCV e PROCH, os vetores de pesquisa e resultado podem estar em diferentes posições; eles não precisam ser adjacentes. Além disso, o vetor de pesquisa para PROC deve estar ordenado em ordem crescente, senão a pesquisa não retornará resultados utilizáveis.

PROC(Procura; VetorPesquisa [;VetorResultado])

Procura é o valor de qualquer tipo a ser procurado; inserido diretamente ou como uma referência.

VetorDePesquisa é uma área de uma coluna ou uma linha a ser pesquisada.

VetorResultante é outro intervalo de uma coluna ou uma linha do qual se obtém o resultado da função. O resultado é a célula do vetor resultante com o mesmo índice que a instância encontrada no vetor de pesquisa.

=PROC(A1;D1:D100;F1:F100) pesquisa a célula correspondente no intervalo D1:D100 pelo número inserido em A1. Para a instância encontrada, o índice é determinado, por exemplo, na 12a célula no intervalo. Então, o conteúdo da 12a. célula será retornado como o valor da função (na matriz resultante).

PROCH

Pesquisa um valor e a referência a células abaixo da área selecionada. Essa função verifica se a primeira linha de uma matriz contém um determinado valor. Em seguida, a função retorna o valor em uma linha da matriz, identificada no parâmetro Índice na mesma coluna.

=PROCH(Procura; Matriz; Índice [; Ordenado])

Para uma explicação dos parâmetros, veja: PROCV (colunas e linhas são trocadas)

Tem-se uma pequena tabela de banco de dados ocupando o intervalo de células A1: DO4 e contendo informações básicas sobre 118 elementos químicos. A primeira coluna contém os cabeçalhos das linhas “Elemento”, “Símbolo”, “Número Atômico” e “Massa Atômica Relativa”. As colunas subsequentes contêm as informações relevantes para cada um dos elementos, ordenadas da esquerda para a direita pelo número atômico. Por exemplo, as células B1: B4 contêm “Hidrogênio”, “H”, “1” e “1.008”, enquanto as células DO1: DO4 contêm “Oganesson”, “Og”, “118” e “294”.

	A	B	C	D	...	DO
1	Elemento	Hidrogênio	Hélio	Lítio	...	Oganesson
2	Símbolo	H	He	Li	...	Og
3	Número atômico	1	2	3	...	118
4	Massa atômica relativa	1.008	4.0026	6.94	...	294

=PROCH("Chumbo"; $A$1:$DO$4; 2; 0) retorna “Pb”, o símbolo do chumbo.

=PROCH("Ouro"; $A$1:$DO$4; 3; 0) retorna 79, o número atômico do ouro.

=PROCH("Carbono"; $A$1:$DO$4; 4; 0) retorna 12,011, a massa atômica relativa do carbono.

PROCV

Pesquisa vertical com referência a células adjacentes à direita. Essa função verifica se um valor específico está contido na primeira coluna de uma matriz. A função retorna então o valor na mesma linha da coluna indicada por Índice. Se o parâmetro Ordenado for omitido ou definido como VERDADEIRO ou 1, assume-se que os dados estão colocados em ordem crescente. Neste caso, se Procura não for encontrado, o último valor menor que o critério será retornado. Se Ordenado é definido como FALSO ou 0, deve haver um valor exato, senão o resultado será Erro: Valor não disponível. Portanto, com um valor 0, os dados não precisam estar em ordem crescente.

=PROCV(Procura; Matriz; Índice [; Ordenado])

Procura é o valor de qualquer tipo procurado na primeira coluna da matriz.

A Matriz é a referência, que contém pelo menos tantas colunas quantas forem passadas no número do argumento do índice.

Índice é o número da coluna na matriz que contém o valor a ser retornado. A primeira coluna começa com 1.

Ordenado é um parâmetro opcional que indica se a primeira coluna da matriz contém limites de segmentos ou valores cheios. Neste modo, a busca retorna o valor na linha com a primeira coluna tendo valor menor ou igual que Procura. Por exemplo, pode conter datas quando algum valor de imposto mudar, e os valores que representam a data inicial de um prazo quando o valor do imposto estava em vigor. Portanto, se pesquisar por uma data ausente na primeira coluna da matriz , e esta cair entre dois valores limites do segmento, retornará o menor deles, permitindo encontrar o dado efetivo da data pesquisada. Insira um valor lógico FALSO ou zero se a primeira coluna não representar uma lista de segmentos. Quando inserir VERDADEIRO, ou ausente, a primeira coluna na matriz deve estar ordenada em ordem crescente. Colunas ordenadas podem ser pesquisadas muito mais rapidamente e a função sempre retorna um valor, mesmo que a busca não coincida exatamente, se for maior que o menor valor da lista. Em listas não ordenadas, a pesquisa deve coincidir exatamente. Senão a função retorna #N/DISP com a mensagem: Erro: Valor não disponível.

Você deseja colocar o número do prato de um cardápio na célula A1, e o nome do prato na célula vizinha B1. A atribuição Número para Nome está na matriz D1:E100. A célula D1 contém 100, E1 contém o nome Sopa de legumes, e assim sucessivamente para os 100 itens do cardápio. Os números na coluna D estão ordenados de forma crescente; portanto, não há a necessidade de passar o parâmetro opcional Ordem.

Insira a seguinte fórmula em B1:

=PROCV(A1;D1:E100;2)

No momento em que inserir um número em A1, B1 mostrará o texto correspondente contido na segunda coluna da referência D1:E100. Quando inserir um número inexistente, será exibido o texto com o número seguinte. Para evitar que isso ocorra, insira FALSO como o último parâmetro da fórmula. Esse procedimento produzirá uma mensagem de erro sempre que um número inexistente for inserido.

TIPODEERRO

Retorna o número correspondente a um valor de erro que ocorre em uma célula diferente. Com a ajuda desse número, você pode gerar um texto de mensagem de erro.

TIPODEERRO(Referência)

Referência contém o endereço da célula onde ocorre o erro.

Se a célula A1 exibe Err:518, a função =TIPODEERRO(A1) retorna o número 518.

ORG.OPENOFFICE.ERRORTYPE