Financiële functies, deel twee

Terug naar Financiële functies - Deel een

Verder naar financiële functies. deel drie

AANG.DUUR

Berekent de gewijzigde Macauley-looptijd van een obligatie in jaren.

AANG.DUUR(Aankoopdatum; Vervaldatum; Nominale rente; Rendement; Frequentie ; Soort jaar (optioneel))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Nominale rente is de jaarlijkse nominale rentekoers (coupon rentekoers).

Rendement is de jaarlijkse opbrengst van het waardepapier.

Frequentie is het aantal rentebetalingen per jaar (1, 2 of 4).

Een waardepapier is gekocht op 1-1-2001; de vervaldatum is 1-1-2006. Het nominale rentepercentage is 8%. Het rendement is 9,0%. Rente wordt halfjaarlijks betaald (frequentie is 2). Wat is de gewijzigde looptijd volgens de dagelijkse balansrente berekening (basis 3)?

=AANG.DUUR("2001-01-01"; "2006-01-01"; 0,08; 0,09; 2; 3) returns 4,02 jaar.

BET

Geeft als resultaat de periodieke betaling voor een annuïteit met constant rentepercentage.

BET(Tarief; APER; HW [ ; [ TW ] [ ; Type ] ]) BET(Tarief; Aantal perioden; Huidige waarde ; Toekomstige waarde (optioneel) ; Type (optioneel)])

Tarief is het periodieke rentepercentage.

Aantal perioden is het totale aantal perioden gedurende welke terugkerende betalingen worden verricht.

Huidige waarde is de huidige geldwaarde op dit moment in een reeks van betalingen.

Toekomstige waarde (optioneel) is de gewenste waarde (toekomstige waarde) aan het einde van de periodieke betalingen.

Type (optioneel) is de betaaldatum voor de periodieke betalingen. Type=1 is betaling aan het begin en Type=0 is betaling aan het einde van elke periode.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

Wat zijn de periodieke betalingen bij een rentepercentage van 1,99% als de betalingsperiode 3 jaar is en de contante geldswaarde 25000 valuta-eenheden is. Er zijn 36 maanden als 36 betalingsperioden, en de rentekoers per betalingsperiode is 1.99%/12.

=BET(1,99%/12;36;25000) = -715,96 valuta-eenheden. De periodieke maandelijkse betaling is daarom 715,96 valuta-eenheden.

CUM.HOOFDSOM

Berekent het cumulatieve kapitaal dat in een investeringsperiode met vast rentepercentage wordt terugbetaald.

CUM.HOOFDSOM(Tarief; Aantal perioden; Huidige waarde; Begintermijn; Eindtermijn; Type)

Tarief is het periodieke rentepercentage.

Aantal perioden is de betalingsperiode met het totale aantal perioden. Aantal perioden kan ook een niet-geheel getal-waarde zijn.

Huidige waarde is de huidige waarde in de reeks van betalingen.

Begintermijn is de eerste periode.

Eindtermijn is de laatste periode.

Type is de vervaldatum van de betaling aan het begin of einde van elke periode.

Wat zijn de afbetalingsbedragen als het rentepercentage 5,5% is gedurende 36 termijnen. De contante geldswaarde is 15000 valuta-eenheden. Het afbetalingsbedrag wordt berekend tussen de 10e en 18e periode. Betaling vindt plaats aan het eind van de termijn.

=CUM.RENTE_ADD(5,5%/12;36;15000;10;18;0) = -3669,74 valuta-eenheden. Het aflossingsbedrag tussen de 10e en 18e periode is 3669,74 valuta-eenheden.

CUM.HOOFDSOM_ADD

Berekent de cumulatieve aflossing van een lening binnen een periode.

CUM.RENTE_ADD(Termijn; Aantal perioden; Huidige waarde; Beginperiode; Eindperiode; Type)

Termijn is de rentekoers voor elke periode.

