Funkcje matematyczne

Ta kategoria zawiera funkcje matematyczne programu Calc. Aby otworzyć Kreator funkcji, wybierz polecenie Wstaw - Funkcja.

AGREGUJ

Zwraca wyniki agregacji obliczeń w zakresie. Dostępne są różne funkcje agregacji z listy poniżej. Funkcja agregacji pozwala pominąć ukryte wiersze, błędy SUMY.CZĘŚCIOWE i inne wyniki funkcji AGREGUJ w obliczeniach.

SUMA

Dodaje zestaw liczb.

SUMA.WARUNKÓW

Zwraca sumę wartości komórek w zakresie, który spełnia wielokrotność kryteriów w wielokrotności zakresów.

ACOS

Zwraca arcus cosinus liczby.

ACOS(liczba)

Ta funkcja zwraca arcus cosinus z Liczba, czyli kąt (w radianach), którego cosinus jest Liczba. Zwrócony kąt jest między 0 a Pi.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

=ACOS(-1) zwraca wartość 3,14159265358979 (PI radianów)

=STOPNIE(ACOS(0,5)) zwraca wartość 60. Cosinus kąta 60 stopni wynosi 0,5.

ACOSH

Zwraca arcus cosinus hiperboliczny liczby.

ACOSH(liczba)

Ta funkcja zwraca arcus cosinus hiperboliczny z Liczby, to liczba, której cosinus hiperboliczny jest Liczba.

Liczba musi być większa lub równa 1.

=ACOSH(1) zwraca wartość 0.

=ACOSH(COSH(4)) zwraca wartość 4.

ACOT

Zwraca arcus cotangens podanej liczby.

ACOT(liczba)

Ta funkcja zwraca arcus cotangens z Liczba, czyli kąt (w radianach), którego cotangens jest Liczba. Zwrócony kąt jest między 0 a Pi.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

=ACOT(1) zwraca wartość 0,785398163397448 (PI/4 radianów).

=STOPNIE(ACOT(1)) zwraca wartość 45. Tangens kąta 45 stopni wynosi 1.

ACOTH

Zwraca arcus cotangens hiperboliczny podanej liczby.

ACOTH(liczba)

Funkcja ta zwraca odwrotny cotangens hiperboliczny z parametru Liczba, czyli wartość, dla której odwrotny cotangens hiperboliczny wynosi parametr Liczba.

Jeśli liczba zawiera się w przedziale od -1 do 1 włącznie, wystąpi błąd.

=ACOTH(1,1) zwraca odwrotny cotangens hiperboliczny z 1,1, czyli ok. 1,52226.

ASIN

Zwraca arcus sinus podanej liczby.

ASIN (liczba)

Ta funkcja zwraca arcus sinus z Liczba, czyli kąt (w radianach), którego sinus jest Liczba. Zwrócony kąt jest między -PI/2 a +Pi/2.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

=ASIN(0) zwraca wartość 0.

=ASIN(1) zwraca wartość 1,5707963267949 (PI/2 radianów).

=STOPNIE(ASIN(0,5)) zwraca wartość 30. Sinus kąta 30 stopni wynosi 0,5.

ASINH

Zwraca arcus sinus hiperboliczny liczby.

ASINH(liczba)

Funkcja ta zwraca arcus sinus hiperboliczny z parametru Liczba, czyli wartość, dla której arcus sinus hiperboliczny wynosi parametr Liczba.

=ASINH(-90) zwraca wartość ok. -5,1929877.

=ASINH(SINH(4)) zwraca wartość 4.

ATAN

Zwraca arcus tangens liczby.

ATAN(liczba)

Ta funkcja zwraca arcus tangens z Liczba, czyli kąt (w radianach), którego tangens jest Liczba. Zwrócony kąt jest między -PI/2 a +Pi/2.

Aby uzyskać wartość kąta w stopniach, zastosuj funkcję STOPNIE.

=ATAN(1)zwraca wartość 0,785398163397448 (PI/4 radianów).

=STOPNIE(ATAN(1)) zwraca wartość 45. Tangens kąta 45 stopni wynosi 1.

ATAN2

Zwraca kąt (w radianach) między osią x a linią od początku do punktu (LiczbaX|LiczbaY).

ATAN2(liczba_X; liczba_Y)

Liczba_X to wartość współrzędnej x.

Liczba_Y jest wartością współrzędnej Y.

ATAN2 zwraca kąt (w radianach) między osią x a linią od początku do punktu (LiczbaX|LiczbaY)

