Funkcje tekstowe

Niniejsza sekcja zawiera opisy funkcji tekstowych.

Aby wykonać tę operację...

Wstaw - Funkcja - Kategoria Tekst

Używanie podwójnych cudzysłowów w formułach

Aby uwzględnić ciąg tekstowy w formule, umieść ciąg tekstowy pomiędzy dwoma podwójnymi cudzysłowami ("), a program Calc pobierze znaki z ciągu bez próby ich interpretacji. Na przykład formuła ="Witaj, świecie!" wyświetla ciąg tekstowy Witaj, świecie! w komórce, bez otaczających go podwójnych cudzysłowów.

Bardziej złożona formuła =ZŁĄCZ.TEKSTY("Życie jest naprawdę proste, "; "ale upieramy się, żeby je skomplikować "; "(Konfucjusz).") łączy trzy pojedyncze ciągi znaków w podwójnym cudzysłowie, otrzymując w wyniku Życie jest naprawdę proste, ale upieramy się, aby je komplikować (Konfucjusz).

Istnieją dwa sposoby umieszczenia podwójnego cudzysłowu w ciągu znaków w formule:

Możesz użyć „sekwencji ucieczki” w podwójnym cudzysłowie, który jest kolejnym podwójnym cudzysłowem. Calc potraktuje podwójny cudzysłów jako ciąg tekstowy. Na przykład wynikiem formuły ="Nazywam się ""Jan Nowak""." będzie wynosić Nazywam się "Jan Nowak". Innym prostym przykładem jest formuła =UNICODE(""""), który zwraca 34, wartość dziesiętną znaku cudzysłowu Unicode (U+0022) – pierwszy i czwarty podwójny cudzysłów oznaczają początek i koniec ciągu, drugi cudzysłów reprezentuje sekwencję ucieczki dla trzeciego.
Aby wstawić podwójne cudzysłowy, możesz użyć funkcji CHAR lub UNICHAR. Na przykład formuła =UNICHAR(34) & "Buszujący w zbożu" & UNICHAR(34) & " to słynna książka J.D. Salingera." wyświetli ciąg "The Buszujący w zbożu" to słynna książka J.D. Salingera.

Należy pamiętać, że funkcja autokorekty programu Calc może modyfikować podwójne cudzysłowy. Autokorekta nie powinna zmieniać podwójnych cudzysłowów w komórkach z formułami, ale może zmieniać cudzysłowy używane w komórkach niebędących formułami zawierających tekst. Na przykład, jeśli skopiujesz ciąg, który jest ujęty w inną formę typograficznych podwójnych cudzysłowów, takich jak lewy podwójny cudzysłów (U+201C) i prawy podwójny cudzysłów (U+201D), a następnie wkleisz do komórce z formułą, może wystąpić błąd. Otwórz obszar Podwójne cudzysłowy w oknie dialogowym Narzędzia - Opcje autokorekty - Opcje zlokalizowane, aby ustawić znaki używane do automatycznego poprawiania podwójnych cudzysłowów typograficznych na początku i na końcu. Usuń zaznaczenie przycisku przełączania Zamień, aby wyłączyć tę funkcję.

ARABSKIE

Zwraca wartość liczbową odpowiadającą liczbie rzymskiej wyrażonej jako tekst.

ASC

Konwertuje znaki dwubajtowe (o pełnej szerokości) na jednobajtowe (o połowie szerokości) znaki ASCII i katakana.

JIS

Konwertuje jednobajtowe (o połowie szerokości) znaki ASCII lub katakana na znaki dwubajtowe (o pełnej szerokości).

REGEX

Dopasowuje i wyodrębnia lub opcjonalnie zastępuje tekst za pomocą wyrażeń regularnych.

RZYMSKIE

Konwertuje liczbę na cyfrę rzymską. Zakres wartości musi mieścić się w przedziale od 0 do 3999. Tryb uproszczenia można określić w zakresie od 0 do 4.

WARTOŚĆ

Konwertuje ciąg znaków reprezentujący liczbę na postać liczbową. Jeśli podany ciąg znaków jest prawidłową datą, godziną lub datą i godziną, zwracany jest odpowiedni numer sekwencyjny daty i godziny.

USŁ.INTER

Pobiera zawartość internetową z URI.

FILTR.XML

Zastosuj wyrażenie XPath do dokumentu XML.

KODUJ.URL

Zwraca ciąg znaków zakodowany w standardzie URL.

BAT.TEKST

Zamienia liczbę na tekst tajski łącznie z nazwami waluty tajlandzkiej.

Składnia

BAT.TEKST(liczba)

Liczba to dowolna liczba. Wartość "Baht" jest dołączana do części całkowitej liczby, a "Satang" do części ułamkowej.

Przykład

=BAT.TEKST(12,65) zwraca ciąg tekstowy zapisany w znakach alfabetu tajskiego, który oznacza "12 batów i 65 satangów".

Szczegóły techniczne

Ta funkcja nie jest częścią standardu Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Przestrzeń nazw to

COM.MICROSOFT.BAHTTEXT

DŁ

Zwraca długość ciągu wraz ze spacjami.

Składnia

DŁ("tekst")

Tekst to wartość tekstowa, dla której należy określić znak.

Przykład

=DŁ("Dzień dobry") zwraca wartość 11.

=DŁ(12345,67) zwraca wartość 8.

DŁ.B

Dla dwubajtowych zestawów znaków języków (DBCS), zwracana jest liczba bajtów użytych do reprezentacji znaków w ciągu tekstowym.

Ta funkcja jest dostępna od wersji 4.2 LibreOffice.

Składnia

DŁ.B("Tekst")

Tekst to wartość tekstowa, dla której należy określić znak.

Przykład

DŁ.B("中") zwraca 2 (1 znak DBCS składający się z 2 bajtów).

DŁ.B("中国") zwraca 4 (2 znaki DBCS każdy składający się z 2 bajtów).

DŁ.B("office") zwraca 6 (6 znaków nie DBCS każdy składający się z 1 bajtu)

=DŁ.B("Dzień dobry") zwraca wartość 11.

=DŁ.B(12345,67) zwraca wartość 8.

FRAGMENT.TEKSTU

Zwraca fragment podanego ciągu znaków. Parametry określają pozycję początkową i liczbę znaków.

Składnia

FRAGMENT.TEKSTU("tekst"; liczba_początkowa; liczba)

Tekst jest ciągiem zawierającym znaki, które należy pobrać.

Start to pozycja pierwszego znaku w tekście do pobrania.

Liczba określa liczbę znaków części tekstu.

Przykład

=FRAGMENT.TEKSTU("office";2;2) zwraca wartość ff.

FRAGMENT.TEKSTU.B

Zwraca fragment podanego ciągu znaków. Parametry określają pozycję początkową i liczbę znaków.

Ta funkcja jest dostępna od wersji 4.2 LibreOffice.

Składnia

FRAGMENT.TEKSTU.B("Tekst"; Liczba_początkowa; Liczba_bajtów)

Tekst jest ciągiem zawierającym znaki, które należy pobrać.

Liczba_początkowa to pozycja pierwszego znaku w tekście do pobrania.

Liczba_bajtów określa liczbę znaków, którą FRAGMENT.TEKSTU.B zwróci z tekstu, w bajtach.

Przykład

=FRAGMENT.TEKSTU.B("中国";1;0) zwraca "" (0 bajtów jest zawsze pustym ciągiem).

=FRAGMENT.TEKSTU.B("中国";1;1) zwraca " " (1 bajt jest połową znaku DBCS i wynikiem jest znak spacji).

=FRAGMENT.TEKSTU.B("中国";1;2) zwraca "中" (2 bajty stanowią jeden kompletny znak DBCS).

=FRAGMENT.TEKSTU.B("中国";1;3) zwraca "中 " (3 bajty stanowią jeden znak DBCS i połowę następnego, ostatni bajt jest zwracany jako znak spacji).

=FRAGMENT.TEKSTU.B("中国";1;4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

=FRAGMENT.TEKSTU.B("中国";2;1) zwraca " " (pozycja bajtu 2 nie jest początkiem znaku w ciągu DBCS, 1 znak spacji jest zwracany).

=FRAGMENT.TEKSTU.B("中国";2;2) zwraca " " (pozycja bajtu 2 punktów do ostatniej połowy pierwszego znaku w ciągu DBCS, 2 bajty stanowią ostatnią połowę pierwszego znaku i pierwszą połowę drugiego znaku w ciągu, 2 znaki spacji są zwracane).

=FRAGMENT.TEKSTU.B("中国";2;3) zwraca " 国" (pozycja bajtu 2 nie jest początkiem znaku w ciągu DBCS, zwracany jest znak spacji dla pozycji bajtu 2).

=FRAGMENT.TEKSTU.B("中国";3;1) " " (pozycja bajtu 3 nie jest początkiem znaku w ciągu DBCS, ale 1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji)

=FRAGMENT.TEKSTU.B("中国";3;2) zwraca "国" (pozycja bajtu 3 jest początkiem znaku w ciągu DBCS i 2 bajty stanowią jeden znak DBCS).

=FRAGMENT.TEKSTU.B("office";2;3) zwraca "ffi" (pozycja bajtu 2 jest początkiem znaku w ciągu nie DBCS i 3 bajty ciągu nie DBCS stanowią 3 znaki).

KOD

Zwraca kod numeryczny pierwszego znaku łańcucha znakowego.

Składnia

KOD("Tekst")

Tekst to wartość tekstowa, dla której należy znaleźć kod pierwszego znaku.

Kody zawierające więcej niż 127 znaków mogą być zależne od sposobu mapowania znaków w systemie (np. iso-8859-1, iso-8859-2, Windows-1252 czy Windows-1250), w związku z czym nie zawsze można ich używać na różnych platformach.

Przykład

=KOD("Hieronymus") zwraca wartość 72, =KOD("hieroglyphic") zwraca wartość 104.

Kod numeryczny nie musi odpowiadać tabeli ASCII, lecz tabeli znaków aktualnie używanej.

KWOTA

Konwertuje liczbę na ciąg znaków reprezentujący kwotę w formacie walutowym, zaokrągloną do określonych miejsc po przecinku, przy użyciu separatora dziesiętnego odpowiadającego bieżącym ustawieniom regionalnym. W polu Wartość wprowadź liczbę do przeliczenia. Opcjonalnie możesz wpisać liczbę miejsc po przecinku w polu Miejsca dziesiętne. Jeżeli nie określono żadnej wartości, wszystkie liczby w formacie walutowym będą wyświetlane z dwoma miejscami po przecinku.

Format waluty definiuje się w ustawieniach systemowych.

Składnia

KWOTA(wartość [; dziesiętne])

Wartość jest liczbą, odwołaniem do komórki zawierającej liczbę lub formułą zwracającą liczbę.

Dziesiętne to parametr opcjonalny, który określa liczbę miejsc dziesiętnych.

Przykład

=KWOTA(255) zwraca 255,00 USD dla języka angielskiego (USA) i waluty USD (dolar); 255,00 jenów dla japońskich ustawień regionalnych i waluty JPY (jen); lub 255,00 € dla lokalizacji niemieckiej (Niemcy) i waluty EUR (euro).

=KWOTA(367,456;2) zwraca 367,46 $.

LEWY

Zwraca początkowe znaki w ciągu tekstowym.

Składnia

LEWY("tekst" [;liczba])

Tekst to wartość tekstowa, dla której należy określić początkowe słowa cząstkowe.

Liczba (parametr opcjonalny) oznacza liczbę znaków w początkowej części tekstu. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

Przykład

=LEWY("wyjście";3) zwraca wartość “wyj”.

LEWY.B

Zwraca początkowe znaki tekstu DBCS.

Ta funkcja jest dostępna od wersji 4.2 LibreOffice.

Składnia

LEWY.B("Tekst" [; Liczba_bajtów])

Tekst to wartość tekstowa, dla której należy określić początkowe słowa cząstkowe.

Liczba_bajtów (parametr opcjonalny) oznacza liczbę znaków, którą LEWYB ma wyodrębnić na podstawie bajtów. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

Przykład

=LEWY.B("中国";1) zwraca " " (1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji).

=LEWY.B("中国";2) zwraca "中" (2 bajty stanowią jeden kompletny znak DBCS).

=LEWY.B("中国";3) zwraca "中 " (3 bajty stanowią jeden znak DBCS i połowę następnego, ostatni znak jest zwracany jako znak spacji).

=LEWY.B("中国";4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

=LEWY.B("office";3) zwraca "off" (3 znaki nie DBCS każdy składający się z 1 bajtu)

LITERY.MAŁE

Przekształca wszystkie wielkie litery ciągu tekstowego na małe.

Składnia

LITERY.MAŁE("tekst")

Tekst oznacza ciąg, który należy przekształcić.

Przykład

=LITERY.MAŁE("Słońce") zwraca wartość słońce.

LITERY.WIELKIE

Zamienia litery ciągu określonego w polu Tekst na wielkie.

Składnia

LITERY.WIELKIE("tekst")

Tekst oznacza ciąg zawierający małe litery, które mają zostać zamienione na wielkie.

Przykład

=LITERY.WIELKIE("Dzień dobry") zwraca wartość DZIEŃ DOBRY.

M.DZIESIĘTNE

Konwertuje tekst reprezentujący liczbę w systemie liczbowym o podanej podstawie na dodatnią liczbę całkowitą. Podstawa musi mieścić się w zakresie od 2 do 36. Spacje i tabulatory są ignorowane. W polu Tekst nie jest rozróżniana wielkość liter.

Jeśli podstawa wynosi 16, początkowe x, X, 0x lub 0X oraz dołączone h lub H są pomijane. Jeżeli podstawa wynosi 2, dołączone b lub B nie są brane pod uwagę. Inne znaki nie należące do systemu liczbowego generują błąd.

Składnia

M.DZIESIĘTNE("tekst"; podstawa)

Tekst to tekst do konwersji.

Podstawa wskazuje podstawę systemu liczbowego. Może to być dowolna dodatnia liczba całkowita z zakresu od 2 do 36.

Przykład

=M.DZIESIĘTNE("17";10) zwraca wartość 17.

=M.DZIESIĘTNE("FACE";16) zwraca wartość 64206.

=M.DZIESIĘTNE("0101";2) zwraca wartość 5.

Zobacz też

PODSTAWA

OCZYŚĆ

Funkcja usuwa z łańcucha wszystkie znaki niedrukowalne.

Składnia

OCZYŚĆ("tekst")

Tekst oznacza wartość tekstową, z której zostaną usunięte wszystkie znaki niedrukowalne.

Przykład

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) zwraca 16, co pokazuje, że funkcja CLEAN usuwa niedrukowalny Unicode U+0007 („BEL”) oraz znaki U+0008 („BS”) na początku i na końcu argumentu ciągu. CLEAN nie usuwa spacji.

PODSTAW

Podstawia nowy tekst w miejsce starego we wskazanym ciągu znaków.

Składnia

PODSTAW("tekst"; "szukany_tekst"; "nowy_tekst" [; wystąpienie])

Tekst jest tekstem, w którym segmenty zostaną zastąpione.

Szukany_tekst to segment tekstu, który ma być zastąpiony (określoną liczbę razy).

Nowy_tekst jest tekstem, który ma zastąpić segment.

Wystąpienie (parametr opcjonalny) wskazuje na numer wystąpienia wyszukiwanego tekstu, które ma być zamienione. Przy braku tego parametru zamienione zostaną wszystkie wystąpienia.

Przykład

=PODSTAW("123123123";"3";"abc") zwraca 12abc12abc12abc.

=PODSTAW("123123123";"3";"abc";2) zwraca wartość 12abc12abc12abc.

PODSTAWA

Konwertuje liczbę dodatnią na tekst w systemie liczbowym o określonej podstawie. Używane cyfry to 0-9, litery to A-Z.

Składnia

PODSTAWA(liczba; podstawa [; minimalna_długość])

Liczba to dodatnia liczba całkowita do konwersji.

Podstawa wskazuje podstawę systemu liczbowego. Może to być dowolna dodatnia liczba całkowita z zakresu od 2 do 36.

Minimalna_długość (parametr opcjonalny) oznacza minimalną długość utworzonej sekwencji znaków. Jeśli długość tekstu jest mniejsza niż określona długość minimalna, zostanie on uzupełniony zerami z lewej strony.

Przykład

=PODSTAWA(17;10;4) zwraca wartość 0017 w systemie dziesiętnym.

=PODSTAWA(17;2) zwraca wartość 10001 w systemie dwójkowym.

=PODSTAWA(255;16;4) zwraca wartość 00FF w systemie szesnastkowym.

Zobacz też

M.DZIESIĘTNE

PORÓWNAJ

Porównuje dwa ciągi tekstowe i zwraca wartość PRAWDA, jeśli są identyczne. Funkcja rozróżnia wielkość liter.

Składnia

PORÓWNAJ("tekst_1";"tekst_2")

Tekst_1 oznacza pierwszy tekst do porównania.

Tekst_2 to druga porównywana wartość tekstowa.

Przykład

=PORÓWNAJ(" microsystems";" Microsystems") zwraca wartość FAŁSZ.

POWT

Powtarza ciąg znaków o podaną liczbę kopii.

Składnia

POWT("tekst"; liczba)

Tekst to wartość tekstowa, która ma być powtarzana.

Liczba oznacza liczbę powtórzeń.

Przykład

=POWT("Dzień dobry";2) zwraca wartość Dzień dobryDzień dobry.

Więcej informacji na temat tej funkcji można znaleźć na stronie wiki POWT.

PRAWY

Zwraca ostatnie znaki w ciągu tekstowym.

Składnia

PRAWY("tekst" [; liczba])

Tekst jest tekstem, dla którego należy określić część po prawej stronie.

Liczba (parametr opcjonalny) to liczba znaków z prawej części tekstu. Jeżeli ten parametr nie jest zdefiniowany, zwracany jest jeden znak.

Przykład

=PRAWY("Słońce";2) zwraca wartość ce.

PRAWY.B

Zwraca ostatni znak lub znaki tekstu z dwubajtowych zestawów znaków (DBCS).

Ta funkcja jest dostępna od wersji 4.2 LibreOffice.

Składnia

PRAWY.B("Tekst" [; Liczba_bajtów])

Tekst jest tekstem, dla którego należy określić część po prawej stronie.

Liczba_bajtów (parametr opcjonalny) oznacza liczbę znaków, którą PRAWY.B ma wyodrębnić na podstawie bajtów. Jeśli ten parametr nie został zdefiniowany, zwracany jest jeden znak.

Przykład

PRAWY.B("中国";1) zwraca " " (1 bajt jest tylko połową znaku DBCS i zwracany jest znak spacji).

PRAWY.B("中国";2) zwraca "国" (2 bajty stanowią jeden kompletny znak DBCS).

PRAWY.B("中国";3) zwraca " 国" (3 bajty stanowią połowę jednego znaku DBCS i jeden cały znak DBCS, spacja zwracana jest dla pierwszej połowy).

PRAWY.B("中国";4) zwraca "中国" (4 bajty stanowią dwa kompletne znaki DBCS).

PRAWY.B("office";3) zwraca "ice" (3 znaki nie DBCS każdy składający się z 1 bajtu).

SZUKAJ.TEKST

Zwraca pozycję segmentu tekstu w ciągu znaków. Opcjonalnie możesz ustawić początek wyszukiwania. Wyszukiwany tekst może być liczbą lub dowolnym ciągiem znaków. W wyszukiwaniu nie jest uwzględniana wielkość liter. Jeśli tekst nie zostanie znaleziony, zwraca błąd 519 (#ARG).

Wyszukiwanie obsługuje symbole wieloznaczne lub wyrażenia regularne. Przy włączonych wyrażeniach regularnych możesz wpisać „all.*”, na przykład, aby znaleźć pierwszą lokalizację „all”, po której następuje dowolny znak. Jeśli chcesz wyszukać tekst, który jest również wyrażeniem regularnym, musisz poprzedzić każdy metaznak lub operator wyrażenia regularnego znakiem „\” albo umieścić tekst w \Q...\E. Możesz włączać i wyłączać automatyczną ocenę symboli wieloznacznych lub wyrażeń regularnych w - LibreOffice Calc - Oblicz.

W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.

Składnia

SZUKAJ.TEKST("znajdź_tekst"; "tekst" [; pozycja])

Znajdź_tekst oznacza szukany tekst.

Tekst jest tekstem, w którym będzie prowadzone wyszukiwanie.

Pozycja (parametr opcjonalny) oznacza pozycję w tekście, od której rozpocznie się wyszukiwanie.

Przykład

=SZUKAJ.TEKST(54;998877665544) zwraca wartość 10.

T

Funkcja zwraca tekst docelowy lub tekst pusty, jeżeli ciąg docelowy nie jest sformatowany jako tekst.

Składnia

T(wartość)

Wartość jest wartością, którą należy przekształcić. Jako parametru można także użyć odwołania. Jeśli komórka odwołania zawiera liczbę lub formułę zwracającą wynik numeryczny, wynikiem tej funkcji będzie ciąg pusty.

Przykład

=T(12345) zwraca pusty ciąg.

=T("12345") zwraca wartość tekstową 12345.

TEKST

Konwertuje wartość na tekst zgodnie z zadanym formatem.

Składnia

TEKST(wartość; format)

Wartość to wartość (numeryczna lub tekstowa) do przeliczenia.

Format to wartość tekstowa, która definiuje format. Przecinek dziesiętny i separator tysięcy muszą być zgodne z formatem komórki dla danego języka.

Przykład

=TEKST(12,34567;"###.##") zwraca wartość tekstową 12,35

=TEKST(12,34567;"000,00") zwraca wartość tekstową 012,35

=TEKST("xyz";"=== @ ===") zwraca tekst === xyz ===

Zobacz także Kody formatu liczb: niestandardowe kody formatu zdefiniowane przez użytkownika.

UNICHAR

Konwertuje kod liczbowy na znak lub literę Unicode.

Składnia

UNICHAR(numer)

Przykład

Zobacz także funkcję UNICODE ()

UNICODE

Zwraca kod liczbowy pierwszego znaku Unicode w ciągu tekstowym.

Składnia

UNICODE("Text")

Przykład

Zobacz także funkcję UNICHAR().

USUŃ.ZBĘDNE.ODSTĘPY

Usuwa spacje na początku ciągu lub wyrównuje zawartość komórki do lewej.

Składnia

USUŃ.ZBĘDNE.ODSTĘPY("tekst")

Tekst oznacza tekst, z którego mają być usunięte spacje.

Przykład

=USUŃ.ZBĘDNE.ODSTĘPY(" wita świecie ") zwraca "witaj świecie" z pojedynczą spacją między wyrazami i bez spacji początkowej oraz końcowej.

Z.WIELKIEJ.LITERY

Zamienia pierwszą literę na wielką w każdym wyrazie w tekście.

Składnia

Z.WIELKIEJ.LITERY("tekst")

Tekst oznacza ciąg, który należy przekształcić.

Przykład

=Z.WIELKIEJ.LITERY("the document foundation") zwraca The Document Foundation.

ZAOKR.DO.TEKST

Formatuje wyświetlanie liczby, uwzględniając ustaloną liczbę miejsc po przecinku i wyświetlanie separatora tysięcy.

Składnia

ZAOKR.DO.TEKST(Liczba [MiejscaDziesiętne = 2 [; BezSeperatoraTysięcy = FAŁSZ]])

Liczba jest zaokrąglana do miejsc dziesiętnych (po separatorze dziesiętnym), a wynik jest formatowany jako tekst przy użyciu ustawień regionalnych.

MiejscaDziesiętne (parametr opcjonalny) odnosi się do liczby wyświetlanych miejsc dziesiętnych. Jeżeli wartość MiejscaDziesiętne jest ujemna, Liczba jest zaokrąglana do miejsc MODUŁ.LICZBY(MiejscaDziesiętne) na lewo od przecinka dziesiętnego. Jeśli MiejscaDziesiętne jest ułamkiem zwykłym, jest on obcinany, ignorując najbliższą liczbę całkowitą.

BezSeperatoraTysięcy (parametr opcjonalny) określa, czy używany jest separator tysięcy. Jeśli ma wartość PRAWDA lub jest różna od zera, wówczas w wynikowym ciągu znaków pomijane są separatory grup. Jeśli parametr jest równy 0 lub w ogóle go nie ma, wyświetlane są separatory tysięcy bieżących ustawień regionalnych.

Przykład

=ZAOKR.DO.TEKST(1234567,89;3) zwraca 1 234 567,890 w postaci ciągu tekstowego.

=ZAOKR.DO.TEKST(123456,789;;TRUE) zwraca wartość 123456,79 w postaci ciągu tekstowego.

=ZAOKR.DO.TEKST(12345,6789;-2) zwraca wartość 12300 w postaci ciągu tekstowego.

=ZAOKR.DO.TEKST(12134567,89;-3;1) zwraca wartość 12135000 w postaci ciągu tekstowego.

=ZAOKR.DO.TEKST(12345,789;3/4) zwraca wartość 12346 w postaci ciągu tekstowego.

=ZAOKR.DO.TEKST(12345,789;8/5) zwraca wartość 12345,8 w postaci ciągu tekstowego.

ZASTĄP

Zamienia część łańcucha tekstowego innym łańcuchem tekstowym. Ta funkcja może być użyta zarówno do znaków jak i liczb (które są automatycznie konwertowane na tekst). Wynik działania tej funkcji zawsze jest tekstem. Jeśli masz zamiar dokonywać obliczeń z użyciem liczb, które zostały zamienione na tekst musisz przeprowadzić ponownie konwersję na liczbę przy użyciu funkcji WARTOŚĆ.

Jeżeli nie chcesz, by tekst zawierający liczby był interpretowany jako liczba i automatycznie konwertowany na tekst, musisz zawrzeć go w cudzysłów.

Składnia

ZASTĄP("tekst"; pozycja; długość; "nowy tekst")

Tekst jest to łańcuch znakowy, którego część chcesz zamienić.

Pozycja oznacza pozycję w tekście, od której rozpocznie się zastępowanie.

Długość to liczba znaków w wartości Tekst, którą należy zastąpić.

Nowy_tekst oznacza tekst, który ma zastąpić wartość Tekst.

Przykład

=ZASTĄP("1234567";1;1;"444") zwraca wartość "444234567". Jeden znak w pozycji 1 jest zastępowany przez całe wyrażenie Nowy_tekst.

ZNAJDŹ

Poszukuje ciągu tekstowego w innym ciągu. Funkcja pozwala także zdefiniować początek wyszukiwania. Wyszukiwany ciąg może być liczbą lub dowolnym ciągiem znakowym. Funkcja rozróżnia wielkość liter.

Składnia

ZNAJDŹ("znajdź_tekst"; "tekst" [; pozycja])

Znajdź_tekst oznacza szukany tekst.

Tekst jest tekstem, w którym będzie prowadzone wyszukiwanie.

Pozycja (parametr opcjonalny) oznacza pozycję w tekście, od której rozpocznie się wyszukiwanie.

Przykład

=ZNAJDŹ(76;998877665544) zwraca wartość 6.

ZNAK

Zamienia liczbę na znak zgodnie z tabelą kodową. Liczba może być dwucyfrową lub trzycyfrową liczbą całkowitą.

Składnia

ZNAK(liczba)

Liczba to wartość liczbowa z zakresu od 1 do 255, która odpowiada wartości kodu danego znaku.

Przykład

=ZNAK(100) zwraca znak d.

="abc" & ZNAK(10) & "def" wstawia do ciągu tekstowego znak nowej linii.

ZŁĄCZ.TEKSTY

Łączy wiele łańcuchów znakowych w jeden.

Składnia

ZŁĄCZ.TEKSTY(Ciąg 1 [; Ciąg 2 [; … [; Ciąg 255]]])

Ciąg 1[; Ciąg 2][; … ;[Ciąg 255]] to ciągi znaków lub odniesienia do komórek zawierających ciągi.

Przykład

=ZŁĄCZ.TEKSTY("Dzień";"dobry";"panie";"Kowalski") zwraca: Dzień dobry panie Kowalski.

Funkcje według kategorii