Funkcje arkusza kalkulacyjnego

Poniżej przedstawiono opisy funkcji grupy Arkusz kalkulacyjny poparte przykładem.

NR.BŁĘDU

Zwraca liczbę reprezentującą określony numer błędu lub wartość błędu #N/D, jeśli błąd nie występuje.

STYL

Stosuje styl do komórki zawierającej formułę.

ADR.POŚR

Zwraca odwołanie określone przez ciąg tekstowy. Funkcja może także zwracać obszar odpowiadającego jej ciągu.

ADR.POŚR(odwołanie [; A1])

Odwołanie oznacza odwołanie do komórki lub obszaru (w postaci tekstowej), dla której należy zwrócić zawartość.

A1 (parametr opcjonalny) – jeżeli ma wartość 0, używana jest notacja W1K1. Jeżeli argument ten jest nieobecny lub została mu przypisana wartość inna niż 0, używana jest notacja A1.

=ADR.POŚR(A1) zwraca wartość 100, jeśli komórka A1 zawiera odwołanie do komórki C108, a komórka C108 zawiera wartość 100.

=SUMA(ADR.POŚR("a1:" & ADRES(1;3))) sumuje komórki w obszarze od komórki A1 do komórki, której adres został zdefiniowany w wierszu 1 i kolumnie 3. Zostaną zatem zsumowane wartości komórek w zakresie A1:C1.

ADRES

Zwraca adres komórki (odwołanie) jako tekst zgodnie z określonymi numerami wiersza i kolumny. Funkcja pozwala na stosowanie adresacji bezwzględnej (np. $A$1), względnej (np. A1) lub mieszanej (np. A$1 lub $A1). Można także określić nazwę arkusza.

Aby zapewnić interoperacyjność, funkcje ADRES oraz ADR.POŚR obsługują dodatkowy argument, który umożliwia zdefiniowanie, czy zamiast domyślnej notacji A1 będzie używana notacja W1K1.

W funkcji ADRES argument ten jest czwartym wpisywanym argumentem, co spowodowało, że opcjonalny argument pozwalający zdefiniować nazwę arkusza został przeniesiony na pozycję piątą.

W przypadku funkcji ADR.POŚR argument ten znajduje się na drugiej pozycji.

W obu funkcjach, gdy argument przyjmie wartość 0, używana będzie notacja W1K1. Jeżeli argument nie zostanie zdefiniowany lub będzie miał wartość inną niż 0, używana będzie notacja A1.

W przypadku notacji W1K1 funkcja ADRES, zwracając łańcuchy adresowe, używa znaku wykrzyknika ('!') w charakterze separatora nazwy arkusza, a funkcja ADR.POŚR oczekuje, że wykrzyknik będzie separatorem nazwy arkusza. Przy notacji A1 w obu przypadkach funkcję separatora nazwy arkusza pełni kropka ('.').

Otwierając dokument w formacie ODF 1.0/1.1, funkcja ADRES, w której nazwa arkusza jest czwartym argumentem, przesunie ten argument w taki sposób, aby stał się on piątym argumentem funkcji. Na czwartej pozycji zostanie wstawiony nowy argument, który przyjmie wartość 1.

Przy zapisywaniu dokumentu w formacie ODF 1.0/1.1, w przypadku gdy funkcje ADRES używają czwartego argumentu, będzie on usunięty.

ADRES(nr_wiersza; nr_kolumny[; ABS; A1 [; "arkusz"]]])

Wiersz oznacza numer wiersza odwołania do komórki

Kolumna oznacza numer kolumny odwołania do komórki (numer, nie litera)

Adres_bezwzględny określa typ odwołania:

1: bezwzględne ($A$1)

2: odwołanie do wiersza jest bezwzględne, odwołanie do komórki jest względne (A$1)

3: wiersz (względne); kolumna (bezwzględne) ($A1)

4: względne (A1)

A1 (parametr opcjonalny) – jeżeli ma wartość 0, używana jest notacja W1K1. Jeżeli argument ten jest nieobecny lub została mu przypisana wartość inna niż 0, używana jest notacja A1.

Arkusz oznacza nazwę arkusza. Należy ją umieścić w cudzysłowie.

Przykład:

=ADRES(1;1;2;"Arkusz2") zwraca następującą wartość: Arkusz2.A$1

Jeśli powyższa formuła znajduje się w komórce B2 bieżącego arkusza, a komórka A1 w arkuszu 2 zawiera wartość -6, możesz odwołać się pośrednio do komórki, do której istnieje odwołanie, za pomocą funkcji w komórce B2 wpisując =ABS(ADR.POŚR(B2)). Wynikiem jest wartość bezwzględna odwołania do komórki określonego w komórce B2, która w tym przypadku wynosi 6.

DDE