=ATAN2(-5;9) zwraca 2,07789 radianów.

Aby uzyskać kąt w stopniach, zastosuj do wyniku funkcję STOPNIE.

=STOPNIE(ATAN2(12,3;12,3)) zwraca 45. Tangens kąta 45 stopni wynosi 1.

Funkcji można użyć do konwersji współrzędnych kartezjańskich na współrzędne biegunowe.

=STOPNIE(ATAN2(-8;5)) zwraca φ = 147,9 stopnia

ATANH

Zwraca arcus tangens hiperboliczny liczby.

ATANH(liczba)

Funkcja ta zwraca arcus tangens hiperboliczny z parametru Liczba, czyli wartość, dla której arcus tangens hiperboliczny wynosi parametr Liczba.

Liczba musi spełniać warunek -1 < liczba < 1.

=ATANH(0) zwraca wartość 0.

COS

Zwraca cosinus podanej liczby (kąta).

COS(liczba)

Zwraca cosinus (trygonometryczny) z Liczba, kąta wyrażonego w radianach.

Aby uzyskać cosinus kąta w stopniach, zastosuj funkcję RADIANY.

=COS(PI()*2) zwraca 1 ― cosinus kąta o mierze równej PI*2 radianów.

=COS(RADIANY(60)) zwraca wartość 0,5, czyli cosinus kąta 60 stopni.

COSH

Zwraca cosinus hiperboliczny liczby.

COSH(liczba)

Zwraca cosinus hiperboliczny z Liczba.

=COSH(0) zwraca wartość 1, cosinus hiperboliczny liczby 0.

COT

Zwraca cotangens argumentu traktowanego jako miara kąta w radianach.

COT(liczba)

Zwraca cotangens (trygonometryczny) z Liczba, kąta wyrażonego w radianach.

Aby uzyskać cotangens kąta w stopniach, zastosuj funkcję RADIANY.

Cotangens kąta jest równy odwrotności tangensa kąta.

Przykłady:

=COT(PI()/4) zwraca wartość 1 ― cotangens kąta o mierze PI/4 radianów.

=COT(RADIANY(45)) zwraca wartość 1, cotangens kąta 45 stopni.

COTH

Zwraca cotangens hiperboliczny podanej liczby (kąta).

COTH(liczba)

Zwraca cotangens hiperboliczny z Liczba.

=COTH(1) zwraca cotangens hiperboliczny z liczby 1 czyli ok. 1,3130.

CSC

Zwraca cosecant podanego kąta (w radianach). Cosecant jest równy 1 dzielone przez sinus tego kąta.

CSC(liczba)

Zwraca (trygonometryczny) cosecans z Liczby, kąta w radianach.

Aby uzyskać cosecans kąta w stopniach, zastosuj funkcję RADIANY.

=CSC(PI()/4) zwraca w przybliżeniu 1.4142135624, odwrotność sinusa z PI/4 radianów.

=CSC(RADIANY(30)) zwraca 2, cosecans 30 stopni.

CSCH

Zwraca hiperboliczny cosecans z liczby.

CSCH(liczba)

Zwraca hiperboliczny cosecans z Liczby.

=CSCH(1) zwraca w przybliżeniu 0.8509181282, hiperboliczny cosecans z 1.

CZ.CAŁK.DZIELENIA

Zwraca część całkowitą z dzielenia.

CZ.CAŁK.DZIELENIA(licznik; mianownik)

Zwraca część całkowitą z dzielenia dzielnej przez dzielnik.

CZ.CAŁK.DZIELENIA jest odpowiednikiem ZAOKR.DO.CAŁK(licznik/mianownik) dla licznika i mianownika tego samego znaku, z tą różnicą, że może zgłaszać błędy z różnymi kodami błędów. Mówiąc bardziej ogólnie, jest to odpowiednik ZAOKR.DO.CAŁK(licznik/mianownik/ZNAK.LICZBY(licznik/mianownik))*ZNAK.LICZBY(licznik/mianownik).

=CZ.CAŁK.DZIELENIA(11;3) zwraca wartość 3. Reszta 2 jest pomijana.

EUROKONWERT

Funkcja umożliwia konwersję walut europejskich na i z euro.

EUROKONWERT(wartość; "z_waluty"; "do_waluty" [; pełna_dokładność [; dokładność_triangulacji]])

Wartość jest wartością waluty, która ma zostać przekonwertowana.

