Faankishinoota Wardii

Kutaan kun ibsa faankishinoota Wardii fakkeenyota wajjiin of keessatti qabata.

[text/scalc/01/func_error_type.xhp#error_type_head not found].

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

STYLE

Applies a style to the cell containing the formula.

ADDRESS

Haala lakkoofsota tarree fi tarjaa adda ba'aaniitiin, teessoo (wabii) mandhee akka barruutti kenna.teessoon akka teesssoo sirriitti(fakkeenyaaf $A$1 ) hiikamuu isaa ykn akka teessoo birqabaatti(akka Al) ykn akkaataa walmakaan(A$1 or $A10 murteessuu ni dandeessa .maqaa wardiis adda baasuu ni dandeessa.

Walkeessa hojeechuuf faankishinootni TEESSOO fi SHAFFAXA ulaagaa dirqalaa teessoo R1C1 bakka beekamaa A1 ta'usaa ifteessuuf yaadannoo deeggarsaa kennuuf fayyada.

TEESSOO keessatti, ulaagaan akka ulaagaa arfaffaatti saagama, maqaan dirqalaa ulaagaa wardii gara qubannoo shanaffaatti hiqsama.

SHAFFAXA keessatti, ulaagaan akka ulaagaa lammafaatti dabalama.

Fankishinoota lamaanuu keessatti, yoo qajeelfamni gatii o waliin saagame, yaadannoon R1C1 ni fayyada. Yoo qajeelfamni hin kennamne ta'e ykn gatii o tin ala qabaate, yaadannoon A1 ni fayyada.

Dubbii yaadannoo R1C1 keessatti, TEESSOOn mallattoo raajeffannoo '!' fayyadamuun diraa teessoo akka footuu maqaa wardiitti deebisa, akkasumas SHAFFAXAAn akka wardii maqaa footuutti mallattoo raajeeffannoo eega. Faankishinootni lachanuu ammallee tuqaa '.' akka maqaa footuu wardiitti yaadannoo A1 fayyadamu.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Yeroo galmee dhangii ODF 1.0/1.1 keessatti kuufamu, yoo faankishiniin TEESSOO ulaagaa arfaffaa qabaate, ulaagaan sun ni haqama.

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

Tarree lakkoofsa tarree wabii mandheetiif bakka bu'a

Tarjaan wabii mandheef lakkoofsa tarjaa bakka buusa (qubicha osoo hin taane, lakkoofsicha)

Absn gosa wabii murteessa:

1: ($A$1)sirrii

2: gosni wabii tarree sirriidha; wabiin tarjaa birqabadha (A$1)

3: tarree (birqaba); tarjaa (sirrii) ($A1)

4: birqaba (Al)

A1 (dirqalee) - 0 tti yoo qindaa'e, yaadannoon R1C1 ni fayyada. Yoo ulaagaan kun hin jiru ta'e ykn gatii 0 tiin alatti qindaa'e, yaadannoon A1 ni fayyada.

Wardiin maqaa wardii bakka bu'a. mallattoo waraabbii keessa taa'uu qaba

Fakkeenya

=ADDRESS(1;1;2;"Wardii2") Wardii2.A$1 armaan gadii deebisa.

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

AREAS

Lakkoofsa hangiiwwan dhuunfaa kan hangii hedduu ta'e deebisa. Hangiin mandheewwan walitti aanan ykn mandhee qeenee qabata.

Faankishiinin qajeelfama tokko qofa eega. Yoo hangii hedduu ibsite, golbee lakkuu dabaltaa keessa isaan kaa'uu qabda. Hangiiwwan hedduun bufata xinnaa (;) fayyadamuun akka ooftuutti galfamuu danda'u, garuu kun ofumaan gara ogeejjii dalduufaa (~) tti jijjiirama. Dalduufaan hangiiwwan walqbsiisuuf fayyada.

AREAS(Wabii)

Wabiin wabii mandhee ykn hangii mandhee bakka bu'a.

=AREAS(A1:B3;F2;G1) akka man'eewwan sadiif fi/ykn bal'inootaaf wabii ta'etti, 3 deebisa.

=AREAS(All) yoo naannoo maqaan isaa Hunda jala Hangii - Deetaa ibsu ibsiteetta ta'e 1 deebisa.

CHOOSE

Tarree gatiiwwan hanga 30 keessaa gatii deebisuuf kasaa fayyadama.

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Kasaan wabii ykn lakkoofsa 1 fi 30 gidduu gatii kamtu tarree keessaa akka fudhatamuu qabu mul'isudha.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

=CHOOSE(A1;B1;B2;B3;"Har'a";"Kaleessa";"Boru"), fakkeenyaf, qabeentoon mandhee B2 A1=2 dhaaf; A1=4 dhaaf, deebisa faankishiniin barruu "Har'a" deebisa.

COLUMN

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

COLUMN([Reference])

Wabiin wabii mandheef ykn naannoo mandhee lakkoofsi tarjaa jalqabaa barbaadamuu qabuuti.

Yoo wabiin tokkoyyu hin seenne ta'e, lakkoofsi tarjaa mandhee foormulaan keessa seene ni argama. LibreOffice Calciin wabii ofumaan gara mandhee ammeetti qindeessa.

=COLUMN(A1) walqixa 1. Tarjaa A n gabatee keessatti tarjaa jalqabaati.

=COLUMN(C3:E3) walqixa 3. Tarjaa C n gabatee keessatti tarjaa sadaffaadha.

=COLUMN(D3:G10)n 4 kenna sababni isaas tarjaa D n gabatee keessatti tarjaa afraffaadha dabalataan immoo faankishiniin TARJAA akka foormulaa waraantootti hin fayyadne. (Haala kana keessatti, gatiin waraantoo inni jalqabaa yeroo hunda akka firiitti fayyada.)

{=COLUMN(B2:B7)} fi =COLUMN(B2:B7) lamaan isaaniiyyu 2 kennu sababni isaas wabiin tarjaa B qofa akka tarjaa lammaffaa gabatee keessaatti of keessatti qabata. Naannoon tajaa-qeenxee lakkoofsa tarjaa tokko qofa waan qabuuf, foormulaan akka foormulaa waraantootti yoo fayyades fayyaduu baates garaagarummaa hin uumu.

=COLUMN()n yoo foormulaan tarjaa C keessa galeera ta'e 3 kenna.

{=COLUMN(Hilleenttii)} yoo hilleensi maqaa naannoo (C1:D3)tti mogga'e ta'e waraantoo tarree-qeenxee (3, 4) kenna.

COLUMN

Lakkoofsa tarjaawwanii wabii kenname keessa jiran deebisa.

COLUMNS(Waraantoo)

Waraantoon hangii mandhee lakkoofsi tarjaawwan isaa hundi barbaadamuu qabuuf wabiidha. Qajeelfamni mandhee qeenxees ta'uu ni danda'a.

=COLUMN(B5)n 1 kenna sababni isaaas mandheen tokko tarjaa tokko qofa qabata.

=COLUMN(A1:C5) walqixa 3. Wabiin tarjaawwan sadii of keessatti qabata.

=COLUMNS(Hilleensi) yoo Hilleensa maqaa hangiitti moggaafame yoo ta'e (C1:D3) 2 deebisa.

DDE

Firii walqabsiisa DDE-irratti hundaa'e deebisa. Yoo qabeentotni hangii walqabatanii ykn kutaa jijjiiraman, gatiin deebi'es ni jijjiirama. Walqabsiitota haaromfaman ilaaluuf wardii irra deebitee fe'uu ykn Gulaali - walqabsiistota filachuu qabda.Walqabsiistonni gulantiyyaa-qaxxaamuraa, fakkeenyaaf LibreOffice galmee maashina Linux irratti uumame maashina foddaawwanii irraatti ijaarsa adeemsisuun, eeyyamamaa miti.

DDE("Server"; "File"; "Range" [; Mode])

Server is the name of a server application. LibreOffice applications have the server name "soffice".

Faayiliimaqaa guutuu faayiliiti, karaa itti baramu dabalatee.

Hangiin bakka deetaa gamaggamamuu qabu qabate dha.

Haalataulaagaa filannoo mala kaadimaan DDE deetaa isaa gara lakkofsaatti ittiin jijjiiru to'atudha.

Mode	Effect
0 ykn dhiisuu	Dhangii lakkoofsaa kan "Durtii" haala mandhee
1	Ingiliffa US tiif deetaan yeroo hundumaa dhangii waltaawaadhaan hiikama.
2	Deetaan akka barruutti walitti qabamu; jijjiiramni lakkoofsota irratti hin raawwatu.

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

ERRORTYPE

Lakkoofsa gatii dogongoraa man'ee biroo keessatti mul'atu waliin walsimu kenna. Gargaarsa lakkoofsa kanaatiin, barruu ergaa dogoggoraa umuu ni dandeessa.

ERRORTYPE(Wabii)

Wabiin teessoo mandhee dogongorri keessatti uumamu of keessatti qabata.

Yoo mandheen A1 Err:518 mul'ise, faankishiniin =ERRORTYPE(A1) lakkoofsa 518 kenna.

ORG.OPENOFFICE.ERRORTYPE

GETPIVOTDATA

Faankishiniin GETPIVOTDATA Gabatee Qiinxaa irraa firii gatii deebisa. Gatichi maqaawwan dirree fi wantaa fayyadamuudhaan teessoon isaa barama, Yoo teessumni Gabatee Qiinxaa jijjiirame gatii qabeessa ta'ee tura.

Ibsoonni caasimaa garaagaraa lama fayyadamamuu danda'u:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

or

GETPIVOTDATA(GabateeQiinxaa; Hanqinoota)

Yoo sirriitti ulaagaaleen lama kennaman caasimni lammaffaan, ulaagaan isaa tokkoffaa mandhee ykn wabii hangii mandhee ta'e ni tilmaamama. Caasimni tokkoffaan haalota biroo hunda keessatti ni tilmaamama. Masakni Faankishinii caasima tokkoffaa agarsiisa.

First Syntax

DirreenGaltee diraa dirreewwan deetaa gabatee qiinxaa tokko filatudha. Diraan maqaa tarjaa maddaa ta'uu danda'a, ykn maqaa dirree deetaa akka gabatee (like "Sum - Sales") keessatti agarsiifameetti.

GabateenQiinxaa mandhee ykn hangii mandhee Gabatee Qiinxaa wajjiin qubate ykn gabatee Gabatee qiinxaa qabatuudhaaf wabiidha. Yoo hangii mandhee gabateewwan Gabatee Qiinxaa hedduu qabaate, gabateen dhuma irratti uumame ni fayyadamama.

Yoo Dirree n / Item n dachaan hin kennamne ta'e, dabaltoon dunneetii ni deebi'a. Yoo ta'uu baate, cimdiin hundi ittisa firiin guutuu qabu ida'a. Dirreen n maqaa wantaa Gabatee qiinxaa irraati. Maalimaan n maqaa maalimaa dirree sana irraati

Yoo gabateen Gabatee Qiinxaa gatii firii qeenxee hanqinoota hunda guutu qofa qabaate, ykn hundamta xiqqaa gatiiwwan walsimatan hunda goolabu, firiin sun ni deebi'a. Yoo firiin walsimatu hin jiru ta'e, ykn tokko hedduu hundamta xiqqaa hin qabne ta'e, dogongorri ni deebi'a. Haalotni kun firiiwwan Gabatee Qiinxaa keessatti hammatamanitti hojii irra oola.

Yoo maddi deetaa galiinsawwan qiindaa'ina Gabatee Qiinxaadhaan dhokatan qabaate, isaan ni dhiifamu. Taartibni cimdii Dirree/Wanta barbaachisaa miti. Maqaawwan dirree fi wantaa qub-sukaanaawoo miti.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Gatiiwwan hundamta xiqqaa Gabatee Qiinxaa irraa yoo faankishinii "auto" fayyadaman qofa fayyadamamu (yeroo ittisa keessatti adda ba'e irraa kan hafe, Caasima Lammaffaa below) armaan gadii ilaali.

