SUMMER.VISS.SETT (SUMIFS på engelsk)

Returnerer summen av celleverdiane i eit område som oppfyller fleire kriteria i fleire område.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.0.

Syntaks

MAKSVISS.SANN(Funksjonsområde; Område1; Kriterium1[; Område2; Kriterium2[; … ;[Område127; Kriterium127]])

Funksjonsområde – nødvendig argument. Dette kan vera eit celleområde, namnet på eit namngjeve område eller etiketten på ei rad eller ein kolonne som inneheld verdiar som vert brukte for å rekna ut summen.

Område1 – nødvendig argument. Det er eit celleområde, eit namn på eit namngjeve område eller ein etikett for ein kolonne eller ei rad, som det tilsvarande kriteriet skal brukast til.

Kriterium: Et kriterium er ei enkelt cellereferanse, tal eller tekst. Det vert brukt i samanlikningar med celleinnhald.

Ein referanse til ei tom celle vert tolka som talverdien 0.

Eit samsvarande uttrykk kan vera:

Eit tal eller ein logisk verdi. Eit samsvarande celleindhald er lik med talet eller den logiske verdien.
Ein verdi som byrjar med ein komparator (<, <=, =, >, >=, <>).

For =, viss verdien er tom, samsvarar tomme celler.

For <>, viss verdien er tom, samsvarar ikkje-tomme celler.

For <>, viss verdien ikkje er tom, samsvarar kva celleinnhald som helst, unnateke verdien, inkludert tomme celler.

Merk: «=0» finn ikkje tomme celle.

For = og <>: viss verdien ikkje er tom og ikkje kan tolkast som ein taltype eller ein av undertypane og eigenskapen Søkjevilkåra = og <> må gjelda for hele celler er merkt, skjer samanlikninga med heile celleinnhaldet. Viss det ikkje er merkt av for dette alternativet, skjer samanlininga mot kva underdel av feltet som helst som samsvarar med vilkåra. For = og <>: viss verdien ikkje er tom og ikkje kan tolkast som ein taltype, eller viss undertypane gjeld.
Annan tekstverdi. Viss eigenskapen Søkjekriterium = og <> skal gjelda heile celler er sann, skjer samanlikninga med heile celleindhald. Viss usann, skjer samanlikninga med kvar delmengde av feltet som helst som svarar til kriteria. Uttrykket kan innehalde tekst, tal, uttrykk eller jokerteikn ( viss desse er slått på i innstillingane for utrekningar).

Område2 – Valfri. Område2 og alle dei følgjande tyder det same som Område1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfølgjande kriteria betyr det same som Kriterium1.

Søkinga har støtte for jokerteikn eller regulære uttrykk. Med regulære uttrykk slått på, kan du for eksempel skriva inn «all.*» for å finna den første staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal søkja etter ein tekst som også er eit regulært uttrykk, må du anten skriva bakoverstrek (\) framføre kvar operator eller kvart metateikn eller du må lukka inn teksten mellom «\Q» og «\E». Du kan slå den automatiske evalueringa av jokerteikn og regulære uttrykk av eller på frå i → LibreOffice Calc → Rekn ut.

Når du brukar funksjonar der eitt eller fleire argument er søkjekriterium som representerer eit regulært uttrykk, vert det først prøvd å konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og så vidare. Viss dette går bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. Når du brukar eit språk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulære uttrykk fungera. For å tvinga evalueringa av det regulære uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».

Funksjonsområde og Område1, Område2 … må vera av same storleik. Elles returnerer funksjonen feil:502 - ugyldig argument.

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frå den tilsvarande cella i det gjevne Funksjons_område tekne med i utrekningane.

Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieområde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)

Eksempel

Studer denne tabellen

	A	B	C
1	Produktnamn	Sal	Inntekt
2	blyant	20	65
3	penn	35	85
4	notisblokk	20	190
5	bok	17	180
6	penal	ikkje	ikkje

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.

Enkel bruk

=SUMMER.VISS.SETT(B2:B6;B2:B6;">=20")

Reknar ut summen av verdiane i område B2:B6 som er større enn eller lik 20. Returnerer 75 fordi den femte rada ikkje oppfyller kriteriet.

=SUMMER.VISS.SETT(C2:C6;B2:B6;">=20";C2:C6;">70")

Reknar ut summen av verdiane i område C2:C6 som er større enn 70 og som svarar til cellene i området B2:B6 med verdiar større enn eller lik 20. Returnerer 275 fordi den andre og femte rada ikkje oppfyller minst eitt av kriteria.

Bruka regulære uttrykk og nøsta funksjonar

=SUMMER.VISS.SETT(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Reknar ut summen av verdiane i område C2:C6 som svarar til alle verdiane i område B2:B6 unntatt den største og minste verdien. Returnerer 255 fordi den tredje og fjerde rada ikkje oppfyller minst eitt av kriteria.

=SUMMER.VISS.SETT(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Reknar ut summen av verdiane i område C2:C6 som svarar til alle verdiane i område A2:A6 som byrjar med «pen» og for alle cellene i området B2:B6 unntatt maksimum. Returnerer 65 fordi berre den andre rada oppfyller alle kriteria.

Referanse til ei celle som kriterium

Dersom du ønskjer å lett kunna endra eit kriterium, kan du skrive dette inn i ei eige celle og bruke ein referanse til denne cella som kriterium i funksjonen SUMMER.VISS.SETT. For eksempel kan funksjonen ovanfor skrivast slik:

=SUMMER.VISS.SETT(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Viss E2 = pen vil funksjonen returnera 65 fordi lenkja til cella er bytt ut med innhaldet.

Opna fil med eksempel:

SUMIFS (SUMMER.VISS.SETT) wikiside.

SUMMER, SUMMER.VISS (SUMIF på engelsk)

TEL.VISS.SETT-funksjonen, MINVISS.SANN, MAKSVISS.SANN, GJENNOMSNITT.VISS.SETT, SUMMER.VISS.SETT (SUMIFS på engelsk)

Liste over regulære uttrykk