Aantal perioden is het totale aantal betalingsperioden. De koers en NPER moeten verwijzen naar dezelfde eenheid en dus kunnen beide jaarlijks of maandelijks berekend worden.

Huidige waarde is de huidige waarde.

Beginperiode is de eerste betalingsperiode voor de berekening.

EindPeriode is de laatste betalingsperiode voor de berekening.

Type is de betaaldatum van de betaling aan het einde van elke periode (Type = 0) of aan het begin van de periode (Type = 1).

De volgende hypotheek wordt genomen op een huis:

Rente: 9,00 procent per jaar (9% / 12 = 0,0075 per maand), Tijdsduur: 30 jaar (betalingstermijnen = 30 * 12 = 360 maanden), NHW: 125000 valuta-eenheden.

Hoeveel zult u moeten terugbetalen in het tweede jaar van de hypotheek (dus van termijn 13 t/m 24)?

=CUM.HOOFDSOM_ADD(0,0075;360;125000;13;24;0) geeft -934,1071 terug.

In de eerste maand zult u het volgende bedrag terugbetalen:

=CUM.HOOFDSOM_ADD(0,0075;360;125000;1;1;0) geeft -68,27827 terug.

CUM.RENTE

Berekent de cumulatieve rentebetalingen, d.w.z. het totale rentebedrag voor een investering op basis van een vast rentepercentage.

CUM.RENTE(Tarief; Aantal perioden; Huidige waarde; Begintermijn; Eindtermijn; Type)

Tarief is het periodieke rentepercentage.

Aantal perioden is de betalingsperiode met het totale aantal perioden. Aantal perioden kan ook een niet-geheel getal-waarde zijn.

Huidige waarde is de huidige waarde in de reeks van betalingen.

Begintermijn is de eerste periode.

Eindtermijn is de laatste periode.

Type is de vervaldatum van de betaling aan het begin of einde van elke periode.

Wat zijn de rentebetalingen bij een periodiek rentepercentage van 5,5 %, een periodieke periode van 2 jaar en een actuele contante geldswaarde van 5.000 valuta-eenheden? De starttermijn is de 4e en de eindtermijn is de 6e termijn. De periodieke betaling wordt aan het begin van elke termijn voldaan.

=CUM.RENTE(5,5%/12;24;5000;4;6;1) = -57,54 valuta-eenheden. De rentebetalingen voor tussen de 4e en 6e periode zijn 57,54 valuta-eenheden.

CUM.RENTE_ADD

Berekent de geaccumuleerde rente voor een periode.

CUM.RENTE_ADD(Termijn; Aantal perioden; Huidige waarde; Beginperiode;Eindperiode; Type)

Termijn is de rentekoers voor elke periode.

Aantal perioden is het totale aantal betalingsperioden. De koers en Aantal perioden moeten verwijzen naar dezelfde eenheid en dus kunnen beide jaarlijks of maandelijks berekend worden.

Huidige waarde is de huidige waarde.

Beginperiode is de eerste betalingsperiode voor de berekening.

EindPeriode is de laatste betalingsperiode voor de berekening.

Type is de betaaldatum van de betaling aan het einde van elke periode (Type = 0) of aan het begin van de periode (Type = 1).

De volgende hypotheek wordt genomen op een huis:

Rente: 9,00 procent per jaar (9% / 12 = 0,0075 per maand), Tijdsduur: 30 jaar (NPER = 30 * 12 = 360 maanden), NHW: 125000 valuta-eenheden.

Hoeveel rente moet u in het tweede jaar van de hypotheek (dus van termijn 13 tot en met 24) betalen?

=CUM.RENTE_ADD(0,0075;360;125000;13;24;0) geeft -11135,23 terug.

Hoe veel rente moet u betalen in de eerste maand?

=CUM.RENTE_ADD(0,0075;360;125000;1;1;0) geeft -937,50 terug.

EURO.BR

Converteert een notering die als een decimaal getal is gegeven, naar een gemengde decimale breuk.

