Korzystanie ze zmiennych

Poniżej opisano podstawowe zasady korzystania ze zmiennych LibreOffice Basic.

Konwencje nazw identyfikatorów zmiennych

Nazwa zmiennej może składać się z maksymalnie 255 znaków. Pierwszy znak nazwy zmiennej musi być literą z zakresu A-Z lub a-z. Nazwa zmiennej może także zawierać cyfry, natomiast nie są dozwolone znaki przestankowe i specjalne, z wyjątkiem znaku podkreślenia ("_"). W identyfikatorach zmiennych w LibreOffice nie są rozróżniane małe i wielkie litery. Nazwy zmiennych mogą zawierać spacje, jednak takie nazwy muszą być ujęte w nawiasy kwadratowe.

Przykłady identyfikatorów zmiennych:


    MyNumber=5      'Prawidłowe'
    MyNumber5=15    'Prawidłowe'
    MyNumber_5=20   'Prawidłowe'
    My Number=20    'Nieprawidłowe, zmienna ze spacją musi być ujęta w nawiasy kwadratowe'
    [My Number]=12  'Prawidłowe'
    DéjàVu=25       'Nieprawidłowe, znaki specjalne są niedozwolone'
    5MyNumber=12    'Nieprawidłowe, zmienna nie może zaczynać się od liczby'
    Number,Mine=12  'Nieprawidłowe, znaki interpunkcyjne są niedozwolone'

Deklaracja zmiennych

W LibreOffice Basic nie ma obowiązku jawnego deklarowania zmiennych. Deklaracji zmiennej można dokonać za pomocą instrukcji Dim. Jednocześnie można zadeklarować kilka zmiennych, oddzielając ich nazwy przecinkami. Aby zdefiniować typ zmiennej, po jej nazwie należy podać znak deklaracji typu lub odpowiednie słowo kluczowe.

Przykłady deklaracji zmiennych:


    Dim a$               'Deklaruje zmienną "a" jako String'
    Dim a As String      'Deklaruje zmienną "a" jako String'
    Dim a$, b As Integer 'Deklaruje jedną zmienną jako String, a drugą jako Integer'
    Dim c As Boolean     'Deklaruje c jako zmienną Boolean, która może mieć wartość TRUE lub FALSE'

Po zadeklarowaniu zmiennej danego typu nie można ponownie deklarować zmiennej o tej samej nazwie jako innego typu.

Kiedy deklarujesz wiele zmiennych w jednym wierszu kodu, musisz określić typ każdej zmiennej. Jeśli typ zmiennej nie jest jawnie określony, Basic przyjmie, że zmienna jest typu Variant.


  ' Obie zmienne "a" i "b" są typu Integer
  Dim a As Integer, b As Integer
  ' Zmienna "c" to Variant, a "d" to Integer
  Dim c, d As Integer
  ' Zmienną można również jawnie zadeklarować jako Variant
  Dim e As Variant, f As Double

Typ Variant to specjalny typ danych, w którym można przechowywać dowolne wartości. Aby dowiedzieć się więcej, zapoznaj się z sekcją Typ Variant poniżej.

Wymuszenie deklaracji zmiennych

Aby wymusić deklarację zmiennych, należy użyć następującego polecenia:


Option Explicit

Instrukcja Option Explicit musi być pierwszą instrukcją w module, przed pierwszym słowem SUB. Ogólnie tylko tablice powinny być deklarowane w sposób jawny. Wszystkie pozostałe zmienne są deklarowane zgodnie ze znakiem deklaracji typu. W przypadku jego braku zmienna jest typu Single (pojedyncza precyzja).

Typy zmiennych

LibreOffice Basic obsługuje cztery klasy zmiennych:

Zmienne Numeric mogą zawierać wartości numeryczne. Niektóre zmienne służą do przechowywania dużych lub małych liczb, inne służą do przechowywania liczb zmiennoprzecinkowych lub ułamkowych.
Zmienne typu String zawierają ciągi znaków.
Zmienne typu Boolean zawierają wartości TRUE (prawda) lub FALSE (fałsz).
Zmienne typu Object zawierają obiekty lub różne typy, takie jak tablice i dokumenty wewnątrz dokumentu.

Zmienne typu Integer

Zmienne typu Integer mogą przyjmować wartości w zakresie od -32768 do 32767. W przypadku przypisania do takiej zmiennej liczby zmiennoprzecinkowej miejsca dziesiętne są zaokrąglane do najbliższej liczby całkowitej. Zmienne typu Integer są bardzo szybko przeliczane, dlatego też są odpowiednie dla zmiennych licznikowych w pętlach. Zmienna całkowita wymaga tylko dwóch bajtów pamięci. Znakiem deklaracji typu jest "%".


