WORKDAY.INTL

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

tip

This function is available since LibreOffice 4.3.


Składnia

WORKDAY.INTL(StartDate; Days [; Weekend [; Holidays]])

StartDate: is the date from when the calculation is carried out.

Days is the number of workdays. Positive value for a result after the start date, negative value for a result before the start date.

Weekend jest parametrem opcjonalnym – liczba lub ciąg użyty do określenia dni tygodnia, będącymi dniami wolnymi od pracy. Weekend jest liczbą lub ciągiem określającym datę wystąpienia dni wolnych od pracy. Wartości liczbowe weekendu wskazują następujące dni wolne od pracy:

Liczby od 1 do 7 dla weekendów trwających dwa dni oraz od 11 do 17 dla weekendów trwających jeden dzień.

Liczba

Weekend

1 lub pominięty

sobota i niedziela

2

niedziela i poniedziałek

3

poniedziałek i wtorek

4

wtorek i środa

5

środa i czwartek

6

czwartek i piątek

7

piątek i sobota

11

tylko niedziela

12

tylko poniedziałek

13

tylko wtorek

14

tylko środa

15

tylko czwartek

16

tylko piątek

17

tylko sobota


Ciąg Weekend dostarcza inny sposób określenia tygodniowych dni wolnych od pracy. Musi on zawierać siedem (7) znaków - zer (0) dla dni roboczych oraz jedynek (1) dla dni wolnych od pracy. Każdy znak reprezentuje dzień tygodnia, zaczynając od poniedziałku. Tylko 1 i 0 są poprawne. Zapis "1111111" jest błędny i nie powinien być użyty. Dla przykładu: zapis ciągu "0000011" określa sobotę i niedzielę jako dni wolne od pracy.

Dni_wolne są opcjonalną listą dat zaliczaną do dni wolnych od pracy. Lista może być podana w zakresie komórek.

note

Podczas wprowadzania dat w ramach formuł, ukośniki lub kreski są używane jako separatory daty oraz są interpretowane jako operatory arytmetyczne, dlatego daty wprowadzone w tym formacie nie są rozpoznawane jako daty, co też skutkuje błędnymi obliczeniami. Aby ustrzec się przed interpretacją dat w ramach formuł , należy użyć funkcji DATA, na przykład DATA(1954;7;20) lub też należy umieścić datę w cudzysłów i użyć notacji ISO 8601, na przykład "1954-07-20". Unikaj używania formatów daty zależnych ustawień regionalnych, takich jak "07/20/54". Jeśli dokument zostanie wczytany w programie z innymi ustawieniami regionalnymi, obliczenia mogą wygenerować błędy.


tip

Unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. If a #VALUE! error occurs, then unselect Generate #VALUE! error in - LibreOffice Calc - Formula, button Details... in section "Detailed Calculation Settings", Conversion from text to number list box.


Przykład

What date comes 20 workdays after December 13, 2016? Enter the start date in C3 and the number of workdays in D3.

The weekend parameter (number) may be left blank or defined as 1 for default weekend (non-working days) – Saturday and Sunday.

Cells F3 to J3 contain five (5) holidays for Christmas and New Year in date format: December 24, 2016; December 25, 2016; December 26, 2016; December 31, 2016; and January 1, 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

Aby zdefiniować piątek i sobotę jako dni weekendowe, należy użyć liczby 7 w parametrze weekend.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

Aby zdefiniować niedzielę jako jedyny dzień weekendu, należy użyć liczby 11 w parametrze weekend.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatywnie można użyć ciągu weekendowego "0000001", aby zdefiniować niedzielę jako jedyny dzień weekendu.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

The function can be used without the two optional parameters – Weekday and Holidays – by leaving them out:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Please support us!