EURO.BR(Decimaal getal; Noemer)

EURO.BR(Decimaal getal; Noemer) is een decimaal getal.

Noemer is een geheel getal dat wordt gebruikt als de noemer van de decimale breuk.

=EURO.BR(1,125;16) converteert naar zestienden. Het resultaat is 1,02 voor 1 plus 2/16.

=EURO.BR(1,125;8) converteert naar achtsten. Het resultaat is 1,1 voor 1 plus 1/8.

EURO.DE

Converteert een notering die als een decimale breuk is gegeven, naar een decimaal getal.

EURO.DE(Breukgetal; Noemer)

BreukEuro is een als een decimale breuk opgegeven getal.

Breukgetal is een als een decimale breuk opgegeven getal

=EURO.DE(1,02;16) staat voor 1 en 2/16e. Dit geeft 1,125 terug.

=EURO.DE(1,1;8) staat voor 1 en 1/8e. Dit geeft 1,125 terug.

GIR

Berekent de gemodificeerde interne rentevoet in een reeks investeringen.

GIR(Waardes; Investering; Herinvesteringsrente)

Waardes correspondeert met de matrix of de celverwijzing voor cellen waarvan de inhoud overeenkomt met de betalingen.

Investering is de rentekoers van de investeringen (de negatieve waarden van de matrix)

HerinvesteringsKoers: de rentekoers van de herinvestering (de positieve waarden van de matrix)

Aannemende dat de celinhoud van A1 = -5, A2 = 10, A3 = 15 en A4 = 8 is en een investeringswaarde van 0,5 en een herinvesteringswaarde van 0,1, is het resultaat 94,16%.

LIN.AFSCHR

Geeft als resultaat de lineaire afschrijving van een bezit in de loop van één periode. Het bedrag van de afschrijving verandert niet gedurende de afschrijvingsperiode.

LIN.AFSCHR(Aanschaffingswaarde; Restwaarde; Nuttige levensduur)

Aanschaffingswaarde is de aanschafprijs van een goed.

Restwaarde is de waarde van een goed aan het eind van de afschrijving.

Nuttige levensduur is de afschrijvingsperiode die het aantal perioden bepaalt voor de afschrijving van het goed.

Kantooruitrusting met een aanvangswaarde van 50.000 valuta-eenheden moet worden afgeschreven in 7 jaar. De waarde aan het einde van de afschrijving wordt geschat op 3.500 valuta-eenheden.

=LIN.AFSCHR(50.000;3.500;84) = 553,57 valuta-eenheden. De periodieke maandelijkse afschrijving voor de kantoorartikelen is 553,57 valuta-eenheden.

NHW

Retourneert de huidige waarde van een investering op basis van een reeks periodieke cashflows en een kortingsvoet. Teneinde de netto huidige waarde te verkrijgen, trekt u de kosten van het project (de eerste cashflow op het tijdstip nul) van de retourwaarde af.

Als de betalingen op regelmatige basis plaatsvinden, gebruikt u functie XNVP.

NHW(Wisselkoers; Waarde 1 ; Waarde 2 (optioneel); ...) Getal 1 [; Getal 2 [; … [; Getal 254]]])

Wisselkoers is de kortingskoers voor een periode.

Wat is de netto contante waarde van periodieke betalingen van 10, 20, 30 en -5 valutaeenheden met een disconteringsvoet van 8,75%. Op tijdstip nul werden de kosten betaald als -40 valutaeenheden.

=NHW(8,75%;10;20;30;-5) = 45,86 munteenheden. De netto contante waarde is de geretourneerde waarde minus de initiële kosten van 40 valutaeenheden, dus 5,86 valutaeenheden.

NOMINALE.RENTE

Berekent het jaarlijkse nominale rentepercentage, bij gegeven effectieve rente en het aantal rentetermijnen per jaar.

NOMINALE.RENTE(Effectieve Rente; Aantal perioden)