Waluta_źródłowa i Waluta_docelowa to jednostki waluty, z których i na które będzie wykonywana konwersja. Musi to być oficjalny skrót danej waluty (np. "EUR"). Stawki (za jedno euro) zostały ustalone przez Komisję Europejską.

Pełna_dokładność jest parametrem opcjonalnym. Jeśli parametr ten zostanie pominięty lub ustawiony jako Fałsz, wynik zostanie zaokrąglony zgodnie z liczbami dziesiętnymi waluty docelowej. Jeśli opcja Pełna_dokładność jest ustawiona jako Prawda, wynik nie zostanie zaokrąglony.

Dokładność_triangulacji jest parametrem opcjonalnym. Jeśli została podana opcja Dokładność_triangulacji i ma wartość wyższą lub równą 3, wynik pośredni konwersji z wykorzystaniem waluty pośredniej (waluta1,EUR,waluta2) zostanie zaokrąglony zgodnie z podaną dokładnością. Pominięcie tego parametru powoduje, że wartość pośrednia nie będzie zaokrąglana. Jeśli walutą docelową jest EUR, parametr Dokładność_triangulacji jest używany, jeśli została wykonana triangulacja i przeliczenie z EUR na EUR.

Przykłady

=EUROKONWERT(100;"ATS";"EUR") konwertuje 100 szylingów austriackich na euro.

=EUROKONWERT(100;"EUR";"DEM") konwertuje 100 marek niemieckich na euro.

EXP

Zwraca wartość e podniesioną do potęgi. Stała e ma wartość około 2,71828182845904.

EXP(liczba)

Liczba jest potęgą, do której ma zostać podniesiona liczba e.

=EXP(1) zwraca 2,71828182845904, stałą matematyczną e z dokładnością programu Calc.

ILOCZYN

Mnoży wszystkie liczby podane w argumencie i zwraca iloczyn.

ILOCZYN(Liczba 1 [; Liczba 2 [; … [; Liczba 255]]])

=ILOCZYN(2;3;4) zwraca wartość 24.

KOMBINACJE

Zwraca liczbę kombinacji podanej liczby elementów bez powtórzeń.

KOMBINACJE(liczba_1; liczba_2)

Liczba_1 jest liczbą wszystkich elementów w zbiorze.

Liczba_2 jest liczbą wybranych elementów zbioru.

KOMBINACJE zwraca liczbę uporządkowanych sposobów wybrania danych elementów. Przykładowo, jeśli w zestawie są 3 elementy, A, B i C, 2 elementy można wybrać na 3 sposoby, tzn. AB, AC i BC.

Funkcja KOMBINACJE działa według formuły: liczba_1!/(liczba_2!*(liczba_1-liczba_2)!)

=KOMBINACJE(3;2) zwraca wartość 3.

KOMBINACJE.A

Zwraca liczbę kombinacji w podzestawie elementów, wliczając w to powtórzenia.

KOMBINACJE.A(liczba_1; liczba_2)

Liczba_1 jest liczbą wszystkich elementów w zbiorze.

Liczba_2 jest liczbą wybranych elementów zbioru.

KOMBINACJE.A zwraca liczbę unikalnych sposobów wyboru elementów, dla których kolejność wyboru nie ma znaczenia i dopuszczalne są powtórzenia. Jeśli w zestawie są przykładowo 3 elementy: A, B i C, 2 elementy można wybrać na 6 sposobów, tzn. AA, AB, AC, BB, BC i CC.

KOMBINACJE.A korzysta ze wzoru: (liczba_1 + liczba_2 - 1)! / (liczba_2! (liczba_1 - 1)!)

=KOMBINACJE.A(3;2) zwraca wartość 6.

KONWERTUJ_OOO

Konwertuje na euro wartość waluty wyrażoną w jednej ze starszych walut 19 państw członkowskich strefy euro i odwrotnie. Przeliczanie wykorzystuje stałe kursy wymiany, po których weszły starsze waluty euro.

KONWERTUJ_OOO(wartość; "tekst1"; "tekst2")

Wartość jest wartością waluty, która ma zostać przekonwertowana.

Tekst1 to trzyznakowy ciąg znaków określający walutę, z której ma zostać przeliczona.

Tekst2 to trzyznakowy ciąg znaków określający walutę, na którą ma zostać przeliczona.

Tekst1 i Tekst2 muszą przyjmować jedną z następujących wartości: "ATS", "BEF", "CYP", "DEM", "EEK", "ESP", "EUR", "FIM", "FRF", "GRD", "IEP", "ITL", "LTL", "LUF", "LVL", "MTL", "NLG", "PTE", "SIT" oraz "SKK".