Zwraca wynik łącza DDE. Jeśli zawartość zakresu lub sekcji łącza ulegnie zmianie, zwracana wartość także się zmieni. Aby aktualizacja łącz była widoczna, należy ponownie załadować arkusz lub wybrać Edycja - Łącza. Łącza utworzone pomiędzy różnymi platformami, na przykład z instalacji LibreOffice pracującej w systemie Windows do dokumentu na komputerze z systemem Linux nie są dopuszczalne.

DDE("serwer"; "plik"; "zakres" [; tryb])

Serwer to nazwa aplikacji serwera. Nazwą serwera aplikacji LibreOffice jest "Soffice".

Plik oznacza pełną nazwę pliku wraz z określeniem ścieżki dostępu.

Zakres oznacza zakres zawierający dane do obliczeń.

Tryb (parametr opcjonalny) określa sposób, w jaki serwer DDE konwertuje dane na liczby.

Tryb	Efekt
0 lub brak	Format liczb ze stylu komórki "Domyślnie"
1	Dane są zawsze interpretowane w standardowym formacie dla języka angielskiego (USA)
2	Dane są pobierane w postaci tekstu bez konwersji na liczby

=DDE("soffice";"c:\office\document\data1.ods";"arkusz1.A1") odczytuje zawartość komórki A1 na arkuszu Arkusz1 programu LibreOffice Calc zapisanego w pliku data1.ods.

=DDE("soffice";"c:\office\document\motto.ods";"Motto na dziś") zwraca motto w komórce zawierającej tę formułę. W pierwszej kolejności w dokumencie motto.ods zawierającym motto należy wprowadzić wiersz tekstu, a następnie zdefiniować go jako pierwszy wiersz sekcji o nazwie Motto na dziś (w programie LibreOffice Writer w menu Wstaw - Sekcja). Po zmodyfikowaniu (i zapisaniu) motta w dokumencie programu LibreOffice Writer, zostanie ono zaktualizowane w komórkach programu LibreOffice Calc zawierających zdefiniowane łącze DDE.

HIPERŁĄCZE

Po kliknięciu komórki zawierającej funkcję HIPERŁĄCZE zostaje otwarty adres docelowy.

Jeśli użyjesz opcjonalnego parametru WartośćKomórki, formuła zlokalizuje adres URL, a następnie wyświetli tekst lub liczbę.

HIPERŁĄCZE("URL" [;WartośćKomórki])

URL określa cel łącza. Opcjonalny parametr WartośćKomórki to tekst lub liczba wyświetlana w komórce, która zostanie zwrócona jako wynik. Jeśli parametr WartośćKomórki nie zostanie określony, URL zostanie wyświetlony w tekście komórki i zostanie zwrócony jako wynik.

Dla pustych komórek i elementów macierzy zwracana jest wartość 0.

=HIPERŁĄCZE("http://www.example.org") wyświetla tekst "http://www.example.org" w komórce i uruchamia hiperłącze po kliknięciu http://www.example.org.

=HIPERŁĄCZE("http://www.example.org";"Kliknij tutaj") wyświetla tekst "Kliknij tutaj" w komórce i uruchamia hiperłącze po kliknięciu http://www.example.org.

=HIPERŁĄCZE("http://www.example.org";12345) wyświetla liczbę 12345 i po kliknięciu uruchamia hiperłącze po kliknięciu http://www.example.org.

=HIPERŁĄCZE($B4), gdzie komórka B4 zawiera http://www.example.org. Funkcja dodaje http://www.example.org do adresu URL komórki hiperłącza i zwraca ten sam tekst, który jest używany jako wynik formuły.

=HIPERŁĄCZE("http://www.";"Kliknij ") & "example.org" wyświetla tekst Kliknij example.org w komórce i po kliknięciu uruchamia hiperłącze http://www.example .org.

=HYPERLINK("#Arkusz1.A1";"Przejdź do góry") wyświetla tekst "Przejdź do góry" i przechodzi do komórki Arkusz1.A1 w tym dokumencie.

=HYPERLINK("file:///C:/writer.odt#Specyfikacja";"Przejdź do zakładki Writer") wyświetla tekst "Przejdź do zakładki Writer", ładuje określony dokument tekstowy i przechodzi do zakładki "Specyfikacja".

=HYPERLINK("file:///C:/Documents/";"Otwórz folder Dokumenty") wyświetla tekst "Otwórz folder Dokumenty" i pokazuje zawartość folderu za pomocą standardowego menedżera plików w systemie operacyjnym.

INDEKS

INDEKS zwraca odwołanie, wartość lub macierz wartości z zakresu odniesienia, określonego przez numer indeksu wiersza i kolumny lub macierz numerów indeksu wiersza i macierzy kolumn oraz opcjonalny indeks zakresu.