Effectieve rente is de effectieve rentekoers

Aantal periodenis het aantal periodieke rentebetalingen per jaar.

Wat is de nominale rente per jaar bij een effectief rentepercentage van 13,5% als twaalf betalingen per jaar worden gedaan.

=NOMINALE.RENTE(13,5%;12) = 12,73%. De nominale rentekoers per jaar is 12,73%.

NOMINALE.RENTE_ADD

Berekent de jaarlijkse nominale rentevoet op basis van de effectieve rente en het aantal rentebetalingen per jaar.

NOMINALE.RENTE_ADD(Effectieve rente; Aantal perioden per jaar)

Effectieve rente is de effectieve jaarlijkse rentekoers.

Aantal perioden per jaaris het aantal rentebetalingen per jaar.

Wat is het nominale rentepercentage voor een 5,3543% effectief rentepercentage en betaling per kwartaal.

=NOMINALE.RENTE_ADD(5,3543%;4) geeft 0,0525 of 5,25% terug.

PBET

Berekent het af te lossen bedrag voor een investering met regelmatige betalingen en een vast rentepercentage.

PBET(Rentepercentage; Periode; Aantal perioden; Huidige waarde ; Toekomstige waarde (optioneel); Type (optioneel ])

Rentepercentage is het periodieke rentepercentage.

Periode is de periode waarover wordt afgeschreven. P = 1 voor de eerste en P = NPer voor de laatste periode.

Aantal perioden is het totale aantal perioden gedurende welke terugkerende betalingen worden verricht.

Huidige waarde is de huidige waarde in de reeks van betalingen.

Toekomstige waarde(optioneel) is de gewenste (toekomstige) waarde.

Type (optioneel) definieert de einddatum. V = 1 voor betaling aan het begin van een periode en V = 0 voor betaling aan het einde van een periode.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

Hoe hoog is de periodieke betaling bij een rentepercentage van 8,75% over een periode van 3 jaar? De contante geldswaarde is 5000 valuta-eenheden. Het moet altijd worden betaald aan het begin van een periode. De toekomstige waarde is 8000 valuta-eenheden.

=PBET(8,75%/12;1;36;5000;8000;1) = -350,99 valuta-eenheden.

PLOOPTIJD

DUUR is een bij de financiële wiskunde behorende functie. Berekent het aantal termijnen dat nodig is om een investering met periodieke rentebetalingen een gewenste waarde te laten bereiken.

PDUUR(Wisselkoers; Huidige waarde; Toekomstige waarde)

Wisselkoers is een constante. De rentekoers moet worden berekend over de gehele looptijd (duurperiode). De rentekoers per periode wordt berekend door de rentekoers te delen door de berekende looptijd. De interne koers voor een vaste uitkering op jaarbasis moet worden ingevoerd als Koers/12.

Huidige waarde is de tegenwoordige (huidige) waarde. De contante waarde is de storting van contanten of de huidige contante waarde in een andere vorm. Als stortingswaarde moet een positieve waarde worden ingevoerd; de storting mag niet 0 of <0 zijn.

Toekomstige waarde is de verwachte waarde. De toekomstige waarde bepaalt de gewenste (toekomstige) waarde van de storting.

Bij een rentepercentage van 4,75%, een contante geldswaarde van 25000 valuta-eenheden en een toekomstige waarde van 1000000 valuta-eenheden wordt een looptijd van 79,49 betalingstermijnen berekend. De periodieke betaling is het resulterende quotiënt van de toekomstige waarde en de looptijd, d.w.z. 1000000/79,49=12850,20.

PRIJS.KORTING

Berekent de prijs per nominale waarde van 100 valuta-eenheden van een niet-rentedragend waardepapier.

PRIJS.DISCONTO(Aankoopdatum; Vervaldatum; Disconto; Aflossingsbedrag ; Soort jaar (optioneel))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Disconto is de korting op een waardepapier als een percentage.