Dim Variable%
Dim Variable As Integer

Zmienne typu Long Integer (liczba całkowita długa)

Zmienne typu Long Integer mogą przyjmować wartości w zakresie od -2147483648 do 2147483647. W przypadku przypisania do takiej zmiennej liczby zmiennoprzecinkowej miejsca dziesiętne są zaokrąglane do najbliższej liczby całkowitej. Zmienne typu Long Integer są bardzo szybko przeliczane, dlatego też są odpowiednie dla zmiennych licznikowych w pętlach o bardzo dużych wartościach liczników. Zmienna typu Long Integer wymaga czterech bajtów pamięci. Znakiem deklaracji typu jest "&".


Dim Variable&
Dim Variable As Long

Zmienne dziesiętne

Zmienne dziesiętne mogą przyjmować wartości dodatnie, ujemne albo wartość zerową. Dokładność wynosi do 29 cyfr.

Jako prefiksy liczb dziesiętnych można stosować znaki plus (+) lub minus (-) (ze spacją lub bez).

Jeśli do zmiennej całkowitej przypisana jest liczba dziesiętna, LibreOffice Basic zaokrągla ją w górę lub w dół.

Zmienne typu Single

Pojedyncze zmienne mogą przyjmować wartości dodatnie lub ujemne z zakresu od 3,402823 x 10E38 do 1,401298 x 10E-45. Pojedyncze zmienne to zmienne zmiennoprzecinkowe, w których dokładność dziesiętna maleje wraz ze wzrostem niedziesiętnej części liczby. Pojedyncze zmienne nadają się do obliczeń matematycznych o średniej precyzji. Obliczenia wymagają więcej czasu niż dla zmiennych Integer, ale są szybsze niż obliczenia ze zmiennymi typu Double. Pojedyncza zmienna wymaga 4 bajtów pamięci. Znak deklaracji typu to "!".


Dim Variable!
Dim Variable As Single

Zmienne typu Double

Zmienne podwójne mogą przyjmować wartości dodatnie lub ujemne z zakresu od 1,79769313486232 x 10E308 do 4,94065645841247 x 10E-324. Zmienne typu Double to zmienne zmiennoprzecinkowe, w których dokładność dziesiętna maleje wraz ze wzrostem niedziesiętnej części liczby. Zmienne Double nadają się do precyzyjnych obliczeń. Obliczenia wymagają więcej czasu niż dla zmiennych Single. Zmienna Double wymaga 8 bajtów pamięci. Znak deklaracji typu to "#".


Dim Variable#
Dim Variable As Double

Zmienne typu Currency

Zmienne typu Currency (waluta) są wewnętrznie przechowywane jako liczby 64-bitowe (8 bajtów) i wyświetlane są w postaci stałoprzecinkowej z 15 cyframi w części całkowitej i 4 miejscami dziesiętnymi. Przyjmowane wartości mieszczą się w zakresie od -922337203685477,5808 do +922337203685477,5807. Zmienne tego typu są używane do precyzyjnych obliczeń finansowych. Znakiem deklaracji typu jest "@".


Dim Variable@
Dim Variable As Currency

Literały dla liczb całkowitych

Liczby mogą być kodowane przy użyciu form ósemkowych i szesnastkowych.


  xi = &o13 '    8 + 3
  ci = &h65 ' 6*16 + 5
  MAX_Integer =  &o77777 '  32767 = &h7FFF
  MIN_Integer = &o100000 ' -32768 = &h8000
  MAX_Long = &h7fffffff '  2147483647 = &o17777777777
  MIN_Long = &h80000000 ' -2147483648 = &o20000000000

Zmienne typu String

Zmienne łańcuchowe mogą przechowywać ciągi znaków o maksymalnej długości 2147483648 znaków. Każdy znak jest przechowywany jako odpowiadająca mu wartość Unicode. Zmienne łańcuchowe są odpowiednie do przetwarzania tekstów w programach i do tymczasowego przechowywania dowolnych znaków niedrukowalnych o maksymalnej długości 2 GB. Pamięć wymagana do przechowywania zmiennych łańcuchowych zależy od liczby znaków w zmiennej. Znak deklaracji typu to "$".

W funkcjach String BASIC pierwszy znak ciągu ma indeks 1.


Dim Variable$
Dim Variable As String

Zmienne typu Boolean

