Reknearksfunksjonar

Dette avsnittet inneheld ein omtale av reknearksfunksjonar med eksempel.

FEIL.TYPE

Returnerer eit tal som viser feiltypen eller feilverdien #I/T dersom det ikkje er feil.

STYLE

Brukar ein stil på cella som inneheld formelen.

ADRESSE (ADDRESS på engelsk)

Returnerer ei celleadresse (referanse) som tekst i samsvar med dei oppgjevne rad- og kolonnenummera. Du kan finna ut om adressa er tolka som ei absolutt adresse (for eksempel $A$1), relativ adresse (A1) eller i blanda form (A$1 eller $A1). Du kan òg oppgje namnet på reknearket.

Av omsyn til interoperabiliteten har funksjonane ADRESSE og INDIREKTE ein valfri parameter for å indikere om R1C1-adresse-notasjonen kan brukast i staden for den vanlege A1-notasjonen.

I ADRESSE, vert parameteren sett inn som den fjerde parameteren, som flytter den valfrie arknamn-parameteren til den femte plasseringa.

I INDIREKTE er parameteren lagt til som den andre parameteren.

I begge funksjonane vert R1C1-notasjonen brukt viss argumentet vert sett inn med verdien 0. Viss argumentet ikkje er gjeve eller har ein annan verdi enn 0, så vert A1-notasjonen brukt.

Viss R1C1-notasjonen er brukt, returnerer ADRESSE strengar som brukar utropsteikn (!) som skiljeteikn for arknamnet og INDIREKTE ventar utropsteiknet som skiljeteikn for arknamn. Begge funksjonane brukar framleis punktum (.) som skiljeteikn for arknamn med A1-notasjon.

Når du opnar dokument frå ODF 1.0/1.1-format der ADRESSE-funksjonen viser eit arknamn som den fjerde parameteren, vert dette endra slik at arknamnet vert den femte parameteren. Det vert sett inn ein ny fjerde parameter med verdien 1.

Når du lagrar eit dokument i ODF 1.0/1.1-format, vert den fjerde parameteren i ADRESSE-funksjonen fjerna.

ADRESSE(Rad; Kolonne[; Abs[; A1[; "Ark"]]])

Rad svarar til radnummeret for cellereferansen

Kolonne svarar til kolonnenummeret for cellereferansen (talet, ikkje bokstaven)

Abs bestemmer referansetypen:

1: absolutt ($A$1)

2: radreferansetypen er absolutt; kolonnereferansen er relativ (A$1)

3: rad (relativ); kolonne (absolutt) ($A1)

4: relativ (A1)

A1 (valfri) – viss sett til 0, vert notasjonen R1C1 brukt. Viss parameteren manglar eller er sett til ein annan verdi enn 0, vert notasjonen A1 brukt.

Ark svarar til namnet på arket. Det må vera plassert i dobbelt hermeteikn (" ").

Eksempel:

=ADRESSE(1; 1; 2; "Ark2") returnerer dette: Ark2.A$1

Viss formelen ovanfor er i cella B2 det gjeldande arket og cella A1 i ark 2 inneheld verdien -6, kan du referera indirekte til den refererte cella ved å skriva inn =ABS(INDIREKTE(B2)). Resultatet er den absolutte verdien av cellereferansen som er vist i B2, som i dette tilfelle er 6.

ARK (SHEET på engelsk)

Returnerer arknummeret til ein referanse eller ein tekst som representerer eit arknamn. Dersom du ikkje skriv inn parametrar, vert resultatet arknummeret til reknearket som inneheld formelen.

ARK([Referanse])

Referanse er valfri og er referansen til ei celle, eit område eller eit arknamn.

=ARK( Ark2.A1) returnerer 2 viss Ark2 er det andre arket i reknearkdokumentet.

=ARK( "Ark3") returnerer 3 viss Ark3 er det tredje arket i reknearkdokumentet.

DDE

Gjev resultatet av ei DDE-basert lenkje. Dersom innhaldet i det lenkja områder vert endra, vert òg resultatet endra. Du må lasta reknearket på nytt eller velja Rediger → Lenkjer for å sjå dei oppdaterte lenkjene. Lenkjer frå ei plattform til ei anna er ikkje tillate, for eksempel frå ein installasjon av LibreOffice på ein Windows-maskin til eit dokument oppretta på ein Linux-maskin.