Aflossingsbedrag is de aflossingswaarde per 100 valuta-eenheden van gelijke waarde.

Een waardepapier is gekocht op 15-2-1999; de vervaldatum is 1-3-1999. Kortingspercentage is 5,25%. De aflossingswaarde is 100. Berekend op basis 2 is de kortingsprijs als volgt:

=PRIJS.KORTING("1999-02-15"; "1999-03-01"; 0,0525; 100; 2) returns 99,79583.

PRIJS.NOM

Berekent de marktwaarde van een obligatie in jaren met een nominale waarde van 100 valuta-eenheden als een functie van het voorspelde rendement.

PRIJS.NOM(Aankoopdatum; Vervaldatum; Termijn; Rendement; Aflossingsbedrag; Frequentie ; Soort jaar))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Termijn is de jaarlijkse nominale rentekoers (coupon rentekoers)

Rendement is de jaarlijkse opbrengst van het waardepapier.

Aflossingsbedrag is de aflossingswaarde per 100 valuta-eenheden van gelijke waarde.

Frequentie is het aantal rentebetalingen per jaar (1, 2 of 4).

Een waardepapier is gekocht op 15-2-1999; de vervaldatum is 15-11-2007. Het nominale rentepercentage is 5,75%. Het rendement is 6,5%. De aflossingswaarde is 100 valuta-eenheden. Rente wordt halfjaarlijks betaald (frequentie is 2). Bij berekening op basis 0 is de prijs als volgt:

=PRIJS.NOM("1999-02-15"; "2007-11-15"; 0,0575; 0,065; 100; 2; 0) returns 95,04287.

PRIJS.VERVALDAG

Berekent de prijs per nominale waarde van 100 valuta-eenheden van een waardepapier waarbij op de vervaldatum rente wordt uitbetaald.

PRIJS.VERVALDAG(Aankoopdatum; Vervaldatum; Uitgifte; Termijn; Rendement ; Soort jaar (optioneel))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Uitgifte is de datum van uitgifte van het waardepapier.

Termijn is de rentekoers van het waardepapier op de uitgiftedatum.

Rendement is de jaarlijkse opbrengst van het waardepapier.

Stortingsdatum: 15 Februari 1999, vervaldatum: 13 April 1999, uitgiftedatum: 11 November 1998. Rentepercentage: 6,1 procent, rendement: 6,1 procent, basis: 30/360 = 0.

De koers wordt als volgt berekend:

=PRIJS.VERVALDAG("1999-02-15";"1999-04-13";"1998-11-11"; 0,061; 0,061;0) returns 99,98449888.

REND.KORTING

Berekent het jaarrendement van een niet-rentedragend waardepapier.

REND.DISCONTO(Aankoopdatum; Vervaldatum; Koers; Aflossingsbedrag ; Soort jaar (optioneel))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Koers is de prijs (aankoopprijs) van het waardepapier per 100 valuta-eenheden van gelijke waarde.

Aflossingsbedrag is de aflossingswaarde per 100 valuta-eenheden van gelijke waarde.

Een niet-rentedragend waardepapier is gekocht op 15-2-1999. Het vervalt op 1-3-1999. De koers is 99,795 valuta-eenheden per 100 eenheden van gelijke waarde, de aflossingswaarde is 100 eenheden. De basis is 2. Hoe hoog is het rendement?

=REND.KORTING("1999-02-15"; "1999-03-01"; 99,795; 100; 2) returns 0,052823 of 5,2823 per cent.

REND.VERVAL

Berekent het jaarrendement van een waardepapier, waarvan de rente op de vervaldatum wordt uitbetaald.

REND.VERVAL(Aankoopdatum; Vervaldatum; Uitgifte; Termijn; Koers ; Soort jaar (optioneel))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Uitgifte is de datum van uitgifte van het waardepapier.

Termijn is de rentekoers van het waardepapier op de uitgiftedatum.

