Tabellfunksjonar

Dette avsnittet handlar om matrisefunksjonane.

Kva er ei matrise?

Ei matrise er eit samanlenkja celleområde som inneheld verdiar i eit rekneark. Et område av 3 rader og 3 kolonnar er ei 3 × 3 matrise:

	A	B	C	D	E
1	7	31	33
2	95	17	2
3	5	10	50
4

Den minste moglege matrisa er ein 1 x 2 eller 2 x 1 tabell med to naboceller.

Kva er ein matriseformel?

Ein formel der verdiane i kvar celle i eit celleområde vert rekna ut for seg vert kalla ein matriseformel. Skilnaden mellom matriseformlar og andre formlar er at matriseformlane arbeider med fleire verdiar samtidig i staden for ein verdi om gongen.

Ein matriseformel kan ikkje berre arbeida med fleire verdiar på same tid, men kan også returnera fleire verdiar. Resultata frå ein matriseformel er også ei matrise.

For å multiplisera verdiane i kvar celle i matrisa ovanfor med 10, treng du ikkje bruka éin formel for kvar celle eller verdi. I staden kan du bruka éin enkelt matriseformel. Marker eit område på 3 × 3 celler i ein annan del av reknearket, skriv inn formelen =10*A1:C3 og bekreft dette med tastekombinasjonen + Shift + Enter. Resultatet vert ei 3 × 3 matrise der kvar celle i celleområdet (A1:C3) er multiplisert med 10.

I tillegg til multiplikasjon kan du også bruka andre operatorar i referanseområdet (ei matrise). Med LibreOffice Calc kan du leggja saman (+), trekkja frå (-), multiplisera (*), dividera (/), bruka eksponentar (^), føya saman (&) og samanlikna (=, <>, <, >, <=, >=). Operatorane kan brukast på kvar einskild verdi i celleområdet og gjev resultatet tilbake som ei matrise dersom det er brukt ein matriseformel.

Samanlikningsoperatorane brukte i ein matriseformel handsamar tomme celler på same måten som i andre formlar. Altså anten som null eller ein tom streng. Viss for eksempel cellene A1 og A2 er tomme, vil matriseformlane {=A1:A2=""} og {=A1:A2=0} begge returnera ei matrise på 1 kolonne og 2 rader der cellene vil innehalda SANN (eller 1).

Når brukar du matriseformlar?

Bruk matriseformlar viss du må gjenta utrekningar på fleire ulike verdiar. Viss du seinare bestemmer deg for å endra utrekningsmetoden, er det nok å endra matriseformelen. For å leggja til ein matriseformel, kan du merkja heile matriseområdet og deretter gjera dei relevante endringane i matriseformelen.

Matriseformlar er også ein måte å spara plass på når mange verdiar skal reknast ut. Matriseformlane brukar nemleg lite minneplass. I tillegg er matrisene eit viktig verktøy når du skal utføra komplekse formlar fordi du kan ta med mange ulike celleområde i kalkulasjonane. I LibreOffice finst det mange matematiske funksjonar for matriser som for eksempel MMULT-funksjonen for å multiplisera to matriser og funksjonen SUMMERPRODUKT som reknar ut skalarproduktet av to matriser.

Bruk av matriseformlar i LibreOffice Calc

Implisitt skjeringspunkt mellom matriseformlar

Du kan også laga ein «normal» formel der referanseområdet som for eksempel parameter vert gjeve i ein matriseformel. Denne formelen er også kjent som «implisitt skjeringspunkt» av matriseformel. Resultatet vert henta frå fellesmengda av referanseområde og dei radene eller kolonnane som formelen er i. Dersom det ikkje finst skjeringspunkt eller at område ved skjeringspunktet dekker fleire rader eller kolonnar, vert det vist ei #VERDI-melding. Eksempelet viser dette prinsippet:

I eksempelet nedanfor set du matriseformelen i D1:

{=A1:A3 + 100}

Cellene D1, D2, D3 har verdiane 107, 195, 105.

Set inn formelen nedanfor E2, ikkje skriv inn som matriseformel.

=A1:A3 + 100

Cellene E1 og E3 er tomme. Celle E2 har verdien 195. Dette er det implisitte skjeringspunktet mellom matriseformlar.