DDE("Tenar"; "Fil"; "Område"[; Modus])

Tenar er namnet på eit tenarprogram. Programma for LibreOffice har tenarnamnet «soffice».

Fil er det fullstendige filnamnet medrekna filstien.

Område er området som inneheld data som skal validerast.

Modus er ein valfri parameter som bestemmer kva metode som DDE-tenaren brukar for å gjera om data til tal.

Modus	Effekt
0 eller manglande	Talformat frå cellestilen «Standard»
1	Data vert alltid tolka som standard US engelsk-format.
2	Data vert henta som tekst; inga omgjering til tal.

=DDE("soffice"; "c:\Kontor\dokument\data1.sxc"; "ark1.A1") les celleinnhaldet i celle A1 i ark1 frå LibreOffice Calc-reknearket data1.ods.

=DDE("soffice";"c:\Kontor\dokument\motto.sxw";"Dagens Motto") returnerer eit motto i den cella som inneheld denne formelen. Først må du skriva inn ei linje i dokumentet motto.sxw som inneheld mottoteksten og definera ho som den første linja av ein bolk med namnet Dagens Motto (i LibreOffice Writer under Set inn → Bolk). Viss mottoet vert endra (og lagra) i LibreOffice Writer-dokumentet, vert mottoet oppdatert i alle LibreOffice Calc cellene der denne DDE-lenkja er definert.

FEILTYPE (ERRORTYPE på engelsk)

Returnerer talet som svarar til ein feilverdi som oppstod i ei anna celle. Ved å bruka dette talet kan du visa ei feilmelding.

FEILTYPE(Referanse)

Referanse inneheld adressa til den cella som feilen oppstår i.

Viss celle A1 viser Err:518, returnerer funksjonen =FEILTYPE(A1) talet 518.

ORG.OPENOFFICE.ERRORTYPE

FINN.KOLONNE (HLOOKUP på engelsk)

Søkjer etter ein verdi og ein referanse til cellene nedanfor det merkte området. Stadfestar om den første rada i ei matrise inneheld ein viss verdi. Gjev verdien til ei rad i matrisa avgjort av Indeksen i same kolonne.

FINN.KOLONNE(Søkjeverdi; Matrise; Indeks[; SortertOmråde])

Du kan finna ei forklaring på parameterane i FINN.RAD (kolonnar og rader må byta plass)

Gå ut frå at vi har laga ein liten databasetabell i celleområdet A1:DO4 som inneheld grunnopplysningar om 118 kjemiske element. Den første kolonnen inneheld radoverskriftene «Element», «Symbol», «Atomnummer» og «Relativ atommasse». Dei neste kolonnane inneheld dei relevante opplysningane for kvart element, ordna frå venstre mot høgre etter atomnummer. Cellene B1:B4 inneheld for eksempel «Hydrogen», «H», «1» og «1,008», medan cellene DO1:DO4 inneheld «Oganesson», «Og», «118» og «294».

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomnummer	1	2	3	...	118
4	Relativ atommasse	1.008	4.0026	6.94	...	294

=FINN.KOLONNE("Bly"; $A$1:$DO$4; 2; 0) returnerer «Pb» som er symbolet for bly.

=FINN.KOLONNE("Gull"; $A$1:$DO$4; 3; 0) returnerer 79, atomnummeret for gull.

=FINN.KOLONNE("Karbon"; $A$1:$DO$4; 4; 0) returnerer 12,011, relativ atommasse for karbon.

FINN.RAD (VLOOKUP på engelsk)

