LICZ.WARUNKI
Zwraca liczbę komórek spełniających kryteria w wielu zakresach.
LICZ.WARUNKI(zakres; kryterium [; zakres2; kryterium2] [; ... ; [zakres1272; kryterium127]])
Wyszukiwanie obsługuje symbole wieloznaczne lub wyrażenia regularne. Przy włączonych wyrażeniach regularnych możesz wpisać „all.*”, na przykład, aby znaleźć pierwszą lokalizację „all”, po której następuje dowolny znak. Jeśli chcesz wyszukać tekst, który jest również wyrażeniem regularnym, musisz poprzedzić każdy metaznak lub operator wyrażenia regularnego znakiem „\” albo umieścić tekst w \Q...\E. Możesz włączać i wyłączać automatyczną ocenę symboli wieloznacznych lub wyrażeń regularnych w .
W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.
Zakres, Zakres2, ... i Kryterium, Kryterium2, ... muszą mieć ten sam rozmiar, w przeciwnym razie funkcja zwróci Błąd:502 – Nieprawidłowy argument.
Logiczną relację między kryteriami można zdefiniować jako logiczne I (koniunkcja). Innymi słowy, wtedy i tylko wtedy, gdy spełnione są wszystkie podane kryteria, do obliczeń brana jest wartość z odpowiedniej komórki danego Zakresu_funkcji.
Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)
Poniżej opisano działanie tego pola na tabeli
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
Nazwa produktu |
Sales |
Revenue |
|
2 |
ołówek |
20 |
65 |
|
3 |
ołów |
35 |
85 |
|
4 |
fotoalbum |
20 |
190 |
|
5 |
album |
17 |
180 |
|
6 |
ołóweczek |
nie |
nie |
We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.
Proste użycie
=LICZ.WARUNKI(B2:B6;">=20")
Oblicza liczbę wierszy z zakresu B2:B6 z wartościami większymi niż lub równymi do 20. Zwraca 3, ponieważ piąty i szósty wiersz nie spełniają kryterium.
=LICZ.WARUNKI(B2:B6;">=20";C2:C6;">70")
Oblicza liczbę wierszy zawierających jednocześnie wartości większe niż 70 w zakresie C2:C6 oraz wartości większe niż lub równe do 20 w zakresie B2:B6.Zwraca 2, ponieważ drugi, piąty i szósty wiersz nie nie spełniają co najmniej jednego kryterium.
Użycie wyrażeń regularnych i funkcji zagnieżdżonych
Aby te przykłady działały zgodnie z opisem, upewnij się, że opcja Włącz wyrażenia regularne w formułach jest zaznaczona w .
=LICZ.WARUNKI(B2:B6;"[:alfa:]*")
Oblicza liczbę wierszy z zakresu B2:B6, które zawierają wyłącznie symbole alfabetu. Zwraca 1, ponieważ tylko szósty wiersz spełnia kryterium.
=LICZ.WARUNKI(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))
Oblicza liczbę wierszy z zakresu B2:B6, wyłączając wiersze z minimalnymi i maksymalnymi wartościami tego zakresu. Zwraca 2, ponieważ trzeci, piąty i szósty wiersz nie spełniają co najmniej jednego kryterium.
=LICZ.WARUNKI(A2:A6;"ołów.*";B2:B6;"<"&MAKS(B2:B6))
Oblicza liczbę wierszy, które odpowiadają wszystkim komórkom z zakresu A2:A6 zaczynającym się od słowa "ołów" i do wszystkich komórek z zakresu B2:B6, oprócz ich maksimum. Zwraca 1, ponieważ tylko drugi wiersz spełnia wszystkie kryteria.
Odwołanie do komórki jako kryterium
Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji LICZ.WARUNKI. Na przykład: powyższa funkcja może być przepisana następująco:
=LICZ.WARUNKI(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))
Jeśli E2 = ołów, funkcja zwraca 1, ponieważ łącze do komórki jest zastąpione jego treścią i działa jak funkcja powyżej.