Jeden i tylko jeden z Tekst1 lub Tekst2 musi być równy "EUR".

=KONWERTUJ_OOO(100;"ATS";"EUR") zwraca wartość 100 szylingów austriackich w euro.

=KONWERTUJ_OOO(100;"EUR";"DEM") konwertuje 100 euro na marki niemieckie.

LICZBA.CAŁK

LN

Zwraca logarytm naturalny o podstawie e (2,71828182845904) dla podanej liczby.

LN(liczba)

Liczba jest wartością, z której należy obliczyć logarytm naturalny.

=LN(3) zwraca logarytm naturalny o podstawie e z liczby 3 (ok. 1,0986).

=LN(EXP(321)) zwraca wartość 321.

LOG

Zwraca logarytm o określonej podstawie z podanej liczby.

LOG(liczba [; podstawa])

Liczba jest wartością, z której należy obliczyć logarytm.

Podstawa (parametr opcjonalny) jest podstawą obliczanego logarytmu. Jeśli wartość ta zostanie pominięta, przyjęta zostanie podstawa 10.

=LOG(10;3) zwraca logarytm o podstawie 3 z liczby 10 (ok. 2,0959).

=LOG(7^4;7) zwraca wartość 4.

LOG10

Zwraca logarytm dziesiętny podanej liczby.

LOG10(liczba)

Zwraca logarytm dziesiętny liczby.

=LOG10(5) zwraca ok. 0,69897 (logarytm dziesiętny z liczby 5).

LOS

Zwraca liczbę losową z zakresu od 0 do 1.

LOS()

Funkcja ta generuje nową liczbę losową za każdym razem, gdy arkusz Calc dokonuje ponownego obliczenia. Aby ręcznie wymusić ponowne wykonanie obliczeń przez arkusz Calc, naciśnij klawisze F9.

Aby wygenerować losowe liczby, które nigdy się nie przeliczają:

• Skopiuj komórki, z których każda zawiera =LOS() i użyj Edycja - Wklej specjalnie (z niezaznaczonymi polami Wklej wszystko i Formuła oraz zaznaczonym polem Liczby).

• Użyj polecenia wypełniania komórek losowymi liczbami (Arkusz - Wypełnij komórki - Wypełnij liczbami losowymi).

• Użyj funkcji LOS.NIEUL() dla nieulotnych liczb losowych.

=LOS() zwraca liczbę losową z zakresu od 0 do 1.

LOS.NIEUL

Zwraca nieulotną liczbę losową z zakresu od 0 do 1.

LOS.NIEUL()

Ta funkcja generuje nieulotną liczbę losową na wejściu. Funkcja nieulotna nie jest ponownie obliczana przy nowych zdarzeniach wejściowych. Funkcja nie jest ponownie obliczana po naciśnięciu F9, z wyjątkiem sytuacji, gdy kursor znajduje się w komórce zawierającej funkcję lub przy użyciu polecenia Oblicz ponownie wszystko (Shift++F9). Funkcja jest przeliczana ponownie podczas otwierania pliku.

=LOS.NIEUL() zwraca nieulotną liczbę losową z przedziału od 0 do 1.

ORG.LIBREOFFICE.RAND.NV

LOS.ZAKR

Zwraca liczbę losową ze zdefiniowanego zakresu.

LOS.ZAKR(dolna granica; górna granica)

Zwraca losową liczbę całkowitą z zakresu od dolnej i górnej (włącznie).

Funkcja ta generuje nową liczbę losową za każdym razem, gdy arkusz Calc dokonuje ponownego obliczenia. Aby ręcznie wymusić ponowne wykonanie obliczeń przez arkusz Calc, naciśnij klawisze F9.

Aby wygenerować liczby losowe, które nigdy nie są przeliczane, skopiuj komórki z tą funkcją i zastosuj funkcje Edycja – Wklej specjalnie... (Wklej wszystko przy niezaznaczonych formułach i zaznaczonych liczbach).

=LOS.ZAKR(20;30) zwraca całkowitą liczbę losową z przedziału od 20 do 30.

LOS.ZAKR.NIEUL

Zwraca nieulotną losową liczbę całkowitą z określonego zakresu.

LOS.ZAKR.NIEUL(górna; dolna)