Loddrett søking med tilvising til tilstøytane celler til høgre. Denne funksjonen kontrollerer om ein bestemt verdi finst i den første kolonnen i ei matrise. Funksjonen returnerer så verdien i den same rada i kolonnen som er namngjeven i Indeks. Viss parameteren Sortert manglar eller er sett til SANN, vert dataa sorterte i stigande rekkjefølgje. Viss det eksakte oppslag ikkje vart funne, vert den siste verdien som er mindre enn kriteriet returnert. Viss Sortert er sett til USANN eller null, må der vera eit eksakt samanfall, elles vert feilen Feil: Verdi ikkje tilgjengeleg (#I/T) returnert. Med ein verdi på null treng dataa ikkje vera sorterte stigande.

=FINN.RAD(Oppslag; Matrise; Indeks[; SortertOmrådeOppslag])

Oppslag er verdien av kva type som helst som det vert sett etter i den første kolonnen i matrisa.

Matrise er referansen som skal innehalda minst så mange kolonnar som det er ført opp i Indeks-argumentet.

Indeks er kolonnenummeret i området som inneheld verdien som skal returnerast. Den første kolonnen har talet 1.

SortertOmråde er ein valfri parameter som indikerer om den første kolonnen i matrisa inneheld områdegrenser i staden for vanlege verdiar. I denne modusen returnerer uttrykket verdien i rada med den første kolonnen som har ein verdi som er lik eller mindre enn oppslag. Den kan for eksempel innehalde datoar når nokre MVA-verdiar er endra når verdiane representerer startdatoar for ein periode når ein bestemt MVA-verdi var brukt. Eit søk etter ein dato som manglar i den første matrisekolonnen, men er mellom nokre eksisterande grensedatoar, vil returnera den lågaste av dei slik at det er råd å finna dataa som høver til den søkte datoen. Bruk USANN eller null viss den første kolonnen ikkje inneheld områdegrenser. Når denne parameteren er sann eller ikkje gjeven, må den første kolonnen i matrisen vera sortert i stigande rekkjefølgje. Ei søk i sorterte kolonnar går mykje raskare og funksjonen returnerer alltid ein verdi, sjølv om søkjeverdien ikkje samsvarar nøyaktig, viss han er større enn den lågaste verdien i den sorterte lista. I usorterte lister må søkjeverdien samsvara nøyaktig elles vil funksjonen returnera #I/T med meldinga Feil: verdi ikkje tilgjengeleg .

Du ønskjer å skriva inn nummeret på ein rett i cella A1 og at namnet på den valde retten skal visast i nabocella B1 med ein gong. Verdien til konverteringa frå nummer til namn finst i området D1:E100. D1 inneheld 100, E1 inneheld namnet Grønnsakssuppe og så vidare opp til 100 menyoppføringar Tala i kolonne D er sorterte i stigande rekkjefølgje, difor er den valfrie parameteren Sortert ikkje nødvendig.

Skriv inn denne formelen i B1:

=FINN.RAD(A1; D1:E100; 2)

Så snart du skriv inn eit tal i A1 vil B1 visa den teksten som ligg i den andre kolonnen i referansen D1:E100. Skriv du inn eit tal som ikkje finst, vil teksten tilsvarande det neste talet i rada verta vist. Dette kan du forhindra ved å skriva inn USANN som den siste parameteren i formelen. Det vil då verta vist ei feilmelding om ikkje-eksisterande tal vert skrivne inn.

FORSKYVING (OFFSET på engelsk)

Returnerer verdien av ei celle som ligg eit visst tal på rader og kolonnar frå eit gjeve referansepunkt.

FORSKYVING(Referanse; Rader; Kolonnar[; Høgd[; Breidd]])

Referanse er cella som funksjonen leitar etter den nye referansen frå.

Rader er talet på rader som referansen vart korrigert oppover (negativ verdi) eller nedover med. Bruk 0 for å verta verande i den same rada.

Kolonnar er talet på kolonnar som referansen vart korrigert til venstre (negativ verdi) eller til høgre. Bruk 0 for å bli i den same kolonnen.

Høgd (valfri) er den loddrette høgda på eit område som byrjar ved den nye referanseposisjonen.

Breidd (valfri) er den vassrette breidda på eit område som byrjar ved den nye referanseposisjonen.

Argumenta Høgd og Breidd kan ikkje resultera i null eller negativ startrad eller startkolonne.

Argumenta Høgd og Breidd kan ikkje resultera i null eller negativt tal på rader eller kolonnar.

I funksjonane i LibreOffice Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein påfølgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

=FORSKYVING(A1; 2; 2) returnerer verdien i celle C3 (A1 flytt to rader og to kolonnar nedover). Viss C3 inneheld verdien 100 returnerer denne funksjonen verdien 100.

=FORSKYVING(B2:C3;1;1) returnerer ein referanse til B2:C3 flytt 1 rad ned og 1 kolonne til høgre (C3:D4).

=FORSKYVING(B2:C3;-1;-1) returnerer ein referanse til B2:C3 flytt 1 rad opp og ein kolonne til venstre (A1:B2).

=FORSKYVING(B2:C3;0;0;3;4) returnerer ein referanse til B2:C3 med storleiken endra til 3 rader og 4 kolonnar (B2:E4).

=FORSKYVING(B2:C3;1;0;3;4) returnerer ein referanse til B2:C3 flytt ei rad ned og med storleiken endra til 3 rader og 4 kolonnar (B3:E5).

=SUMMER(FORSKYVING(A1;2;2;5;6)) bestemmer summen av området som startar i celle C3 og har ei høgd på 5 rader og ei breidd på 6 kolonnar (område=C3:H7).

HENTPIVOTDATA (GETPIVOTDATA på engelsk)

Funksjonen HENTPIVOTDATA returnerer ein resultatverdi frå ein pivottabell. Verdien vert adressert ved hjelp av felt- og elementnamna slik at adresseringa framleis er gyldige sjølv om oppbyggjinga av pivottabellen vert endra.

To ulike syntaksdefinisjonar kan brukast:

HENTPIVOTDATA(Målfelt; pivottabell[; Felt 1; Element 1][; ... [Felt 126; Element 126]])

eller

HENTPIVOTDATA(pivottabell;vilkår)

Den andre syntaksen vert brukt viss nøyaktig to parameter er gjevne, der den første parameteren er ein referanse til ei celle eller eit celleområde. I alle andre tilfelle vert den første syntaksen brukt. Funksjonsvegvisaren viser det første syntaksen.

Første syntaks

Målfelt er ein tekststreng som vel eit av datafelta i pivottabellen. Tekststrengen kan vera namnet på kjeldekolonnen eller namn på datafeltet som vert vist i tabellen ("Summer → Sal").

pivottabell er ein referanse til ei celle eller eit celleområde som er plassert inne i ein pivottabell eller som indeheld ein pivottabell. Viss celleområdet inneheld fleire pivottabellar, vert den sist brukte pivottabellen brukt.

Viss det ikkje er oppgjeve noko Felt n / Element n par, vert totalen returnert. Elles utgjer kvart par vilkår som må oppfyllast. Felt n er namnet på eit felt frå pivottabellen. Element n er namnet på eit element frå dette feltet.

Viss pivottabellen inneheld ein einaste resultatverdi som oppfyller alle vilkåra, eller eit resultat for delsummar som summerer alle passande verdiar, vert det resultatet returnert. Viss det ikkje finst passande verdiar eller det finst fleire utan delsum, vert det returnert ei feilmelding. Desse vilkåra gjeld for resultat som er tekne med i pivottabellen.

Viss kjeldedata inneheld element som er gøymde som følgje av innstillingane for pivottabellen, vert desse ignorerte. Rekkjefølgja på felt og element er ikkje viktig. Namn på felt og element skil ikkje mellom store og små bokstavar.

Viss det ikkje er sett avgrensingar for eit sidefelt, vert den markerte verdien brukt implisitt. Viss avgrensinga for eit felt er oppgjeve, må dette stemma med den markerte verdien i feltet. Dersom dette ikkje er tilfelle, vert det returnert ei feilmelding. Filter er felta oppe til venstre i ein pivottabell, bestemt av området «Filter» i dialogvindauget for utforming av pivottabellen. For kvart filterfelt kan du markera eit element (ein verdi) som berre betyr at feltet skal vera med i utrekningane.

Verdiar frå delsummar frå pivottabellen vert berre brukte viss funksjonen «auto» er brukt. (Bortsett frå når dei vert nytta i vilkåret, sjå andre syntaks nedanfor).

Andre syntaks

pivottabell har den same meininga som ved første syntaks.

Avgrensingar er ei mellomromsseparert liste. Heile strengen må vera innskriven mellom doble hermeteikn (" ") viss du ikkje refererer til tekststrengen frå ei anna celle. Kvart element kan vera mellom enkle hermeteikn (' ').

Ei av innskrivingane kan vera namnet på datafeltet. Namnet på datafeltet kan sløyfast berre viss pivottabellen inneheld berre eitt datafelt.

Kvar av dei andre innskrivingane spesifiserer eit vilkår på forma Felt[Element] (med teiknmaska [ og ]), eller berre Element viss elementnamnet er brukt berre ein gong i alle felta som er brukte i pivottabellen.

Eit funksjonsnamn kan leggjast til på forma Felt[element;funksjon], som gjer at kriteria berre passar på delsumverdiar som nyttar denne funksjonen. Moglege funksjonsnamn er Summer, Tall, Middel, Maks, Min, Produkt, Tal (berre tal), Stdav (utval), Stdavp (populasjon), Varians (utval) og Variansp (populasjon). Systemet skil ikkje mellom små og store bokstavar.

HYPERLENKJE (HYPERLINK på engelsk)

Når du trykkjer på ei celle som inneheld HYPERLENKJE-funksjonen, vert hyperlenkja opna.

Viss du brukar den valfrie parameteren celleverdi, vil formelen finna URL-en (nettadressa) og visa teksten eller talet i «celletekst».

HYPERLENKJE("URL" [; Celleverdi])

URL er lenkjemålet. Den valfrie parameteren celleverdi er den teksten eller det talet som vert vist i cella og som vert returnert som resultatet. Viss parameteren celleverdi ikkje er utfylt, vert parameteren URL vist i celleteksten og vert returnert som resultatet.

Talet 0 vert returnert for tomme celler og matriselement.

=HYPERLENKJE("http://www.eksempel.org") viser teksten "http://www.eksempel.org" i cella og opnar hyperlenkja http://www.eksempel.org når du trykkjer på cella.

=HYPERLENKJE("http://www.eksempel.org";"Trykk her") viser teksten «Trykk her» i cella og opnar hyperlenkja http://www.eksempel.org når det vert trykt på cella.

=HYPERLINJKE("http://www.eksempel.org";12345) viser talet 12345 og opnar hyperlenkja http://www.eksempel.org når det vert trykt på cella.

=HYPERLENKJE($B4) der celle B4 inneheld http://www.eksempel.org". Funksjonen legg «http://www.eksempel.org» til adressa i hyperlenkjecella og returnerer den same teksten som vert brukt som formelresultat.

=HYPERLENKJE("http://www."; "Trykk ") & "eksempel.org" viser teksten «Trykk eksempel.org» i cella og opnar hyperlenkja http://www.eksempel.org når det vert trykt på cella.

=HYPERLENKJE("#Ark1.A1";"Gå til toppen") viser teksten «Gå til toppen» og går til cella Ark1.A1 i dette dokumentet.

=HYPERLENKJE("file:///C:/writer.odt#Spesifikasjon";"Gå til Writer-bokmerke") viser teksten «Gå til Writer-bokmerke», lastar inn det aktuelle tekstdokumentet og hoppar til bokmerket "Spesifikasjon".

=HYPERLENKJE("file:///C:/Documents/";"Opna dokumentmappa") viser teksten «Opna dokumentmappa» og viser innhaldet i mappa ved hjelp av filutforskaren brukt av operativsystemet.

INDEKS (INDEX på engelsk)

INDEX returnerer ein verdi eller ei matrise med verdiar frå eit referanseområde spesifisert med indeksnummer for rader og kolonnar, eller ei matrise med indeksnummer for rader og kolonnar og ein valfri områdeindeks.

INDEX() returnerer ein referanse viss argumentet er éin eller fleire referansar. Når han vert brukt i ei celle på forma =INDEX(), vert referansen løyst og verdiane vert viste. Viss INDEX() vert brukt i argument for andre funksjonar, =FUNCTION(INDEX()...), får funksjonen referansen som vart returnert av INDEX(). Å returnere ein referanse er ulikt å returnera ei matrise med verdiar for funksjonar som handsamar han annleis.

INDEKS(Referanse [; [Rad] [; [Kolonne] [; Område]]])

Referanse er ein referanse som anten er skrive inn direkte eller ved å bruka namnet på eit område. Viss referansen inneheld fleire område, må du skriva referansen eller områdenamnet i parentes eller bruka områdesamankoplingsoperatøren tilde (~) .

Rad (valfri) representerer radnummeret eller indeksen for rada i referanseområdet som skal returnerast som ein verdi. Viss denne er null eller manglar (inga spesifikk rad), vert alle dei refererte radene returnerte.

Kolonne (valfri) representerer kolonnenummeret eller indeksen til referanseområdet som skal returnerast som ein verdi. Viss denne er sett til null eller manglar (ingen spesifikk kolonne), vert alle dei refererte kolonnane returnerte.

Område (valfri) svarar til indeksen for underområdet som refererer til fleire område. Standard er 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} returnerer to-rads matrise med 7 og 1. Radindeksen {2;1} hentar rad 2 og så rad 1. Kolonneindeksen 1 hentar den første kolonnen.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} returnerer ei matrise med 4 rader og 2 kolonnar. Matrisa med radindeksar {1;2;3;4} hentar radene 3 til 6 og {3;1} hentar den tredje (F) og første kolonnen (D). Kolonne 1 og 3 i kjeldereferansen vert byt ut i den resulterande matrisa.