INDEKS() zwraca odwołanie, jeśli argumentem jest jedno lub więcej odwołań. W przypadku użycia w komórce w postaci =INDEKS(), odwołanie jest rozpoznawane i wyświetlane są wartości. Gdy INDEKS() jest używany w argumentach innych funkcji, =FUNKCJA(INDEKS()...), funkcja pobiera przekazane odwołanie, które zostało zwrócone przez INDEKS(). Zwracanie odwołania różni się od zwracania macierzy wartości dla funkcji, które obsługują je w inny sposób.

INDEKS(odwołanie [; [wiersz] [; [kolumna] [; zakres]]])

Odwołanie to referencja wprowadzona bezpośrednio lub przez określenie nazwy zakresu. Jeśli odwołanie składa się z wielu zakresów, należy umieścić listę odwołań lub nazwy zakresów w nawiasach okrągłych albo użyć tyldy (~) operatora łączenia zakresów, lub zdefiniować nazwany zakres z wieloma obszarami.

Wiersz (parametr opcjonalny) reprezentuje wiersz lub tablicę indeksów wierszy zakresu odniesienia, dla którego ma zostać zwrócona wartość. W przypadku zera lub pominięcia (brak określonego wiersza) zwracane są wszystkie wiersze, do których istnieje odwołanie.

Kolumna (parametr opcjonalny) reprezentuje kolumnę lub tablicę indeksów kolumn zakresu odwołania, dla którego ma zostać zwrócona wartość. W przypadku zera lub pominięcia (brak określonej kolumny) zwracane są wszystkie przywoływane kolumny.

Zakres (parametr opcjonalny) reprezentuje indeks podzakresu, jeśli odnosi się do wielu zakresów, domyślnie jest to 1.

{=INDEKS({1,3,5;7,9,10},{2;1},1)} zwraca dwuwierszową macierz zawierającą 7 i 1. Indeks wiersza {2;1} wybiera najpierw wiersz 2, a następnie wiersz 1. Indeks kolumny 1 wybiera pierwszą kolumnę.

{=INDEKS(D3:G12,{1;2;3;4},{3,1})} zwraca macierz z 4 wierszami i 2 kolumnami. Macierz indeksów wierszy {1;2;3;4} wybiera wiersze od 3 do 6, a macierz indeksów kolumn {3;1} wybiera trzecią kolumnę (F) i pierwszą kolumnę (D). Kolumny 1 i 3 odniesienia źródłowego są zamieniane miejscami w wynikowej macierzy.

=INDEKS(Ceny;4;1) zwraca wartość z wiersza 4 i kolumny 1 bazy danych zdefiniowanej jako Ceny za pomocą polecenia menu Dane - Określ.

=INDEKS(Suma_X;4;1) zwraca wartość w wierszu 4 i kolumnie 1 zakresu Suma_X zdefiniowanego za pomocą polecenia menu Arkusz - Nazwane zakresy i wyrażenia - Określ.

{=INDEKS(A1:B6;1)} zwraca wartości pierwszego wiersza A1:B6. Wprowadź tę formułę jako formułę macierzową.

{=INDEKS(A1:B6;0;1)} zwraca wartości z pierwszej kolumny A1:B6. Wprowadź tę formułę jako formułę macierzową.

=INDEKS(A1:B6;1;1) oznacza wartość w lewym górnym rogu zakresu A1:B6.

{=INDEKS((A1:B6;C1:D6);0;0;2)} zwraca wartości drugiego zakresu C1:D6 wielokrotnego zakresu. Wprowadź formułę jako formułę macierzową.

KOLUMNA

Zwraca numer kolumny odwołania do komórki. Jeśli odwołaniem jest komórka, zwracany jest numer kolumny tej komórki; jeśli parametrem jest obszar komórki, odpowiednie numery kolumn są zwracane w jednowierszowej macierzy, jeśli wprowadzono formułę jako formuła macierzową. Jeśli funkcja KOLUMNA z parametrem odwołania do obszaru nie jest używana w formule macierzowej, określany jest tylko numer kolumny pierwszej komórki w obszarze.

KOLUMNA([odwołanie])

Odwołanie oznacza odwołanie do komórki lub obszaru komórek, dla którego należy odnaleźć numer pierwszej kolumny.

Jeśli odwołanie nie zostało podane, zostanie zwrócony numer kolumny komórki, w której wprowadzono formułę. Program LibreOffice Calc automatycznie definiuje odwołanie do bieżącej komórki.

=KOLUMNA(A1) zwraca wartość 1. Kolumna A jest pierwszą kolumną w tabeli.

=KOLUMNA(C3:E3) zwraca wartość 3. Kolumna C jest trzecią kolumną w tabeli.

=KOLUMNA(D3:G10) zwraca wartość 4, ponieważ kolumna D jest czwartą kolumną w tabeli, a funkcja KOLUMNA nie została użyta jako formuła macierzowa (w takim przypadku wynikiem jest zawsze pierwsza wartość macierzy).