Zwraca nieulotną losową liczbę całkowitą między liczbami całkowitymi Dolna i Górna (obie włącznie). Funkcja nieulotna nie jest przeliczana przy nowych zdarzeniach wejściowych lub naciśnięciu F9. Jednak funkcja jest przeliczana po naciśnięciu F9 z kursorem na komórce zawierającej funkcję, podczas otwierania pliku, podczas korzystania z polecenia Oblicz ponownie wszystko (Shift++F9) i kiedy Górna lub Dolna są przeliczane.

=LOS.ZAKR.NIEUL(20;30) zwraca nieulotną liczbę całkowitą z przedziału od 20 do 30.

=LOS.ZAKR.NIEUL(A1;30) zwraca nieulotną liczbę całkowitą między wartością komórki A1 a 30. Funkcja jest przeliczana ponownie, gdy zmienia się zawartość komórki A1.

ORG.LIBREOFFICE.RANDBETWEEN.NV

MOD

Zwraca resztę z dzielenia liczby przez dany podzielnik.

MOD(dzielna; dzielnik)

Dla całkowitych argumentów ta funkcja zwraca Dzielną modulo Dzielnik, tzn. resztę z dzielenia Dzielnej przez Dzielnik.

Ta funkcja została zaimplementowana jako Dzielna - Dzielnik * ZAOKR.DO.CAŁK(Dzielna / Dzielnik).

=MOD(22;3) zwraca wartość 1, resztę z dzielenia 22 przez 3.

=MOD(11,25;2,5) zwraca wartość 1,25.

MODUŁ.LICZBY

Zwraca wartość bezwzględną liczby.

MODUŁ.LICZBY(liczba)

Liczba to liczba, której wartość bezwzględna ma być obliczona. Wartość bezwzględna to wartość liczby bez znaku +/-.

=MODUŁ.LICZBY(-56) zwraca wartość 56.

=MODUŁ.LICZBY(12) zwraca wartość 12.

=MODUŁ.LICZBY(0) zwraca wartość 0.

NAJMN.WSP.WIEL

Zwraca najmniejszą wspólną wielokrotność dwóch lub więcej liczb całkowitych.

NAJMN.WSP.WIEL(Liczba całkowita 1 [; Liczba całkowita 2 [; … [; Liczba całkowita 255]]])

Jeśli umieścisz liczby 512, 1024 i 2000 w polach Liczba_całkowita 1, 2 i 3, wynikiem będzie 128000.

NAJMN.WSP.WIEL_EXCEL2003

Wynikiem jest najmniejsza wspólna wielokrotność listy liczb.

NAJMN.WSP.WIEL_EXCEL2003(Liczba 1 [; Liczba 2 [; … [; Liczba 255]]])

=NAJMN.WSP.WIEL_EXCEL2003(5;15;25) zwraca wartość 75.

NAJW.WSP.DZIEL

Zwraca największy wspólny dzielnik dwóch lub więcej liczb całkowitych.

Największy wspólny dzielnik jest największą dodatnią liczbą całkowitą, która dzieli bez reszty każdą z podanych liczb całkowitych.

NAJW.WSP.DZIEL(Liczba całkowita 1 [; Liczba całkowita 2 [; … [; Liczba całkowita 255]]])

=NAJW.WSP.DZIEL(16;32;24) zwraca wynik 8, ponieważ jest to największy wspólny dzielnik liczb podanych w wywołaniu funkcji.

=NAJW.WSP.DZIEL(B1:B3), gdzie komórki B1, B2, B3 zawierają wartości 9, 12, 9 daje w wyniku 3.

NAJW.WSP.DZIEL_EXCEL2003

Wynikiem jest największy wspólny dzielnik listy liczb.

NAJW.WSP.DZIEL_EXCEL2003(Liczba 1 [; Liczba 2 [; … [; Liczba 255]]])

=NAJW.WSP.DZIEL_EXCEL2003(5;15;25) zwraca wartość 5.

PI

Zwraca 3,14159265358979, jako wartość stałej matematycznej PI z dokładnością do 14 miejsc po przecinku.

PI()

=PI() zwraca wartość 3,14159265358979.

PIERW.PI

Zwraca wartość pierwiastka kwadratowego z liczby pomnożonej razy liczbę Pi.

PIERW.PI(liczba)

Zwraca dodatni pierwiastek kwadratowy wartości (PI pomnożone przez liczbę).

Jest to ekwiwalent funkcji PIERWIASTEK(PI()*liczba).

=PIERW.PI(2) zwraca pierwiastek z (2*Pi), czyli ok. 2,506628.

PIERWIASTEK