=INDEKS(Prisar;4;1) returnerer verdien frå rad 4 og kolonne 1 av databaseområdet definert i Data → Definer område som Prisar.

=INDEKS(SumX; 4; 1) returnerer verdien frå området SumX i rad 4 og kolonne 1 som definert i Set inn → Namn → Skriv inn.

{=INDEX(A1:B6;1)} returnerer verdien av den første rada i A1:B6. Skriv inn formelen som ein matriseformel.

{=INDEX(A1:B6;0;1)} returnerer verdien av den første kolonnen i A1:B6. Skriv inn formelen som ein matriseformel.

=INDEKS(A1:B6;1;1) returnerer verdien øvst i det venstre hjørnet av området A1:B6.

=INDEX((A1:B6;C1:D6);0;0;2)} returnerer verdiane til det andre området C1:D6 i multippelområdet. Skriv inn formelen som ein matriseformel.

INDIREKTE (INDIRECT på engelsk)

Returnerer referansen som er oppgjeve ved ein tekststreng. Du kan òg bruka denne funksjonen til å finna område til ein samsvarande streng.

INDIREKTE(Referanse[; A1])

Referanse representerer ein referanse til ei celle eller eit område (i tekstform) som verdien skal returnerast frå.

A1 (valfri) – viss sett til 0, vert notasjonen R1C1 brukt. Viss parameteren manglar eller er sett til ein annan verdi enn 0, vert notasjonen A1 brukt.

