Identyfikacja systemu operacyjnego

Identyfikację systemu operacyjnego można przeprowadzić za pomocą języka Python lub Basic.

Właściwość ComputerName jest dostępna wyłącznie dla systemu Windows. Podstawowe wywołania makr języka Python pomagają przezwyciężyć podstawowe ograniczenia programu LibreOffice.

Korzystanie z klasy Pythona:


        """ the_module """
        import os, platform
        class Platform():
            @property
            def ComputerName(self): return platform.node()
            @property
            def DirSeparator(self): return os.sep
            @property
            def isLinux(self): return (self.OSName=='Linux')
            @property
            def isMacOSX(self): return (self.OSName=='Darwin')
            @property
            def isWindows(self): return (self.OSName=='Windows')
            @property
            def OSName(self): return platform.system()
            @property
            def PathDelimiter(self): return os.pathsep

Korzystanie z modułu klas Basic:

LibreOffice Basic nie ma natywnego rozpoznawania systemu MacOS X. Identyfikacja platformy jest możliwa za pomocą API (Application Programming Interface) LibreOffice.


        Option Compatible
        Option ClassModule
        Option Explicit
        
        Public Property Get ComputerName As String
            If isWindows Then ComputerName = Environ("ComputerName")
        End Property ' Platform.ComputerName
        
        Public Property Get DirSeparator As String
            DirSeparator = GetPathSeparator()
        End Property ' Platform.DirSeparator
        
        Public Property Get IsLinux As Boolean
            isLinux = ( GetGUIType()=4 ) ' Applies to macOS as well 
        End Property ' Platform.isLinux
        
        Public Property Get IsMacOSX As Boolean
            isMacOSX = ( OSName="MAC" )
        End Property ' Platform.isMacOSX
        
        Public Property Get IsWindows As Boolean
            isWindows = ( GetGUIType()=1 )
        End Property ' Platform.isWindows
        
        Public Property Get OSName As String
            ' Zwróć nazwę platformy jako "MAC", "UNIX", "WIN"
            ' Pochodzi z funkcji "Tools.UCB.ShowHelperDialog"
            With GlobalScope.Basiclibraries
                If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
            End With
            Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess
            keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Help")
            OSName = keyNode.GetByName("System")
        End Property ' Platform.OSName
        
        Public Property Get PathDelimiter As String
            Select Case OSName
                Case "MAC", "UNIX" : PathDelimiter = ":"
                Case "WIN" : PathDelimiter = ";"
             End Select
        End Property ' Platform.PathDelimiter

Przykłady:

Za pomocą języka Python

>>> from < the_module > import Platform

>>> print(Platform().isMacOSX) # właściwość obiektu

True

>>> input(Platform().OSName) # właściwość obiektu

Darwin

Z menu Narzędzia - Makra - Wykonaj makro….


        from < the_module > import Platform
        import screen_io as ui
        p = Platform()
        ui.MsgBox(''.join(['isMacOS: ',str(p.isMacOSX)]),0,p.OSName)

Za pomocą języka LibreOffice Basic


        Sub Platform_example()
            Dim p As New Platform ' instancja klasy Platform
            MsgBox p.isLinux ' właściwość obiektu
            Print p.isWindows, p.OSName ' właściwość obiektu
        End Sub ' Platform_example

Wejście i wyjście ekranu

Funkcja GetGuiType

Funkcja GetPathSeparator

Wywoływanie skryptów Pythona z Basic

Przykłady programowania w Pythonie

Pomoc skryptów Pythona LibreOffice