GEMIDDELDE.ALS-functie

Geeft het rekenkundig gemiddelde van alle cellen in een bereik die voldoen aan meerdere opgegeven criteria . De GEMIDDELDEN.ALS-functie telt alle resultaten die overeenkomen met de logische tests op en deelt dit totaal door het aantal geselecteerde waarden.

tip

Deze functie is beschikbaar sinds LibreOffice 4.0.


Syntaxis

GEMIDDELDEN.ALS(Func_Bereik; Bereik1; Criterium[; Bereik2; Criterium2][; … ; [Bereik127; Criterium127]])

Functiebereik – vereist argument. Het is een reeks cellen, een naam van een benoemd bereik of een label van een kolom of een rij met waarden, voor de berekening van het gemiddelde.

Bereik 1 – vereist argument. Het is een celbereik, een naam van een benoemd bereik of een label van een kolom of rij waarop het overeenkomstige criterium moet worden toegepast.

Criterium: Een criterium is een enkele cel Referentie, Getal of Tekst. Het wordt gebruikt in vergelijkingen met celinhoud.

Een verwijzing naar een lege cel wordt geïnterpreteerd als de numerieke waarde 0.

Een overeenkomende uitdrukking kan zijn:

Bereik2 – Optioneel. Bereik2 en alle volgende hebben dezelfde betekenis als Bereik1.

Criterium2 – Optioneel. Criterium2 en alle volgende betekenen hetzelfde als Criterium.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" Invoeren, bijvoorbeeld om de eerste locatie van "all" te zoeken, gevolgd door willekeurige tekens. Als u naar een tekst wilt zoeken die ook een reguliere expressie is, moet u elk teken vooraf laten gaan met een "\" -teken of de tekst tussen \ Q ... \ E. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in - LibreOffice Calc - Berekenen.

warning

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".


Functiebereik enBereik1, Bereik2... moeten hetzelfde formaat hebben, anders geeft de functie fout:502 - Ongeldig argument.

note

De logische relatie tussen criteria kan worden gedefinieerd als logische EN (conjunctie). Met andere woorden, als en alleen als aan alle gegeven criteria is voldaan, wordt een waarde uit de overeenkomstige cel van de gegeven Functiebereik in de berekening meegenomen.


De functie kan maximaal 255 argumenten bevatten, wat betekent dat u 127 bereiken en voorwaarden kunt opgeven.

Als een cel WAAR bevat, wordt het behandeld als 1, als een cel ONWAAR bevat als 0 (nul).

note

Deze functie maakt deel uit van het Open Document Format voor Office Applications (OpenDocument) standaard versie 1.2. (ISO/IEC 26300: 2-2015)


Voorbeeld

Overweeg de volgende tabel

A

B

C

1

Productnaam

Verkopen

Ontvangsten

2

potlood

20

65

3

pen

35

85

4

kladblok

20

190

5

boek

17

180

6

etui

niet

niet


warning

In alle onderstaande voorbeelden, bevatten bereiken voor berekening de rij # 6, die genegeerd wordt omdat deze tekst bevat.


Eenvoudig gebruik

=GEMIDDELDE.ALS(B2:B6;B2:B6;">=20")

Berekent het gemiddelde van de waarden van het bereik B2:B6 die groter of gelijk zijn aan 20. Dit geeft 25, omdat de vijfde rij niet aan het criterium voldoet.

=GEMIDDELDE.ALS(C2:C6;B2:B6;">=20";C2:C6;">70")

Berekent het gemiddelde van de waarden van het bereik C2:C6, die groter zijn dan 70 en overeenkomen met cellen van B2:B6 met waarden groter dan of gelijk aan 20. Dit geeft 137,5, omdat de tweede en vijfde rij niet voldoen aan tenminste één criterium.

Met behulp van reguliere expressies en geneste functies

=GEMIDDELDE.ALS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van de waarden van het bereik C2:C6, die overeenkomen met alle waarden van het bereik B2 B6 behalve de kleinste en de grootste. Dit geeft 127,5, omdat de derde en vijfde rij niet voldoen aan tenminste één criterium.

=GEMIDDELDE.ALS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van de waarden van het bereik C2:C6, die overeenkomen met alle cellen van het bereik A2: A6, die beginnen met "pen" en alle cellen van het bereik B2:B6 behalve de grootste. Dit geeft 65, want alleen tweede rij voldoet aan alle criteria.

Refereer naar een cel als een criterium

Als u een criterium gemakkelijk moet kunnen veranderen, kunt u dit in een aparte cel opvoeren en gebruik maken van een verwijzing naar deze cel in de voorwaarde van de GEMIDDELDE.ALS-functie. De bovenstaande functie kan bijvoorbeeld als volgt worden herschreven:

=GEMIDDELDE.ALS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Als E2 = pen, geeft de functie 65, omdat de koppeling naar de cel wordt vervangen met de inhoud ervan.

Open bestand met voorbeeld:

Help ons, alstublieft!