=INDIREKTE(A1) er lik 100 viss A1 inneheld C108 som ein referanse og celle C108 inneheld verdien 100.

=SUMMER(INDIREKTE("A1:" & ADRESSE(1;3))) summerer cellene i området frå A1 til den cella som er definert ved rad 1 og kolonne 3. Det vil seia at A1:C1 er oppsummert.

KOLONNAR (COLUMNS på engelsk)

Returnerer talet på kolonnar i den oppgjevne referansen.

KOLONNAR(Matrise)

Matrise er referansen til eit celleområde der det totale talet på kolonnar finst. Argumentet kan også vera ei enkelt celle.

=KOLONNAR(B5) returnerer 1 fordi ei celle inneheld berre ein enkelt kolonne.

=KOLONNER(A1:C5) er lik 3. Referansen omfattar tre kolonnar.

=KOLONNAR(Kanin) Returnerer 2 viss Kanin er det namngjevne området (C1:D3).

KOLONNE (COLUMN på engelsk)

Returnerer kolonnenummeret i ein cellereferanse. Viss referansen er ei celle, vert kolonnenummeret for cella returnert. Viss parameteren er eit celleområde, vert det tilsvarande kolonnenumeret i ei enkeltrekkje-matrise viss formelen er skriven inn som ein matriseformel. Viss funksjonen KOLONNE med eit område som referanseparameter ikkje er brukt til ein matriseformel, vert kolonnetalet bestemt berre for den første cella i området.

