TEL.VISS.SETT-funksjonen

Returnerer kor mange celler som oppfyller kriteria i fleire område.

tip

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.0.


Syntaks

TEL.VISS.SETT(Område; Kriterium[; Område2; Kriterium2][; … ; [Område127; Kriterium127]])

Område1 – nødvendig argument. Det er eit celleområde, eit namn på eit namngjeve område eller ein etikett for ein kolonne eller ei rad, som det tilsvarande kriteriet skal brukast til.

Kriterium: Et kriterium er ei enkelt cellereferanse, tal eller tekst. Det vert brukt i samanlikningar med celleinnhald.

Ein referanse til ei tom celle vert tolka som talverdien 0.

Eit samsvarande uttrykk kan vera:

Område2 – Valfri. Område2 og alle dei følgjande tyder det same som Område1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfølgjande kriteria betyr det same som Kriterium1.

Søkinga har støtte for jokerteikn eller regulære uttrykk. Med regulære uttrykk slått på, kan du for eksempel skriva inn «all.*» for å finna den første staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal søkja etter ein tekst som også er eit regulært uttrykk, må du anten skriva bakoverstrek (\) framføre kvar operator eller kvart metateikn eller du må lukka inn teksten mellom «\Q» og «\E». Du kan slå den automatiske evalueringa av jokerteikn og regulære uttrykk av eller på frå i → LibreOffice Calc → Rekn ut.

warning

Når du brukar funksjonar der eitt eller fleire argument er søkjekriterium som representerer eit regulært uttrykk, vert det først prøvd å konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og så vidare. Viss dette går bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. Når du brukar eit språk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulære uttrykk fungera. For å tvinga evalueringa av det regulære uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Funksjonsområde og Område1, Område2 … må vera av same storleik. Elles returnerer funksjonen feil:502 - ugyldig argument.

note

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frå den tilsvarande cella i det gjevne Funksjons_område tekne med i utrekningane.


Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieområde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

note

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)


Eksempel

Studer denne tabellen

A

B

C

1

Produktnamn

Sal

Inntekt

2

blyant

20

65

3

penn

35

85

4

notisblokk

20

190

5

bok

17

180

6

penal

ikkje

ikkje


warning

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.


Enkel bruk

=TEL.VISS.SETT(B2:B6;">=20")

Tel kor mange rader i området B2:B6 som har verdiar større enn eller lik 20. Returnerer 3 fordi den femte og sjette rada ikkje oppfyller kriteria.

=TEL.VISS.SETT(B2:B6;">=20";C2:C6;">70")

Tel kor mange rader i området C2:C6 som samtidig har verdiar større enn 70 og verdiar større enn eller lik 20 i området B2:B6. Returnerer 2 fordi den andre, femte og sjette rada ikkje oppfyller minst eitt kriterium.

Bruka regulære uttrykk og nøsta funksjonar

For at desse eksempla skal verka slik som omtalt, sjå etter at det er merkt av for Bruk regulære uttrykk i formlar is selected in → LibreOffice Calc → Rekn ute.

=TEL.VISS.SETT(B2:B6;"[:alpha:]*")

Tel kor mange rader i området B2:B6 som inneheld alfabetsymbol. Returnerer 1 fordi berre den sjette rada oppfyller kriteriet.

=TEL.VISS.SETT(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Tel kor mange rader det er i området B2:B6. Reknar ikkje med rader som inneheld maksimums- og minimumsverdien i dette området. Returnerer 2 fordi den tredje, femte og sjette rada ikkje oppfyller minst eitt kriterium.

=TEL.VISS.SETT(A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Tel kor mange rader som samsvarar med alle cellene i området A2:A6 som byrjar med «pen» og alle cellene i området B2:B6 unntatt dei som inneheld minimum. Returnerer 1 fordi berre den andre rada oppfyller alle kriteria.

Referanse til ei celle som kriterium

Dersom du ønskjer å lett kunna endra eit kriterium, kan du skrive dette inn i ei eige celle og bruke ein referanse til denne cella som kriterium i funksjonen TEL.VISS.SETT. For eksempel kan funksjonen ovanfor skrivast slik:

=TEL.VISS.SETT(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Viss E2 = pen vil funksjonen returnera 1 fordi lenkja til cella er bytt ut med innhaldet og såleis verkar som funksjonen ovanfor.

Opna fil med eksempel:

Støtt oss!