{=KOLUMNA(B2:B7)} i =KOLUMNA(B2:B7) zwracają wartość 2, ponieważ odwołanie zawiera wyłącznie kolumnę B będącą drugą kolumną w tabeli. Ponieważ obszary składające się z jednej kolumny mają tylko jeden numer kolumny, nie ma znaczenia, czy formuła została zapisana w postaci macierzowej.

=KOLUMNA() zwraca wartość 3, jeśli formuła została wprowadzona w kolumnie C.

{=KOLUMNA(Królik)} zwraca jednokolumnową macierz (3, 4) jeśli we wskazanym obszarze (C1:D3) znajduje się słowo "Królik".

LICZBA.ARKUSZY

Określa liczbę arkuszy odwołania. Jeśli nie zostały podane żadne parametry, funkcja zwraca liczbę arkuszy bieżącego dokumentu.

ARKUSZ([odwołanie])

Odwołanie jest odwołaniem do arkusza lub obszaru. Ten parametr jest opcjonalny.

=LICZBA.ARKUSZY(Arkusz1.A1:Arkusz3.G12) zwraca wartość 3, jeśli Arkusz1, Arkusz2 i Arkusz3 występują w określonej kolejności.

LICZBA.KOLUMN

Zwraca liczbę kolumn podanego odwołania.

LICZBA.KOLUMN(macierz)

Macierz oznacza odwołanie do zakresu komórek, dla którego należy obliczyć liczbę kolumn. Argument może być też pojedynczą komórką.

=LICZBA.KOLUMN(B5) zwraca wartość 1, ponieważ komórka zawiera tylko jedną kolumnę.

=LICZBA.KOLUMN(A1:C5) zwraca wartość 3. Odwołanie składa się z trzech kolumn.

=LICZBA.KOLUMN(Królik) zwraca wartość 2, jeśli Królik jest nazwanym zakresem (C1:D3).

LICZBA.WIERSZY

Zwraca liczbę wierszy w odwołaniu lub w macierzy.

LICZBA.WIERSZY(macierz)

Macierz oznacza odwołanie lub nazwany obszar, dla którego należy obliczyć liczbę wierszy.

=LICZBA.WIERSZY(B5) zwraca wartość 1, ponieważ komórka zawiera tylko jeden wiersz.

=LICZBA.WIERSZY(A10:B12) zwraca wartość 3.

=WIERSZE(Królik) zwraca wartość 3, jeśli "Królik" jest nazwanym obszarem (C1:D3).

NR.BŁĘDU

Zwraca liczbę określającą wartość błędu, który wystąpił w komórce. Za pomocą tego numeru można wygenerować tekst komunikatu.

NR.BŁĘDU(odwołanie)

Odwołanie zawiera adres komórki, w której wystąpił błąd.

Jeśli w komórce A1 został wyświetlony komunikat Błąd:518, funkcja =NR.BŁĘDU(A1) zwraca liczbę 518.

ORG.OPENOFFICE.ERRORTYPE

OBSZARY

Zwraca liczbę pojedynczych zakresów należących do zakresu złożonego. Zakres może składać się z ciągłego obszaru komórek lub z pojedynczej komórki.

Funkcja oczekuje jednego argumentu. Jeśli chcesz podać wiele zakresów, musisz je umieścić w dodatkowych nawiasach. Wprowadzane zakresy można rozdzielać znakiem średnika (;), jednak jest on automatycznie konwertowany na operator tyldy (~). Tylda służy do łączenia zakresów.

OBSZARY(odwołanie)

Odwołanie oznacza odwołanie do komórki lub zakresu komórek.

=OBSZARY((A1:B3;F2;G1)) zwraca wartość 3, ponieważ jest to odwołanie do trzech komórek i/lub obszarów. Po wpisaniu formuła jest konwertowana na =OBSZARY((A1:B3~F2~G1)).

=OBSZARY(Wszystko) zwraca wartość 1, jeśli w menu Dane - Określ zakres został określony zakres Wszystko.

PODAJ.POZYCJĘ

Zwraca względną pozycję elementu macierzy pasującego do określonej wartości. Funkcja zwraca pozycję wartości odnalezionej w przeszukiwanej_macierzy w postaci liczbowej.

PODAJ.POZYCJĘ(szukaj; macierz wyszukiwaniaa [; typ])

Szukaj jest wartością, której należy szukać w macierzy jednowierszowej lub jednokolumnowej.

Przeszukiwana_macierz jest przeszukiwanym odwołaniem. Przeszukiwana macierz może być jednym wierszem lub kolumną, a także częścią jednego wiersza lub kolumny.

Typ może przyjmować wartości 1, 0 lub -1. Jeśli typ = 1 lub nie został podany, zakłada się, że pierwsza kolumna przeszukiwanej macierzy została posortowana w kolejności rosnącej. Jeśli Typ = -1, zakłada się, że pierwsza kolumna została posortowana w kolejności malejącej. Odpowiada to analogicznej funkcji programu Microsoft Excel.