Zwraca dodatni pierwiastek kwadratowy z liczby.

PIERWIASTEK(liczba)

Zwraca dodatni pierwiastek kwadratowy z liczba.

Liczba musi być dodatnia.

=PIERWIASTEK(16) zwraca wartość 4.

=PIERWIASTEK(-16) zwraca błąd nieprawidłowy argument.

POTĘGA

Zwraca potęgę podanej liczby.

POTĘGA(podstawa; wykładnik)

Zwraca podstawę podniesioną do potęgi równej wykładnikowi.

Ten sam wynik można osiągnąć poprzez zastosowanie operatora potęgowania ^:

Podstawa^wykładnik

=POTĘGA(4;3) zwraca wartość 64, tzn. 4 podniesione do potęgi 3.

4^3 również zwraca 4 do potęgi 3.

RADIANY

Konwertuje stopnie na radiany

RADIANY(liczba)

Liczba jest kątem w stopniach, który ma zostać zamieniony na radiany.

=RADIANY(90) zwraca wartość 1,5707963267949, co stanowi wartość PI/2 z dokładnością programu Calc.

SEC

Zwraca secans podanego kąta (w radianach).Secans równy jest 1 dzielone przez cosinus podanego kąta

SEC(liczba)

Zwraca (trygonometryczny) sekans z Liczby, kąt w radianach.

Aby uzyskać sekans kąta w stopniach, zastosuj funkcję RADIANY.

=SEC(PI()/4) zwraca w przybliżeniu 1.4142135624, odwrotność kosinusa z PI/4 radianów.

=SEC(RADIANY(60)) zwraca 2, sekans z 60 stopni.

SECH

Zwraca hiperboliczny sekans z liczby

SECH(liczba)

Zwraca hiperboliczny sekans z Liczby.

=SECH(0) zwraca 1, hiperboliczny sekans z 0.

SILNIA

Zwraca silnię liczby.

SILNIA(liczba)

Zwraca Liczba!, silnię z Liczba, obliczonej jako 1*2*3*4* ... * Liczba.

=SILNIA(0) z definicji wynosi 1.

Silnia liczby ujemnej zwraca błąd "nieprawidłowy argument".

=SILNIA(3) wynosi 6.

=SILNIA(0) wynosi 1.

SIN

Zwraca sinus podanej liczby (kąta).

SIN(liczba)

Zwraca sinus liczby (kąta w radianach).

Aby uzyskać sinus kąta w stopniach, zastosuj funkcję RADIANY.

=SIN(PI()/2) zwraca 1 ― sinus kąta o mierze PI/2 radianów.

=SIN(RADIANY(30)) zwraca wartość 0,5, czyli sinus kąta 30 stopni.

SINH

Zwraca sinus hiperboliczny liczby.

SINH(liczba)

Zwraca sinus hiperbolicznyliczby.

=SINH(0) zwraca wartość 0, sinus hiperboliczny dla 0.

STOPNIE

Konwertuje radiany na stopnie.

STOPNIE(liczba)

Liczba to kąt wyrażony w radianach, który ma być przeliczony na stopnie.

=STOPNIE(PI()) zwraca wartość 180 stopni.

SUMA.JEŻELI

Dodaje komórki określone przez podane kryterium. Ta funkcja służy do sumowania zakresu podczas wyszukiwania określonej wartości.

SUMA.JEŻELI(zakres; kryterium [; zakres_sumowania])

Zakres jest zakresem, do którego ma być zastosowane kryterium.

Zakres_sumowania to zakres wartości, które mają być zsumowane. Jeśli ten parametr nie został określony, zostaną zsumowane wartości odnalezione w zakresie.

Przykład sumowania jedynie ujemnych liczb: =SUMA.JEŻELI(A1:A10;"<0")

=SUMA.JEŻELI(A1:A10;">0";B1:B10) – sumuje wartości z zakresu B1:B10 tylko wtedy, gdy odpowiednie wartości z zakresu A1:A10 są > 0.

Aby zapoznać się z innymi przykładami składni, które mogą być wykorzystywane z funkcją SUMA.JEŻELI(), patrz funkcja LICZ.JEŻELI().

SUMA.KWADRATÓW

Oblicza sumę kwadratów zbioru liczb.

SUMA.KWADRATÓW(Liczba 1 [; Liczba 2 [; … [; Liczba 255]]])

Jeśli podasz jako argumenty Liczby 1; 2 i 3 wartości 2; 3 i 4, otrzymujesz wynik 29.

