MINVISS.SANN-funksjonen

Returnerer minimum av celleverdiane i eit område som oppfyller fleire kriterium i fleire område.

tip

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 5.2.


Syntaks

MINVISS.SANN(Funksjonsområde; Område1; Kriterium1[; Område2; Kriterium2[; … ;[Område127; Kriterium127]])

Funksjonsområde – nødvendig argument. Dette kan vera eit celleområde, namnet på eit namngjeve område eller etiketten på ei rad eller ein kolonne som inneheld verdiar som vert brukte for å rekna ut minimum.

Område1 – nødvendig argument. Det er eit celleområde, eit namn på eit namngjeve område eller ein etikett for ein kolonne eller ei rad, som det tilsvarande kriteriet skal brukast til.

Kriterium1 må ha eit argument. Eit strenguttrykk som representerer eit logisk vilkår eller ein cellereferanse til eit slikt uttrykk. Uttrykket kan innehalda tekst, tal, regulære uttrykk eller jokerteikn (viss det er opna for desse i innstillingane for utrekningane).

Område2 – Valfri. Område2 og alle dei følgjande tyder det same som Område1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfølgjande betyr det same som Kriterium1.

Søkinga har støtte fpr jokerteikn eller regulære uttrykk. Med regulære uttrykk slått på, kan du for eksempel skriva inn «all» for å finna den første staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal søkja etter ein tekst som også er eit regulært uttrykk, må du skriva bakoverstrek (\) framføre kvart teikn eller du må lukka inn teksten mellom «\Q» og «\E». Du kan slå den automatiske evalueringa av jokerteikn og regulære uttrykk av eller på frå i → LibreOffice Calc → Rekn ut.

warning

Når du brukar funksjonar der eitt eller fleire argument er søkjekriterium som representerer eit regulært uttrykk, vert det først prøvd å konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og så vidare. Viss dette går bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. Når du brukar eit språk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulære uttrykk fungera. For å tvinga evalueringa av det regulære uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Funksjonsområde og Område1, Område2 … må vera av same storleik. Elles returnerer funksjonen feil:502 - ugyldig argument.

note

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frå den tilsvarande cella i det gjevne Funksjons_område tekne med i utrekningane.


Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieområde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

note

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)


Eksempel

Studer denne tabellen

A

B

C

1

Produktnamn

Sal

Inntekt

2

blyant

20

65

3

penn

35

85

4

notisblokk

20

190

5

bok

17

180

6

penal

ikkje

ikkje


warning

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.


Enkel bruk

=MINVISS.SANN(B2:B6;B2:B6;"<35")

Reknar ut minimum for verdiane i området B2:B6, som er mindre enn eller lik 20. Returnerer 17.

=MINVISS.SANN(C2:C6;B2:B6;">=20";C2:C6;">90")

Reknar ut minimum for verdiane i området C2:C6 som er mindre end 90 og samsvarar med celler i området B2:B6 som har verdiar større enn eller lik 20. Returnerer 190.

Bruka regulære uttrykk og nysta funksjonar

=MINVISS.SANN(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Reknar ut minimum for verdiane i område C2:C6 som svarar til alle verdiane i område B2:B6 unntatt den største og minste verdien. Returnerer 65.

=MINVISS.SANN(C2:C6;A2:A6;".*book";B2:B6;"<="&MAKS(B2:B6))

Reknar ut minimum for verdiane i område C2:C6 som svarar til alle cellene i område A2:A6 som byrjar på «penn» og til alle cellene i området B2:B6 unntatt minimumsverdien. Returnerer 180.

Referanse til ei celle som kriterium

Har du bruK for å endra eit kriterium på ein enkel måte, kan du skriva det inn i ei ledig celle og bruka ein referanse til denne cella i vilkåret for MINVISS.SANN-funksjonen. For eksempel kan funksjonen ovanfor skrivast slik:

=MAKSVISS.SANN(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAKS(B2:B6))

Viss E2 = "bok", vil funksjonen returnera 180 fordi lenkja til cella er bytt ut med innhaldet.

Opna fil med eksempel:

Støtt oss!