Set inn formelen nedanfor E4, som i E2.

=A1:A3 + 100

Cella E4 viser #VERDI!. Rada 4 er utføre området A1:A3 for formelen.

Laga matriseformlar

Viss du har laga ein matriseformel ved å bruka funksjonsvegvisaren, må du merkja av i avkryssingsboksen Matrise kvar gong slik at verdiane vert returnerte i ein tabell. Elles vert berre verdien i den øvre, venstre cella i tabellen returnert.

Viss du skriv inn ein matriseformel direkte i ei celle, må du bruka tastekombinasjonen Shift + + Enter i staden for Enter. Formelen vert då gjort om til ein matriseformel.

Bruk av innebygde områdekonstantar i formlar

Calc har støtte for innebygde konstantar av typen matrise/område i formlar. Eit nøsta område er omslutta av krøllparentesar «{» og «}». Elementa kan kvar for seg vera eit tal (også negative), ein logisk konstant (SANN, USANN), eller ein bokstavstreng. Ikkje-konstante uttrykk er ikkje tillatne. Område kan skrivast inn med éi eller fleire rader, og éin eller fleire kolonnar. Alle radene må ha like mange element og alle kolonnane må ha like mange element.

Kva skiljeteikn som vert brukte for å skilje elementa i ein kolonne eller ei rad er avhengig av språklege og lokale innstillingar. På desse hjelpesidene vert semikolon (;) og «pipesymbolet» (|) brukte som skiljeteikn i rader og kolonnar. (I for eksempel engelsk vert komma (,) brukt som skiljeteikn i kolonnar og semikolon (;) vert brukt som skiljeteikn i rader).

Matriser kan ikkje vere nøsta.

Eksempel:

={1;2;3}

Ei matrise med ei rad som inneheld dei tre tala 1, 2 og 3.

For å skriva inn denne matrisekonstanten, merk tre celler i ei rad og skriv inn formelen ={1;2;3}. Merk bruken av krøllparentesar og semikolon. Trykk deretter + Shift + Enter.

={1;2;3|4;5;6}

Ei matrise med to rader og tre verdiar i kvar rad.

={0;1;2|USANN;SANN;"to"}

Ei blanda datamatrise.

=SIN({1;2;3})

Som ein matriseformel vert resultatet av tre SIN-utrekningar levert med argumenta 1, 2, og 3.

Redigering av matriseformlar

1. Vel celleområdet eller matrisa som inneheld matriseformelen. For å velja heile matrisa set du cellemarkøren i matriseområdet og trykkjer på + / der / er divisjonstasten i det numeriske tastaturet.

2. Anten trykk F2 eller plasser peikaren i skrivefeltet. Begge desse handlingane let deg redigera formelen.

3. Når du har gjort endringane, trykk + Shift + Enter.

Sletta matriseformlar

1. Merk celleområdet eller matrisa som inneheld matriseformelen. Du kan merkja heile matrisa ved å setja cellemarkøren inne i matriseområdet og trykkja + / (divisjonsteiknet på det numeriske tastaturet).

2. Trykk på Delete for å sletta matriseinnhaldet, inkludert matriseformelen, eller trykk på Rettetasten for å opna dialogvindauget Slett innhald. Vel Formel eller Slett alt og klikk på OK.

Kopiering av matriseformlar

1. Marker celleområdet eller matrisa som inneheld matriseformelen.

2. Anten trykk F2 eller plasser peikaren i skrivefeltet.

3. Kopier formelen inn i innskrivingsfeltet ved å trykkja + C.

4. Merk celleområdet der du vil setja inn matriseformelen og trykk anten F2 eller plasser peikaren i skrivefeltet.

5. Lim inn formelen ved å trykkja + V i det merkte området og stadfest ved å trykkja + Shift + Enter. Det merkte området inneheld nå matriseformelen.

Justering av eit matriseområde

Vil du redigera resultatområdet, gjer slik:

1. Marker celleområdet eller matrisa som inneheld matriseformelen.

2. Under merkinga, til høgre, vil du sjå du eit lite ikon som du kan bruka til å forstørra eller forminska området ved hjelp av musa.