Jeśli typ = 0, zwracane są tylko wartości dokładnie pasujące do kryterium. Jeśli to samo kryterium zostało odnalezione kilka razy, zwracane jest wyłącznie pierwsze wystąpienie. Wyrażenia regularne lub symbole wieloznaczne można wyszukiwać wyłącznie, jeśli typ = 0 (jeśli włączono w opcjach obliczeń).

Jeżeli Typ = 1 lub brakuje trzeciego parametru, zwracany jest indeks ostatniej wartości, która jest mniejsza lub równa kryterium wyszukiwania. Dla Typ = -1 zwracany jest indeks ostatniej wartości, która jest większa lub równa.

=PODAJ.POZYCJĘ(200;D1:D100) poszukuje wartości 200 w zakresie D1:D100, który został posortowany według kolumny D. Po odnalezieniu tej wartości zwracany jest numer zawierającego jej wiersza. Jeśli podczas przeszukiwania kolumny zostanie odnaleziona większa wartość, zwracany jest numer poprzedniego wiersza.

PRZESUNIĘCIE

Zwraca wartość przesunięcia komórki o pewną liczbę wierszy i kolumn względem danego punktu odniesienia.

PRZESUNIĘCIE(odwołanie; wiersze; kolumny [; wysokość [; szerokość]])

Odwołanie jest komórką, od której funkcja wyszukuje nowego odwołania.

Wiersze to liczba komórek, o którą nastąpi przesunięcie odwołania w górę (wartość ujemna) lub w dół. Użyj 0, aby pozostać w tym samym wierszu.

Kolumny to liczba kolumn, o którą nastąpi przesunięcie odwołania w lewo (wartość ujemna) lub w prawo. Użyj 0, aby pozostać w tej samej kolumnie.

Wysokość (parametr opcjonalny) to wysokość obszaru zaczynającego się w pozycji nowego odwołania.

Szerokość (parametr opcjonalny) jest szerokością obszaru zaczynającego się w pozycji nowego odwołania.

Z argumentów Wiersze i Kolumny nie mogą wynikać zerowe lub ujemne początkowe wiersze lub kolumny.

Z argumentów Wysokość i Szerokość nie może wynikać zerowa lub ujemna liczba wierszy bądź kolumn.

W funkcjach programu LibreOffice Calc parametry oznaczone jako „opcjonalne” można pominąć tylko wtedy, gdy żaden parametr nie występuje. Na przykład w funkcji z czterema parametrami, gdzie ostatnie dwa parametry są oznaczone jako „opcjonalne”, możesz pominąć parametr 4 lub parametry 3 i 4, ale nie możesz pominąć samego parametru 3.

=PRZESUNIĘCIE(A1;2;2) zwraca wartość w komórce C3 (A1 przesunięta w dół o dwa wiersze i dwie kolumny). Jeśli komórka C3 zawiera wartość 100, funkcja zwraca wartość 100.

=PRZESUNIĘCIE(B2:C3;1;1) zwraca odwołanie do B2:C3 po przesunięciu o 1 wiersz w dół i jedną kolumnę w prawo (C3:D4).

=PRZESUNIĘCIE(B2:C3;-1;-1) zwraca odwołanie do B2:C3 po przesunięciu o 1 wiersz w górę i jedną kolumnę w lewo (A1:B2).

=PRZESUNIĘCIE(B2:C3;0;0;3;4) zwraca odwołanie do B2:C3 po zmianie rozmiaru na 3 wiersze i 4 kolumny (B2:E4).

=PRZESUNIĘCIE(B2:C3;1;0;3;4) zwraca odwołanie do B2:C3 po przesunięciu w dół o jeden wiersz i zmianie rozmiaru na 3 wiersze i 4 kolumny (B3:E5).

=SUMA(PRZESUNIĘCIE(A1; 2; 2; 5; 6)) zwraca sumę wartości obszaru rozpoczynającego się w komórce C3 o wysokości 5 wierszy i szerokości 6 kolumn (obszar=C3:H7).

SHEET

Zwraca numer arkusza albo odnośnika, albo ciąg reprezentujący nazwę arkusza. Jeśli nie wprowadzisz żadnych parametrów, wynikiem będzie numer arkusza kalkulacyjnego zawierającego formułę.

ARKUSZ([odwołanie])

Odwołanie (parametr opcjonalny) jest ciągiem określającym odwołanie do komórki lub obszaru.

=ARKUSZ(Arkusz2.A1) zwraca 2, jeśli Arkusz2 jest drugim arkuszem w dokumencie arkusza kalkulacyjnego.

=ARKUSZ("Arkusz3") zwraca 3, jeśli Arkusz3 jest trzecim arkuszem w dokumencie arkusza kalkulacyjnego.

WEŹDANETABELI

Funkcja WEŹDANETABELI zwraca wartość wynikową z tabeli przestawnej. Wartość jest adresowana za pomocą nazw pola i elementu, dlatego też pozostaje prawidłowa po zmianie układu tabeli przestawnej.