SUMA.SZER.POT

Zwraca sumę potęg liczby.

SUMA.SZER.POT(x;n;m;w) = w₁xⁿ + w₂x^n+m + w₃x^n+2m + ... + w_ix^{n + (i-1)m}.

SUMA.SZER.POT(x; n; m; współczynniki)

X to liczba będąca zmienną niezależną.

n: potęga początkowa

M to przyrost wartości N

Współczynniki są serią współczynników. Dla każdego współczynnika suma serii jest rozszerzana o jedną sekcję.

=SUMA.SZER.POT(A1; 0; 1; {1; 2; 3}) oblicza wartość 1+2x+3x², gdzie x jest wartością w komórce A1. Jeśli A1 zawiera 1, formuła zwraca 6; jeśli A1 zawiera 2, formuła zwraca 17; jeśli A1 zawiera 3, formuła zwraca 34 i tak dalej.

SUMY.CZĘŚCIOWE

Oblicza sumy częściowe. Jeśli zakres już zawiera sumy częściowe, nie są one uwzględniane w dalszych obliczeniach. Ta funkcja użyta wraz z autofiltrami pozwala uwzględnić w obliczeniach tylko filtrowane rekordy.

SUMY.CZĘŚCIOWE(funkcja; zakres)

Funkcja jest liczbą oznaczającą jedną z następujących funkcji:

Indeks funkcji (zawiera ukryte wartości)	Indeks funkcji (ignoruje ukryte wartości)	Funkcja
1	101	ŚREDNIA
2	102	LICZBA
3	103	NIEPUSTE
4	104	MAKS
5	105	MIN
6	106	ILOCZYN
7	107	ODCH.STANDARDOWE
8	108	ODCH.STANDARD.POPUL
9	109	SUMA
10	110	WARIANCJA
11	111	WARIANCJA.POPUL

Użyj numerów 1-11, aby uwzględnić ręcznie ukryte wiersze lub 101-111, aby je wykluczyć; Odfiltrowane komórki są zawsze wykluczone.

Zakres jest zakresem uwzględnianych komórek.

Masz taberlę w zakresie komórek A1: B6 zawierającą zestawienie materiałów dla 10 uczniów. Rząd 2 (pióro) jest ręcznie ukryty. Chcesz zobaczyć sumę wyświetlanych liczb; to jest tylko podsuma dla filtrowanych wierszy. W tym przypadku prawidłową formułą będzie:

	A	B
1	PRZEDMIOT	ILOŚĆ
2	Pióro	10
3	Ołówek	10
4	Notes	10
5	Gumka	10
6	Temperówka	10

=SUMY.CZĘŚCIOWE(9; B2:B6) zwraca 50

=SUMY.CZĘŚCIOWE(109; B2:B6) zwraca 40

TAN

Zwraca tangens podanego kąta.

TAN(liczba)

Zwraca tangens (trygonometryczny) z Liczba, kąta wyrażonego w radianach.

Aby uzyskać tangens kąta w stopniach, zastosuj funkcję RADIANY.

=TAN(PI()/4) zwraca wartość 1, tangens kąta o mierze PI/4 radianów.

=TAN(RADIANY(45)) zwraca wartość 1, czyli tangens kąta 45 stopni.

TANH

Zwraca tangens hiperboliczny liczby.

TANH(liczba)

Zwraca tangens hiperboliczny z liczby.

=TANH(0) zwraca wartość 0, tangens hiperboliczny wartości 0.

WIELOMIAN

Zwraca silnię sum argumentów podzieloną przez iloczyn silni argumentów.

WIELOMIAN(Liczba 1 [; Liczba 2 [; … [; Liczba 255]]])

=WIELOMIAN(F11:H11) zwraca wartość 1260, jeżeli komórki od F11 do H11 zawierają wartości 2, 3 i 4. Funkcja odpowiada formule =(2+3+4)! / (2!*3!*4!)

ZAOKR

Zwraca liczbę zaokrągloną do pewnej liczby miejsc dziesiętnych.

ZAOKR(liczba [; miejsce])

Zwraca Liczbę zaokrągloną do tylu miejsc dziesiętnych, ile wynosi argument Miejsce. Jeśli argument Miejsce jest pominięty lub wynosi zero, to funkcja zaokrągla do najbliższej liczby całkowitej. Jeśli argument Miejsce jest mniejszy od zera, to funkcja zaokrągla do najbliższych 10, 100, 1000, itd.