KOLONNE([Referanse])

Referanse er referansen til ei celle eller eit celleområde som det første kolonnenummeret skal finnast i.

Viss det ikkje vert skrive inn referanse, vert kolonnenummeret for cella som formelen er skrive inn i funne.LibreOffice Calc set automatisk referansen til den gjeldande cella.

=KOLONNE(A1) er lik 1. Kolonne A er den første kolonnen i tabellen.

=KOLONNE(C3:E3) er lik 3. Kolonne C er den tredje kolonnen i tabellen.

=KOLONNE(D3:G10) returnerer 4, fordi kolonne D er den fjerde kolonnen i tabellen, og KOLONNE-funksjonen ikkje er brukt som ein matriseformel. (I dette tilfellet vil den første verdien i matrisa alltid verta brukt som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) returnerer begge 2 fordi referansen berre inneheld kolonne B som den andre kolonnen i tabellen. Fordi enkelt-kolonneområde berre har eitt kolonnenummer, gjer det ingen skilnad om formelen vert brukt som ein matriseformel eller ei.

==KOLONNE() returnerer 3 viss formelen vart skriven i kolonne C.

{=KOLONNE(Kanin)} returnerer enkeltradmatrisen (3; 4) viss «Kanin» er det namngjevne området (C1:D3).

