SUMIFS

Zwraca sumę wartości komórek w zakresie, który spełnia wielokrotność kryteriów w wielokrotności zakresów.

tip

Ta funkcja jest dostępna od wersji 4.0 LibreOffice.


Składnia

SUMA.WARUNKÓW(Func_Range; Range1; Criterion[; Range2; Criterion2][; … ; [Range127; Criterion127]])

zakres_sumowania – wymagany argument. Jest to zakres komórek, nazwa zakresu lub etykieta kolumny lub wiersz zawierający wartości do obliczenia sumy.

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

Zakres2 – Opcjonalnie. Zakres2 i wszystkie następujące oznaczają to samo co Zakres1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

Wyszukiwanie obsługuje symbole wieloznaczne lub wyrażenia regularne. Przy włączonych wyrażeniach regularnych możesz wpisać „all.*”, na przykład, aby znaleźć pierwszą lokalizację „all”, po której następuje dowolny znak. Jeśli chcesz wyszukać tekst, który jest również wyrażeniem regularnym, musisz poprzedzić każdy metaznak lub operator wyrażenia regularnego znakiem „\” albo umieścić tekst w \Q...\E. Możesz włączać i wyłączać automatyczną ocenę symboli wieloznacznych lub wyrażeń regularnych w - LibreOffice Calc - Oblicz .

warning

W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.


Func_Range and Range1, Range2... must have the same size, otherwise the function returns err:502 - Invalid argument.

note

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.


Ta funkcja może mieć do 255 argumentów, co oznacza, że ​​można podać 127 zakresów kryteriów i kryteriów dla nich.

Jeśli komórka zawiera PRAWDA, jest traktowana jak 1. Jeśli zawiera FAŁSZ – jak 0 (zero).

note

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)


Przykład

Poniżej opisano działanie tego pola na tabeli

A

B

C

1

Nazwa produktu

Sprzedaże

Przychód

2

ołówek

20

65

3

ołów

35

85

4

notes

20

190

5

książka

17

180

6

piórnik

nie

nie


warning

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.


Proste użycie

=SUMA.WARUNKÓW(B2:B6;B2:B6;">=20")

Oblicza sumę wartości z zakresu B2:B6, które są większe niż lub równe do 20. Zwraca 75, ponieważ piąty wiersz nie spełnia kryterium.

=SUMA.WARUNKÓW(C2:C6;B2:B6;">=20";C2:C6;">70")

Oblicza sumę wartości z zakresu C2:C6, które są większe niż 70 i odpowiadają komórkom z zakresu B2:B6 z wartościami większymi niż lub równymi do 20. Zwraca 275, ponieważ drugi i piąty wiersz nie spełniają co najmniej jednego kryterium.

Użycie wyrażeń regularnych i funkcji zagnieżdżonych

=SUMA.WARUNKÓW(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Oblicza sumę wartości z zakresu C2:C6, które odpowiadają wszystkim wartościom z zakresu B2:B6, oprócz jego minimum i maksimum. Zwraca 255, ponieważ trzeci i piąty wiersz nie spełniają co najmniej jednego kryterium.

=SUMA.WARUNKÓW(C2:C6;A2:A6;"ołów.*";B2:B6;"<"&MAKS(B2:B6))

Oblicza sumę wartości z zakresu C2:C6, które odpowiadają wszystkim komórkom z zakresu A2:A6 zaczynającym się od słowa "ołów" i do wszystkich komórek z zakresu B2:B6, oprócz ich maksimum. Zwraca 65, ponieważ tylko drugi wiersz spełnia wszystkie kryteria.

Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji SUMA.WARUNKÓW. Na przykład: powyższa funkcja może być przepisana następująco:

=SUMA.WARUNKÓW(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Jeśli E2 = ołów, funkcja zwraca 65, ponieważ łącze do komórki jest zastąpione jego treścią.

Otwórz plik z przykładem:

[text/scalc/01/04060106.xhp#sum_head not found]., SUMIF

COUNTIFS, MIN.WARUNKÓW, MAKS.WARUNKÓW, ŚREDNIA.JEŻELI, SUMIFS

Lista wyrażeń regularnych

Prosimy o wsparcie!