Funkcja zaokrągla wartość do najbliższej liczby. Patrz też ZAOKR.DÓŁ i ZAOKR.GÓRA.

=ZAOKR(2,348;2) zwraca wartość 2,35

=ZAOKR(-32,4834;3) zwraca wartość -32,483. Aby wyświetlić wszystkie pozycje dziesiętne, należy zmienić format komórki.

=ZAOKR(2,348;0) zwraca wartość 2.

=ZAOKR(2,5) zwraca wartość 3.

=ZAOKR(987,65;-2) zwraca wartość 1000.

ZAOKR.DO.CAŁK

Zaokrągla liczbę w dół do najbliższej liczby całkowitej.

ZAOKR.DO.CAŁK(liczba)

Zwraca Liczbę zaokrągloną w dół do najbliższej liczby całkowitej.

Liczby ujemne są zaokrąglane do mniejszej liczby całkowitej.

=ZAOKR.DO.CAŁK(5,7) zwraca wartość 5.

=ZAOKR.DO.CAŁK(-1,3) zwraca wartość -2.

ZAOKR.DO.NPARZ

Zwraca liczbę zaokrągloną w górę do następnej liczby nieparzystej.

ZAOKR.DO.NPARZ(liczba)

Liczba jest liczbą, która ma zostać zaokrąglona w kierunku od zera.

=ZAOKR.DO.NPARZ(1,2) zwraca wartość 3.

=ZAOKR.DO.NPARZ(1) zwraca wartość 1.

=ZAOKR.DO.NPARZ(0) zwraca wartość 1.

=ZAOKR.DO.NPARZ(-3,1) zwraca wartość -5.

ZAOKR.DO.PARZ

Zwraca liczbę zaokrągloną w górę do następnej liczby parzystej.

ZAOKR.DO.PARZ(liczba)

Liczba jest liczbą, która ma zostać zaokrąglona w górę do następnej liczby parzystej.

=ZAOKR.DO.PARZ(2,3) zwraca wartość 4.

=ZAOKR.DO.PARZ(2) zwraca wartość 2.

=ZAOKR.DO.PARZ(0) zwraca wartość 0.

=ZAOKR.DO.PARZ(-0,5) zwraca wartość -2.

ZAOKR.DO.WIELOKR

Wynikiem jest liczba zaokrąglona do najbliższej całkowitej wielokrotności drugiej liczby.

ZAOKR.DO.WIELOKR(liczba; wielokrotność)

Zwraca liczbę po zaokrągleniu do najbliższej wielokrotności.

Alternatywnie można zastosować funkcję Wielokrotność * ZAOKR(liczba/wielokrotność).

=ZAOKR.DO.WIELOKR(15,5;3) zwraca wartość 15, bo liczbie 15,5 jest bliżej do 15 (= 3*5) niż do 18 (= 3*6).

=ZAOKR.DO.WIELOKR(1,4;0,5) zwraca wartość 1,5 (=0,5*3).

ZAOKR.DÓŁ

ZAOKR.GÓRA

Zaokrągla liczbę w górę, uwzględniając podaną liczbę miejsc po przecinku.

ZAOKR.GÓRA(liczba [; miejsce])

Zwraca Liczba zaokrągloną w górę (od zera) do Miejsc po przecinku. Jeśli argument Miejsce jest pominięty lub zero, funkcja zaokrągla w górę do najbliższej liczby całkowitej. Jeśli argument Miejsce jest ujemny, funkcja zaokrągla w górę do najbliższej 10, 100, 1000, itd.

Funkcja zaokrągla liczbę w górę. Patrz też ZAOKR.DÓŁ i ZAOKR.

=ZAOKR.GÓRA(1,1111;2) zwraca wartość 1,12.

=ZAOKR.GÓRA(1,2345;1) zwraca wartość 1,3.

=ZAOKR.GÓRA(45,67;0) zwraca wartość 46.

=ZAOKR.GÓRA(-45,67) zwraca wartość -46.

=ZAOKR.GÓRA(987,65;-2) zwraca wartość 1000.

ZNAK.LICZBY

Zwraca znak liczby. Funkcja zwraca wartość 1 dla znaku dodatniego i -1 dla znaku ujemnego. Jeśli liczba jest zerem, funkcja zwraca również zero.

ZNAK.LICZBY(liczba)

Liczba jest liczbą, dla której należy określić znak.

=ZNAK.LICZBY(3,4) zwraca wartość 1.

=ZNAK.LICZBY(-4,5) zwraca wartość -1.