Du kan laga ein kopi av matriseformelen i det gjevne området ved å halde nede -tasten.

Betinga matriseutrekningar

Ei betinga matriseutrekning er ei matrise eller ein matriseformel som inneheld ein VISS()- eller VEL()-funksjon. Vilkårsargumentet i formelen er ein områdereferanse eller eit matriseresultat.

I eksempelet vert testen >0 i formelen {=VISS(A1:A3>0; "Ja"; "Nei")} brukt på kvar celle i området A1:A3 og resultatet vert kopiert til den tilsvarande cella.

	A	B (formel)	B (resultat)
1	1	{=VISS(A1:A3>0; "Ja"; "Nei")}	ja
2	0	{=VISS(A1:A3>0; "Ja"; "Nei")}	nei
3	1	{=VISS(A1:A3>0; "Ja"; "Nei")}	ja

Desse funksjonane brukar tvungen matrisehandsaming: KORRELASJON, KOVARIANS, PROGNOSE, FTEST, SKJERINGSPUNKT, MDETERM, MINVERS, MMULT, MODUS, PEARSON, SANNSYNLEG, RKVADRAT, STIGINGSTAL, STANDARDFEIL, SUMMERPRODUKT, SUMMERX2MY2, SUMMERX2PY2, SUMMERXMY2 OG TTEST. Dersom du brukar områdereferansar som argument i desse funksjonane, vil funksjonen fungere som matrisefunksjon. Tabellen nedanfor viser eit eksempel på tvungen matrisehandsaming.

	A	B (formel)	B (resultat)	C (tvungen matriseformel)	C (resultat)
1	1	=A1:A2+1	2	=SUMMERPRODUKT(A1:A2+1)	5
2	2	=A1:A2+1	3	=SUMMERPRODUKT(A1:A2+1)	5
3		=A1:A2+1	#VERDI!	=SUMMERPRODUKT(A1:A2+1)	5

FREKVENS (FREQUENCY på engelsk)

Indikerer frekvensfordelinga i ei enkeltkolonnematrise. Funksjonen tel kor mange verdiar det er i matrisa Data som er innføre verdiane gjevne av matrisa Klassar.

FREKVENS(Data; Klassar)

Data representerer referansen til dei verdiane som skal teljast.

Klassar representerer matrisa med grenseverdiane.

I tabellen nedanfor vert usorterte måledata lista i kolonne A. Kolonne B inneheld den øvre grensa som du har skrive inn for dei gruppene der du vil fordela data i kolonne A. Ut i frå grensa skrive inn i B1, gjev FREKVENS-funksjonen talet på målte verdiar mindre enn eller lik 5. Då grensa i B2 er 10, gjev FREKVENS-funksjonen det andre resultatet med talet på målte verdiar som er større enn 5 og mindre enn eller lik 10. Den teksten du skreiv inn i B6, «25», er berre til referanseføremål.

	A	B	C
1	12	5	1
2	8	10	3
3	24	15	2
4	11	20	3
5	5	25	1
6	20	>25	1
7	16
8	9
9	7
10	16
11	33

Marker eit enkelt kolonneområde der frekvensen i høve til klassegrensene skal skrivast inn. Du må markera eitt felt meir enn den øvre grensa for klassen. I dette eksempelet vel du området C1:C6. Hent fram funksjonen FREKVENS i Funksjonsvegvisaren. Skriv inn dataområdet (A1:A11) som Data. Skriv deretter den kolonnen du skreiv inn klassegrensene (B1:B6) i inn i Klassar. Kryss av i boksen Matrise og trykk OK. Du vil nå sjå frekvenstala i området (C1:C6).

Du finn fleire forklaringar øvst på denne sida.

KURVE (LOGEST på engelsk)

Denne funksjonen reknar ut dei innskrivne data som ei eksponentiell regresjonskurve (y=b×m^x).

KURVE(DataY [; DataX [; FunksjonType [; Statsistikk]]])

DataY representerer matrisa med Y-data.

DataX (valfri) representerer matrisa med X-data.

Funksjonstype (valfri). Viss Funksjonstype = 0, vert funksjonar på forma Y = m^X rekna ut. Elles vert funksjonane Y = B*m^X rekna ut.