OMRÅDE (AREAS på engelsk)

Returnerer talet på individuelle område som er med i eit samansett område. Eit dataområde kan vera både ei enkeltcelle og eit samanhengande celleområde.

Funksjonen krev eitt enkelt argument. Viss du skriv inn fleire område, må du setja dei i eigne parentesar. Du kan skrive inn fleire område ved å skilja dei med semikolon (;), men desse vert automatisk omgjort til tilde (~). Tilde vert brukt for å slå saman område.

OMRÅDE(Referanse)

Referanse representerer referansen til ei celle eller eit celleområde.

=OMRÅDE(A1:B3;F2;G1) returnerer 3, fordi det er ein referanse til tre celler og/eller celleområde. Etter innskrivinga vert det konvertert til = OMRÅDE((A1:B3~F2~G1)).

=OMRÅDE(Alt) returnerer 1, viss du har definert eit område med namnet Alt under Data → Definer område.

RAD

Returnerer radnummeret til ein cellereferanse. Dersom referansen er ei celle, vert radnummeret for cella gjeve, dersom parameteren er eit celleområde vert dei tilsvarande radnumra gjeve i ei ein-kolonnes matrise dersom formelen er skriven inn som ein matriseformel. Dersom RAD-funksjonen med ein områdereferansepeikar ikkje vert brukt i ein matriseformel, vert radnummeret til den første cella i området returnert.

RAD(Referanse)

Referanse er ei celle, eit område eller namnet på eit område.

Viss du ikkje gjev ein referanse, vert radnummeret for cella som formelen er skrive inn i brukt.LibreOffice Calc set automatisk referansen til den gjeldande cella.

RAD(B3) returnerer 3 fordi referansen viser til den tredje rada i tabellen.

{=RAD(D5:D8)} returnerer matrisa med enkeltkolonnen (5, 6, 7, 8) fordi den gjevne referansen inneheld radene 5 til 8.

=RAD(D5:D8) returnerer 5 fordi RAD-funksjonen ikkje er brukt som matriseformel og berre nummeret på den første rada i referansen vert returnert.

{=RAD(A1:E1)} og =RAD(A1:E1) returnerer begge 1 fordi referansen indeheld berre rad 1 som den første rada i tabellen. (Fordi område med enkeltrader berre har eitt radnummer, gjer det ingen skilnad om formelen er brukt som matriseformel eller ei).

=RAD() returnerer 3 viss formelen vart skriven inn i rad 3.

{=RAD(Kanin)} returnerer matrisa med enkeltkolonnen (1, 2, 3) viss «Kanin» er det namngjevne området (C1:D3).

RADER (ROWS på engelsk)

Returnerer talet på rader i ein referanse eller tabell.

RADER(Matrise)

Matrise er referansen eller det namngjevne området som det totale talet på rader skal fastsetjast for.

=Rader(B5) returnerer 1, fordi ei celle inneheld berre éi rad.

=RADER(A10;B12) returnerer 3.

=RADER(Kanin) returnerer 3, viss «Kanin» er det namngjevne området (C1:D3).

SAMANLIKNA (MATCH på engelsk)

Returnerer den relative posisjonen til eit element i ein tabell, der elementet svarar til ein viss verdi. Gjev posisjonen til verdien funnen i søkjetabellen som eit tal.