Można zastosować dwie różne definicji składni:

GETPIVOTDATA(PoleDocelowe; Tabela przestawna [; Pole 1; Element 1] [; ... [Pole 126; Element 126]])

lub

WEŹDANETABELI(tabela przestawna; ograniczenia)

Druga składnia jest używana, jeśli są dane dokładnie dwa parametry, z czego pierwszy parametr jest komórką lub odwołaniem do zakresu komórek. Pierwsza składnia jest używana we wszystkich pozostałych przypadkach. Kreator funkcji przedstawia pierwszą składnię.

Pierwsza składnia

PoleDocelowe jest ciągiem, który wybiera jedno z pól danych tabeli przestawnej. Nazwa ciągu może być nazwą kolumny źródłowej lub nazwą pola danych, jak to zostało przedstawione w tabeli (np. "Suma – Sprzedaż").

Tabela przestawna jest odwołaniem do komórki lub zakresu komórek umieszczonych wewnątrz tabeli przestawnej lub zawierających ją. Jeśli zakres komórek zawiera kilka tabel przestawnych, będzie wykorzystana tabela, która została utworzona jako ostatnia.

Jeśli nie zostały podane żadne pary danych Pole n / Element n, zwracana jest suma końcowa. W przeciwnym razie każda para dodaje ograniczenie, które musi być spełnione przez wyniki. Pole n jest nazwą pola z tabeli przestawnej. Element n jest nazwą elementu z tego pola.

Jeśli tabela przestawna zawiera tylko jedną wartość wynikową, która spełnia wszystkie ograniczenia, lub wartość sumy częściowej wszystkich zgodnych wartości, ten wynik jest zwracany. Jeśli nie ma zgodnego wyniku lub kilka z nich nie ma sumy częściowej, zwracany jest błąd. Te warunki mają zastosowanie do wyników zawartych w tabeli przestawnej.

Jeśli dane źródłowe zawierają pozycje ukryte przez ustawienia tabeli przestawnej, są one ignorowane. Kolejność par Pole/Element nie ma znaczenia. W nazwach pól i elementów nie jest rozróżniana wielkość liter.

Jeśli nie podano żadnego ograniczenia dla filtru, domyślnie używana jest wybrana wartość pola. Jeśli podano ograniczenie dla filtru, musi ono odpowiadać wybranej wartości pola, w przeciwnym razie zostanie zwrócony błąd. Filtry to pola w lewym górnym rogu tabeli przestawnej, wypełniane przy użyciu obszaru „Filtry” w oknie dialogowym układu tabeli przestawnej. Z każdego filtra można wybrać pozycję (wartość), co oznacza, że tylko ta pozycja zostanie uwzględniona w kalkulacji.

Wartości sum częściowych z tabeli przestawnej są używane pod warunkiem, że wykorzystują funkcję "auto" (z wyjątkiem sytuacji, kiedy jest to określone w ograniczeniu, zobacz Druga składnia poniżej).

Druga składnia

Tabela przestawna ma to samo znaczenie, co w pierwszej składni.

Ograniczenia to lista oddzielona spacjami. Pozycje mogą być zapisane w apostrofach. Cały ciąg musi być umieszczony w cudzysłowach, chyba że stosowane jest odwołanie do ciągu z innej komórki.

Jedna z pozycji może być nazwą pola danych. Nazwa pola danych może zostać pominięta, jeśli tabela przestawna zawiera tylko jedno pole danych, w przeciwnym razie musi być określona.

Każda z tych pozycji określa ograniczenie w formie Pole[Element]. Element musi być umieszczony w nawiasach kwadratowych, o ile nazwa elementu nie jest jednoznaczna we wszystkich polach używanych w tabeli przestawnej.

Nazwa funkcji może być dodana w postaci Pole[Element;Funkcja], co wymusza ograniczenia dopasowania tylko do wartości sum częściowych, które wykorzystują tę funkcję. Dopuszczalne nazwy funkcji to: Suma, Policz, Średnia, Maks, Min, Iloczyn, Liczba, Odch. standardowe, Odch.standard. popul., Wariancja i Wariancja popul. Wielkość liter nie ma znaczenia.

WIERSZ

Zwraca numer wiersza odwołania do komórki. Jeśli odwołaniem jest komórka, zwraca numer wiersza komórki. Jeśli odwołanie jest zakresem komórek, zwraca odpowiednie numery wierszy w jednokolumnowej macierzy, jeśli wprowadzono formułę jako formułę macierzową. Jeśli funkcja WIERSZ z odwołaniem do zakresu nie jest używana w formule macierzowej, zwrócony zostanie tylko numer wiersza pierwszej komórki zakresu.

WIERSZ([odwołanie])

Odwołanie jest komórką, obszarem lub nazwą obszaru.