Statistikk (valfri). Viss Statistikk=0, vert berre regresjonskoeffisienten rekna ut.

I funksjonane i LibreOffice Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein påfølgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

Du finn fleire forklaringar øvst på denne sida.

Sjå RETTLINJE. Derimot vert kvadratsum ikkje returnert.

MDETERM (MDETERM på engelsk)

Returnerer determinanten til ei matrise. Gjev verdien til gjeldande celle. Du treng altså ikkje oppgje eit dataområde for resultata.

MDETERM(Matrise)

Matrise er ei kvadratisk matrise der determinantane er definerte.

Du finn fleire forklaringar øvst på denne sida.

MEINING (MUNIT på engelsk)

Returnerer einskapsmatrisa av ein viss storleik. Einskapsmatrisa er ei firkanta matrise der dei diagonale hovudelementa er 1 og alle andre matriseelement er 0.

MEINING(Dimensjonar)

Dimensjonar viser til storleiken på matriseeininga.

Marker eit kvadratisk område inne i reknearket, for eksempel frå A1 til E5.

Vel funksjonen MEINING utan å fjerne merking av området. Merk avkryssingsfeltet Matrise. Skriv inn den ønskte dimensjonen av einingsmatrisa, i dette tilfellet 5 og trykk på OK.

Du kan også skriv inn formelen =MEINING(5) i den siste cella i det merkte området (E5), og trykkja .

Du vil nå sjå ei einingsmatrise med område A1:E5.

Du finn fleire forklaringar øvst på denne sida.

MINVERS (MINVERSE på engelsk)

Returnerer den inverse matrisa.

MINVERS(Matrise)

Matrise er ei kvadratisk matrise som kan inverterast.

Du finn fleire forklaringar øvst på denne sida.

Marker eit kvadratisk område og vel MINVERS. Merk matrise for utdata, merk Matrise-feltet og trykk på OK.

MMULT (MMULT på engelsk)

Reknar ut matriseproduktet av to matriser. Kolonnemengda i matrise 1 må vera lik radmengda i matrise 2. Ei firkanta matrise har like mange rader som kolonnar.

MMULT(Tabell 1; Tabell 2)

Tabell 1 er den første tabellen brukt i tabellproduktet.

Tabell 2 er den andre tabellen, med like mange rader.

Merk eit kvadratisk område. Vel funksjonen MMULT. Merk tabell 1 og deretter tabell 2. Bruk funksjonsvegvisaren og merk av for Tabell. Trykk OK. Tabellen med utdata vil nå dukka opp i det først merkte området.

RETTLINJE (LINEST på engelsk)

Returnerer ein tabell med statistiske opplysningar for ei rett linje som passar best til eit datasett.

RETTLINJE(data_Y [; data_X [; lineærType [; statsistikk]]])

DataY er eit enkelt rad- eller kolonneområde som bestemmer y-koordinata i eit sett datapunkt.

DataX er eit enkelt tilsvarande rad- eller kolonneområde som spesifiserer x-koordinatane. Viss DataX vert sløyfa, vert standardverdiane 1, 2, 3, ..., n brukte i staden. Viss det er meir enn eitt enkelt sett variablar, kan DataX vera eit område med tilsvarande fleire rader eller kolonnar.

RETTLINJE finn ei rett linje y = a + bx som best passer data ved hjelp av ein lineær regresjon («minste kvadrats» metode). Med meir enn eitt sett variablar, er den rette linja av forma y = a + b1x1 + b2x2 ... + bnxn.

Viss Linjetype er USANN, vert den rette linja tvunge til å bryta gjennom utgangspunktet (konstanten a = 0; y=bx). Dersom denne manglar, vert Linjetype sett til SANN og linja vert ikkje tvunge igjennom nullpunktet.

Viss Statistikkmanglar eller er USANN, vert berre den øvste linja frå statistikktabellen returnert. Viss SANN, vert heile tabellen returnert.

RETTLINJE returnerer ein tabell (matrise) med ein statistikk som nedanfor og må setjast inn som ein matriseformel (for eksempel ved å bruka + Shift + Enter i staden for berre Enter).

I funksjonane i LibreOffice Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein påfølgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

Du finn fleire forklaringar øvst på denne sida.

