ŚREDNIA.JEŻELI function

Zwraca średnią arytmetyczną wszystkich komórek w zakresie spełniające dany warunek. Funkcja ŚREDNIA.JEŻELI sumuje wszystkie wyniki które pasują do logicznego test i dzieli tę sumę przez ilość wybranych wartości.

tip

This function is available since LibreOffice 4.0.


Składnia

ŚREDNIA.JEŻELI(Zakres; Kryterium [; Zakres_średniej ])

Zakres – argument wymagany. Tablica, nazwa nazwanego zakresu, etykieta kolumny lub wiersz zawierający liczby do uśrednienia, lub liczby, lub tekst dla warunku.

Kryterium – argument wymagany. Warunek w postaci wyrażenia lub odwołania komórki z wyrażeniem, które określa komórki potrzebne do obliczenia średniej. Wyrażenie może zawierać tekst, liczby, wyrażenia regularne (jeśli włączone w opcjach obliczeń) lub symbole wieloznaczne (jeśli włączone w opcjach obliczeń).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOffice Calc - Calculate.

warning

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".


Zakres_średniej – opcjonalne. Zakres wartości do obliczenia średniej.

note

If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.


Ikona notatki

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)


warning

Jeśli komórka w zakresie wartości do obliczenia średniej jest pusta lub zawiera tekst, funkcja ŚREDNIA.JEŻELI zignoruje tę komórkę.
Jeśli cały zakres jest pusty, zawiera tylko tekst lub wszystkie wartości zakresu nie spełniają warunku (lub dowolna ich kombinacja), funkcja zwraca błąd #DZIEL/0!


Przykład

Poniżej opisano działanie tego pola na tabeli

A

B

C

1

Nazwa produktu

Sprzedaże

Przychód

2

ołówek

20

65

3

ołów

35

85

4

notes

20

190

5

książka

17

180

6

piórnik

nie

nie


warning

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.


warning

We wszystkich obliczeniach poniżej, zakres dla obliczeń średnich zawiera wiersz #6, który jest ignorowany, ponieważ zawiera tekst.


Proste użycie

=ŚREDNIA.JEŻELI(B2:B6;"<35")

Oblicza średnią wartości z zakresu B2:B6, która jest mniejsza niż 35. Zwraca 19, ponieważ drugi wiersz nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;"<"&MAKS(B2:B6))

Oblicza średnią wartości z tego samego zakresu, która jest mniejsza niż maksymalna wartość tego zakresu. Zwraca 19, ponieważ największa wartość (drugi wiersz) nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;">"&MIN.K(B2:B6;1))

Oblicza średnią wartości z tego samego zakresu, która jest większa niż pierwsza, najmniejsza wartość tego zakresu. Zwraca 25, ponieważ pierwsza, najmniejsza wartość (czwarty wiersz) nie bierze udziału w obliczeniach.

Użycie Zakres_średniej

=ŚREDNIA.JEŻELI(B2:B6;"<35";C2:C6)

Funkcja przeszukuje jakie wartości są mniej niż 35 w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Zwraca 145, ponieważ drugi wiersz nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;">"&MIN(B2:B6);C2:C6)

Funkcja przeszukuje jakie wartości z zakresu B2:B6 są większe niż ostatnie wartości w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z C2:C6. Zwraca 113,31 ponieważ czwarty wiersz (w którym znajduje się co najmniej wartość w zakresie B2: B6) nie bierze udziału w obliczeniach.

=ŚREDNIA.JEŻELI(B2:B6;"<"&MAKS.K(B2:B6;2);C2:C6)

Funkcja przeszukuje jakie wartości z zakresu B2:B6 są mniejsze niż druga, duża wartość w zakresie B2:B6 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Zwraca 180, ponieważ tylko czwarty wiersz bierze udział w obliczeniach.

Użycie wyrażeń regularnych

=ŚREDNIA.JEŻELI(A2:A6;"ołów";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają tylko słowo "ołów" i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Zwraca 35, ponieważ tylko drugi wiersz bierze udział w obliczeniach. Wyszukiwanie wykonane jest w zakresie A2:A6, lecz wartości są zwracane z zakresu B2:B6.

=ŚREDNIA.JEŻELI(A2:A6;"ołów.*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zaczynają się od słowa "ołów", a na końcu zawierają dowolną ilość innych symboli i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Zwraca 27,5, ponieważ teraz także słowo "ołówek" spełnia warunek i oba, pierwszy oraz drugi wiersz, biorą udział w obliczeniach.

=ŚREDNIA.JEŻELI(A2:A6;".*książka.*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają słowo "książka", a na początku i na końcu zawierają dowolną ilość innych symboli i oblicza średnią odpowiadającą wartościom z zakresu B2: B6. Zwraca 18,5, ponieważ tylko trzeci i czwarty wiersz bierze udział w obliczeniach.

Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji ŚREDNIA.JEŻELI.

=ŚREDNIA.JEŻELI(A2:A6;".*"&E2&".*";B2:B6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 zawierają kombinację znaków określonych w komórce E2, a na początku i na końcu zawierają dowolną ilością innych znaków i oblicza średnią odpowiadającą wartościom z zakresu B2:B6. Jeśli komórka E2 = książka, funkcja zwraca 18,5.

=ŚREDNIA.JEŻELI(B2:B6;"<"&E2;C2:C6)

Funkcja przeszukuje jakie komórki z zakresu A2:A6 są mniejsze niż wartość określona w E2 i oblicza średnią odpowiadającą wartościom z zakresu C2:C6. Jeśli komórka E2 = 35, funkcja zwraca 145.

Please support us!