Koers is de prijs (aankoopprijs) van het waardepapier per 100 valuta-eenheden van gelijke waarde.

Een waardepapier is gekocht op 15-3-1999. Het vervalt op 3-11-1999. De uitgiftedatum was 8-11-1998. Het rentepercentage is 6,25%, de koers is 100,0123 eenheden. De basis is 0. Hoe hoog is het rendement?

=REND.VERVAL("1999-03-15"; "1999-11-03"; "1998-11-08"; 0,0625; 100,0123; 0) returns 0,060954 of 6,0954 per cent.

RENDEMENT

Berekent het rendement van een waardepapier.

RENDEMENT(Aankoopdatum; Vervaldatum; Termijn; Koers; Aflossingsbedrag; Frequentie ; Soort jaar (optioneel))

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Termijn is de jaarlijkse rentekoers.

Koers is de prijs (aankoopprijs) van het waardepapier per 100 valuta-eenheden van gelijke waarde.

Aflossingsbedrag is de aflossingswaarde per 100 valuta-eenheden van gelijke waarde.

Frequentie is het aantal rentebetalingen per jaar (1, 2 of 4).

Een waardepapier is gekocht op 15-2-1999. Het vervalt op 15-11-2007. Het rentepercentage is 5,75%. De koers is 95,04287 valuta-eenheden per 100 eenheden van gelijke waarde, de aflossingswaarde is 100 eenheden. Rente wordt halfjaarlijks betaald (frequentie = 2) en de basis is 0. Hoe hoog is het rendement?

=RENDEMENT("1999-02-15"; "2007-11-15"; 0,0575 ;95,04287; 100; 2; 0) returns 0,065 of 6,50 per cent.

SCHATK.PRIJS

Berekent de prijs van een schatkistpapier per 100 valuta-eenheden.

SCHATK.PRIJS(Aankoopdatum; Vervaldatum; Discontopercentage)

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Discontopercentage is het kortingspercentage bij het verkrijgen van het waardepapier.

Aankoopdatum: 31 maart 1999, vervaldatum: 1 juni 1999, korting: 9 procent.

De koers van de staatsobligatie wordt als volgt uitgewerkt:

=SCHATK.PRIJS("1999-03-31";"1999-06-01"; 0,09) returns 98,45.

SCHATK.REND

Berekent het rendement van een schatkistpapier.

SCHATK.REND(Aankoopdatum; Vervaldatum; Prijs)

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Prijs is de prijs (aankoopprijs) van de schatkistobligatie per 100 valuta-eenheden van de nominale waarde.

Stortingsdatum: 31 maart 1999, vervaldatum: 1 juni 1999, prijs: 98,45 valuta-eenheden.

Het rendement van de staatsobligatie wordt als volgt uitgewerkt:

=SCHATK.REND("1999-03-31";"1999-06-01"; 98,45) geeft 0,091417 of 9,1417 per cent.

SCHATKIST.OBL

Berekent het jaarlijkse rendement op een schatkistpapier. Een schatkistpapier wordt aangeschaft op de aankoopdatum en verkocht tegen de volledige nominale waarde op de vervaldatum, die in hetzelfde jaar moet vallen. Er wordt een korting van de inkoopprijs afgetrokken.

SCHATK.OBL(Aankoopdatum; Vervaldatum; Discontopercentage)

Aankoopdatum is de datum van aankoop van het waardepapier.

Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).

Discontopercentage is het kortingspercentage bij het verkrijgen van het waardepapier.

Aankoopdatum: 31 maart 1999, vervaldatum: 1 juni 1999, korting: 9,14 procent.

Het rendement van de staatsobligatie of overeenkomstig waardepapier wordt als volgt uitgewerkt:

=SCHATK.OBL("1999-03-31";"1999-06-01"; 0,0914) returns 0,094151 of 9,4151 per cent.

Terug naar Financiële functies - deel één

Verder naar financiële functies. deel drie