Denne funksjonen gjev ei matrise og vert handtert på same måten som dei andre matrisefunksjonane. Merk av eit område til svara og deretter funksjonen. Vel DataY. Om du vil, kan du skriva inn andre parametrar. Vel Matrise og trykk på OK.

Dersom Statistikk = 0, vil resultatet i det minste vise skråninga på regresjonslinja og skjeringspunktet med Y-aksen. Dersom Statistikk ikkje er lik 0, vert andre resultat viste.

Andre RETTLINJE-resultat:

Studer desse eksempla:

	A	B	C	D	E	F	G
1	x1	x2	y		RETTLINJE-verdi
2	4	7	100		4,17	-3,48	82,33
3	5	9	105		5,46	10,96	9,35
4	6	11	104		0,87	5,06	#IT
5	7	12	108		13,21	4	#IT
6	8	15	111		675,45	102,26	#IT
7	9	17	120
8	10	19	133

Kolonne A inneheld fleire X1-verdiar, kolonne B fleire X2-verdiar og kolonne C Y-verdiane. Du har alt skrive inn desse verdiane i reknearket. Du har nå sett opp E2:G6 i reknearket og aktivert Funksjonsvegvisaren. For å få funksjonen RETTLINJE til å verke, må du ha merkt av i avkryssingsboksen for Matrise i Funksjonsvegvisaren. Marker deretter dei viste verdiane i reknearket, eller skriv dei direkte inn:

DataY er C2:C8

DataX er A2:B8

Linjetype og Statistikk er begge sette til 1.

Så snart du trykkjer OK, vil LibreOffice Calc fylla ut eksempelet ovanfor med RETTLINJE-verdiar som vist i eksempelet.

Formelen i Formellinja svarer til kvar celle av RETTLINJE-matrisa {=RETTLINJE(C2:C8;A2:B8;1;1)}.

Dette representerer dei utrekna RETTLINJE-verdiane:

E2 og F2: Skråning m på regresjonslinja y=b+m*x for x1- og x2-verdiane. Verdiane er gjevne i omvendt rekkjefølgje. Det vil seie skråninga for x2 i E2 og skråninga for x1 i F2.

G2: Skjeringspunkt b med y-aksen.

E3 og F3: standardavviket for skråningsverdien.

G3: standardavviket for skjeringa.

E4: RKVADRAT

F4: standardavviket for regresjonen kalkulert for Y-verdien.

E5: F-verdien frå variansanalysen.

F5: Fridomsgradene frå variansanalysane.

E6: summen av det kvadrerte avviket på dei estimerte Y-verdiane frå deira lineære middelverdi.

F6: summen av det kvadrerte avviket på dei estimerte Y-verdiane frå dei gjevne Y-verdiane.

Du finn fleire forklaringar øvst på denne sida.

SUMMERPRODUKT (SUMPRODUCT på engelsk)

Multipliserer samsvarande element i dei oppgjevne matrisene og gjev summen av produkta.

SUMMERPRODUKT(Tabell 1[;tabell 2][…;[tabell 255]])

Tabell 1[;tabell 2;][…[tabell 255]] representere tabellar der dei tilsvarande elementa skal multipliserast.

Minst éin tabell må vera ein del av argumentlista. Dersom det berre er éin tabell, vert alle elementa summerte. Er det fleire tabellar, må alle vera like store.

	A	B	C	D
1	2	3	4	5
2	6	7	8	9
3	10	11	12	13

=SUMMERPRODUKT(A1:B3; C1:D3) gjev 397.

Utrekning: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Du kan bruka SUMMERPRODUKT for å rekna ut skalarproduktet av to vektorar.

Du finn fleire forklaringar øvst på denne sida.

SUMMERX2MY2 (SUMX2MY2 på engelsk)

Returnerer summen av differansen mellom kvadrata til korresponderande verdiar i to matriser.

SUMMERX2MY2(MatriseX; MatriseY)

MatriseX er den første matrisa som elementa skal kvadrerast for og leggjast til.

MatriseY er den andre matrisa som elementa skal kvadrerast for og trekkjast frå.

Du finn fleire forklaringar øvst på denne sida.

SUMMERX2PY2 (SUMX2PY2 på engelsk)