SAMANLIKNA(Søk; Søkjetabell[; Type])

Søk er den verdien det skal søkjast etter i matrisa bygd opp av ei rad eller ein kolonne.

Søkjetabell er referansen som det skal søkjast i. Ein søkjetabell kan vera ei einskild rad eller ein einskild kolonne eller ein del av desse.

Type kan ha verdiane 1, 0 eller -1. Viss Type = 1 eller viss denne valfrie parameteren manglar, går ein ut frå at den første kolonnen i søkjeområdet er sortert i stigande rekkjefølgje. Med Type = -1 går ein ut frå at kolonnen er sortert i fallande rekkjefølgje. Dette svarar til slik det vert gjort i Microsoft Excel.

Viss Type = 0, vil berre identiske resultat verta funne. Viss søkekriteriet finst fleire stadar, vil berre det første funnet verta returnert. Det er berre med Type = 0 at du kan leita etter regulære uttrykk (dersom slått på i innstillingane for utrekning) eller jokerteikn (dersom slått på i innstillingane for utrekning).

Viss Type = 1 eller den tredje parameteren manglar, vert den siste verdien som er mindre eller lik søkekriteriet returnert. For Type = -1 vert den første verdien som er større eller lik returnert.

=SAMANLIKNA(200;D1:D100) søkjer i området D1:D100, som er sortert etter kolonne D, etter verdien 200. Så snart denne verdien er nådd, vert radnummeret der verdien vart funne returnert. Viss ein høgare verdi vart funnen i søket i kolonnen, vert radnummeret for den førre rada returnert.

SLÅ.OPP (LOOKUP på engelsk)

Returnerer innhaldet av ei celle anten frå eit område med ei rad eller ein kolonne. Du kan også returnera den tildelte verdien, med den same indeksen, i ein annan kolonne eller ei anna rad. I motsetnad til FINN.RAD og FINN.KOLONNE kan søkje- og resultatvektoren vera på ulike stadar. Dei treng ikkje grensa opp mot kvarandre. Søkjevektoren for SLÅ.OPP må vera sortert i stigande rekkjefølgje, ellers vil søket ikkje returnera eit brukbart resultat.

SLÅ.OPP(Søkjeverdi; Søkjevektor [; Resultatvektor])

Søkjeverdi er den verdien av kva type som helst det skal søkjast etter, skrive inn direkte eller som ein referanse.

Søkjevektor er eit område med 1 rad eller 1 kolonne som det skal søkjast i.

Resultatvektor er eit anna område med 1 rad eller 1 kolonne som resultatet vert henta frå. Resultatet er resultatvektorcella som har same indeks som funnet i søkjevektoren har.

=SLÅ.OPP(A1; D1:D100; F1:F100) søkjer den tilsvarande cella i området D1:D100 for talet du skreiv inn i A1. Indeksen vert bestemt av førekomsten der, for eksempel den 12. cella i dette området. Innhaldet i den 12. cella vert då returnert som verdien av funksjonen (i resultatvektoren).

TAL.PÅ.ARK (SHEETS på engelsk)

Finn arkmengda i ein referanse. Om du ikkje oppgjev nokon parametrar, gjev han arkmengda i dette dokumentet.

TAL.PÅ.ARK([Referanse])

Referanse er referansen til eit ark eller eit område. Denne parameteren er valfri.

=TAL.PÅ.ARK(Ark1.A1:Ark3.G12) returnerer 3 viss Ark1, Ark2 og Ark3 finst i den oppgjevne rekkjefølgja.

VEL (CHOOSE på engelsk)

Brukar eit register for å returnera ein verdi frå ei liste med opp til 30 verdiar.

VEL(Indeks; Verdi1 [; Verdi2 [; … [; Verdi30]]])

Indeks er eIn referanse eller eIt tal mellom 1 og 30, som viser kva verdiar som skal takast frå lista.

Verdi1, Verdi2 … Verdi30 er lista med verdiar skrivne inn som ein referanse til ei celle eller som individuelle verdiar.

=VEL(A1; B1; B2; B3; "I dag"; "I går"; "I morgon") vil for eksempel returnera innhaldet av celle B2 for A1 = 2; for A1 = 4 vil funksjonen returnera teksten "I dag".