Jeśli odwołanie nie zostało podane, zwracany jest numer wiersza komórki, w której wprowadzono formułę. Program LibreOffice Calc automatycznie definiuje odwołanie do bieżącej komórki.

=WIERSZ(B3) zwraca wartość 3, ponieważ odwołanie określa trzeci wiersz tabeli.

{=WIERSZ(D5:D8)} zwraca jednokolumnową macierz (5, 6, 7, 8), ponieważ odwołanie określa wiersze od 5 do 8.

=WIERSZ(D5:D8) zwraca wartość 5, ponieważ funkcja WIERSZ nie została zapisana w postaci macierzowej, w związku z czym zwracany jest wyłącznie numer pierwszego wiersza odwołania.

{=WIERSZ(A1:E1)} i =WIERSZ(A1:E1) zwracają wartość 1, ponieważ odwołanie zawiera wyłącznie wiersz 1 będący pierwszym wierszem w tabeli. Ponieważ obszary składające się z jednego wiersza mają tylko jeden numer wiersza, nie ma znaczenia, czy formuła została zapisana w postaci macierzowej.

=WIERSZ() zwraca wartość 3, jeśli formuła została wprowadzona w wierszu 3.

{=WIERSZ(Królik)} zwraca macierz jednokolumnową (1, 2, 3), jeśli "Królik" jest nazwanym obszarem (C1:D3).

WYBIERZ

Na podstawie indeksu zwraca wartość z listy zawierającej do 30 argumentów.

WYBIERZ(indeks; wartość 1 [; wartość 2 [; ... [; wartość 30]]])

Indeks oznacza odwołanie lub liczbę od 1 do 30 określającą, którą wartość z listy należy wybrać.

Wartość 1, Wartość 2, ..., Wartość 30 to lista wartości wprowadzonych jako odwołanie do komórki lub jako pojedyncze wartości.

=WYBIERZ(A1;B1;B2;B3;"Dzisiaj";"Wczoraj";"Jutro") zwraca zawartość komórki B2 dla A1 = 2; dla A1 = 4 funkcja zwraca tekst "Dzisiaj".

WYSZUKAJ

Zwraca zawartość komórki zawartej w jednym wierszu, jednej kolumnie lub w macierzy. Opcjonalnie przypisana wartość (o tym samym indeksie) może być zwracana w innym wierszu lub kolumnie. W przeciwieństwie do funkcji WYSZUKAJ.PIONOWO i WYSZUKAJ.POZIOMO wektor przeszukiwany i wynikowy mogą być w różnych miejscach i nie muszą być przylegające. Przeszukiwany wektor funkcji WYSZUKAJ musi być ponadto posortowany, w przeciwnym razie funkcja nie będzie zwracać użytecznych wyników.

WYSZUKAJ(wyszukaj; wektor wyszukiwania [; wektor wyniku])

Wyszukaj jest wartością dowolnego typu, której należy szukać; wprowadzoną bezpośrednio lub jako odniesienie.

Przeszukiwany_wektor określa przeszukiwany obszar składający się z jednego wiersza lub jednej kolumny.

Wektor_wynikowy jest innym zakresem składającym się z jednego wiersza lub jednej kolumny, z którego pobierany jest wynik funkcji. Wynik jest komórką wektora wynikowego o tym samym indeksie stanowiącą odnaleziony element w wektorze wyszukiwania.

=WYSZUKAJ(A1;D1:D100;F1:F100) poszukuje w zakresie D1:D100 komórki zawierającej wartość wprowadzoną w komórce A1. Dla odnalezionego wystąpienia obliczany jest indeks, na przykład komórka numer 12 w danym zakresie. Następnie zawartość 12 komórki jest zwracana jako wartość funkcji (w postaci wektora wyników).

WYSZUKAJ.PIONOWO

Wyszukiwanie w pionie w odniesieniu do sąsiednich komórek po prawej stronie. Ta funkcja sprawdza, czy określona wartość jest zawarta w pierwszej kolumnie tablicy. Następnie funkcja zwraca wartość w tym samym wierszu kolumny o nazwie Indeks. Jeśli parametr Posortowane zostanie pominięty lub ustawiony na PRAWDA lub jeden, zakłada się, że dane są sortowane w porządku rosnącym. W takim przypadku, jeśli dokładne Wyszukaj nie zostanie znalezione, zwrócona zostanie ostatnia wartość, która jest mniejsza niż kryterium. Jeśli Posortowane jest ustawione na FAŁSZ lub zero, musi zostać znalezione dokładne dopasowanie, w przeciwnym razie wynikiem będzie błąd Błąd: wartość niedostępna. Zatem przy wartości zero dane nie muszą być sortowane w porządku rosnącym.

=WYSZUKAJ.PIONOWO(wyszukiwanie; macierz; indeks [; wyszukaj w posortowanym obszarze])

Wyszukaj jest wartością dowolnego typu szukaną w pierwszej kolumnie macierzy.