Second Syntax

Gabateen Qiinxaa akka caasima tokkoffaa keessaatti hiikkaa wal fakkaataa qaba.

Ittisamoonni tarree iddoo-adda ba'edha. Galiinsonni waraabbii (mallattoo waraabbii qeenxee) keessa taa'uu danda'u. Diraa mandhee biraa irraa yoo wabeessiteen ala, diraan hundi waraabbiiwwan (mallattoo waraabbi dachaa) keessatti hammatamuu qabu.

Galiinsota keessaa tokko maqaa dirree deetaa ta'uu ni danda'a. Yoo Gabateen Qiinxaa dirree tokko qofa qabaate maqaan dirree deetaa ni dhiisama, ta'uu baannaan jiraachuu qaba.

Tokko tokkoon galiinsota biroo ittisamoota uunkaField[Item] (arfiiwwan jargiffa wajjiin [ fi ]), ykn Item yoo maqaan wantaa dirreewwan hunda Gabatee Qiinxaa keessatti fayyadamaman keessatti adda ta'e adda baasa.

Maqaan faankishinii uunka Dirree[Wanta;Faankishinii], ittisama gatiiwwan hundamta xiqqaa faankishini sana fayyadamu wajjiin akka waal simatu taasisu keessatti ida'amuu danda'a. Maqaan faankishinii danda'amu Ida'uu, Lakkaawuu, Gidduugala, Guddaa, Xiqqaa, Baay'ataa, Lakkaawuu (Lakkoofsota qofa), StDev (Fakkeenya), StDev (Baay'ina), Var (Fakkeenya), fi Varp (Baay'ina), qub-sukaanaa'aa kan hin taane.

HLOOKUP

Mandheewwan naannoo filatamee gad jiraniif gatii fi wabii barbaada. Faankishiniin kun tarreen jalqabaa waraantoo gatii murtaa'e qabaachuu isaa mirkaneessa. Faankishinichi ni deebisa sana booda gatiin tarree waraantoo keessaa, Kasaa tarjaa wal fakkaatu, keessatti moggaafama.

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomic Number	1	2	3	...	118
4	Relative Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

HYPERLINK

Yeroo mandhee faankishinii HYPERLINK qabatu cuqaastu, geessituun ni banama.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

Mandheewwan duwwaa fi maalimoota tareentaaf lakkoofsi 0 deebi'a.

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

INDEX

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=INDEX(Prices;4;1) tarree 4 fi tarjaa 1 hangii kuusdeetaa Deetaa - Ibsi akka Gatiiwwaniitti keessatti ibsame irraa gatii deebisa.

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=INDEX(A1:B6;1;1) gatii harka bitaa gara olii hangii A1:B6 keessa jiru agarsiisa.

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.

INDIRECT

wabii diraa barruutiin adda ba'e kenna. Faankishiniin kun naannoo diraa walfaakkatu kennuufis ni gargaara.

INDIRECT(Ref [; A1])

Ref wabii mandheefii ykn naannoo( bifa barruutiin taa'e) qabeentota deebisuufi qabnuuf bakka bu'a.

A1 (dirqalee) - 0 tti yoo qindaa'e, yaadannoon R1C1 ni fayyada. Yoo ulaagaan kun hin jiru ta'e ykn gatii 0 tiin alatti qindaa'e, yaadannoon A1 ni fayyada.

Yoo A1 akka wabiitti C108 of keessatti qabaatee fi mandheen C108 gatii 100 qabaate =INDIRECT(A1) 100 waliin wal qixa ta'a.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) mandheewwan naannoo A1 keessa jiranii hanga mandhee teessoon isaa tarree 1 fi tarjaa 3n ibsametti hundamteessa. Kana jechuun naannoon A1:C1 hundamtaa'eera.

LOOKUP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

KalqabeenBarbaachaa bal'ina tarree-qeenxee ykn tarjaa-qeenxee barbaadamuuf jirudha.

KalqabeenFirii hangii tarree-qeenxee ykn tarjaa-qeenee biraa firiin faankishinii irraa fudhatamudha. Firiin mandhee kalqabee firii kasaa walfakkaataa akka miseensa kalqabee barbaachaa keessaa argameedha.

=LOOKUP(A1;D1:D100;F1:F100) Lakkoofsa A1 keessa galchiteef hangii D1:D100 keessaa mandhee barbaada. Miseensa argameef, kasaan murtaa'eera, fakkeenyaaf, mandhee 12ffaa hangii kana keessaa. Sana booda, qabeentotni mandhee 12ffaa akka gatii faankishinii (kalqabee firii keessaatti) deebi'u.

MATCH

Qubannoo birqabaa wanta waraantoo keessa jiruu kan gatii adda ba'e wajjiin walsimatu kenna. Faankishinichi qubannoo gatii waraantoo_ilaaluu keessatti akka lakkoofsaatti argamu kenna.

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

WaraantoonIlaaluu wabii barbaadanedha. Waraantoon ilaaluu tarree ykn tarjaa qeenxee, ykn kutaa tarree ykn tarjaa qeenxee ta'uu ni danda'a.

Gosni gatiiwwan 1, 0, ykn -1 fudhachuu danda'a. Yoo Gosni = 1 ykn yoo ulaagaan dirqalaa kun hafe, tarjaan jalqabaa waraantoo barbaachaa jalaa ol akka tartiibeffametti ilaalama. Yoo Gosni = -1 tarjaan irraa gad akka tartiibeffametti ilaalama. Kun Maaykiroosooft Ekseelii keessatti faankishinii wal fakkaataa ilaallata.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

=MATCH(200;D1:D100) naannoo D1:D100, gatii 200f, tajaa D dhaan tartiiba'e barbaada. Akkuma gatii kana bira ga'ametti, lakkoofsi tarree gatiin kun kun keessaa argame ni deebi'a. Yeroo tarjaa keessa barbaachi adeemsifamu yoo gatii guddaan argame, lakkoofsi tarree duraa ni deebi'a.

OFFSET

Gatii iddooda mandhee tarreewwanii fi tarjaawwan murta'aaniin tuqaa wabii kenname keessaa deebisa.

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Wabiin wabii faankishiniin wabii haaraa irraa barbaadudha.

Tarreewwan lakkoofsa tarreewwanii wabiin ittiin ol(gatii negetiivaa) ykn gad sirraa'edha.

Tarreewwan lakkoofsa tarreewwanii wabiin ittiin ol(gatii negetiivaa) ykn gad sirraa'edha.

Hojjaan (dirqala) hojjaa sarjaa bal'ina qubannoo wabii haaraa irratti jalqabuuti.

Dalgeen (dirqala) dalgee surdalaa bal'ina qubannoo wabii haaaraa irratti jalqabuuti.

Qajeelfamoonni Tarreewwan fi Tarjaawwan gara zeerootti ykn tarree jalqabaa negetiiviitti ykn tarjaatti deemsisuu hin qabu.

Qajeelfamoonni Hojjaa fi Dalgee gara zeerootti ykn tarree negetiiviidhaan lakkaawuutti ykn tarjaatti deemsisuu hin qabu.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

=OFFSET(A1;2;2) gatii mandhee C3 (A1 tarreewwan lamaa fi tarjaawwan lamaan gad hiiqe) kenna. Yoo C3n gatii 100 qabaate faankishiniin kun gatii 100 kenna.

=OFFSET(B2:C3;1;1) wabii B2:C3 tarree 1 fi tarjaa tokkoon gad hiiqe gara mirgaatti (C3:D4) kenna.

=OFFSET(B2:C3;-1;-1) wabii B2:C3 tarree 1 fi tarjaa tokkoon ol hiiqe gara bitaatti (A1:B2) kenna.

=OFFSET(B2:C3;0;0;3;4) wabii B2:C3 tarreewwan 3 fi tarjaawwan 4 (B2:E4)tti irra deebi'anii hamamtooman kenna.

=OFFSET(B2:C3;1;0;3;4) wabii B2:C3 tarree tokko gara tarreewwan 3 fi tarjaawwan 4tti irra deebi'ee hamamtoomeetiin (B2:E4) gara gadiitti hiiqe kenna.

=SUM(OFFSET(A1;2;2;5;6)) dimshaasha bal'inaa mandhee C3 keessatti jalqabu murteessa dabalataanis hojjaa tarreewwan 5 fi dalgee tarjaawwan 6 qaba (bal'ina=C3:H7).

ROW

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

ROW([Reference])

wabiin man'ee tokko, iddoo, ykn maqaa iddooti.

Yoo wabii hin agarsiisnee ta'e, lakkoofsi tarree mandhee foormulaan keessa seene ni argama. LibreOffice Calciin wabii ofumaan gara mandhee ammeetti qindeessa.

=ROW(B3) 3 deebisa sababni isaas wabiin tarree sadaffaa gabatee keessaa agarsiisa.

{=ROW(D5:D8)} waraantoo tarjaa-qeenxee (5, 6, 7, 8) deebisa sababni isaas wabiin adda ba'e tarreewwan 5 hanga 8 of keessatti qabata.

=ROW(D5:D8) 5 deebisa sababni isaaas faankishiniin ROW akka foormulaa waraantootti hin fayyadu dabalataanis lakkoofsi tarree jalqabaa wabii qofti ni deebi'a.

{=ROW(A1:E1)} fi =ROW(A1:E1) lamaan isaaniyyu 1 deebisu sababni isaas wabiin gabatee keessatti akka tarjaa jalqabaatti tarree 1 qofa qabata. (Sababni isaas naannoowwan tarree-qeenxee lakkoofsa tarree tokkoo formulaan akka foormulaa waraantootti fayyadus fayyaduu baatus garaagarummaa hin uumne qofa qaba.)

=ROW() yoo foormulaan tarree 3 keessa seene 3 deebisa.

{=ROW(Hilleensi)} yoo "Hilleensi" maqaa naannoo (C1:D3) ta'e waraantoo tarjaa-qeenxee (1, 2, 3) deebisa.

ROWS

Lakkoofsa tarreewwanii wabii ykn waraantoo keessaa deebisa.

ROWS(Waraantoo)

Waraantoon wabii ykn naannoo maqaan itti moggaafame lakkoofsi dimshaashaa tarreewwan isaa murtaa'uu qabudha.

=Rows(B5) 1 deebisa sababni isaas mandheen tarree tokko qofa qabata.

=ROWS(A10:B12) 3 deebisa.

=ROWS(Hilleensi) Yoo "Hilleensi" maqaa naannoo (C1:D3) ta'e 3 deebisa.

SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

SHEET([Reference])

Wabiin dirqalaa fi mandheef, naannoof, ykn diraa maqaa wardiidhaaf wabiidha.

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

SHEETS

Lakkoofsa wardiiwwanii wabii keessa jiran murteessa. Yoo ulaagaalee kamiyyu hin galchine ta'e, lakkoofsa wardiiwwanii galmee ammee keessa jiran kenna.

SHEETS([Reference])

Wabiin wabii wardii ykn naannoo ti. Ulaagaan kun dirqaladha.

=SHEETS(Sheet1.A1:Sheet3.G12) yoo wardii1, wardii2, fi wardii3 akka tartiiba agarsiifameetti jiraatan 3 kenna.

VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Kasaan lakkoofsa tarjaa waraantoo keessa jiru kan gatii kennamuu qabu of keessatti qabatudha. Tarjaan jalqabaa lakkoofsa 1 qaba.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Foormulaa armaan gadii B1 keessa galchi:

=VLOOKUP(A1;D1:E100;2)

Akkuma lakkoofsa A1 keessa galchiteen B1 barruu tarjaa lammaffaa wabii D1:E100 keessa jiru agarsiisa. Lakkoofsa hin jirre galchuun barruu lakkoofsa gadii itti aanu wajjiin mul'issa. Kana ittisuuf, foormulaa keessatti akka ulaagaa dhumaatti SOBA galchi kanaafuu yeroo lakkoofsi hin jirre seenu ergaan dogongoraa ni uumama.