Zmienne tego typu mogą przechowywać jedną z dwóch wartości: TRUE (prawda) lub FALSE (fałsz). Liczba 0 oznacza wartość FALSE (fałsz), inna wartość oznacza TRUE (prawda).


Dim Variable As Boolean

Zmienne typu Date

Zmienne typu Date mogą zawierać wyłącznie informacje o dacie i godzinie zapisane w formacie wewnętrznym. Wartości przypisane do zmiennych typu Date za pomocą instrukcji Dateserial, Datevalue, Timeserial lub Timevalue są automatycznie konwertowane na format wewnętrzny. Zmienne tego typu można konwertować na zwykłe liczby za pomocą funkcji Day, Month, Year lub Hour, Minute, Second. Format wewnętrzny pozwala na porównywanie wartości daty lub godziny przez obliczenie różnicy pomiędzy dwiema liczbami. Te zmienne mogą być deklarowane wyłącznie za pomocą słowa kluczowego Dim.


Dim Variable As Date

Literały dla dat

Literały daty pozwalają określić jednoznaczne zmienne daty, które są niezależne od bieżącego języka. Literały są ujęte między znakami krzyżyka #. Możliwe formaty to:

#yyyy-mm-dd#
#mm/dd/yyyy#


  start_date = #12/30/1899# ' = 1
  dob = #2010-09-28#

Typ Variant

Zmienne zadeklarowane jako Variant mogą obsługiwać dane dowolnego typu. Oznacza to, że rzeczywisty typ danych jest definiowany w czasie wykonywania, gdy wartość jest przypisywana do zmiennej.

Istnieją trzy główne sposoby tworzenia zmiennej Variant, jak pokazano poniżej:


  Dim varA            ' Typ nie jest określony, stąd zmienna jest typu Variant
  Dim varB as Variant ' Zmienna jest jawnie zadeklarowana jako Variant
  varC = "abc"        ' Wcześniej niezadeklarowane zmienne są traktowane jako Variant

Poniższy przykład wykorzystuje funkcję TypeName, aby pokazać, jak typ zmiennej Variant zmienia się po przypisaniu.


  Dim myVar As Variant
  MsgBox TypeName(myVar) ' Empty
  myVar = "Hello!"
  MsgBox TypeName(myVar) ' String
  myVar = 10
  MsgBox TypeName(myVar) ' Integer

Zmienna Variant jest inicjowana specjalnym typem danych Empty. Możesz użyć funkcji IsEmpty, aby sprawdzić, czy zmienna jest Empty Variant.

Możesz także użyć słowa kluczowego Any, aby zadeklarować zmienną jako Variant. Jednak Any jest przestarzały i jest dostępny dla kompatybilności wstecznej.

Argumenty typu Variant lub Any przekazywane w wywołaniach funkcji nie są sprawdzane pod kątem swoich typów.


  Dim myVar As Any ' Zmienna "myVar" to Variant

Początkowe wartości zmiennych

Bezpośrednio po deklaracji zmienna przyjmuje wartość "Null". Uwagi dotyczące konwencji:

Zmienne typu Numeric (numeryczne) bezpośrednio po deklaracji przyjmują wartość "0".

Zmienne typu Date przyjmują wartość 0; odpowiada to konwersji do wartości "0" przez funkcję Day, Month, Year lub Hour, Minute, Second.

Zmienne typu String bezpośrednio po deklaracji są ciągiem pustym ("").

Tablice

LibreOffice Basic obsługuje tablice jedno- lub wielowymiarowe zdefiniowane jako określony typ zmiennych. Tablice są odpowiednim typem zmiennych dla edycji list i tabel w programach. Pojedyncze elementy tablicy można adresować za pomocą indeksów numerycznych.

Tablice muszą być deklarowane za pomocą instrukcji Dim. Istnieje kilka sposobów definiowania zakresu indeksu tablicy:


    Dim Text$(20)       '21 elementów ponumerowanych od 0 do 20'
    Dim Text$(5,4)      '30 elementów (macierz 6 x 5 elementów)'
    Dim Text$(5 To 25)  '21 elementów ponumerowanych od 5 do 25'
    Dim Text$(-15 To 5) '21 elementów (w tym 0), ponumerowanych od -15 do 5'

Zakres indeksu może obejmować zarówno liczby dodatnie, jak i ujemne.

Stałe

Stałe posiadają ustaloną wartość. Są definiowane tylko raz w programie i nie można ich później zmieniać:


Const ConstName=Expression

Stałe Basic

Instrukcja Dim