Macierz to odwołanie, które ma zawierać co najmniej tyle kolumn, ile wynosi liczba podana w argumencie Indeks.

Indeks oznacza numer kolumny w macierzy zawierającej wartość, która ma być zwrócona. Pierwsza kolumna ma numer 1.

Wyszukaj w posortowanym obszarze to opcjonalny parametr wskazujący, czy pierwsza kolumna w macierzy zawiera granice zakresu, a nie zwykłe wartości. W tym trybie wyszukiwanie zwraca wartość w wierszu, w którym pierwsza kolumna ma wartość równą lub mniejszą niż Wyszukaj. Np. może zawierać daty, kiedy pewna wartość podatku została zmieniona, a więc wartości reprezentują daty rozpoczęcia okresu, w którym obowiązywała określona wartość podatku. Zatem wyszukanie daty, której nie ma w pierwszej kolumnie macierzy, ale mieści się między niektórymi istniejącymi datami granicznymi, dałoby niższą z nich, co pozwoliłoby znaleźć dane obowiązujące do wyszukiwanej daty. Wprowadź wartość logiczną FAŁSZ lub zero, jeśli pierwsza kolumna nie jest listą granic zakresu. Gdy ten parametr ma wartość PRAWDA lub nie jest podany, pierwsza kolumna w macierzy musi być posortowana w porządku rosnącym. Posortowane kolumny można przeszukiwać znacznie szybciej, a funkcja zawsze zwraca wartość, nawet jeśli szukana wartość nie została dokładnie dopasowana, jeśli jest większa niż najniższa wartość z posortowanej listy. Na listach nieposortowanych szukana wartość musi być dokładnie dopasowana. W przeciwnym razie funkcja zwróci #N/D z komunikatem: Błąd: wartość niedostępna.

Po wprowadzeniu numeru dania menu do komórki A1 nazwa dania ma pojawić się natychmiast w sąsiedniej komórce (B1). Przypisanie numeru do nazwy znajduje się w macierzy D1:E100. D1 zawiera numer 100, E1 zawiera nazwę zupa jarzynowa, następne komórki zawierają kolejne 100 elementów. Numery w kolumnie D są sortowane w kolejności rosnącej, zatem opcjonalny parametr posortowane nie jest wymagany.

W komórce B1 wprowadź następującą formułę:

=WYSZUKAJ.PIONOWO(A1;D1:E100;2)

Po wprowadzeniu numeru do komórki A1 w komórce B1 zostanie wyświetlony odpowiedni tekst zawarty w drugiej kolumnie odwołania D1:E100. Wprowadzenie nie istniejącego numeru powoduje wyświetlenie wartości z następnej komórki. Aby temu zapobiec, jako ostatni parametr formuły należy wprowadzić wyrażenie logiczne FAŁSZ, dzięki czemu wprowadzenie nieistniejącego numeru powoduje wyświetlenie komunikatu o błędzie.

WYSZUKAJ.POZIOMO

Szuka wartości i odwołania do komórek poniżej zaznaczonego obszaru. Funkcja sprawdza, czy pierwszy wiersz macierzy zawiera określoną wartość, a następnie w tej samej kolumnie zwraca wartość wiersza macierzy nazwanego Indeks.

WYSZUKAJ.PIONOWO(wyszukaj; macierz; indeks [; wyszukaj w posortowanym obszarze])

Aby uzyskać wyjaśnienie parametrów, zobacz: WYSZUKAJ.PIONOWO (kolumny i wiersze są wymieniane)

Załóżmy, że zbudowaliśmy małą tabelę bazy danych zajmującą zakres komórek A1:DO4 i zawierającą podstawowe informacje o 118 pierwiastkach chemicznych. Pierwsza kolumna zawiera nagłówki wierszy „Pierwiastek”, „Symbol”, „Liczba atomowa” i „Względna masa atomowa”. Kolejne kolumny zawierają odpowiednie informacje dla każdego z pierwiastków, uporządkowane od lewej do prawej według liczby atomowej. Na przykład komórki B1:B4 zawierają „wodór”, „H”, „1” i „1,008”, podczas gdy komórki DO1:DO4 zawierają „Oganeson”, „Og”, „118” i „294”.

	A	B	C	D	...	DO
1	Pierwiastek	Wodór	Hel	Lit	...	Oganeson
2	Symbol	H	He	Li	...	Og
3	Liczba atomowa	1	2	3	...	118
4	Względna masa atomowa	1.008	4.0026	6.94	...	294

=WYSZUKAJ.POZIOMO("Ołów"; $A$1:$DO$4; 2; 0) zwraca „Pb”, symbol ołowiu.

=WYSZUKAJ.POZIOMO("Złoto"; $A$1:$DO$4; 3; 0) zwraca 79, liczbę atomową złota.

=WYSZUKAJ.POZIOMO("Węgiel"; $A$1:$DO$4; 4; 0) zwraca 12,011, względną masę atomową węgla.