GJENNOMSNITT.VISS-funksjonen
Returnerer det aritmetiske gjennomsnittet for alle cellene i eit område som oppfyller eit gjeve vilkår. Funksjonen GJENNOMSNITT.VISS summerer alle resultata som høver til den logiske testen og deler denne summen med talet på dei merkte cellene.
GJENNOMSNITT.VISS(Område; Kriterium [; Gjennomsnitt_område])
Område – nødvendig argument. Kan vere ei matrise, namnet på eit namngjeve område eller etiketten til ei rad eller ein kolonne som inneheld tal som det skal finnast gjennomsnitt for, eller tal eller tekst for vilkåret.
Søkinga har støtte for jokerteikn eller regulære uttrykk. Med regulære uttrykk slått på, kan du for eksempel skriva inn «all.*» for å finna den første staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal søkja etter ein tekst som også er eit regulært uttrykk, må du anten skriva bakoverstrek (\) framføre kvar operator eller kvart metateikn eller du må lukka inn teksten mellom «\Q» og «\E». Du kan slå den automatiske evalueringa av jokerteikn og regulære uttrykk av eller på frå i.
Når du brukar funksjonar der eitt eller fleire argument er søkjekriterium som representerer eit regulært uttrykk, vert det først prøvd å konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og så vidare. Viss dette går bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. Når du brukar eit språk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulære uttrykk fungera. For å tvinga evalueringa av det regulære uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».
Gjennomsnitt_område – valfritt. Det er eit område med verdiar som gjennomsnittet skal reknast ut for.
Viss Gjennomsnitt_område ikkje er spesifisert, vert Område brukt for begge, både for utrekning av gjennomsnitt og for søkjet i høve til vilkåret. Gjennomsnitt_områdeiss Gjennomsnitt_område er oppgjeve, vert Område brukt berre for vilkårstesten medan Gjennomsnitt_område vert brukt for å rekna ut gjennomsnittet.
Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)
Dersom ei celle i eit område det skal reknast ut gjennomsnitt for er tom, vil funksjonen GJENNOMSNITT.VISS ignorere denne cella.
Dersom heile området er tomt, inneheld berre tekst eller at ingen av cellene i området oppfyller vilkåret, vil funksjonen returnera feilen #DIV/0.
Studer denne tabellen
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
Produktnamn |
Sal |
Inntekt |
|
2 |
blyant |
20 |
65 |
|
3 |
penn |
35 |
85 |
|
4 |
notisblokk |
20 |
190 |
|
5 |
bok |
17 |
180 |
|
6 |
penal |
ikkje |
ikkje |
Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.
Enkel bruk
=GJENNOMSNITT.VISS(B2:B6;"<35")
Reknar ut gjennomsnittet for verdiane i område B2:B6 som er mindre enn 35. Returnerer 19 fordi den andre rada ikkje vert teke med i utrekninga.
=GJENNOMSNITT.VISS(B2:B6;"<"&MAKS(B2:B6))
Reknar ut gjennomsnittet for verdiane som er mindre enn maksimumsverdien i det same område. Returnerer 19 fordi den største verdien (den andre rada) ikkje vert teke med i utrekninga.
=GJENNOMSNITT.VISS(B2:B6;">"&MINST(B2:B6;1))
Reknar ut gjennomsnittet for verdiane som er større enn den første minste verdien i det same område. Returnerer 25 fordi den første minsteverdien (den fjerde rada) ikkje vert teke med i utrekninga.
Bruk av Gjennomsnitt_område
=GJENNOMSNITT.VISS(B2:B6;"<35";C2:C6)
Funksjonen leitar i området B2:B6 etter verdiar som er mindre enn 35 og reknar ut gjennomsnittet av dei tilsvarande verdiane i området C2:C6. Returnerer 145 fordi den andre rada ikkje vert teke med i utrekninga.
=GJENNOMSNITT.VISS(B2:B6;">"&MIN(B2:B6);C2:C6)
Funksjonen leitar i området B2:B6 etter verdiar som er større enn den minste verdien i område B2:B6 og reknar ut gjennomsnittet av dei tilsvarande verdiane i området C2:C6. Returnerer 113,3 fordi den fjerde rada (som inneheld den minste verdien i området B2:B6) ikkje vert teke med i utrekninga.
=GJENNOMSNITT.VISS(B2:B6;"<"&STØRST(B2:B6;2);C2:C6)
Funksjonen leitar i området B2:B6 etter verdiar som er mindre enn den nest største verdien i området B2:B6 og reknar ut gjennomsnittet av dei tilsvarande verdiane i området C2:C6. Returnerer 180 fordi berre den fjerde rada vert teke med i utrekninga.
Bruka regulære uttrykk
=GJENNOMSNITT.VISS(A2:A6;"pen";B2:B6)
Funksjonen leitar i området A2:A6 etter ordet «pen» og reknar ut gjennomsnittet av dei tilsvarande verdiane i området C2:C6. Returnerer 35 fordi berre den andre rada vert teke med i utrekninga. Søket vert gjort i området A2:A6, men verdiane vert henta i området B2:B6.
=GJENNOMSNITT.VISS(A2:A6;"pen.*";B2:B6)
Funksjonen leitar i området A2:A6 etter ord som byrjar med «pen» og reknar ut gjennomsnittet av dei tilsvarande verdiane i området B2:B6. Returnerer 27,5 fordi nå oppfyller også «pennen» vilkåret slik at både den første og den andre rada vert rekna med.
=GJENNOMSNITT.VISS(A2:A6;".*bok.*";B2:B6)
Funksjonen leitar i området A2:A6 etter ord som inneheld ordet «bok» og reknar ut gjennomsnittet av dei tilsvarande verdiane i området B2:B6. Returnerer 18,5 fordi nå vert berre tredje og fjerde rada rekna med.
Referanse til ei celle som kriterium
Dersom du ønskjer å lett kunna endra eit kriterium, kan du skrive dette inn i ei eige celle og bruke ein referanse til denne cella som kriterium i funksjonen GJENNOMSNITT.VISS.
=GJENNOMSNITT.VISS(A2:A6;".*"&E2&".*";B2:B6)
Funksjonen leitar i området A2:A6 etter ord som inneheld ein kombinasjon av teikn spesifiserte i E2 og reknar ut gjennomsnittet av dei tilsvarande verdiane i området B2:B6. Dersom E2 = bok, vil funksjonen returnera 18,5.
=GJENNOMSNITT.VISS(B2:B6;"<"&E2;C2:C6)
Funksjonen leitar i området A2:A6 etter verdiar som er mindre enn verdien sett i E2 og reknar ut gjennomsnittet av dei tilsvarande verdiane i området B2:B6. Dersom E2 = 35 vil funksjonen returnera 145.