Returnerer summen av summen av kvadrata til verdiar som høyrer saman i to matriser.

SUMMERX2PY2(Matrise_X; Matrise_Y)

MatriseX er den første matrisa som elementa skal kvadrerast for og leggjast til.

MatriseY er den andre matrisa. Elementa i denne vert kvadrert og deretter lagt saman.

Du finn fleire forklaringar øvst på denne sida.

SUMMERXMY2 (SUMXMY2 på engelsk)

Legg saman kvadrata av variansen mellom verdiar som høyrer saman i to matriser.

SUMMERXMY2(Matrise_X; Matrise_Y)

MatriseX er den første matrisa. Elementa i denne skal subtraherast og kvadrerast.

MatriseY er den andre matrisa. Elementa i denne skal subtraherast og kvadrerast.

Du finn fleire forklaringar øvst på denne sida.

TRANSPONER (TRANSPOSE på engelsk)

Transponerer radene og kolonnane i ei matrise.

TRANSPONER(Matrise)

Matrise er den matrisa i reknearket som skal transponerast.

Marker det området i reknearket der den transponerte tabellen skal visast. Dersom originaltabellen har n rader og m kolonnar, skal det markerte området ha minst m rader og n kolonnar. Skriv inn formelen direkte, merk originaltabellen og trykk . Brukar du i staden funksjonsvegvisaren, må du hugsa å kryssa av for Matrise. Den transponerte matrisa vert vist i det valde målområdet og er automatisk verna mot endringar.

	A	B	C	D
1	2	3	4	5
2	6	7	8	9

Tabellen ovanfor har to rader og fire kolonnar. For å transponere han, må du merkja fire rader og to kolonnar. Dersom vi går ut frå at du vil transponere tabellen ovanfor til området A7:B10 (4 rader og to kolonnar), må du merkja heile området og skriva inn:

TRANSPONER(A1:D2)

Skriv det inn som matriseformel ved å bruka . Resultatet vert slik:

	A	B
7	2	6
8	3	7
9	4	8
10	5	9

TREND (TREND på engelsk)

Returnerer verdiane langs ein lineær trend.

TREND(DataY [; DataX [; NyDataX [; LineærType]]])

DataY representerer matrisa med Y-data.

DataX (valfri) representerer matrisa med X-data.

NyDataX (valfri) representerer den matrisa av X-data som vert bruk til å rekna ut verdiane på nytt.

Linjetype (Valfri). Viss Linjetype = 0, vert linja rekna ut gjennom nullpunktet. Elles vert forskyvingslinjer også rekna ut. Standardverdien er Linjetype <> 0.

I funksjonane i LibreOffice Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein påfølgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

Du finn fleire forklaringar øvst på denne sida.

Marker reknearkområdet der trenddata skal visast. Vel funksjonen. Skriv inn resultatområdet eller merk det med musa. Merk feltet Matrise. Trykk på OK. Trenddataa, som er rekna ut frå utdataa, vert viste.

VEKST (GROWTH på engelsk)

Reknar ut punkta i ein eksponensiell trend i ei matrise.

VEKST(DataY [; DataX [; NyDataX [; FunksjonType]]])

DataY representerer matrisa med Y-data.

DataX (valfri) representerer matrisa med X-data.

NyeDataX (valfri) representerer den matrisa med X-data der verdiane vert rekna ut på nytt.

Funksjonstype (valfri). Viss funksjonstype = 0 vert funksjonar på forma y = m^x rekna ut, elles vert funksjonar på forma y = b*m^X rekna ut.

I funksjonane i LibreOffice Calc kan ein utelata parametrar som er merkte som valfrie viss det ikkje kjem ein påfølgjande parameter. For eksempel kan du utelata parameter 4 eller parameter 3 og 4 i ein funksjon med fire parametrar, der dei siste to parametrane er merkte som valfrie, men du kan ikkje utelata berre parameter 3.

Du finn fleire forklaringar øvst på denne sida.

Denne funksjonen gjev ei matrise og vert handtert på same måten som andre matrisefunksjonar. Merk det området der du ønskjer at svaret skal visast og vel funksjonen Marker DataY. Skriv inn eventuelle andre parameter, merk av for Matrise og trykk på OK.