Instrução MkDir

Cria um novo diretório na mídia de dados.

Sintaxe:


MkDir Text As String

Parâmetros:

Text: qualquer expressão de cadeia de caracteres que especifique o nome e o caminho do diretório a ser criado. Também pode-se usar uma notação URL.

Se o caminho não for determinado, o diretório será criado no diretório atual.

Códigos de erro:

5 Chamada de procedimento inválida

76 Caminho não encontrado

Exemplo:


Sub ExampleFileIO
' Exemplo para funções de organização de arquivo
Const sFile1 As String = "file://c|/autoexec.bat"
Const sDir1 As String = "file://c|/Temp"
Const sSubDir1 as String ="Teste"
Const sFile2 as String = "Copied.tmp"
Const sFile3 as String = "Renamed.tmp"
Dim sFile As String
    sFile = sDir1 + "/" + sSubDir1
    ChDir( sDir1 )
    If Dir(sSubDir1,16)="" Then ' O diretório existe?
        MkDir sSubDir1
        MsgBox sFile,0,"Criar diretório"
    End If
    sFile = sFile + "/" + sFile2
    FileCopy sFile1 , sFile
    MsgBox fSysURL(CurDir()),0,"Diretório atual"
    MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Hora da criação"
    MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Tamanho do arquivo"
    MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Atributos de arquivo"
    Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
    ' Renomear no mesmo diretório
    sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
    SetAttr( sFile, 0 ) 'Excluir todos os atributos
    MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Novos atributos do arquivo"
    Kill sFile
    RmDir sDir1 + "/" + sSubDir1
End Sub
 
' Converte um caminho no sistema em URL
Function fSysURL( fSysFp As String ) As String
Dim iPos As String
    iPos = 1
    iPos = Instr(iPos,fSysFp, getPathSeparator())
    Do While iPos > 0
        Mid( fSysFp, iPos , 1,"/")
        iPos = Instr(iPos+1,fSysFp, getPathSeparator())
    Loop
    ' os dois-pontos do DOS
    iPos = Instr(1,fSysFp,":")
    If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
    fSysURL = "file://" & fSysFp
End Function

♥ Doe para nosso projeto! ♥